@heyitsiveen/dotfiles 1.0.0 → 1.0.2

package/dotfiles/macos/.config/fish/functions/fish_prompt.fish

@@ -0,0 +1,170 @@
+function fish_prompt
+end # In case this file gets loaded non-interactively, e.g by conda
+status is-interactive || exit
+
+_tide_remove_unusable_items
+_tide_cache_variables
+_tide_parent_dirs
+source (functions --details _tide_pwd)
+
+set -l prompt_var _tide_prompt_$fish_pid
+set -U $prompt_var # Set var here so if we erase $prompt_var, bg job won't set a uvar
+
+set_color normal | read -l color_normal
+status fish-path | read -l fish_path
+
+# _tide_repaint prevents us from creating a second background job
+function _tide_refresh_prompt --on-variable $prompt_var --on-variable COLUMNS
+    set -g _tide_repaint
+    commandline -f repaint
+end
+
+if contains newline $_tide_left_items # two line prompt initialization
+    test "$tide_prompt_add_newline_before" = true && set -l add_newline '\n'
+
+    set_color $tide_prompt_color_frame_and_connection -b normal | read -l prompt_and_frame_color
+
+    set -l column_offset 5
+    test "$tide_left_prompt_frame_enabled" = true &&
+        set -l top_left_frame "$prompt_and_frame_color╭─" &&
+        set -l bot_left_frame "$prompt_and_frame_color╰─" &&
+        set column_offset 3
+    test "$tide_right_prompt_frame_enabled" = true &&
+        set -l top_right_frame "$prompt_and_frame_color─╮" &&
+        set -l bot_right_frame "$prompt_and_frame_color─╯" &&
+        set column_offset (math $column_offset-2)
+
+    if test "$tide_prompt_transient_enabled" = true
+        eval "
+function fish_prompt
+    _tide_status=\$status _tide_pipestatus=\$pipestatus if not set -e _tide_repaint
+        jobs -q && jobs -p | count | read -lx _tide_jobs
+        $fish_path -c \"set _tide_pipestatus \$_tide_pipestatus
+set _tide_parent_dirs \$_tide_parent_dirs
+PATH=\$(string escape \"\$PATH\") CMD_DURATION=\$CMD_DURATION fish_bind_mode=\$fish_bind_mode set $prompt_var (_tide_2_line_prompt)\" &
+        builtin disown
+
+        command kill \$_tide_last_pid 2>/dev/null
+        set -g _tide_last_pid \$last_pid
+    end
+
+    if not set -q _tide_transient
+        math \$COLUMNS-(string length -V \"\$$prompt_var[1][1]\$$prompt_var[1][3]\")+$column_offset | read -lx dist_btwn_sides
+
+        echo -n $add_newline'$top_left_frame'(string replace @PWD@ (_tide_pwd) \"\$$prompt_var[1][1]\")'$prompt_and_frame_color'
+        string repeat -Nm(math max 0, \$dist_btwn_sides-\$_tide_pwd_len) '$tide_prompt_icon_connection'
+
+        echo \"\$$prompt_var[1][3]$top_right_frame\"
+    end
+    echo -n \e\[0J\"$bot_left_frame\$$prompt_var[1][2]$color_normal \"
+end
+
+function fish_right_prompt
+    set -e _tide_transient || string unescape \"\$$prompt_var[1][4]$bot_right_frame$color_normal\"
+end"
+    else
+        eval "
+function fish_prompt
+    _tide_status=\$status _tide_pipestatus=\$pipestatus if not set -e _tide_repaint
+        jobs -q && jobs -p | count | read -lx _tide_jobs
+        $fish_path -c \"set _tide_pipestatus \$_tide_pipestatus
+set _tide_parent_dirs \$_tide_parent_dirs
+PATH=\$(string escape \"\$PATH\") CMD_DURATION=\$CMD_DURATION fish_bind_mode=\$fish_bind_mode set $prompt_var (_tide_2_line_prompt)\" &
+        builtin disown
+
+        command kill \$_tide_last_pid 2>/dev/null
+        set -g _tide_last_pid \$last_pid
+    end
+
+    math \$COLUMNS-(string length -V \"\$$prompt_var[1][1]\$$prompt_var[1][3]\")+$column_offset | read -lx dist_btwn_sides
+
+    echo -ns $add_newline'$top_left_frame'(string replace @PWD@ (_tide_pwd) \"\$$prompt_var[1][1]\")'$prompt_and_frame_color'
+    string repeat -Nm(math max 0, \$dist_btwn_sides-\$_tide_pwd_len) '$tide_prompt_icon_connection'
+    echo -ns \"\$$prompt_var[1][3]$top_right_frame\"\n\"$bot_left_frame\$$prompt_var[1][2]$color_normal \"
+end
+
+function fish_right_prompt
+    string unescape \"\$$prompt_var[1][4]$bot_right_frame$color_normal\"
+end"
+    end
+else # one line prompt initialization
+    test "$tide_prompt_add_newline_before" = true && set -l add_newline '\0'
+
+    math 5 -$tide_prompt_min_cols | read -l column_offset
+    test $column_offset -ge 0 && set column_offset "+$column_offset"
+
+    if test "$tide_prompt_transient_enabled" = true
+        eval "
+function fish_prompt
+    set -lx _tide_status \$status
+    _tide_pipestatus=\$pipestatus if not set -e _tide_repaint
+        jobs -q && jobs -p | count | read -lx _tide_jobs
+        $fish_path -c \"set _tide_pipestatus \$_tide_pipestatus
+set _tide_parent_dirs \$_tide_parent_dirs
+PATH=\$(string escape \"\$PATH\") CMD_DURATION=\$CMD_DURATION fish_bind_mode=\$fish_bind_mode set $prompt_var (_tide_1_line_prompt)\" &
+        builtin disown
+
+        command kill \$_tide_last_pid 2>/dev/null
+        set -g _tide_last_pid \$last_pid
+    end
+
+    if set -q _tide_transient
+        echo -n \e\[0J
+        add_prefix= _tide_item_character
+        echo -n '$color_normal '
+    else
+        math \$COLUMNS-(string length -V \"\$$prompt_var[1][1]\$$prompt_var[1][2]\")$column_offset | read -lx dist_btwn_sides
+        string replace @PWD@ (_tide_pwd) $add_newline \$$prompt_var[1][1]'$color_normal '
+    end
+end
+
+function fish_right_prompt
+    set -e _tide_transient || string unescape \"\$$prompt_var[1][2]$color_normal\"
+end"
+    else
+        eval "
+function fish_prompt
+    _tide_status=\$status _tide_pipestatus=\$pipestatus if not set -e _tide_repaint
+        jobs -q && jobs -p | count | read -lx _tide_jobs
+        $fish_path -c \"set _tide_pipestatus \$_tide_pipestatus
+set _tide_parent_dirs \$_tide_parent_dirs
+PATH=\$(string escape \"\$PATH\") CMD_DURATION=\$CMD_DURATION fish_bind_mode=\$fish_bind_mode set $prompt_var (_tide_1_line_prompt)\" &
+        builtin disown
+
+        command kill \$_tide_last_pid 2>/dev/null
+        set -g _tide_last_pid \$last_pid
+    end
+
+    math \$COLUMNS-(string length -V \"\$$prompt_var[1][1]\$$prompt_var[1][2]\")$column_offset | read -lx dist_btwn_sides
+    string replace @PWD@ (_tide_pwd) $add_newline \$$prompt_var[1][1]'$color_normal '
+end
+
+function fish_right_prompt
+    string unescape \"\$$prompt_var[1][2]$color_normal\"
+end"
+    end
+end
+
+# Inheriting instead of evaling because here load time is more important than runtime
+function _tide_on_fish_exit --on-event fish_exit --inherit-variable prompt_var
+    set -e $prompt_var
+end
+
+if test "$tide_prompt_transient_enabled" = true
+    function _tide_enter_transient
+        # If the commandline will be executed or is empty, and the pager is not open
+        # Pager open usually means selecting, not running
+        # Can be untrue, but it's better than the alternative
+        if commandline --is-valid || test -z "$(commandline)" && not commandline --paging-mode
+            set -g _tide_transient
+            set -g _tide_repaint
+            commandline -f repaint
+        end
+        commandline -f execute
+    end
+
+    bind \r _tide_enter_transient
+    bind \n _tide_enter_transient
+    bind -M insert \r _tide_enter_transient
+    bind -M insert \n _tide_enter_transient
+end

package/dotfiles/macos/.config/fish/functions/fisher.fish

@@ -0,0 +1,251 @@
+function fisher --argument-names cmd --description "A plugin manager for Fish"
+    set --query fisher_path || set --local fisher_path $__fish_config_dir
+    set --local fisher_version 4.4.8
+    set --local fish_plugins $__fish_config_dir/fish_plugins
+
+    switch "$cmd"
+        case -v --version
+            echo "fisher, version $fisher_version"
+        case "" -h --help
+            echo "Usage: fisher install   <plugins...>  Install plugins"
+            echo "       fisher remove    <plugins...>  Remove installed plugins" 
+            echo "       fisher uninstall <plugins...>  Remove installed plugins (alias)" 
+            echo "       fisher update    <plugins...>  Update installed plugins"
+            echo "       fisher update                  Update all installed plugins"
+            echo "       fisher list    [<regex>]       List installed plugins matching regex"
+            echo "Options:"
+            echo "       -v, --version  Print version"
+            echo "       -h, --help     Print this help message"
+            echo "Variables:"
+            echo "       \$fisher_path  Plugin installation path. Default: $__fish_config_dir" | string replace --regex -- $HOME \~
+        case ls list
+            string match --entire --regex -- "$argv[2]" $_fisher_plugins
+        case install update remove uninstall
+            isatty || read --local --null --array stdin && set --append argv $stdin
+
+            test "$cmd" = uninstall && set cmd remove
+
+            set --local install_plugins
+            set --local update_plugins
+            set --local remove_plugins
+            set --local arg_plugins $argv[2..-1]
+            set --local old_plugins $_fisher_plugins
+            set --local new_plugins
+
+            test -e $fish_plugins && set --local file_plugins (string match --regex -- '^[^\s]+$' <$fish_plugins | string replace -- \~ ~)
+
+            if ! set --query argv[2]
+                if test "$cmd" != update
+                    echo "fisher: Not enough arguments for command: \"$cmd\"" >&2 && return 1
+                else if ! set --query file_plugins
+                    echo "fisher: \"$fish_plugins\" file not found: \"$cmd\"" >&2 && return 1
+                end
+                set arg_plugins $file_plugins
+            else if test "$cmd" = install && ! set --query old_plugins[1] 
+                set --append arg_plugins $file_plugins
+            end
+
+            for plugin in $arg_plugins
+                set plugin (test -e "$plugin" && realpath $plugin || string lower -- $plugin)
+                contains -- "$plugin" $new_plugins || set --append new_plugins $plugin
+            end
+
+            if set --query argv[2]
+                for plugin in $new_plugins
+                    if contains -- "$plugin" $old_plugins
+                        test "$cmd" = remove &&
+                            set --append remove_plugins $plugin ||
+                            set --append update_plugins $plugin
+                    else if test "$cmd" = install
+                        set --append install_plugins $plugin
+                    else
+                        echo "fisher: Plugin not installed: \"$plugin\"" >&2 && return 1
+                    end
+                end
+            else
+                for plugin in $new_plugins
+                    contains -- "$plugin" $old_plugins &&
+                        set --append update_plugins $plugin ||
+                        set --append install_plugins $plugin
+                end
+
+                for plugin in $old_plugins
+                    contains -- "$plugin" $new_plugins || set --append remove_plugins $plugin
+                end
+            end
+
+            set --local pid_list
+            set --local source_plugins
+            set --local fetch_plugins $update_plugins $install_plugins
+            set --local fish_path (status fish-path)
+
+            echo (set_color --bold)fisher $cmd version $fisher_version(set_color normal)
+
+            for plugin in $fetch_plugins
+                set --local source (command mktemp -d)
+                set --append source_plugins $source
+
+                command mkdir -p $source/{completions,conf.d,themes,functions}
+
+                $fish_path --command "
+                    if test -e $plugin
+                        command cp -Rf $plugin/* $source
+                    else
+                        set resp (command mktemp)
+                        set temp (command mktemp -d)
+                        set repo (string split -- \@ $plugin) || set repo[2] HEAD
+
+                        if set path (string replace --regex -- '^(https://)?gitlab.com/' '' \$repo[1])
+                            set name (string split -- / \$path)[-1]
+                            set url https://gitlab.com/\$path/-/archive/\$repo[2]/\$name-\$repo[2].tar.gz
+                        else
+                            set url https://api.github.com/repos/\$repo[1]/tarball/\$repo[2]
+                        end
+
+                        echo Fetching (set_color --underline)\$url(set_color normal)
+
+                        set http (command curl -q --silent -L -o \$resp -w %{http_code} \$url)
+
+                        if test \"\$http\" = 200 && command tar -xzC \$temp -f \$resp 2>/dev/null
+                            command cp -Rf \$temp/*/* $source
+                        else if test \"\$http\" = 403
+                            echo fisher: GitHub API rate limit exceeded \(HTTP 403\) >&2
+                            command rm -rf $source
+                        else
+                            echo fisher: Invalid plugin name or host unavailable: \\\"$plugin\\\" >&2
+                            command rm -rf $source
+                        end
+
+                        command rm -rf \$temp
+                    end
+
+                    set files $source/* && string match --quiet --regex -- .+\.fish\\\$ \$files
+                " &
+
+                set --append pid_list (jobs --last --pid)
+            end
+
+            wait $pid_list 2>/dev/null
+
+            for plugin in $fetch_plugins
+                if set --local source $source_plugins[(contains --index -- "$plugin" $fetch_plugins)] && test ! -e $source
+                    if set --local index (contains --index -- "$plugin" $install_plugins)
+                        set --erase install_plugins[$index]
+                    else
+                        set --erase update_plugins[(contains --index -- "$plugin" $update_plugins)]
+                    end
+                end
+            end
+
+            for plugin in $update_plugins $remove_plugins
+                if set --local index (contains --index -- "$plugin" $_fisher_plugins)
+                    set --local plugin_files_var _fisher_(string escape --style=var -- $plugin)_files
+
+                    if contains -- "$plugin" $remove_plugins
+                        for name in (string replace --filter --regex -- '.+/conf\.d/([^/]+)\.fish$' '$1' $$plugin_files_var)
+                            emit {$name}_uninstall
+                        end
+                        printf "%s\n" Removing\ (set_color red --bold)$plugin(set_color normal) "         "$$plugin_files_var | string replace -- \~ ~
+                        set --erase _fisher_plugins[$index]
+                    end
+
+                    command rm -rf (string replace -- \~ ~ $$plugin_files_var)
+
+                    functions --erase (string replace --filter --regex -- '.+/functions/([^/]+)\.fish$' '$1' $$plugin_files_var)
+
+                    for name in (string replace --filter --regex -- '.+/completions/([^/]+)\.fish$' '$1' $$plugin_files_var)
+                        complete --erase --command $name
+                    end
+
+                    set --erase $plugin_files_var
+                end
+            end
+
+            if set --query update_plugins[1] || set --query install_plugins[1]
+                command mkdir -p $fisher_path/{functions,themes,conf.d,completions}
+            end
+
+            for plugin in $update_plugins $install_plugins
+                set --local source $source_plugins[(contains --index -- "$plugin" $fetch_plugins)]
+                set --local files $source/{functions,themes,conf.d,completions}/*
+
+                if set --local index (contains --index -- $plugin $install_plugins)
+                    set --local user_files $fisher_path/{functions,themes,conf.d,completions}/*
+                    set --local conflict_files
+
+                    for file in (string replace -- $source/ $fisher_path/ $files)
+                        contains -- $file $user_files && set --append conflict_files $file
+                    end
+
+                    if set --query conflict_files[1] && set --erase install_plugins[$index]
+                        echo -s "fisher: Cannot install \"$plugin\": please remove or move conflicting files first:" \n"        "$conflict_files >&2
+                        continue
+                    end
+                end
+
+                for file in (string replace -- $source/ "" $files)
+                    command cp -RLf $source/$file $fisher_path/$file
+                end
+
+                set --local plugin_files_var _fisher_(string escape --style=var -- $plugin)_files
+
+                set --query files[1] && set --universal $plugin_files_var (string replace -- $source $fisher_path $files | string replace -- ~ \~)
+
+                contains -- $plugin $_fisher_plugins || set --universal --append _fisher_plugins $plugin
+                contains -- $plugin $install_plugins && set --local event install || set --local event update
+
+                printf "%s\n" Installing\ (set_color --bold)$plugin(set_color normal) "           "$$plugin_files_var | string replace -- \~ ~
+
+                for file in (string match --regex -- '.+/[^/]+\.fish$' $$plugin_files_var | string replace -- \~ ~)
+                    source $file
+                    if set --local name (string replace --regex -- '.+conf\.d/([^/]+)\.fish$' '$1' $file)
+                        emit {$name}_$event
+                    end
+                end
+            end
+
+            command rm -rf $source_plugins
+
+            if set --query _fisher_plugins[1]
+                set --local commit_plugins
+
+                for plugin in $file_plugins
+                    contains -- (string lower -- $plugin) (string lower -- $_fisher_plugins) && set --append commit_plugins $plugin
+                end
+
+                for plugin in $_fisher_plugins
+                    contains -- (string lower -- $plugin) (string lower -- $commit_plugins) || set --append commit_plugins $plugin
+                end
+
+                string replace --regex -- $HOME \~ $commit_plugins >$fish_plugins
+            else
+                set --erase _fisher_plugins
+                command rm -f $fish_plugins
+            end
+
+            set --local total (count $install_plugins) (count $update_plugins) (count $remove_plugins)
+
+            test "$total" != "0 0 0" && echo (string join ", " (
+                test $total[1] = 0 || echo "Installed $total[1]") (
+                test $total[2] = 0 || echo "Updated $total[2]") (
+                test $total[3] = 0 || echo "Removed $total[3]")
+            ) plugin/s
+        case \*
+            echo "fisher: Unknown command: \"$cmd\"" >&2 && return 1
+    end
+end
+
+if ! set --query _fisher_upgraded_to_4_4
+    set --universal _fisher_upgraded_to_4_4
+    if functions --query _fisher_list
+        set --query XDG_DATA_HOME[1] || set --local XDG_DATA_HOME ~/.local/share
+        command rm -rf $XDG_DATA_HOME/fisher
+        functions --erase _fisher_{list,plugin_parse}
+        fisher update >/dev/null 2>/dev/null
+    else
+        for var in (set --names | string match --entire --regex '^_fisher_.+_files$')
+            set $var (string replace -- ~ \~ $$var)
+        end
+        functions --erase _fisher_fish_postexec
+    end
+end

package/dotfiles/macos/.config/fish/functions/tide/configure/choices/all/finish.fish

@@ -0,0 +1,46 @@
+function finish
+    _tide_title Finish
+
+    echo
+    set_color red
+    _tide_option y 'Overwrite your current tide config'
+    set_color normal
+    echo
+
+    _tide_option p 'Exit and print the config you just generated'
+    echo
+
+    _tide_menu (status function)
+    switch $_tide_selected_option
+        case 'Overwrite your current tide config'
+            _tide_finish
+            command -q clear && clear
+            set -q _flag_auto || _tide_print_configure_current_options
+        case 'Exit and print the config you just generated'
+            _tide_exit_configure
+            command -q clear && clear
+            _tide_print_configure_current_options
+    end
+end
+
+function _tide_finish
+    _tide_exit_configure
+
+    # Deal with prompt char/vi mode
+    contains character $fake_tide_left_prompt_items || set -p fake_tide_left_prompt_items vi_mode
+
+    # Set the real variables
+    for fakeVar in (set --names | string match -r "^fake_tide.*")
+        set -U (string replace 'fake_' '' $fakeVar) $$fakeVar
+    end
+
+    # Make sure old prompt won't display
+    set -e $_tide_prompt_var 2>/dev/null
+
+    # Re-initialize the prompt
+    tide reload
+end
+
+function _tide_print_configure_current_options
+    _tide_fish_colorize "tide configure --auto $_tide_configure_current_options"
+end

package/dotfiles/macos/.config/fish/functions/tide/configure/choices/all/icons.fish

@@ -0,0 +1,33 @@
+function icons
+    _tide_title Icons
+
+    _tide_option 1 'Few icons'
+    _tide_display_prompt
+
+    _tide_option 2 'Many icons'
+    _enable_icons
+    _tide_display_prompt
+
+    _tide_menu (status function)
+    switch $_tide_selected_option
+        case 'Few icons'
+            _disable_icons
+    end
+    _next_choice all/transient
+end
+
+function _enable_icons
+    set -p fake_tide_left_prompt_items os
+    set -g fake_tide_pwd_icon 
+    set -g fake_tide_pwd_icon_home 
+    set -g fake_tide_cmd_duration_icon 
+    set -g fake_tide_git_icon 
+end
+
+function _disable_icons
+    _tide_find_and_remove os fake_tide_left_prompt_items
+    set fake_tide_pwd_icon
+    set fake_tide_pwd_icon_home
+    set fake_tide_cmd_duration_icon
+    set fake_tide_git_icon
+end

package/dotfiles/macos/.config/fish/functions/tide/configure/choices/all/prompt_colors.fish

@@ -0,0 +1,26 @@
+function prompt_colors
+    _tide_title 'Prompt Colors'
+
+    _tide_option 1 'True color'
+    _tide_display_prompt
+
+    _tide_option 2 '16 colors'
+    _load_config "$_tide_configure_style"_16color
+    set -g _tide_16color true
+    _tide_display_prompt
+
+    _tide_menu (status function)
+    switch $_tide_selected_option
+        case 'True color'
+            _load_config "$_tide_configure_style"
+            set -e _tide_16color
+            switch $_tide_configure_style
+                case lean rainbow
+                    _next_choice all/show_time
+                case classic
+                    _next_choice classic/classic_prompt_color
+            end
+        case '16 colors'
+            _next_choice all/show_time
+    end
+end

package/dotfiles/macos/.config/fish/functions/tide/configure/choices/all/prompt_connection.fish

@@ -0,0 +1,31 @@
+function prompt_connection
+    _tide_title 'Prompt Connection'
+
+    _tide_option 1 Disconnected
+    set -g fake_tide_prompt_icon_connection ' '
+    _tide_display_prompt
+
+    _tide_option 2 Dotted
+    set -g fake_tide_prompt_icon_connection '·'
+    _tide_display_prompt
+
+    _tide_option 3 Solid
+    set -g fake_tide_prompt_icon_connection '─'
+    _tide_display_prompt
+
+    _tide_menu (status function)
+    switch $_tide_selected_option
+        case Disconnected
+            set -g fake_tide_prompt_icon_connection ' '
+        case Dotted
+            set -g fake_tide_prompt_icon_connection '·'
+        case Solid
+            set -g fake_tide_prompt_icon_connection '─'
+    end
+    switch $_tide_configure_style
+        case lean
+            _next_choice all/prompt_connection_andor_frame_color
+        case classic rainbow
+            _next_choice powerline/powerline_right_prompt_frame
+    end
+end

package/dotfiles/macos/.config/fish/functions/tide/configure/choices/all/prompt_connection_andor_frame_color.fish

@@ -0,0 +1,40 @@
+function prompt_connection_andor_frame_color
+    if test "$_tide_16color" = true ||
+            test "$fake_tide_left_prompt_frame_enabled" = false -a \
+                "$fake_tide_right_prompt_frame_enabled" = false -a \
+                "$fake_tide_prompt_icon_connection" = ' '
+        _next_choice all/prompt_spacing
+        return 0
+    end
+
+    _tide_title "Connection & Frame Color"
+
+    _tide_option 1 Lightest
+    set -g fake_tide_prompt_color_frame_and_connection 808080
+    _tide_display_prompt
+
+    _tide_option 2 Light
+    set -g fake_tide_prompt_color_frame_and_connection 6C6C6C
+    _tide_display_prompt
+
+    _tide_option 3 Dark
+    set -g fake_tide_prompt_color_frame_and_connection 585858
+    _tide_display_prompt
+
+    _tide_option 4 Darkest
+    set -g fake_tide_prompt_color_frame_and_connection 444444
+    _tide_display_prompt
+
+    _tide_menu (status function)
+    switch $_tide_selected_option
+        case Lightest
+            set -g fake_tide_prompt_color_frame_and_connection 808080
+        case Light
+            set -g fake_tide_prompt_color_frame_and_connection 6C6C6C
+        case Dark
+            set -g fake_tide_prompt_color_frame_and_connection 585858
+        case Darkest
+            set -g fake_tide_prompt_color_frame_and_connection 444444
+    end
+    _next_choice all/prompt_spacing
+end

package/dotfiles/macos/.config/fish/functions/tide/configure/choices/all/prompt_spacing.fish

@@ -0,0 +1,22 @@
+function prompt_spacing
+    _tide_title 'Prompt Spacing'
+
+    _tide_option 1 Compact
+    set -g fake_tide_prompt_add_newline_before false
+    _tide_display_prompt
+    _tide_display_prompt
+
+    _tide_option 2 Sparse
+    set -g fake_tide_prompt_add_newline_before true
+    _tide_display_prompt
+    _tide_display_prompt
+
+    _tide_menu (status function)
+    switch $_tide_selected_option
+        case Compact
+            set -g fake_tide_prompt_add_newline_before false
+        case Sparse
+            set -g fake_tide_prompt_add_newline_before true
+    end
+    _next_choice all/icons
+end

package/dotfiles/macos/.config/fish/functions/tide/configure/choices/all/show_time.fish

@@ -0,0 +1,33 @@
+function show_time
+    _tide_title 'Show current time?'
+
+    _tide_option 1 No
+    _tide_display_prompt
+
+    set -a fake_tide_right_prompt_items time
+
+    _tide_option 2 '24-hour format'
+    set -g fake_tide_time_format %T
+    _tide_display_prompt
+
+    _tide_option 3 '12-hour format'
+    set -g fake_tide_time_format %r
+    _tide_display_prompt
+
+    _tide_menu (status function)
+    switch $_tide_selected_option
+        case No
+            set -g fake_tide_time_format ''
+            set -e fake_tide_right_prompt_items[-1]
+        case '24-hour format'
+            set -g fake_tide_time_format %T
+        case '12-hour format'
+            set -g fake_tide_time_format %r
+    end
+    switch $_tide_configure_style
+        case lean
+            _next_choice "$_tide_configure_style"/"$_tide_configure_style"_prompt_height
+        case classic rainbow
+            _next_choice "$_tide_configure_style"/"$_tide_configure_style"_prompt_separators
+    end
+end