@gooddollar/goodprotocol 1.0.29-beta.4 → 1.0.29

package/contracts/fuseFaucet/Faucet.sol

@@ -1,247 +0,0 @@
-//SPDX-License-Identifier: MIT
-
-pragma solidity >=0.8.0;
-
-import "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol";
-import "@openzeppelin/contracts-upgradeable/proxy/utils/UUPSUpgradeable.sol";
-import "@openzeppelin/contracts-upgradeable/access/AccessControlUpgradeable.sol";
-import "../Interfaces.sol";
-import "../utils/NameService.sol";
-
-/**
- * @title DonationStaking contract that receives funds in ETH/DAI
- * and stake them in the SimpleStaking contract
- */
-contract Faucet is Initializable, UUPSUpgradeable, AccessControlUpgradeable {
-	bytes32 public constant RELAYER_ROLE = keccak256("relayer");
-
-	event WalletTopped(
-		address indexed account, //address topped
-		uint256 amount,
-		address whitelistedRoot, //if account is connected to a whitelisted account, this will be it
-		address indexed relayerOrWhitelisted //the sender of the tx
-	);
-
-	uint256 public perDayRoughLimit;
-	uint256 public toppingAmount;
-	uint256 public gasRefund;
-	uint256 public startTime;
-	uint256 public currentDay;
-
-	NameService public nameService;
-
-	mapping(uint256 => mapping(address => uint256)) public toppings;
-	mapping(address => bool) public notFirstTime;
-
-	struct Wallet {
-		uint128 lastDayTopped;
-		uint32 dailyToppingCount;
-		uint128[7] lastWeekToppings;
-	}
-
-	mapping(address => Wallet) public wallets;
-	uint32 public maxDailyToppings;
-	uint64 public gasPrice;
-	uint32 public maxPerWeekMultiplier;
-	uint32 public maxSwapAmount;
-	address public goodDollar_unused; //kept because of upgrades
-	uint64 public maxDailyNewWallets;
-	uint64 public dailyNewWalletsCount;
-
-	function initialize(
-		NameService _ns,
-		uint64 _gasPrice,
-		address relayer,
-		address owner
-	) public initializer {
-		__AccessControl_init_unchained();
-		_setupRole(DEFAULT_ADMIN_ROLE, owner);
-		if (relayer != address(0)) _setupRole(RELAYER_ROLE, relayer);
-		gasPrice = _gasPrice;
-		toppingAmount = 600000 * gasPrice; //0.6M gwei
-		perDayRoughLimit = 2 * toppingAmount;
-		maxDailyToppings = 3;
-		startTime = block.timestamp;
-		nameService = _ns;
-		maxPerWeekMultiplier = 2;
-		maxSwapAmount = 1000;
-		maxDailyNewWallets = 5000;
-	}
-
-	function _authorizeUpgrade(address newImplementation)
-		internal
-		override
-		onlyRole(DEFAULT_ADMIN_ROLE)
-	{}
-
-	function getIdentity() public view returns (IIdentityV2) {
-		return IIdentityV2(nameService.getAddress("IDENTITY"));
-	}
-
-	function upgrade() public {
-		if (maxDailyNewWallets == 0) maxDailyNewWallets = 5000;
-	}
-
-	modifier reimburseGas() {
-		uint256 _gasRefund = gasleft();
-		_;
-		_gasRefund = _gasRefund - gasleft() + 42000;
-		payable(msg.sender).transfer(_gasRefund * gasPrice); //gas price assumed 1e9 = 1gwei
-	}
-
-	receive() external payable {}
-
-	/*
-	 * only whitelisted account or relayer can top non whitelisted accounts
-	 * if target account is whitelisted anyone can top it
-	 */
-	modifier onlyAuthorized(address toTop) {
-		require(
-			getIdentity().getWhitelistedRoot(toTop) != address(0) ||
-				getIdentity().getWhitelistedRoot(msg.sender) != address(0) ||
-				hasRole(RELAYER_ROLE, msg.sender)
-		);
-		_;
-	}
-
-	modifier toppingLimit(address _user) {
-		//switch wallet to the account we do the accounting for
-		address whitelistedRoot = getIdentity().getWhitelistedRoot(_user);
-		_user = whitelistedRoot == address(0) ? _user : payable(whitelistedRoot);
-
-		uint256 prevDay = currentDay;
-
-		setDay();
-		if (currentDay != prevDay) dailyNewWalletsCount = 0;
-
-		require(
-			wallets[_user].lastDayTopped != uint128(currentDay) ||
-				wallets[_user].dailyToppingCount < maxDailyToppings,
-			"max daily toppings"
-		);
-
-		require(
-			(notFirstTime[_user] == false &&
-				dailyNewWalletsCount < maxDailyNewWallets) ||
-				whitelistedRoot != address(0),
-			"User not whitelisted or not first time"
-		);
-
-		//reset inactive days
-		uint256 dayOfWeek = currentDay % 7;
-		uint256 dayDiff = (currentDay - wallets[_user].lastDayTopped);
-		dayDiff = dayDiff > 7 ? 7 : dayDiff;
-		dayDiff = dayDiff > dayOfWeek ? dayOfWeek + 1 : dayDiff;
-		for (uint256 day = dayOfWeek + 1 - dayDiff; day <= dayOfWeek; day++) {
-			wallets[_user].lastWeekToppings[day] = 0;
-		}
-
-		uint128 weekTotal = 0;
-		for (uint256 i = 0; i <= dayOfWeek; i++) {
-			weekTotal += wallets[_user].lastWeekToppings[uint256(i)];
-		}
-
-		require(
-			weekTotal < perDayRoughLimit * maxPerWeekMultiplier,
-			"User wallet has been topped too many times this week"
-		);
-		_;
-	}
-
-	/* @dev Internal function that sets current day
-	 */
-	function setDay() internal {
-		currentDay = (block.timestamp - startTime) / 1 days;
-	}
-
-	function canTop(address _user) external view returns (bool) {
-		if (toppingAmount < address(_user).balance) return false;
-
-		address whitelistedRoot = getIdentity().getWhitelistedRoot(_user);
-		_user = whitelistedRoot == address(0) ? _user : whitelistedRoot;
-
-		uint256 _currentDay = (block.timestamp - startTime) / 1 days;
-		bool can = (wallets[_user].lastDayTopped != uint128(_currentDay) ||
-			wallets[_user].dailyToppingCount < 3) &&
-			((notFirstTime[_user] == false &&
-				dailyNewWalletsCount < maxDailyNewWallets) ||
-				whitelistedRoot != address(0));
-
-		uint128[7] memory lastWeekToppings = wallets[_user].lastWeekToppings;
-		//reset inactive days
-		uint256 dayOfWeek = _currentDay % 7;
-		uint256 dayDiff = (_currentDay - wallets[_user].lastDayTopped);
-		dayDiff = dayDiff > 7 ? 7 : dayDiff;
-		dayDiff = dayDiff > dayOfWeek ? dayOfWeek + 1 : dayDiff;
-
-		for (uint256 day = dayOfWeek + 1 - dayDiff; day <= dayOfWeek; day++) {
-			lastWeekToppings[day] = 0;
-		}
-
-		uint128 weekTotal = 0;
-		for (uint256 i = 0; i <= dayOfWeek; i++) {
-			weekTotal += lastWeekToppings[uint256(i)];
-		}
-		can = can && weekTotal < perDayRoughLimit * maxPerWeekMultiplier;
-		return can;
-	}
-
-	/* @dev Function to top given address with amount of G$ given in constructor
-	 * can only be done by admin the amount of times specified in constructor per day
-	 * @param _user The address to transfer to
-	 */
-	function topWallet(address payable _user)
-		public
-		reimburseGas
-		toppingLimit(_user)
-		onlyAuthorized(_user)
-	{
-		_topWallet(_user);
-	}
-
-	function _topWallet(address payable _wallet) internal {
-		address payable target = _wallet;
-
-		//switch wallet to the account we do the accounting for
-		address whitelistedRoot = getIdentity().getWhitelistedRoot(_wallet);
-		_wallet = whitelistedRoot == address(0)
-			? _wallet
-			: payable(whitelistedRoot);
-
-		require(toppingAmount > address(_wallet).balance);
-		uint256 toTop = toppingAmount - address(_wallet).balance;
-
-		uint256 dayOfWeek = currentDay % 7;
-
-		if (wallets[_wallet].lastDayTopped == uint128(currentDay))
-			wallets[_wallet].dailyToppingCount += 1;
-		else wallets[_wallet].dailyToppingCount = 1;
-		wallets[_wallet].lastDayTopped = uint128(currentDay);
-		wallets[_wallet].lastWeekToppings[dayOfWeek] += uint128(toTop);
-
-		if (notFirstTime[_wallet] == false && whitelistedRoot == address(0)) {
-			dailyNewWalletsCount++;
-		}
-		notFirstTime[_wallet] = true;
-
-		target.transfer(toTop);
-		emit WalletTopped(target, toTop, whitelistedRoot, msg.sender);
-	}
-
-	function onTokenTransfer(
-		address payable _from,
-		uint256 amount,
-		bytes calldata data
-	) external returns (bool) {
-		require(amount <= maxSwapAmount, "slippage");
-		address uniswapLike = abi.decode(data, (address));
-		Uniswap uniswap = Uniswap(uniswapLike);
-		address[] memory path = new address[](2);
-		path[0] = address(msg.sender);
-		path[1] = uniswap.WETH();
-
-		cERC20(msg.sender).approve(address(uniswapLike), type(uint256).max);
-		uniswap.swapExactTokensForETH(amount, 0, path, _from, block.timestamp);
-		return true;
-	}
-}

