@hyperlane-xyz/core 0.5.5 → 1.0.0-beta1

package/contracts/test/MysteryMath.sol

@@ -1,21 +0,0 @@
-// SPDX-License-Identifier: MIT
-
-pragma solidity >=0.8.0;
-
-abstract contract MysteryMath {
-    uint256 public stateVar;
-
-    function setState(uint256 _var) external {
-        stateVar = _var;
-    }
-
-    function getState() external view returns (uint256) {
-        return stateVar;
-    }
-
-    function doMath(uint256 a, uint256 b)
-        external
-        pure
-        virtual
-        returns (uint256 _result);
-}

package/contracts/test/MysteryMathV1.sol

@@ -1,22 +0,0 @@
-// SPDX-License-Identifier: MIT
-
-pragma solidity >=0.8.0;
-
-import "./MysteryMath.sol";
-
-contract MysteryMathV1 is MysteryMath {
-    uint32 public immutable version;
-
-    constructor() {
-        version = 1;
-    }
-
-    function doMath(uint256 a, uint256 b)
-        external
-        pure
-        override
-        returns (uint256 _result)
-    {
-        _result = a + b;
-    }
-}

package/contracts/test/MysteryMathV2.sol

@@ -1,22 +0,0 @@
-// SPDX-License-Identifier: MIT
-
-pragma solidity >=0.8.0;
-
-import "./MysteryMath.sol";
-
-contract MysteryMathV2 is MysteryMath {
-    uint32 public immutable version;
-
-    constructor() {
-        version = 2;
-    }
-
-    function doMath(uint256 a, uint256 b)
-        external
-        pure
-        override
-        returns (uint256 _result)
-    {
-        _result = a * b;
-    }
-}

package/contracts/test/TestAbacusConnectionClient.sol

@@ -1,23 +0,0 @@
-// SPDX-License-Identifier: MIT OR Apache-2.0
-pragma solidity >=0.6.11;
-import {IOutbox} from "../../interfaces/IOutbox.sol";
-
-import "../AbacusConnectionClient.sol";
-
-contract TestAbacusConnectionClient is AbacusConnectionClient {
-    function initialize(address _abacusConnectionManager) external initializer {
-        __AbacusConnectionClient_initialize(_abacusConnectionManager);
-    }
-
-    function outbox() external view returns (IOutbox) {
-        return _outbox();
-    }
-
-    function isInbox(address _potentialInbox) external view returns (bool) {
-        return _isInbox(_potentialInbox);
-    }
-
-    function localDomain() external view returns (uint32) {
-        return _localDomain();
-    }
-}

package/contracts/test/TestInbox.sol

@@ -1,54 +0,0 @@
-// SPDX-License-Identifier: MIT OR Apache-2.0
-pragma solidity >=0.8.0;
-
-import "../Inbox.sol";
-
-contract TestInbox is Inbox {
-    using Message for bytes32;
-    using TypeCasts for bytes32;
-
-    constructor(uint32 _localDomain) Inbox(_localDomain) {} // solhint-disable-line no-empty-blocks
-
-    function testBranchRoot(
-        bytes32 leaf,
-        bytes32[32] calldata proof,
-        uint256 index
-    ) external pure returns (bytes32) {
-        return MerkleLib.branchRoot(leaf, proof, index);
-    }
-
-    function testProcess(bytes calldata _message, uint256 leafIndex) external {
-        bytes32 _messageHash = keccak256(abi.encodePacked(_message, leafIndex));
-        _process(_message, _messageHash);
-    }
-
-    function testHandle(
-        uint32 origin,
-        bytes32 sender,
-        bytes32 recipient,
-        bytes calldata body
-    ) external {
-        IMessageRecipient(recipient.bytes32ToAddress()).handle(
-            origin,
-            sender,
-            body
-        );
-    }
-
-    function setMessageStatus(bytes32 _leaf, MessageStatus status) external {
-        messages[_leaf] = status;
-    }
-
-    function getRevertMsg(bytes calldata _res)
-        internal
-        pure
-        returns (string memory)
-    {
-        // If the _res length is less than 68, then the transaction failed
-        // silently (without a revert message)
-        if (_res.length < 68) return "Transaction reverted silently";
-
-        // Remove the selector (first 4 bytes) and decode revert string
-        return abi.decode(_res[4:], (string));
-    }
-}

package/contracts/test/TestMultisigValidatorManager.sol

