@harvest-finance/harvest-strategy-polygon 0.0.1-security → 1.0.0

package/contracts/strategies/ape/ApeStrategyMainnet_ETH_MATIC.sol

@@ -0,0 +1,36 @@
+//SPDX-License-Identifier: Unlicense
+pragma solidity 0.6.12;
+
+import "../../base/interface/IVault.sol";
+import "../../base/ape-base/MiniApeV2Strategy.sol";
+
+contract ApeStrategyMainnet_ETH_MATIC is MiniApeV2Strategy {
+
+  address constant public weth = address(0x7ceB23fD6bC0adD59E62ac25578270cFf1b9f619);
+  address constant public banana = address(0x5d47bAbA0d66083C52009271faF3F50DCc01023C);
+  address constant public weth_matic = address(0x6Cf8654e85AB489cA7e70189046D507ebA233613);
+  address constant public wmatic = address(0x0d500B1d8E8eF31E21C99d1Db9A6444d3ADf1270);
+  address constant public miniApe = address(0x54aff400858Dcac39797a81894D9920f16972D1D);
+  
+  constructor() public {}
+
+  function initializeStrategy(
+    address _storage,
+    address _vault
+  ) public initializer {
+
+    MiniApeV2Strategy.initializeBaseStrategy(
+      _storage, 
+      weth_matic, 
+      _vault, 
+      miniApe, 
+      banana, 
+      1
+    );
+
+    require(IVault(_vault).underlying() == weth_matic, "Underlying mismatch");
+    
+    uniswapRoutes[wmatic] = [banana, wmatic];
+    uniswapRoutes[weth] = [banana, wmatic, weth];
+  }
+}

package/contracts/strategies/ape/ApeStrategyMainnet_USDT_MATIC.sol

@@ -0,0 +1,36 @@
+//SPDX-License-Identifier: Unlicense
+pragma solidity 0.6.12;
+
+import "../../base/interface/IVault.sol";
+import "../../base/ape-base/MiniApeV2Strategy.sol";
+
+contract ApeStrategyMainnet_USDT_MATIC is MiniApeV2Strategy {
+
+  address constant public usdt = address(0xc2132D05D31c914a87C6611C10748AEb04B58e8F);
+  address constant public banana = address(0x5d47bAbA0d66083C52009271faF3F50DCc01023C);
+  address constant public usdt_matic = address(0x65D43B64E3B31965Cd5EA367D4c2b94c03084797);
+  address constant public wmatic = address(0x0d500B1d8E8eF31E21C99d1Db9A6444d3ADf1270);
+  address constant public miniApe = address(0x54aff400858Dcac39797a81894D9920f16972D1D);
+  
+  constructor() public {}
+
+  function initializeStrategy(
+    address _storage,
+    address _vault
+  ) public initializer {
+
+    MiniApeV2Strategy.initializeBaseStrategy(
+      _storage, 
+      usdt_matic, 
+      _vault, 
+      miniApe, 
+      banana, 
+      3
+    );
+
+    require(IVault(_vault).underlying() == usdt_matic, "Underlying mismatch");
+    
+    uniswapRoutes[usdt] = [banana, wmatic, usdt];
+    uniswapRoutes[wmatic] = [banana, wmatic];
+  }
+}

package/contracts/strategies/aura/AuraStrategy.sol

