@hyperlane-xyz/core 1.2.3 → 1.3.1

package/contracts/libs/middleware/InterchainAccountMessage.sol

@@ -0,0 +1,86 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+import {CallLib} from "../Call.sol";
+import {TypeCasts} from "../TypeCasts.sol";
+
+/**
+ * Format of message:
+ * [   0:  32] ICA owner
+ * [  32:  64] ICA ISM
+ * [  64:????] Calls, abi encoded
+ */
+library InterchainAccountMessage {
+    using TypeCasts for bytes32;
+
+    /**
+     * @notice Returns formatted (packed) InterchainAccountMessage
+     * @dev This function should only be used in memory message construction.
+     * @param _owner The owner of the interchain account
+     * @param _ism The address of the remote ISM
+     * @param _to The address of the contract to call
+     * @param _value The value to include in the call
+     * @param _data The calldata
+     * @return Formatted message body
+     */
+    function encode(
+        address _owner,
+        bytes32 _ism,
+        address _to,
+        uint256 _value,
+        bytes memory _data
+    ) internal pure returns (bytes memory) {
+        CallLib.Call[] memory _calls = new CallLib.Call[](1);
+        _calls[0] = CallLib.build(_to, _value, _data);
+        return abi.encode(TypeCasts.addressToBytes32(_owner), _ism, _calls);
+    }
+
+    /**
+     * @notice Returns formatted (packed) InterchainAccountMessage
+     * @dev This function should only be used in memory message construction.
+     * @param _owner The owner of the interchain account
+     * @param _ism The address of the remote ISM
+     * @param _calls The sequence of calls to make
+     * @return Formatted message body
+     */
+    function encode(
+        bytes32 _owner,
+        bytes32 _ism,
+        CallLib.Call[] calldata _calls
+    ) internal pure returns (bytes memory) {
+        return abi.encode(_owner, _ism, _calls);
+    }
+
+    /**
+     * @notice Returns formatted (packed) InterchainAccountMessage
+     * @dev This function should only be used in memory message construction.
+     * @param _owner The owner of the interchain account
+     * @param _ism The address of the remote ISM
+     * @param _calls The sequence of calls to make
+     * @return Formatted message body
+     */
+    function encode(
+        address _owner,
+        bytes32 _ism,
+        CallLib.Call[] calldata _calls
+    ) internal pure returns (bytes memory) {
+        return encode(TypeCasts.addressToBytes32(_owner), _ism, _calls);
+    }
+
+    /**
+     * @notice Parses and returns the calls from the provided message
+     * @param _message The interchain account message
+     * @return The array of calls
+     */
+    function decode(bytes calldata _message)
+        internal
+        pure
+        returns (
+            bytes32,
+            bytes32,
+            CallLib.Call[] memory
+        )
+    {
+        return abi.decode(_message, (bytes32, bytes32, CallLib.Call[]));
+    }
+}

package/contracts/libs/middleware/InterchainQueryMessage.sol

@@ -0,0 +1,125 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.13;
+
+import {CallLib} from "../Call.sol";
+
+/**
+ * Format of message:
+ * [   0: 32] Sender address
+ * [  32: 64] Message type (left padded with zeroes)
+ * [  64:???] Encoded call array
+ */
+library InterchainQueryMessage {
+    uint256 private constant SENDER_OFFSET = 0;
+    uint256 private constant TYPE_OFFSET = 32;
+    uint256 private constant CALLS_OFFSET = 64;
+
+    enum MessageType {
+        QUERY,
+        RESPONSE
+    }
+
+    /**
+     * @notice Parses and returns the query sender from the provided message
+     * @param _message The interchain query message
+     * @return The query sender as bytes32
+     */
+    function sender(bytes calldata _message) internal pure returns (bytes32) {
+        return bytes32(_message[SENDER_OFFSET:TYPE_OFFSET]);
+    }
+
+    /**
+     * @notice Parses and returns the message type from the provided message
+     * @param _message The interchain query message
+     * @return The message type (query or response)
+     */
+    function messageType(bytes calldata _message)
+        internal
+        pure
+        returns (MessageType)
+    {
+        // left padded with zeroes
+        return MessageType(uint8(bytes1(_message[CALLS_OFFSET - 1])));
+    }
+
+    /**
+     * @notice Returns formatted InterchainQueryMessage, type == QUERY
+     * @param _sender The query sender as bytes32
+     * @param _calls The sequence of queries to make, with the corresponding
+     * response callbacks
+     * @return Formatted message body
+     */
+    function encode(
+        bytes32 _sender,
+        CallLib.StaticCallWithCallback[] calldata _calls
+    ) internal pure returns (bytes memory) {
+        return abi.encode(_sender, MessageType.QUERY, _calls);
+    }
+
+    /**
+     * @notice Returns formatted InterchainQueryMessage, type == QUERY
+     * @param _sender The query sender as bytes32
+     * @param _to The address of the contract to query
+     * @param _data The calldata encoding the query
+     * @param _callback The calldata of the callback that will be made on the sender.
+     * The return value of the query will be appended.
+     * @return Formatted message body
+     */
+    function encode(
+        bytes32 _sender,
+        address _to,
+        bytes memory _data,
+        bytes memory _callback
+    ) internal pure returns (bytes memory) {
+        CallLib.StaticCallWithCallback[]
+            memory _calls = new CallLib.StaticCallWithCallback[](1);
+        _calls[0] = CallLib.build(_to, _data, _callback);
+        return abi.encode(_sender, MessageType.QUERY, _calls);
+    }
+
+    /**
+     * @notice Parses and returns the calls and callbacks from the message
+     * @param _message The interchain query message, type == QUERY
+     * @return _calls The sequence of queries to make with the corresponding
+     * response callbacks
+     */
+    function callsWithCallbacks(bytes calldata _message)
+        internal
+        pure
+        returns (CallLib.StaticCallWithCallback[] memory _calls)
+    {
+        assert(messageType(_message) == MessageType.QUERY);
+        (, , _calls) = abi.decode(
+            _message,
+            (bytes32, MessageType, CallLib.StaticCallWithCallback[])
+        );
+    }
+
+    /**
+     * @notice Returns formatted InterchainQueryMessage, type == RESPONSE
+     * @param _sender The query sender as bytes32
+     * @param _calls The sequence of callbacks to make
+     * @return Formatted message body
+     */
+    function encode(bytes32 _sender, bytes[] memory _calls)
+        internal
+        pure
+        returns (bytes memory)
+    {
+        return abi.encode(_sender, MessageType.RESPONSE, _calls);
+    }
+
+    /**
+     * @notice Parses and returns the callbacks from the message
+     * @param _message The interchain query message, type == RESPONSE
+     * @return _calls The sequence of callbacks to make
+     */
+    function rawCalls(bytes calldata _message)
+        internal
+        pure
+        returns (bytes[] memory _calls)
+    {
+        assert(messageType(_message) == MessageType.RESPONSE);
+        (, , _calls) = abi.decode(_message, (bytes32, MessageType, bytes[]));
+    }
+}