@@ -1,26 +0,0 @@
-// SPDX-License-Identifier: MIT OR Apache-2.0
-pragma solidity >=0.8.0;
-
-import {MultisigValidatorManager} from "../validator-manager/MultisigValidatorManager.sol";
-
-/**
- * This contract exists to test MultisigValidatorManager.sol, which is abstract
- * and cannot be deployed directly.
- */
-contract TestMultisigValidatorManager is MultisigValidatorManager {
-    // solhint-disable-next-line no-empty-blocks
-    constructor(
-        uint32 _domain,
-        address[] memory _validators,
-        uint256 _threshold
-    ) MultisigValidatorManager(_domain, _validators, _threshold) {}
-
-    /**
-     * @notice Hash of domain concatenated with "ABACUS".
-     * @dev This is a public getter of _domainHash to test with.
-     * @param _domain The domain to hash.
-     */
-    function getDomainHash(uint32 _domain) external pure returns (bytes32) {
-        return _domainHash(_domain);
-    }
-}

package/contracts/test/TestOutbox.sol

@@ -1,46 +0,0 @@
-// SPDX-License-Identifier: MIT OR Apache-2.0
-pragma solidity >=0.8.0;
-
-// ============ Internal Imports ============
-import "../Outbox.sol";
-import {MerkleLib} from "../libs/Merkle.sol";
-
-contract TestOutbox is Outbox {
-    constructor(uint32 _localDomain) Outbox(_localDomain) {} // solhint-disable-line no-empty-blocks
-
-    /**
-     * @notice Set the validator manager
-     * @param _validatorManager Address of the validator manager
-     */
-    function testSetValidatorManager(address _validatorManager) external {
-        validatorManager = _validatorManager;
-    }
-
-    function proof() external view returns (bytes32[32] memory) {
-        bytes32[32] memory _zeroes = MerkleLib.zeroHashes();
-        uint256 _index = tree.count - 1;
-        bytes32[32] memory _proof;
-
-        for (uint256 i = 0; i < 32; i++) {
-            uint256 _ithBit = (_index >> i) & 0x01;
-            if (_ithBit == 1) {
-                _proof[i] = tree.branch[i];
-            } else {
-                _proof[i] = _zeroes[i];
-            }
-        }
-        return _proof;
-    }
-
-    function branch() external view returns (bytes32[32] memory) {
-        return tree.branch;
-    }
-
-    function branchRoot(
-        bytes32 _item,
-        bytes32[32] memory _branch,
-        uint256 _index
-    ) external pure returns (bytes32) {
-        return MerkleLib.branchRoot(_item, _branch, _index);
-    }
-}

package/contracts/test/TestValidatorManager.sol

@@ -1,21 +0,0 @@
-// SPDX-License-Identifier: MIT OR Apache-2.0
-pragma solidity >=0.8.0;
-
-import {IInbox} from "../../interfaces/IInbox.sol";
-
-/**
- * Intended for testing Inbox.sol, which requires its validator manager
- * to be a contract.
- */
-contract TestValidatorManager {
-    function process(
-        IInbox _inbox,
-        bytes32 _root,
-        uint256 _index,
-        bytes calldata _message,
-        bytes32[32] calldata _proof,
-        uint256 _leafIndex
-    ) external {
-        _inbox.process(_root, _index, _message, _proof, _leafIndex);
-    }
-}

package/contracts/upgrade/UpgradeBeacon.sol