@@ -0,0 +1,347 @@
+//SPDX-License-Identifier: Unlicense
+pragma solidity 0.6.12;
+pragma experimental ABIEncoderV2;
+
+import "@openzeppelin/contracts/math/Math.sol";
+import "@openzeppelin/contracts/math/SafeMath.sol";
+import "@openzeppelin/contracts/token/ERC20/SafeERC20.sol";
+import "../../base/interface/IUniversalLiquidator.sol";
+import "../../base/interface/IVault.sol";
+import "../../base/upgradability/BaseUpgradeableStrategyV2.sol";
+import "../../base/interface/balancer/IBVault.sol";
+import "../../base/interface/balancer/Gauge.sol";
+import "../../base/interface/balancer/IBalancerMinter.sol";
+import "./interface/IAuraBooster.sol";
+import "./interface/IAuraBaseRewardPool.sol";
+
+contract AuraStrategy is BaseUpgradeableStrategyV2 {
+
+  using SafeMath for uint256;
+  using SafeERC20 for IERC20;
+
+  address public constant weth = address(0x7ceB23fD6bC0adD59E62ac25578270cFf1b9f619);
+  address public constant harvestMSIG = address(0x39cC360806b385C96969ce9ff26c23476017F652);
+  address public constant bVault = address(0xBA12222222228d8Ba445958a75a0704d566BF2C8);
+  address public constant booster = address(0x98Ef32edd24e2c92525E59afc4475C1242a30184);
+
+  // additional storage slots (on top of BaseUpgradeableStrategy ones) are defined here
+  bytes32 internal constant _AURA_POOLID_SLOT = 0xbc10a276e435b4e9a9e92986f93a224a34b50c1898d7551c38ef30a08efadec4;
+  bytes32 internal constant _BALANCER_POOLID_SLOT = 0xbf3f653715dd45c84a3367d2975f271307cb967d6ce603dc4f0def2ad909ca64;
+  bytes32 internal constant _DEPOSIT_TOKEN_SLOT = 0x219270253dbc530471c88a9e7c321b36afda219583431e7b6c386d2d46e70c86;
+
+  // this would be reset on each upgrade
+  address[] public rewardTokens;
+
+  constructor() public BaseUpgradeableStrategyV2() {
+    assert(_AURA_POOLID_SLOT == bytes32(uint256(keccak256("eip1967.strategyStorage.auraPoolId")) - 1));
+    assert(_BALANCER_POOLID_SLOT == bytes32(uint256(keccak256("eip1967.strategyStorage.balancerPoolId")) - 1));
+    assert(_DEPOSIT_TOKEN_SLOT == bytes32(uint256(keccak256("eip1967.strategyStorage.depositToken")) - 1));
+  }
+
+  function initializeBaseStrategy(
+    address _storage,
+    address _underlying,
+    address _vault,
+    address _rewardPool,
+    bytes32 _balancerPoolID,
+    uint256 _auraPoolID,
+    address _depositToken
+  ) public initializer {
+
+    BaseUpgradeableStrategyV2.initialize(
+      _storage,
+      _underlying,
+      _vault,
+      _rewardPool,
+      weth,
+      harvestMSIG
+    );
+
+    (address _lpt,) = IBVault(bVault).getPool(_balancerPoolID);
+    require(_lpt == _underlying, "Underlying mismatch");
+    (_lpt,,,,,) = IAuraBooster(booster).poolInfo(_auraPoolID);
+    require(_lpt == underlying(), "Pool Info does not match underlying");
+
+    _setAuraPoolId(_auraPoolID);
+    _setBalancerPoolId(_balancerPoolID);
+    _setDepositToken(_depositToken);
+  }
+
+  function depositArbCheck() public pure returns(bool) {
+    return true;
+  }
+
+  function _rewardPoolBalance() internal view returns (uint256 balance) {
+      balance = IAuraBaseRewardPool(rewardPool()).balanceOf(address(this));
+  }
+
+  function _emergencyExitRewardPool() internal {
+    uint256 stakedBalance = _rewardPoolBalance();
+    if (stakedBalance != 0) {
+        IAuraBaseRewardPool(rewardPool()).withdrawAllAndUnwrap(false); //don't claim rewards
+    }
+  }
+
+  function _partialWithdrawalRewardPool(uint256 amount) internal {
+    IAuraBaseRewardPool(rewardPool()).withdrawAndUnwrap(amount, false);  //don't claim rewards at this point
+  }
+
+  function _exitRewardPool() internal {
+      uint256 stakedBalance = _rewardPoolBalance();
+      if (stakedBalance != 0) {
+          IAuraBaseRewardPool(rewardPool()).withdrawAllAndUnwrap(true);
+      }
+  }
+
+  function _enterRewardPool() internal {
+    address underlying_ = underlying();
+    uint256 entireBalance = IERC20(underlying_).balanceOf(address(this));
+    IERC20(underlying_).safeApprove(booster, 0);
+    IERC20(underlying_).safeApprove(booster, entireBalance);
+    IAuraBooster(booster).depositAll(auraPoolId(), true); //deposit and stake
+  }
+
+  function _investAllUnderlying() internal onlyNotPausedInvesting {
+    if(IERC20(underlying()).balanceOf(address(this)) > 0) {
+      _enterRewardPool();
+    }
+  }
+
+  /*
+  *   In case there are some issues discovered about the pool or underlying asset
+  *   Governance can exit the pool properly
+  *   The function is only used for emergency to exit the pool
+  */
+  function emergencyExit() public onlyGovernance {
+    _emergencyExitRewardPool();
+    _setPausedInvesting(true);
+  }
+
+  /*
+  *   Resumes the ability to invest into the underlying reward pools
+  */
+  function continueInvesting() public onlyGovernance {
+    _setPausedInvesting(false);
+  }
+
+  function unsalvagableTokens(address token) public view returns (bool) {
+    return (token == rewardToken() || token == underlying());
+  }
+
+  function addRewardToken(address _token) public onlyGovernance {
+    rewardTokens.push(_token);
+  }
+
+  function changeDepositToken(address _depositToken) public onlyGovernance {
+    _setDepositToken(_depositToken);
+  }
+
+  function _approveIfNeed(address token, address spender, uint256 amount) internal {
+    uint256 allowance = IERC20(token).allowance(address(this), spender);
+    if (amount > allowance) {
+      IERC20(token).safeApprove(spender, 0);
+      IERC20(token).safeApprove(spender, amount);
+    }
+  }
+
+  function _balancerDeposit(
+    address tokenIn,
+    bytes32 poolId,
+    uint256 amountIn,
+    uint256 minAmountOut
+  ) internal {
+    (address[] memory poolTokens,,) = IBVault(bVault).getPoolTokens(poolId);
+    uint256 _nTokens = poolTokens.length;
+
+    IAsset[] memory assets = new IAsset[](_nTokens);
+    uint256[] memory amountsIn = new uint256[](_nTokens);
+    for (uint256 i = 0; i < _nTokens; i++) {
+      assets[i] = IAsset(poolTokens[i]);
+      amountsIn[i] = poolTokens[i] == tokenIn ? amountIn : 0;
+    }
+
+    IBVault.JoinKind joinKind = IBVault.JoinKind.EXACT_TOKENS_IN_FOR_BPT_OUT;
+
+    bytes memory userData = abi.encode(joinKind, amountsIn, minAmountOut);
+
+    IBVault.JoinPoolRequest memory request;
+    request.assets = assets;
+    request.maxAmountsIn = amountsIn;
+    request.userData = userData;
+    request.fromInternalBalance = false;
+
+    _approveIfNeed(tokenIn, bVault, amountIn);
+    IBVault(bVault).joinPool(
+      poolId,
+      address(this),
+      address(this),
+      request
+    );
+  }
+
+  function _liquidateReward() internal {
+    if (!sell()) {
+      // Profits can be disabled for possible simplified and rapid exit
+      emit ProfitsNotCollected(sell(), false);
+      return;
+    }
+    address _rewardToken = rewardToken();
+    address _universalLiquidator = universalLiquidator();
+    for(uint256 i = 0; i < rewardTokens.length; i++){
+      address token = rewardTokens[i];
+      uint256 rewardBalance = IERC20(token).balanceOf(address(this));
+      if (rewardBalance == 0) {
+        continue;
+      }
+      if (token != _rewardToken){
+          IERC20(token).safeApprove(_universalLiquidator, 0);
+          IERC20(token).safeApprove(_universalLiquidator, rewardBalance);
+          IUniversalLiquidator(_universalLiquidator).swap(token, _rewardToken, rewardBalance, 1, address(this));
+      }
+    }
+
+    uint256 rewardBalance = IERC20(_rewardToken).balanceOf(address(this));
+    _notifyProfitInRewardToken(_rewardToken, rewardBalance);
+    uint256 remainingRewardBalance = IERC20(_rewardToken).balanceOf(address(this));
+
+    if (remainingRewardBalance == 0) {
+      return;
+    }
+
+    address _depositToken = depositToken();
+    if (_depositToken != _rewardToken) {
+      IERC20(_rewardToken).safeApprove(_universalLiquidator, 0);
+      IERC20(_rewardToken).safeApprove(_universalLiquidator, remainingRewardBalance);
+      IUniversalLiquidator(_universalLiquidator).swap(_rewardToken, _depositToken, remainingRewardBalance, 1, address(this));
+    }
+
+    uint256 tokenBalance = IERC20(_depositToken).balanceOf(address(this));
+    if (tokenBalance > 0 && !(_depositToken == underlying())) {
+      depositLP();
+    }
+  }
+
+  function depositLP() internal {
+    address _depositToken = depositToken();
+    uint256 depositTokenBalance = IERC20(_depositToken).balanceOf(address(this));
+
+    _balancerDeposit(
+      _depositToken,
+      balancerPoolId(),
+      depositTokenBalance,
+      1
+    );
+  }
+
+  /** Withdraws all the asset to the vault
+   */
+  function withdrawAllToVault() public restricted {
+    address _underlying = underlying();
+    _exitRewardPool();
+    _liquidateReward();
+    IERC20(_underlying).safeTransfer(vault(), IERC20(_underlying).balanceOf(address(this)));
+  }
+
+  /** Withdraws specific amount of asset to the vault
+   */
+  function withdrawToVault(uint256 amount) public restricted {
+    address _underlying = underlying();
+    // Typically there wouldn't be any amount here
+    // however, it is possible because of the emergencyExit
+    uint256 entireBalance = IERC20(_underlying).balanceOf(address(this));
+
+    if(amount > entireBalance){
+      // While we have the check above, we still using SafeMath below
+      // for the peace of mind (in case something gets changed in between)
+      uint256 needToWithdraw = amount.sub(entireBalance);
+      uint256 toWithdraw = Math.min(_rewardPoolBalance(), needToWithdraw);
+      _partialWithdrawalRewardPool(toWithdraw);
+    }
+    IERC20(_underlying).safeTransfer(vault(), amount);
+  }
+
+  /*
+  *   Note that we currently do not have a mechanism here to include the
+  *   amount of reward that is accrued.
+  */
+  function investedUnderlyingBalance() external view returns (uint256) {
+    // Adding the amount locked in the reward pool and the amount that is somehow in this contract
+    // both are in the units of "underlying"
+    // The second part is needed because there is the emergency exit mechanism
+    // which would break the assumption that all the funds are always inside of the reward pool
+    return _rewardPoolBalance().add(IERC20(underlying()).balanceOf(address(this)));
+  }
+
+  /*
+  *   Governance or Controller can claim coins that are somehow transferred into the contract
+  *   Note that they cannot come in take away coins that are used and defined in the strategy itself
+  */
+  function salvage(address recipient, address token, uint256 amount) external onlyControllerOrGovernance {
+     // To make sure that governance cannot come in and take away the coins
+    require(!unsalvagableTokens(token), "token is defined as not salvagable");
+    IERC20(token).safeTransfer(recipient, amount);
+  }
+
+  /*
+  *   Get the reward, sell it in exchange for underlying, invest what you got.
+  *   It's not much, but it's honest work.
+  *
+  *   Note that although `onlyNotPausedInvesting` is not added here,
+  *   calling `investAllUnderlying()` affectively blocks the usage of `doHardWork`
+  *   when the investing is being paused by governance.
+  */
+  function doHardWork() external onlyNotPausedInvesting restricted {
+    IAuraBaseRewardPool(rewardPool()).getReward();
+    _liquidateReward();
+    _investAllUnderlying();
+  }
+
+  /**
+  * Can completely disable claiming UNI rewards and selling. Good for emergency withdraw in the
+  * simplest possible way.
+  */
+  function setSell(bool s) public onlyGovernance {
+    _setSell(s);
+  }
+
+  /**
+  * Sets the minimum amount of CRV needed to trigger a sale.
+  */
+  function setSellFloor(uint256 floor) public onlyGovernance {
+    _setSellFloor(floor);
+  }
+
+  /** Aura deposit pool ID
+   */
+  function _setAuraPoolId(uint256 _value) internal {
+    setUint256(_AURA_POOLID_SLOT, _value);
+  }
+
+  /** Balancer deposit pool ID
+   */
+  function _setBalancerPoolId(bytes32 _value) internal {
+    setBytes32(_BALANCER_POOLID_SLOT, _value);
+  }
+
+  function auraPoolId() public view returns (uint256) {
+    return getUint256(_AURA_POOLID_SLOT);
+  }
+
+  function balancerPoolId() public view returns (bytes32) {
+    return getBytes32(_BALANCER_POOLID_SLOT);
+  }
+
+  function _setDepositToken(address _address) internal {
+    setAddress(_DEPOSIT_TOKEN_SLOT, _address);
+  }
+
+  function depositToken() public view returns (address) {
+    return getAddress(_DEPOSIT_TOKEN_SLOT);
+  }
+
+  function finalizeUpgrade() external onlyGovernance {
+    _finalizeUpgrade();
+  }
+
+  receive() external payable {} // this is needed for the receiving Matic
+}

