@gearbox-protocol/periphery-v3 1.3.19 → 1.4.0

package/README.md

@@ -1,2 +1 @@
-## Gearbox PeripheryV3
-
+# Gearbox V3 Periphery

package/contracts/test/ForkTest.sol

@@ -0,0 +1,44 @@
+// SPDX-License-Identifier: UNLICENSED
+// Gearbox Protocol. Generalized leverage for DeFi protocols
+// (c) Gearbox Foundation, 2024.
+pragma solidity ^0.8.17;
+
+import {Test} from "forge-std/Test.sol";
+
+import {ACL} from "@gearbox-protocol/core-v2/contracts/core/ACL.sol";
+import {ContractsRegister} from "@gearbox-protocol/core-v2/contracts/core/ContractsRegister.sol";
+
+import {
+    AP_ACL,
+    AP_CONTRACTS_REGISTER,
+    IAddressProviderV3,
+    NO_VERSION_CONTROL
+} from "@gearbox-protocol/core-v3/contracts/interfaces/IAddressProviderV3.sol";
+
+abstract contract ForkTest is Test {
+    IAddressProviderV3 addressProvider;
+    ACL acl;
+    ContractsRegister register;
+    address configurator;
+
+    modifier onlyFork() {
+        if (address(addressProvider) != address(0)) _;
+    }
+
+    function _createFork() internal {
+        string memory rpcUrl = vm.envOr("FORK_RPC_URL", string(""));
+        if (bytes(rpcUrl).length == 0) return;
+
+        uint256 blockNumber = vm.envOr("FORK_BLOCK_NUMBER", type(uint256).max);
+        if (blockNumber == type(uint256).max) {
+            vm.createSelectFork(rpcUrl);
+        } else {
+            vm.createSelectFork(rpcUrl, blockNumber);
+        }
+
+        addressProvider = IAddressProviderV3(vm.envAddress("FORK_ADDRESS_PROVIDER"));
+        acl = ACL(addressProvider.getAddressOrRevert(AP_ACL, NO_VERSION_CONTROL));
+        register = ContractsRegister(addressProvider.getAddressOrRevert(AP_CONTRACTS_REGISTER, NO_VERSION_CONTROL));
+        configurator = acl.owner();
+    }
+}

package/contracts/test/MultiPause.t.sol