@@ -1,98 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity >=0.8.0;
-
-// ============ External Imports ============
-import {Address} from "@openzeppelin/contracts/utils/Address.sol";
-
-/**
- * @title UpgradeBeacon
- * @notice Stores the address of an implementation contract
- * and allows a controller to upgrade the implementation address
- * @dev This implementation combines the gas savings of having no function selectors
- * found in 0age's implementation:
- * https://github.com/dharma-eng/dharma-smart-wallet/blob/master/contracts/proxies/smart-wallet/UpgradeBeaconProxyV1.sol
- * With the added niceties of a safety check that each implementation is a contract
- * and an Upgrade event emitted each time the implementation is changed
- * found in OpenZeppelin's implementation:
- * https://github.com/OpenZeppelin/openzeppelin-contracts/blob/master/contracts/proxy/beacon/BeaconProxy.sol
- */
-contract UpgradeBeacon {
-    // ============ Immutables ============
-
-    // The controller is capable of modifying the implementation address
-    address private immutable controller;
-
-    // ============ Private Storage Variables ============
-
-    // The implementation address is held in storage slot zero.
-    address private implementation;
-
-    // ============ Events ============
-
-    // Upgrade event is emitted each time the implementation address is set
-    // (including deployment)
-    event Upgrade(address indexed implementation);
-
-    // ============ Constructor ============
-
-    /**
-     * @notice Validate the initial implementation and store it.
-     * Store the controller immutably.
-     * @param _initialImplementation Address of the initial implementation contract
-     * @param _controller Address of the controller who can upgrade the implementation
-     */
-    constructor(address _initialImplementation, address _controller) payable {
-        _setImplementation(_initialImplementation);
-        controller = _controller;
-    }
-
-    // ============ External Functions ============
-
-    /**
-     * @notice For all callers except the controller, return the current implementation address.
-     * If called by the Controller, update the implementation address
-     * to the address passed in the calldata.
-     * Note: this requires inline assembly because Solidity fallback functions
-     * do not natively take arguments or return values.
-     */
-    fallback() external payable {
-        if (msg.sender != controller) {
-            // if not called by the controller,
-            // load implementation address from storage slot zero
-            // and return it.
-            assembly {
-                mstore(0, sload(0))
-                return(0, 32)
-            }
-        } else {
-            // if called by the controller,
-            // load new implementation address from the first word of the calldata
-            address _newImplementation;
-            assembly {
-                _newImplementation := calldataload(0)
-            }
-            // set the new implementation
-            _setImplementation(_newImplementation);
-        }
-    }
-
-    // ============ Private Functions ============
-
-    /**
-     * @notice Perform checks on the new implementation address
-     * then upgrade the stored implementation.
-     * @param _newImplementation Address of the new implementation contract which will replace the old one
-     */
-    function _setImplementation(address _newImplementation) private {
-        // Require that the new implementation is different from the current one
-        require(implementation != _newImplementation, "!upgrade");
-        // Require that the new implementation is a contract
-        require(
-            Address.isContract(_newImplementation),
-            "implementation !contract"
-        );
-        // set the new implementation
-        implementation = _newImplementation;
-        emit Upgrade(_newImplementation);
-    }
-}

package/contracts/upgrade/UpgradeBeaconController.sol

@@ -1,48 +0,0 @@
-// SPDX-License-Identifier: MIT OR Apache-2.0
-pragma solidity >=0.8.0;
-
-// ============ Internal Imports ============
-import {UpgradeBeacon} from "./UpgradeBeacon.sol";
-// ============ External Imports ============
-import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
-import {Address} from "@openzeppelin/contracts/utils/Address.sol";
-
-/**
- * @title UpgradeBeaconController
- * @notice Set as the controller of UpgradeBeacon contract(s),
- * capable of changing their stored implementation address.
- * @dev This implementation is a minimal version inspired by 0age's implementation:
- * https://github.com/dharma-eng/dharma-smart-wallet/blob/master/contracts/upgradeability/DharmaUpgradeBeaconController.sol
- */
-contract UpgradeBeaconController is Ownable {
-    // ============ Events ============
-
-    event BeaconUpgraded(address indexed beacon, address implementation);
-
-    // ============ External Functions ============
-
-    /**
-     * @notice Modify the implementation stored in the UpgradeBeacon,
-     * which will upgrade the implementation used by all
-     * Proxy contracts using that UpgradeBeacon
-     * @param _beacon Address of the UpgradeBeacon which will be updated
-     * @param _implementation Address of the Implementation contract to upgrade the Beacon to
-     */
-    function upgrade(address _beacon, address _implementation)
-        external
-        onlyOwner
-    {
-        // Require that the beacon is a contract
-        require(Address.isContract(_beacon), "beacon !contract");
-        // Call into beacon and supply address of new implementation to update it.
-        (bool _success, ) = _beacon.call(abi.encode(_implementation));
-        // Revert with message on failure (i.e. if the beacon is somehow incorrect).
-        if (!_success) {
-            assembly {
-                returndatacopy(0, 0, returndatasize())
-                revert(0, returndatasize())
-            }
-        }
-        emit BeaconUpgraded(_beacon, _implementation);
-    }
-}

package/contracts/upgrade/UpgradeBeaconProxy.sol