package/contracts/strategies/aura/AuraStrategyMainnet_jEUR_PAR.sol

@@ -0,0 +1,30 @@
+//SPDX-License-Identifier: Unlicense
+pragma solidity 0.6.12;
+pragma experimental ABIEncoderV2;
+
+import "./AuraStrategy.sol";
+
+contract AuraStrategyMainnet_jEUR_PAR is AuraStrategy {
+
+  constructor() public {}
+
+  function initializeStrategy(
+    address _storage,
+    address _vault
+  ) public initializer {
+    address underlying = address(0x513CdEE00251F39DE280d9E5f771A6eaFebCc88E);
+    address aura = address(0x1509706a6c66CA549ff0cB464de88231DDBe213B);
+    address bal = address(0x9a71012B13CA4d3D0Cdc72A177DF3ef03b0E76A3);
+    address rewardPool = address(0x333122d446A950a951942a6C065b6ebBEE72EA98);
+    AuraStrategy.initializeBaseStrategy(
+      _storage,
+      underlying,
+      _vault,
+      rewardPool,
+      0x513cdee00251f39de280d9e5f771a6eafebcc88e000000000000000000000a6b,  // Balancer Pool id
+      6,      // Aura Pool id
+      underlying   //depositToken
+    );
+    rewardTokens = [aura, bal];
+  }
+}

