@fornari-lanza/domain-design-language-language 0.0.1

package/src/domain-design-language.langium

@@ -0,0 +1,299 @@
+grammar DomainDesignLanguage
+
+entry DomainModel:
+    (boundedContext=BoundedContext)?
+    (contextMap=ContextMap)?;
+
+//BOUNDED CONTEXTS
+BoundedContext:
+    'BoundedContext' name=ID '{'
+        description=STRING
+        ubiquitousLanguage=UbiquitousLanguageDeclaration
+        (aggregates+=AggregateRoot)*
+        (domainServices+=DomainService)*
+        (ports+=Port)*
+        (commands+=Command)*
+        (eventStorming=EventStormingDeclaration)?
+    '}';
+
+//UBIQUITOUS LANGUAGE
+UbiquitousLanguageDeclaration:
+    'UbiquitousLanguage' '{'
+        (terms+=Term)*
+    '}';
+
+Term:
+    name=ID '{'
+        'definition:' definition=STRING
+        ('aliases:' '['
+            (aliases+=STRING (',' aliases+=STRING)*)?
+        ']')?
+    '}';
+
+//CONTEXT MAP
+ContextMap:
+    'ContextMap' '{'
+        (relationships+=Relationship)*
+    '}';
+
+Relationship:
+    AsymmetricRelationship | SymmetricRelationship;
+
+AsymmetricRelationship:
+    'Relationship' '{'
+        'upstream:' upstream=[BoundedContext:ID] ('[' (upstreamRoles+=UpstreamRole) (',' upstreamRoles+=UpstreamRole)? ']')?
+        'downstream:' downstream=[BoundedContext:ID] ('[' (downstreamRole=DownstreamRole) ']')?
+        (customerSupplier?='Customer/Supplier')?
+        (description=STRING)?
+    '}';
+
+UpstreamRole returns string:
+    ('OpenHostService' | 'PublishedLanguage');
+
+DownstreamRole returns string:
+    ('AntiCorruptionLayer' | 'Conformist');
+
+SymmetricRelationship:
+    'Relationship' '{'
+        type=('Partnership' | 'SharedKernel')
+        'between' participant1=[BoundedContext:ID]
+        'and' participant2=[BoundedContext:ID]
+        (description=STRING)?
+    '}';
+
+//AGGREGATES
+AggregateRoot:
+    'AggregateRoot' name=ID '{'
+        description=STRING
+        ('enforcedInvariants:' '['
+            (enforcedInvariants+=STRING (',' enforcedInvariants+=STRING)*)?
+        ']')?
+        ('correctivePolicies:' '['
+            (correctivePolicies+=STRING (',' correctivePolicies+=STRING)*)?
+        ']')?
+        id=UID
+        (attributes+=AggregateAttribute)*
+        (methods=MethodsDeclaration)?
+        (events=DomainEventsDeclaration)?
+        (exceptions=ExceptionsDeclaration)?
+    '}';
+
+AggregateAttribute:
+    (many?='many')? (optional?='optional')? type=(ValueObject | Entity | Reference); 
+
+//AGGREGATE METHODS
+MethodsDeclaration:
+    'Methods' '{'
+        (methods+=Method)*
+    '}';
+
+Method:
+    name=ID '(' (input=MethodInput)? ')' '{'
+        (description=STRING)?
+    '}';
+
+MethodInput:
+    (attributes+=DomainAttribute) (',' attributes+=DomainAttribute)*;
+
+//DOMAIN EXCEPTIONS
+ExceptionsDeclaration:
+    'DomainExceptions' '{'
+        (exceptions+=DomainException)*
+    '}';
+
+DomainException:
+    name=ID (description=STRING)?;
+
+//ENTITIES
+Entity:
+    'Entity' name=ID '{'
+        description=STRING
+        id=UID
+        (attributes+=EntityAttribute)*
+    '}';
+
+EntityAttribute:
+    (many?='many')? (optional?='optional')? type=(ValueObject | Reference); 
+
+//VALUE OBJECTS
+ValueObject:
+    'ValueObject' name=ID '{'
+        (description=STRING)?
+        ('enforcedInvariants:' '['
+            (enforcedInvariants+=STRING (',' enforcedInvariants+=STRING)*)?
+        ']')? 
+        (attributes+=PrimitiveAttribute)+
+    '}';
+
+//DOMAIN EVENTS
+DomainEventsDeclaration:
+    'DomainEvents' '{'
+        (events+=DomainEvent)*
+    '}';
+
+DomainEvent:
+    name=ID '{'
+        (description=STRING)?
+        (payload=Payload)?
+    '}';
+
+Payload:
+    'payload:' '{'
+        (attributes+=PrimitiveAttribute)+
+    '}';
+
+//DOMAIN SERVICES
+DomainService:
+    'DomainService' name=ID '{'
+        description=STRING
+        'type:' type=('contract' | 'coordination' | 'calculation')
+        (input=DomainServiceInput)?   
+        (response=DomainServiceResponse)?
+    '}';
+
+DomainServiceInput:
+    'input:' '{' 
+        (attributes+=DomainAttribute)+
+    '}';
+
+DomainServiceResponse:
+    'response:' '{' 
+        (attributes+=(DomainAttribute | PrimitiveAttribute))+
+    '}';
+
+//REPOSITORIES
+/* Repository:
+    'Repository' aggregate=[AggregateRoot:QualifiedName]; */
+
+//APPLICATION LAYER
+Port:
+    'Port' name=ID '{'
+        (description=STRING)?
+    '}';
+
+Command:
+    'Command' name=ID '{'
+        (description=STRING)?
+        (input=InputDTO)?
+        (response=ResponseDTO)?
+        'uses' aggregate=[AggregateRoot:QualifiedName]
+        'emits' events+=[DomainEvent:QualifiedName] (',' events+=[DomainEvent:QualifiedName])*
+        ('uses' domainServices+=[DomainService:QualifiedName] (',' domainServices+=[DomainService:QualifiedName])*)?
+        ('dependencies:' '[' (dependencies+=Dependency) (',' dependencies+=Dependency)* ']')?
+    '}';
+
+InputDTO:
+    'input:' '{' 
+        (attributes+=PrimitiveAttribute)+
+    '}';
+
+ResponseDTO:
+    'response:' '{' 
+        (attributes+=PrimitiveAttribute)+
+    '}';
+
+Dependency:
+    port=[Port:QualifiedName];
+
+//EVENT STORMING
+EventStormingDeclaration:
+    'EventStorming' '{'
+        (elements+=EventStormingElement)*
+        (flows+=ProcessFlow)*
+    '}';
+
+EventStormingElement:
+    Actor | ExternalSystem | ReadModel;
+
+Actor:
+    'Actor' name=ID '{'
+        (description=STRING)?
+    '}';
+
+Policy:
+    'Policy' name=ID '{'
+        (description=STRING)?
+        'invokes' command=[Command:ID]
+    '}';
+
+ReadModel:
+    'ReadModel' name=ID '{'
+        (description=STRING)?
+    '}';
+
+ExternalSystem:
+    'ExternalSystem' name=ID '{'
+        (description=STRING)?
+    '}';
+
+ProcessFlow:
+    'ProcessFlow' name=ID '{'
+        (description=STRING)?
+        (given=GivenStep)?
+        (command=ActorCommandStep)
+        (reactions+=ReactionStep)*
+    '}';
+
+GivenStep:
+    'given' actor=[Actor:ID] 'views' readModel=[ReadModel:QualifiedName];
+
+ActorCommandStep:
+    issuer=[Actor:ID] 'issues' command=[Command:ID];
+
+ReactionStep:
+    'on' trigger=[DomainEvent:QualifiedName] 'then' '{'
+        (outcomes+=ReactionOutcome)+
+    '}';
+
+ReactionOutcome:
+    Projection | PolicyTrigger;
+
+Projection:
+    'projects' 'to' readModel=[ReadModel:QualifiedName] ('hotspot' hotspot=STRING)?;
+
+PolicyTrigger:
+    'triggers' policy=Policy ('hotspot' hotspot=STRING)?;
+
+//ID
+UID:
+    'UID' '{'
+        'type:' type=IDType
+        ('enforcedInvariants:' '['
+            (enforcedInvariants+=STRING (',' enforcedInvariants+=STRING)*)?
+        ']')? 
+    '}';
+
+IDType returns string:
+    'string' | 'number';
+
+//TYPES
+Reference:
+    name=ID ':' to=[AggregateRoot:ID];
+
+DomainAttribute:
+    (many?='many')? (optional?='optional')? name=ID ':' type=[DomainObject:QualifiedName];
+
+type DomainObject =
+    ValueObject | AggregateRoot | Entity;
+
+PrimitiveAttribute:
+    (many?='many')? (optional?='optional')? name=ID ':' type=(Primitive | Enum);
+
+Primitive returns string:
+    'string' | 'number' | 'boolean' | 'date';
+
+Enum:
+    'Enum' '('
+        (values+=ID) (',' values+=ID)*
+    ')';
+
+QualifiedName returns string:
+    ID ('.' ID)*;
+
+hidden terminal WS: /\s+/;
+terminal ID: /[_a-zA-Z][\w_]*/;
+terminal INT returns number: /[0-9]+/;
+terminal STRING: /"(\\.|[^"\\])*"|'(\\.|[^'\\])*'/;
+
+hidden terminal ML_COMMENT: /\/\*[\s\S]*?\*\//;
+hidden terminal SL_COMMENT: /\/\/[^\n\r]*/;