@@ -1,176 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity >=0.8.0;
-
-// ============ External Imports ============
-import {Address} from "@openzeppelin/contracts/utils/Address.sol";
-
-/**
- * @title UpgradeBeaconProxy
- * @notice
- * Proxy contract which delegates all logic, including initialization,
- * to an implementation contract.
- * The implementation contract is stored within an Upgrade Beacon contract;
- * the implementation contract can be changed by performing an upgrade on the Upgrade Beacon contract.
- * The Upgrade Beacon contract for this Proxy is immutably specified at deployment.
- * @dev This implementation combines the gas savings of keeping the UpgradeBeacon address outside of contract storage
- * found in 0age's implementation:
- * https://github.com/dharma-eng/dharma-smart-wallet/blob/master/contracts/proxies/smart-wallet/UpgradeBeaconProxyV1.sol
- * With the added safety checks that the UpgradeBeacon and implementation are contracts at time of deployment
- * found in OpenZeppelin's implementation:
- * https://github.com/OpenZeppelin/openzeppelin-contracts/blob/master/contracts/proxy/beacon/BeaconProxy.sol
- */
-contract UpgradeBeaconProxy {
-    // ============ Immutables ============
-
-    // Upgrade Beacon address is immutable (therefore not kept in contract storage)
-    address private immutable upgradeBeacon;
-
-    // ============ Constructor ============
-
-    /**
-     * @notice Validate that the Upgrade Beacon is a contract, then set its
-     * address immutably within this contract.
-     * Validate that the implementation is also a contract,
-     * Then call the initialization function defined at the implementation.
-     * The deployment will revert and pass along the
-     * revert reason if the initialization function reverts.
-     * @param _upgradeBeacon Address of the Upgrade Beacon to be stored immutably in the contract
-     * @param _initializationCalldata Calldata supplied when calling the initialization function
-     */
-    constructor(address _upgradeBeacon, bytes memory _initializationCalldata)
-        payable
-    {
-        // Validate the Upgrade Beacon is a contract
-        require(Address.isContract(_upgradeBeacon), "beacon !contract");
-        // set the Upgrade Beacon
-        upgradeBeacon = _upgradeBeacon;
-        // Validate the implementation is a contract
-        address _implementation = _getImplementation(_upgradeBeacon);
-        require(
-            Address.isContract(_implementation),
-            "beacon implementation !contract"
-        );
-        // Call the initialization function on the implementation
-        if (_initializationCalldata.length > 0) {
-            _initialize(_implementation, _initializationCalldata);
-        }
-    }
-
-    // ============ External Functions ============
-
-    /**
-     * @notice Forwards all calls with data to _fallback()
-     * No public functions are declared on the contract, so all calls hit fallback
-     */
-    fallback() external payable {
-        _fallback();
-    }
-
-    /**
-     * @notice Forwards all calls with no data to _fallback()
-     */
-    receive() external payable {
-        _fallback();
-    }
-
-    // ============ Private Functions ============
-
-    /**
-     * @notice Call the initialization function on the implementation
-     * Used at deployment to initialize the proxy
-     * based on the logic for initialization defined at the implementation
-     * @param _implementation - Contract to which the initalization is delegated
-     * @param _initializationCalldata - Calldata supplied when calling the initialization function
-     */
-    function _initialize(
-        address _implementation,
-        bytes memory _initializationCalldata
-    ) private {
-        // Delegatecall into the implementation, supplying initialization calldata.
-        (bool _ok, ) = _implementation.delegatecall(_initializationCalldata);
-        // Revert and include revert data if delegatecall to implementation reverts.
-        if (!_ok) {
-            assembly {
-                returndatacopy(0, 0, returndatasize())
-                revert(0, returndatasize())
-            }
-        }
-    }
-
-    /**
-     * @notice Delegates function calls to the implementation contract returned by the Upgrade Beacon
-     */
-    function _fallback() private {
-        _delegate(_getImplementation());
-    }
-
-    /**
-     * @notice Delegate function execution to the implementation contract
-     * @dev This is a low level function that doesn't return to its internal
-     * call site. It will return whatever is returned by the implementation to the
-     * external caller, reverting and returning the revert data if implementation
-     * reverts.
-     * @param _implementation - Address to which the function execution is delegated
-     */
-    function _delegate(address _implementation) private {
-        assembly {
-            // Copy msg.data. We take full control of memory in this inline assembly
-            // block because it will not return to Solidity code. We overwrite the
-            // Solidity scratch pad at memory position 0.
-            calldatacopy(0, 0, calldatasize())
-            // Delegatecall to the implementation, supplying calldata and gas.
-            // Out and outsize are set to zero - instead, use the return buffer.
-            let result := delegatecall(
-                gas(),
-                _implementation,
-                0,
-                calldatasize(),
-                0,
-                0
-            )
-            // Copy the returned data from the return buffer.
-            returndatacopy(0, 0, returndatasize())
-            switch result
-            // Delegatecall returns 0 on error.
-            case 0 {
-                revert(0, returndatasize())
-            }
-            default {
-                return(0, returndatasize())
-            }
-        }
-    }
-
-    /**
-     * @notice Call the Upgrade Beacon to get the current implementation contract address
-     * @return _implementation Address of the current implementation.
-     */
-    function _getImplementation()
-        private
-        view
-        returns (address _implementation)
-    {
-        _implementation = _getImplementation(upgradeBeacon);
-    }
-
-    /**
-     * @notice Call the Upgrade Beacon to get the current implementation contract address
-     * @dev _upgradeBeacon is passed as a parameter so that
-     * we can also use this function in the constructor,
-     * where we can't access immutable variables.
-     * @param _upgradeBeacon Address of the UpgradeBeacon storing the current implementation
-     * @return _implementation Address of the current implementation.
-     */
-    function _getImplementation(address _upgradeBeacon)
-        private
-        view
-        returns (address _implementation)
-    {
-        // Get the current implementation address from the upgrade beacon.
-        (bool _ok, bytes memory _returnData) = _upgradeBeacon.staticcall("");
-        // Revert and pass along revert message if call to upgrade beacon reverts.
-        require(_ok, string(_returnData));
-        // Set the implementation to the address returned from the upgrade beacon.
-        _implementation = abi.decode(_returnData, (address));
-    }
-}