package/contracts/strategies/aura/interface/IAuraBaseRewardPool.sol

@@ -0,0 +1,25 @@
+//SPDX-License-Identifier: Unlicense
+pragma solidity 0.6.12;
+
+interface IAuraBaseRewardPool {
+
+    function balanceOf(address account) external view returns(uint256 amount);
+
+    function pid() external view returns (uint256 _pid);
+
+    function stakingToken() external view returns (address _stakingToken);
+
+    function getReward() external;
+
+    function stake(uint256 _amount) external;
+
+    function stakeAll() external;
+
+    function withdraw(uint256 amount, bool claim) external;
+
+    function withdrawAll(bool claim) external;
+
+    function withdrawAndUnwrap(uint256 amount, bool claim) external;
+
+    function withdrawAllAndUnwrap(bool claim) external;
+}

package/contracts/strategies/aura/interface/IAuraBooster.sol

@@ -0,0 +1,17 @@
+//SPDX-License-Identifier: Unlicense
+pragma solidity 0.6.12;
+
+interface IAuraBooster {
+    
+    function deposit(uint256 _pid, uint256 _amount, bool _stake) external;
+
+    function depositAll(uint256 _pid, bool _stake) external;
+
+    function withdraw(uint256 _pid, uint256 _amount) external;
+
+    function withdrawAll(uint256 _pid) external;
+
+    function poolInfo(uint256 _pid) external view returns (address lpToken, address, address, address, address, bool);
+
+    function earmarkRewards(uint256 _pid) external;
+}

package/contracts/strategies/aura/interface/IAuraDepositor.sol

@@ -0,0 +1,7 @@
+//SPDX-License-Identifier: Unlicense
+pragma solidity 0.6.12;
+
+interface IAuraDepositor{
+    function deposit(uint256, bool) external;
+    function lockIncentive() external view returns(uint256);
+}