package/contracts/identity/IdentityV2.sol

@@ -1,434 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity >=0.8.0;
-
-import "@openzeppelin/contracts-upgradeable/access/AccessControlUpgradeable.sol";
-import "@openzeppelin/contracts-upgradeable/security/PausableUpgradeable.sol";
-import "@openzeppelin/contracts/utils/cryptography/SignatureChecker.sol";
-
-import "../utils/DAOUpgradeableContract.sol";
-import "../utils/NameService.sol";
-import "../Interfaces.sol";
-
-/* @title Identity contract responsible for whitelisting
- * and keeping track of amount of whitelisted users
- */
-contract IdentityV2 is
-	DAOUpgradeableContract,
-	AccessControlUpgradeable,
-	PausableUpgradeable
-{
-	struct Identity {
-		uint256 dateAuthenticated;
-		uint256 dateAdded;
-		string did;
-		uint256 whitelistedOnChainId;
-		uint8 status; //0 nothing, 1 whitelisted, 2 daocontract, 255 blacklisted
-	}
-
-	bytes32 public constant IDENTITY_ADMIN_ROLE = keccak256("identity_admin");
-	bytes32 public constant PAUSER_ROLE = keccak256("pause_admin");
-
-	uint256 public whitelistedCount;
-	uint256 public whitelistedContracts;
-	uint256 public authenticationPeriod;
-
-	mapping(address => Identity) public identities;
-
-	mapping(bytes32 => address) public didHashToAddress;
-
-	mapping(address => address) public connectedAccounts;
-
-	IIdentity public oldIdentity;
-
-	event BlacklistAdded(address indexed account);
-	event BlacklistRemoved(address indexed account);
-
-	event WhitelistedAdded(address indexed account);
-	event WhitelistedRemoved(address indexed account);
-	event WhitelistedAuthenticated(address indexed account, uint256 timestamp);
-
-	event ContractAdded(address indexed account);
-	event ContractRemoved(address indexed account);
-
-	function initialize(address _owner, IIdentity _oldIdentity)
-		public
-		initializer
-	{
-		__AccessControl_init_unchained();
-		__Pausable_init_unchained();
-		authenticationPeriod = 365 * 3;
-		_setupRole(DEFAULT_ADMIN_ROLE, avatar);
-		_setupRole(DEFAULT_ADMIN_ROLE, _owner);
-		_setupRole(PAUSER_ROLE, avatar);
-		_setupRole(PAUSER_ROLE, _owner);
-		_setupRole(IDENTITY_ADMIN_ROLE, _owner);
-		_setupRole(IDENTITY_ADMIN_ROLE, avatar);
-
-		oldIdentity = _oldIdentity;
-	}
-
-	function initDAO(address _ns) external onlyRole(DEFAULT_ADMIN_ROLE) {
-		require(address(nameService) == address(0), "already initialized");
-		setDAO(INameService(_ns));
-		_setupRole(DEFAULT_ADMIN_ROLE, avatar);
-		_setupRole(PAUSER_ROLE, avatar);
-		_setupRole(IDENTITY_ADMIN_ROLE, avatar);
-	}
-
-	modifier onlyWhitelisted() {
-		require(isWhitelisted(msg.sender), "not whitelisted");
-		_;
-	}
-
-	/* @dev Sets a new value for authenticationPeriod.
-	 * Can only be called by Identity Administrators.
-	 * @param period new value for authenticationPeriod
-	 */
-	function setAuthenticationPeriod(uint256 period) external whenNotPaused {
-		_onlyAvatar();
-		authenticationPeriod = period;
-	}
-
-	/* @dev Sets the authentication date of `account`
-	 * to the current time.
-	 * Can only be called by Identity Administrators.
-	 * @param account address to change its auth date
-	 */
-	function authenticate(address account)
-		public
-		onlyRole(IDENTITY_ADMIN_ROLE)
-		whenNotPaused
-	{
-		require(identities[account].status == 1, "not whitelisted");
-		identities[account].dateAuthenticated = block.timestamp;
-		emit WhitelistedAuthenticated(account, block.timestamp);
-	}
-
-	/* @dev Adds an address as whitelisted.
-	 * Can only be called by Identity Administrators.
-	 * @param account address to add as whitelisted
-	 */
-	function addWhitelisted(address account)
-		public
-		onlyRole(IDENTITY_ADMIN_ROLE)
-		whenNotPaused
-	{
-		_addWhitelisted(account, _chainId());
-	}
-
-	/* @dev Adds an address as whitelisted under a specific ID
-	 * @param account The address to add
-	 * @param did the ID to add account under
-	 */
-	function addWhitelistedWithDIDAndChain(
-		address account,
-		string memory did,
-		uint256 orgChain,
-		uint256 dateAuthenticated
-	) external onlyRole(IDENTITY_ADMIN_ROLE) whenNotPaused {
-		_addWhitelistedWithDID(account, did, orgChain);
-
-		//in case we are whitelisting on a new chain an already whitelisted account, we need to make sure it expires at the same time
-		if (dateAuthenticated > 0) {
-			identities[account].dateAuthenticated = dateAuthenticated;
-		}
-	}
-
-	/* @dev Adds an address as whitelisted under a specific ID
-	 * @param account The address to add
-	 * @param did the ID to add account under
-	 */
-	function addWhitelistedWithDID(address account, string memory did)
-		public
-		onlyRole(IDENTITY_ADMIN_ROLE)
-		whenNotPaused
-	{
-		_addWhitelistedWithDID(account, did, _chainId());
-	}
-
-	/* @dev Removes an address as whitelisted.
-	 * Can only be called by Identity Administrators.
-	 * @param account address to remove as whitelisted
-	 */
-	function removeWhitelisted(address account)
-		public
-		onlyRole(IDENTITY_ADMIN_ROLE)
-		whenNotPaused
-	{
-		_removeWhitelisted(account);
-	}
-
-	/* @dev Renounces message sender from whitelisted
-	 */
-	function renounceWhitelisted() external whenNotPaused {
-		_removeWhitelisted(msg.sender);
-	}
-
-	/* @dev Returns true if given address has been added to whitelist
-	 * @param account the address to check
-	 * @return a bool indicating weather the address is present in whitelist
-	 */
-	function isWhitelisted(address account) public view returns (bool) {
-		uint256 daysSinceAuthentication = (block.timestamp -
-			identities[account].dateAuthenticated) / 1 days;
-		if (
-			(daysSinceAuthentication <= authenticationPeriod) &&
-			identities[account].status == 1
-		) return true;
-
-		if (address(oldIdentity) != address(0)) {
-			try oldIdentity.isWhitelisted(account) returns (bool res) {
-				return res;
-			} catch {
-				return false;
-			}
-		}
-		return false;
-	}
-
-	/* @dev Function that gives the date the given user was added
-	 * @param account The address to check
-	 * @return The date the address was added
-	 */
-	function lastAuthenticated(address account) external view returns (uint256) {
-		return identities[account].dateAuthenticated;
-	}
-
-	/* @dev Adds an address to blacklist.
-	 * Can only be called by Identity Administrators.
-	 * @param account address to add as blacklisted
-	 */
-	function addBlacklisted(address account)
-		public
-		onlyRole(IDENTITY_ADMIN_ROLE)
-		whenNotPaused
-	{
-		identities[account].status = 255;
-		emit BlacklistAdded(account);
-	}
-
-	/* @dev Removes an address from blacklist
-	 * Can only be called by Identity Administrators.
-	 * @param account address to remove as blacklisted
-	 */
-	function removeBlacklisted(address account)
-		external
-		onlyRole(IDENTITY_ADMIN_ROLE)
-		whenNotPaused
-	{
-		if (address(oldIdentity) != address(0))
-			try oldIdentity.removeBlacklisted(account) {} catch {}
-
-		identities[account].status = 0;
-		emit BlacklistRemoved(account);
-	}
-
-	/* @dev Function to add a Contract to list of contracts
-	 * @param account The address to add
-	 */
-	function addContract(address account)
-		public
-		onlyRole(IDENTITY_ADMIN_ROLE)
-		whenNotPaused
-	{
-		require(isContract(account), "Given address is not a contract");
-		_addWhitelisted(account, _chainId());
-		identities[account].status = 2;
-
-		emit ContractAdded(account);
-	}
-
-	/* @dev Function to remove a Contract from list of contracts
-	 * @param account The address to add
-	 */
-	function removeContract(address account)
-		public
-		onlyRole(IDENTITY_ADMIN_ROLE)
-		whenNotPaused
-	{
-		_removeWhitelisted(account);
-
-		emit ContractRemoved(account);
-	}
-
-	/* @dev Function to check if given contract is on list of contracts.
-	 * @param address to check
-	 * @return a bool indicating if address is on list of contracts
-	 */
-	function isDAOContract(address account) external view returns (bool) {
-		if (identities[account].status == 2) return true;
-		if (address(oldIdentity) != address(0)) {
-			try oldIdentity.isDAOContract(account) returns (bool res) {
-				return res;
-			} catch {
-				return false;
-			}
-		}
-		return false;
-	}
-
-	/* @dev Internal function to add to whitelisted
-	 * @param account the address to add
-	 */
-	function _addWhitelisted(address account, uint256 orgChain) internal {
-		whitelistedCount += 1;
-		identities[account].status = 1;
-		identities[account].dateAdded = block.timestamp;
-		identities[account].dateAuthenticated = block.timestamp;
-		identities[account].whitelistedOnChainId = orgChain;
-		connectedAccounts[account] = address(0);
-
-		if (isContract(account)) {
-			whitelistedContracts += 1;
-		}
-
-		emit WhitelistedAdded(account);
-	}
-
-	/* @dev Internal whitelisting with did function.
-	 * @param account the address to add
-	 * @param did the id to register account under
-	 */
-	function _addWhitelistedWithDID(
-		address account,
-		string memory did,
-		uint256 orgChain
-	) internal {
-		bytes32 pHash = keccak256(bytes(did));
-		require(didHashToAddress[pHash] == address(0), "DID already registered");
-
-		identities[account].did = did;
-		didHashToAddress[pHash] = account;
-
-		_addWhitelisted(account, orgChain);
-	}
-
-	/* @dev Internal function to remove from whitelisted
-	 * @param account the address to add
-	 */
-	function _removeWhitelisted(address account) internal {
-		whitelistedCount -= 1;
-
-		if (isContract(account)) {
-			whitelistedContracts -= 1;
-			if (address(oldIdentity) != address(0)) {
-				try oldIdentity.removeContract(account) {} catch {}
-			}
-		}
-		if (address(oldIdentity) != address(0)) {
-			try oldIdentity.removeWhitelisted(account) {} catch {}
-		}
-
-		string memory did = identities[account].did;
-		bytes32 pHash = keccak256(bytes(did));
-
-		delete identities[account];
-		delete didHashToAddress[pHash];
-
-		emit WhitelistedRemoved(account);
-	}
-
-	/// @notice helper function to get current chain id
-	/// @return chainId id
-	function _chainId() internal view returns (uint256 chainId) {
-		assembly {
-			chainId := chainid()
-		}
-	}
-
-	/* @dev Returns true if given address has been added to the blacklist
-	 * @param account the address to check
-	 * @return a bool indicating weather the address is present in the blacklist
-	 */
-	function isBlacklisted(address account) public view returns (bool) {
-		if (identities[account].status == 255) return true;
-		if (address(oldIdentity) != address(0)) {
-			try oldIdentity.isBlacklisted(account) returns (bool res) {
-				return res;
-			} catch {
-				return false;
-			}
-		}
-	}
-
-	/* @dev Function to see if given address is a contract
-	 * @return true if address is a contract
-	 */
-	function isContract(address _addr) internal view returns (bool) {
-		uint256 length;
-		assembly {
-			length := extcodesize(_addr)
-		}
-		return length > 0;
-	}
-
-	function connectAccount(address _account, bytes memory signature)
-		external
-		onlyWhitelisted
-	{
-		require(
-			!isWhitelisted(_account) && !isBlacklisted(_account),
-			"invalid account"
-		);
-		require(connectedAccounts[_account] == address(0x0), "already connected");
-		//signature ensures the whitelisted (msg.sender) has submited a signature by connected account
-		//that connects both accounts
-		require(
-			SignatureChecker.isValidSignatureNow(
-				_account,
-				keccak256(abi.encode(msg.sender, _account)),
-				signature
-			),
-			"invalid signature"
-		);
-		connectedAccounts[_account] = msg.sender;
-	}
-
-	function getWhitelistedRoot(address _account)
-		external
-		view
-		returns (address whitelisted)
-	{
-		if (isWhitelisted(_account)) return _account;
-		if (isWhitelisted(connectedAccounts[_account]))
-			return connectedAccounts[_account];
-
-		return address(0x0);
-	}
-
-	function pause(bool _toPause) external onlyRole(PAUSER_ROLE) {
-		if (_toPause) _pause();
-		else _unpause();
-	}
-
-	function setDID(string calldata did) external onlyWhitelisted {
-		bytes32 pHash = keccak256(bytes(did));
-		require(didHashToAddress[pHash] == address(0), "DID already registered");
-
-		bytes32 oldHash = keccak256(bytes(identities[msg.sender].did));
-		delete didHashToAddress[oldHash];
-		identities[msg.sender].did = did;
-		didHashToAddress[pHash] = msg.sender;
-	}
-
-	function addrToDID(address account)
-		external
-		view
-		returns (string memory did)
-	{
-		did = identities[msg.sender].did;
-		if (bytes(did).length > 0) return did;
-		try oldIdentity.addrToDID(account) returns (string memory _did) {
-			return _did;
-		} catch {
-			return "";
-		}
-	}
-
-	/**
-	 * compatability with IdentityV1 that GoodDollar token checks if the identity contract is registered
-	 */
-	function isRegistered() external pure returns (bool) {
-		return true;
-	}
-}