@@ -0,0 +1,113 @@
+// SPDX-License-Identifier: UNLICENSED
+// Gearbox Protocol. Generalized leverage for DeFi protocols
+// (c) Gearbox Foundation, 2024.
+pragma solidity ^0.8.17;
+
+import {ICreditManagerV3} from "@gearbox-protocol/core-v3/contracts/interfaces/ICreditManagerV3.sol";
+import {CallerNotPausableAdminException} from "@gearbox-protocol/core-v3/contracts/interfaces/IExceptions.sol";
+import {ACLNonReentrantTrait} from "@gearbox-protocol/core-v3/contracts/traits/ACLNonReentrantTrait.sol";
+
+import {MultiPause} from "../utils/MultiPause.sol";
+
+import {ForkTest} from "./ForkTest.sol";
+
+contract MultiPauseTest is ForkTest {
+    MultiPause multiPause;
+    address admin;
+
+    function setUp() public {
+        _createFork();
+
+        multiPause = new MultiPause(address(addressProvider));
+        admin = makeAddr("ADMIN");
+
+        vm.startPrank(configurator);
+        acl.addPausableAdmin(admin);
+        acl.addPausableAdmin(address(multiPause));
+        vm.stopPrank();
+    }
+
+    function test_MP_01_functions_revert_if_caller_is_not_pausable_admin() public onlyFork {
+        vm.expectRevert(CallerNotPausableAdminException.selector);
+        multiPause.pauseContracts(new address[](0));
+
+        vm.expectRevert(CallerNotPausableAdminException.selector);
+        multiPause.pauseAllPools();
+
+        vm.expectRevert(CallerNotPausableAdminException.selector);
+        multiPause.pauseAllCreditManagers();
+
+        vm.expectRevert(CallerNotPausableAdminException.selector);
+        multiPause.pauseAllContracts();
+    }
+
+    function test_MP_02_pauseContracts_works_as_expected() public onlyFork {
+        address[] memory pools = register.getPools();
+
+        // ensure that at least one contract is paused
+        if (!ACLNonReentrantTrait(pools[0]).paused()) {
+            vm.prank(admin);
+            ACLNonReentrantTrait(pools[0]).pause();
+        }
+
+        vm.prank(admin);
+        multiPause.pauseContracts(pools);
+
+        _assert_allPoolsPaused();
+    }
+
+    function test_MP_03_pauseAllPools_works_as_expected() public onlyFork {
+        vm.prank(admin);
+        multiPause.pauseAllPools();
+        _assert_allPoolsPaused();
+    }
+
+    function test_MP_04_pauseAllCreditManagers_works_as_expected() public onlyFork {
+        vm.prank(admin);
+        multiPause.pauseAllCreditManagers();
+        _assert_allManagersPaused();
+    }
+
+    function test_MP_05_pauseAllContracts_works_as_expected() public onlyFork {
+        vm.prank(admin);
+        multiPause.pauseAllContracts();
+        _assert_allPoolsPaused();
+        _assert_allManagersPaused();
+    }
+
+    function _assert_contractsPaused(address[] memory contracts) internal {
+        for (uint256 i; i < contracts.length; ++i) {
+            assertTrue(
+                ACLNonReentrantTrait(contracts[i]).paused(),
+                string.concat("Contract ", vm.toString(contracts[i]), " is not paused")
+            );
+        }
+    }
+
+    function _assert_allPoolsPaused() internal {
+        address[] memory pools = register.getPools();
+        for (uint256 i; i < pools.length; ++i) {
+            assertTrue(
+                ACLNonReentrantTrait(pools[i]).paused(), string.concat("Pool ", vm.toString(pools[i]), " is not paused")
+            );
+        }
+    }
+
+    function _assert_allManagersPaused() internal {
+        address[] memory creditManagers = register.getCreditManagers();
+        for (uint256 i; i < creditManagers.length; ++i) {
+            if (ICreditManagerV3(creditManagers[i]).version() < 3_00) {
+                assertTrue(
+                    ACLNonReentrantTrait(creditManagers[i]).paused(),
+                    string.concat("Manager ", vm.toString(creditManagers[i]), " is not paused")
+                );
+            } else {
+                address facade = ICreditManagerV3(creditManagers[i]).creditFacade();
+                assertTrue(
+                    ACLNonReentrantTrait(facade).paused(),
+                    string.concat("Facade ", vm.toString(facade), " is not paused")
+                );
+            }
+        }
+    }
+}

package/contracts/utils/MultiPause.sol