package/contracts/validator-manager/InboxValidatorManager.sol

@@ -1,58 +0,0 @@
-// SPDX-License-Identifier: MIT OR Apache-2.0
-pragma solidity >=0.8.0;
-
-// ============ Internal Imports ============
-import {IInbox} from "../../interfaces/IInbox.sol";
-import {MultisigValidatorManager} from "./MultisigValidatorManager.sol";
-
-/**
- * @title InboxValidatorManager
- * @notice Verifies checkpoints are signed by a quorum of validators and submits
- * them to an Inbox.
- */
-contract InboxValidatorManager is MultisigValidatorManager {
-    // ============ Constructor ============
-
-    /**
-     * @dev Reverts if `_validators` has any duplicates.
-     * @param _remoteDomain The remote domain of the outbox chain.
-     * @param _validators The set of validator addresses.
-     * @param _threshold The quorum threshold. Must be greater than or equal
-     * to the length of `_validators`.
-     */
-    // solhint-disable-next-line no-empty-blocks
-    constructor(
-        uint32 _remoteDomain,
-        address[] memory _validators,
-        uint256 _threshold
-    ) MultisigValidatorManager(_remoteDomain, _validators, _threshold) {}
-
-    // ============ External Functions ============
-
-    /**
-     * @notice Verifies a signed checkpoint and submits a message for processing.
-     * @dev Reverts if `_signatures` is not a quorum of validator signatures.
-     * @dev Reverts if `_signatures` is not sorted in ascending order by the signer
-     * address, which is required for duplicate detection.
-     * @param _inbox The inbox to submit the message to.
-     * @param _root The merkle root of the signed checkpoint.
-     * @param _index The index of the signed checkpoint.
-     * @param _signatures Signatures over the checkpoint to be checked for a validator
-     * quorum. Must be sorted in ascending order by signer address.
-     * @param _message The message to process.
-     * @param _proof Merkle proof of inclusion for message's leaf
-     * @param _leafIndex Index of leaf in outbox's merkle tree
-     */
-    function process(
-        IInbox _inbox,
-        bytes32 _root,
-        uint256 _index,
-        bytes[] calldata _signatures,
-        bytes calldata _message,
-        bytes32[32] calldata _proof,
-        uint256 _leafIndex
-    ) external {
-        require(isQuorum(_root, _index, _signatures), "!quorum");
-        _inbox.process(_root, _index, _message, _proof, _leafIndex);
-    }
-}