@@ -0,0 +1,80 @@
+// SPDX-License-Identifier: BUSL-1.1
+// Gearbox Protocol. Generalized leverage for DeFi protocols
+// (c) Gearbox Foundation, 2024.
+pragma solidity ^0.8.17;
+
+import {IContractsRegister} from "@gearbox-protocol/core-v2/contracts/interfaces/IContractsRegister.sol";
+
+import {ICreditManagerV3} from "@gearbox-protocol/core-v3/contracts/interfaces/ICreditManagerV3.sol";
+import {ACLNonReentrantTrait} from "@gearbox-protocol/core-v3/contracts/traits/ACLNonReentrantTrait.sol";
+import {ContractsRegisterTrait} from "@gearbox-protocol/core-v3/contracts/traits/ContractsRegisterTrait.sol";
+
+/// @title MultiPause
+/// @author Gearbox Foundation
+/// @notice Allows pausable admins to pause multiple contracts in a single transaction
+/// @dev This contract is expected to be one of pausable admins in the ACL contract
+contract MultiPause is ACLNonReentrantTrait, ContractsRegisterTrait {
+    constructor(address addressProvider)
+        ACLNonReentrantTrait(addressProvider)
+        ContractsRegisterTrait(addressProvider)
+    {}
+
+    /// @notice Pauses contracts from the given list
+    /// @dev Ignores contracts that are already paused
+    /// @dev Reverts if caller is not a pausable admin
+    function pauseContracts(address[] memory contracts) external pausableAdminsOnly {
+        _pauseContracts(contracts);
+    }
+
+    /// @notice Pauses all registered pools
+    /// @dev Ignores contracts that are already paused
+    /// @dev Reverts if caller is not a pausable admin
+    function pauseAllPools() external pausableAdminsOnly {
+        _pauseAllPools();
+    }
+
+    /// @notice Pauses all registered credit managers
+    /// @dev For V3, credit facades are paused instead
+    /// @dev Ignores contracts that are already paused
+    /// @dev Reverts if caller is not a pausable admin
+    function pauseAllCreditManagers() external pausableAdminsOnly {
+        _pauseAllCreditManagers();
+    }
+
+    /// @notice Pauses all registered credit managers and pools
+    /// @dev Ignores contracts that are already paused
+    /// @dev Reverts if caller is not a pausable admin
+    function pauseAllContracts() external pausableAdminsOnly {
+        _pauseAllPools();
+        _pauseAllCreditManagers();
+    }
+
+    /// @dev Internal function to pause all pools
+    function _pauseAllPools() internal {
+        _pauseContracts(IContractsRegister(contractsRegister).getPools());
+    }
+
+    /// @dev Internal function to pause all credit managers
+    function _pauseAllCreditManagers() internal {
+        address[] memory contracts = IContractsRegister(contractsRegister).getCreditManagers();
+        uint256 len = contracts.length;
+        unchecked {
+            for (uint256 i; i < len; ++i) {
+                if (ICreditManagerV3(contracts[i]).version() < 3_00) continue;
+                contracts[i] = ICreditManagerV3(contracts[i]).creditFacade();
+            }
+        }
+        _pauseContracts(contracts);
+    }
+
+    /// @dev Internal function to pause contracts from the given list
+    function _pauseContracts(address[] memory contracts) internal {
+        uint256 len = contracts.length;
+        unchecked {
+            for (uint256 i; i < len; ++i) {
+                if (ACLNonReentrantTrait(contracts[i]).paused()) continue;
+                ACLNonReentrantTrait(contracts[i]).pause();
+            }
+        }
+    }
+}

package/package.json

@@ -1,6 +1,6 @@
 {
   "name": "@gearbox-protocol/periphery-v3",
-  "version": "1.3.19",
+  "version": "1.4.0",
   "main": "index.js",
   "repository": "git@github.com:Gearbox-protocol/periphery-v3.git",
   "author": "Mikael <26343374+0xmikko@users.noreply.github.com>",

package/contracts/emergency/PauseMulticall.sol

@@ -1,78 +0,0 @@
-// SPDX-License-Identifier: BUSL-1.1
-// Gearbox Protocol. Generalized leverage for DeFi protocols
-// (c) Gearbox Holdings, 2024
-pragma solidity ^0.8.17;
-
-import {ACLNonReentrantTrait} from "@gearbox-protocol/core-v3/contracts/traits/ACLNonReentrantTrait.sol";
-import {
-    IAddressProviderV3,
-    AP_CONTRACTS_REGISTER,
-    NO_VERSION_CONTROL
-} from "@gearbox-protocol/core-v3/contracts/interfaces/IAddressProviderV3.sol";
-import {ContractsRegister} from "@gearbox-protocol/core-v2/contracts/core/ContractsRegister.sol";
-import {
-    IAddressProviderV3,
-    AP_CONTRACTS_REGISTER
-} from "@gearbox-protocol/core-v3/contracts/interfaces/IAddressProviderV3.sol";
-import {ICreditManagerV3} from "@gearbox-protocol/core-v3/contracts/interfaces/ICreditManagerV3.sol";
-
-contract PauseMulticall is ACLNonReentrantTrait {
-    ContractsRegister public immutable cr;
-
-    constructor(address _addressProvider) ACLNonReentrantTrait(_addressProvider) {
-        cr = ContractsRegister(
-            IAddressProviderV3(_addressProvider).getAddressOrRevert(AP_CONTRACTS_REGISTER, NO_VERSION_CONTROL)
-        ); // F: [PM-01]
-    }
-
-    function pauseAllCreditManagers()
-        external
-        pausableAdminsOnly // F:[PM-05]
-    {
-        _pauseAllCreditManagers();
-    }
-
-    function pauseAllPools()
-        external
-        pausableAdminsOnly // F:[PM-05]
-    {
-        _pauseAllPools(); // F: [PM-03]
-    }
-
-    function pauseAllContracts()
-        external
-        pausableAdminsOnly // F:[PM-05]
-    {
-        _pauseAllPools();
-        _pauseAllCreditManagers();
-    }
-
-    function _pauseAllPools() internal {
-        _pauseBatchOfContracts(cr.getPools()); // F: [PM-03]
-    }
-
-    function _pauseAllCreditManagers() internal {
-        address[] memory allCreditManagers = cr.getCreditManagers();
-
-        unchecked {
-            for (uint256 i = 0; i < allCreditManagers.length; ++i) {
-                uint256 version = ICreditManagerV3(allCreditManagers[i]).version();
-                if (version >= 3_00) {
-                    allCreditManagers[i] = ICreditManagerV3(allCreditManagers[i]).creditFacade();
-                }
-            }
-        }
-
-        _pauseBatchOfContracts(allCreditManagers); // F: [PM-04] // F: [PM-02]
-    }
-
-    function _pauseBatchOfContracts(address[] memory contractsToPause) internal {
-        uint256 len = contractsToPause.length;
-        unchecked {
-            for (uint256 i = 0; i < len; ++i) {
-                // try-catch block to ignore some contracts which are already paused
-                try ACLNonReentrantTrait(contractsToPause[i]).pause() {} catch {}
-            }
-        }
-    }
-}

package/contracts/test/PauseMulticall.t.sol

@@ -1,48 +0,0 @@
-// SPDX-License-Identifier: UNLICENSED
-// Gearbox Protocol. Generalized leverage for DeFi protocols
-// (c) Gearbox Holdings, 2024
-pragma solidity ^0.8.17;
-
-import {PauseMulticall} from "../emergency/PauseMulticall.sol";
-import {
-    IAddressProviderV3,
-    AP_CONTRACTS_REGISTER,
-    NO_VERSION_CONTROL
-} from "@gearbox-protocol/core-v3/contracts/interfaces/IAddressProviderV3.sol";
-import {ContractsRegister} from "@gearbox-protocol/core-v2/contracts/core/ContractsRegister.sol";
-import {
-    IAddressProviderV3,
-    AP_CONTRACTS_REGISTER
-} from "@gearbox-protocol/core-v3/contracts/interfaces/IAddressProviderV3.sol";
-import {ICreditManagerV3} from "@gearbox-protocol/core-v3/contracts/interfaces/ICreditManagerV3.sol";
-import {NetworkDetector} from "@gearbox-protocol/sdk-gov/contracts/NetworkDetector.sol";
-
-import {Test} from "forge-std/Test.sol";
-import "forge-std/console.sol";
-
-address constant ap = 0x9ea7b04Da02a5373317D745c1571c84aaD03321D;
-
-contract PauseMulticallTest is Test {
-    uint256 chainId;
-
-    PauseMulticall pm;
-
-    constructor() {
-        NetworkDetector nd = new NetworkDetector();
-        chainId = nd.chainId();
-    }
-
-    modifier liveTestOnly() {
-        if (chainId == 1) {
-            _;
-        }
-    }
-
-    function setUp() public liveTestOnly {
-        pm = new PauseMulticall(ap);
-    }
-
-    ///
-    /// TESTS
-    ///
-}