@fendent/react-native-enriched 0.5.2-fork.1

package/ios/styles/UnorderedListStyle.mm

@@ -0,0 +1,86 @@
+#import "EnrichedTextInputView.h"
+#import "RangeUtils.h"
+#import "StyleHeaders.h"
+#import "TextInsertionUtils.h"
+
+@implementation UnorderedListStyle
+
++ (StyleType)getType {
+  return UnorderedList;
+}
+
+- (NSString *)getValue {
+  return @"EnrichedUnorderedList";
+}
+
+- (BOOL)isParagraph {
+  return YES;
+}
+
+- (BOOL)needsZWS {
+  return YES;
+}
+
+- (void)applyStyling:(NSRange)range {
+  // lists are drawn manually
+  // margin before bullet + gap between bullet and paragraph
+  CGFloat listHeadIndent = [self.input->config unorderedListMarginLeft] +
+                           [self.input->config unorderedListGapWidth];
+
+  [self.input->textView.textStorage
+      enumerateAttribute:NSParagraphStyleAttributeName
+                 inRange:range
+                 options:0
+              usingBlock:^(id _Nullable value, NSRange range,
+                           BOOL *_Nonnull stop) {
+                NSMutableParagraphStyle *pStyle =
+                    [(NSParagraphStyle *)value mutableCopy];
+                pStyle.headIndent = listHeadIndent;
+                pStyle.firstLineHeadIndent = listHeadIndent;
+                [self.input->textView.textStorage
+                    addAttribute:NSParagraphStyleAttributeName
+                           value:pStyle
+                           range:range];
+              }];
+}
+
+- (BOOL)tryHandlingListShorcutInRange:(NSRange)range
+                      replacementText:(NSString *)text {
+  NSRange paragraphRange =
+      [self.input->textView.textStorage.string paragraphRangeForRange:range];
+  // space was added - check if we are both at the paragraph beginning + 1
+  // character (which we want to be a dash)
+  if ([text isEqualToString:@" "] &&
+      range.location - 1 == paragraphRange.location) {
+    unichar charBefore = [self.input->textView.textStorage.string
+        characterAtIndex:range.location - 1];
+    if (charBefore == '-') {
+      // we got a match - add a list if possible
+      if ([self.input handleStyleBlocksAndConflicts:[[self class] getType]
+                                              range:paragraphRange]) {
+        // don't emit during the replacing
+        self.input->blockEmitting = YES;
+
+        // remove the dash
+        [TextInsertionUtils replaceText:@""
+                                     at:NSMakeRange(paragraphRange.location, 1)
+                   additionalAttributes:nullptr
+                                  input:self.input
+                          withSelection:YES];
+
+        self.input->blockEmitting = NO;
+
+        // add attributes on the dashless paragraph
+        [self add:NSMakeRange(paragraphRange.location,
+                              paragraphRange.length - 1)
+                withTyping:YES
+            withDirtyRange:YES];
+
+        return YES;
+      }
+    }
+  }
+  return NO;
+}
+
+@end

package/ios/utils/CheckboxHitTestUtils.h

@@ -0,0 +1,10 @@
+#import <UIKit/UIKit.h>
+
+@class EnrichedTextInputView;
+
+@interface CheckboxHitTestUtils : NSObject
+
++ (NSInteger)hitTestCheckboxAtPoint:(CGPoint)pt
+                            inInput:(EnrichedTextInputView *)input;
+
+@end

package/ios/utils/CheckboxHitTestUtils.mm

@@ -0,0 +1,122 @@
+#import "CheckboxHitTestUtils.h"
+#import "EnrichedTextInputView.h"
+#import "InputConfig.h"
+#import "StyleHeaders.h"
+
+static const CGFloat kCheckboxHitSlopLeft = 8.0;
+static const CGFloat kCheckboxHitSlopVertical = 6.0;
+
+@implementation CheckboxHitTestUtils
+
+// MARK: - Coordinate helpers
+
++ (CGPoint)containerPointFromViewPoint:(CGPoint)point
+                              textView:(UITextView *)textView {
+  return CGPointMake(point.x - textView.textContainerInset.left,
+                     point.y - textView.textContainerInset.top);
+}
+
+// MARK: - Glyph lookup
+
++ (NSUInteger)glyphIndexAtContainerPoint:(CGPoint)point
+                                textView:(UITextView *)textView {
+  return [textView.layoutManager glyphIndexForPoint:point
+                                    inTextContainer:textView.textContainer
+                     fractionOfDistanceThroughGlyph:nil];
+}
+
+// MARK: - Checkbox detection
+
++ (BOOL)isCheckboxGlyph:(NSUInteger)glyphIndex
+                inInput:(EnrichedTextInputView *)input {
+  UITextView *textView = input->textView;
+  NSLayoutManager *layoutManager = textView.layoutManager;
+  NSTextStorage *storage = textView.textStorage;
+
+  NSUInteger charIndex =
+      [layoutManager characterIndexForGlyphAtIndex:glyphIndex];
+
+  if (charIndex >= storage.length) {
+    return NO;
+  }
+
+  CheckboxListStyle *checkboxListStyle =
+      (CheckboxListStyle *)input->stylesDict[@([CheckboxListStyle getType])];
+
+  if (!checkboxListStyle) {
+    return NO;
+  }
+
+  return [checkboxListStyle detect:NSMakeRange(charIndex, 0)];
+}
+
+// MARK: - Checkbox rect
+
++ (CGRect)checkboxRectForGlyphIndex:(NSUInteger)glyphIndex
+                            inInput:(EnrichedTextInputView *)input {
+  UITextView *textView = input->textView;
+  NSLayoutManager *layoutManager = textView.layoutManager;
+  InputConfig *config = input->config;
+
+  if (!config) {
+    return CGRectNull;
+  }
+
+  CGRect lineRect = [layoutManager lineFragmentRectForGlyphAtIndex:glyphIndex
+                                                    effectiveRange:nil];
+
+  CGFloat originX = lineRect.origin.x + config.checkboxListMarginLeft;
+
+  CGFloat originY = lineRect.origin.y +
+                    (lineRect.size.height - config.checkboxListBoxSize) / 2.0;
+
+  return CGRectMake(originX, originY, config.checkboxListBoxSize,
+                    config.checkboxListBoxSize);
+}
+
+// MARK: - Hit rect
+
++ (CGRect)expandedHitRectFromCheckboxRect:(CGRect)rect {
+  if (CGRectIsNull(rect))
+    return rect;
+
+  return CGRectInset(rect, -kCheckboxHitSlopLeft, -kCheckboxHitSlopVertical);
+}
+
+// MARK: - Public API
+
++ (NSInteger)hitTestCheckboxAtPoint:(CGPoint)point
+                            inInput:(EnrichedTextInputView *)input {
+  UITextView *textView = input->textView;
+
+  CGPoint containerPoint = [self containerPointFromViewPoint:point
+                                                    textView:textView];
+
+  NSUInteger glyphIndex = [self glyphIndexAtContainerPoint:containerPoint
+                                                  textView:textView];
+
+  if (glyphIndex == NSNotFound) {
+    return -1;
+  }
+
+  if (![self isCheckboxGlyph:glyphIndex inInput:input]) {
+    return -1;
+  }
+
+  CGRect checkboxRect = [self checkboxRectForGlyphIndex:glyphIndex
+                                                inInput:input];
+
+  if (CGRectIsNull(checkboxRect)) {
+    return -1;
+  }
+
+  CGRect hitRect = [self expandedHitRectFromCheckboxRect:checkboxRect];
+
+  if (!CGRectContainsPoint(hitRect, containerPoint)) {
+    return -1;
+  }
+
+  return [textView.layoutManager characterIndexForGlyphAtIndex:glyphIndex];
+}
+
+@end

package/ios/utils/DotReplacementUtils.h

@@ -0,0 +1,10 @@
+#import <UIKit/UIKit.h>
+#pragma once
+
+@interface DotReplacementUtils : NSObject
++ (void)handleDotReplacement:(id)input
+                 textStorage:(NSTextStorage *)textStorage
+                  editedMask:(NSTextStorageEditActions)editedMask
+                 editedRange:(NSRange)editedRange
+                       delta:(NSInteger)delta;
+@end

package/ios/utils/DotReplacementUtils.mm

@@ -0,0 +1,68 @@
+#import "DotReplacementUtils.h"
+#import "EnrichedTextInputView.h"
+
+@implementation DotReplacementUtils
+
+// This is a fix for iOS replacing a space with a dot when two spaces are
+// quickly inputted That operation doesn't properly extend our custom attributes
+// and we do it here manually
++ (void)handleDotReplacement:(id)input
+                 textStorage:(NSTextStorage *)textStorage
+                  editedMask:(NSTextStorageEditActions)editedMask
+                 editedRange:(NSRange)editedRange
+                       delta:(NSInteger)delta {
+  EnrichedTextInputView *typedInput = (EnrichedTextInputView *)input;
+  if (typedInput == nullptr) {
+    return;
+  }
+
+  // Conditions for the dot attributes fix:
+  // - character edition was done
+  // - it edited one character
+  // - new character is a dot
+  // - delta=0, meaning a replacement was done
+  // - there is something before the edited range to get attributes from
+  if ((editedMask & NSTextStorageEditedCharacters) != 0 &&
+      editedRange.length == 1 &&
+      [[textStorage.string substringWithRange:editedRange]
+          isEqualToString:@"."] &&
+      delta == 0 && editedRange.location > 0) {
+    // If all of the above are true, we are sure some dot replacement has been
+    // done So we manually need to apply the preceeding attribtues to the dot
+    NSDictionary *prevAttrs =
+        [textStorage attributesAtIndex:editedRange.location - 1
+                        effectiveRange:nullptr];
+    [textStorage addAttributes:prevAttrs range:editedRange];
+    typedInput->dotReplacementRange = [NSValue valueWithRange:editedRange];
+    return;
+  }
+
+  // Space after the dot added by iOS comes in a separate, second callback.
+  // Checking its conditions:
+  // - dotReplacementRange defined
+  // - dotReplacementRange was exactly before the new edited range
+  // - character edition was done
+  // - it edited one character
+  // - edited character is a space
+  // - delta=1, meaning addition was done
+  if (typedInput->dotReplacementRange != nullptr &&
+      [typedInput->dotReplacementRange rangeValue].location + 1 ==
+          editedRange.location &&
+      (editedMask & NSTextStorageEditedCharacters) != 0 &&
+      editedRange.length == 1 &&
+      [[textStorage.string substringWithRange:editedRange]
+          isEqualToString:@" "] &&
+      delta == 1) {
+    // If all of the above are true, we are now sure it was the iOS dot
+    // replacement Only then do we also fix attribtues of the space added
+    // afterwards
+    NSDictionary *prevAttrs =
+        [textStorage attributesAtIndex:editedRange.location - 1
+                        effectiveRange:nullptr];
+    [textStorage addAttributes:prevAttrs range:editedRange];
+  }
+  // always reset the replacement range after any processing
+  typedInput->dotReplacementRange = nullptr;
+}
+
+@end

package/ios/utils/KeyboardUtils.h

@@ -0,0 +1,7 @@
+#import <UIKit/UIKit.h>
+#pragma once
+
+@interface KeyboardUtils : NSObject
++ (UIReturnKeyType)getUIReturnKeyTypeFromReturnKeyType:
+    (NSString *)returnKeyType;
+@end

package/ios/utils/KeyboardUtils.mm

@@ -0,0 +1,31 @@
+#import "KeyboardUtils.h"
+#import "RCTTextInputUtils.h"
+
+@implementation KeyboardUtils
++ (UIReturnKeyType)getUIReturnKeyTypeFromReturnKeyType:
+    (NSString *)returnKeyType {
+  if ([returnKeyType isEqualToString:@"done"])
+    return UIReturnKeyDone;
+  if ([returnKeyType isEqualToString:@"go"])
+    return UIReturnKeyGo;
+  if ([returnKeyType isEqualToString:@"next"])
+    return UIReturnKeyNext;
+  if ([returnKeyType isEqualToString:@"search"])
+    return UIReturnKeySearch;
+  if ([returnKeyType isEqualToString:@"send"])
+    return UIReturnKeySend;
+  if ([returnKeyType isEqualToString:@"emergency-call"])
+    return UIReturnKeyEmergencyCall;
+  if ([returnKeyType isEqualToString:@"google"])
+    return UIReturnKeyGoogle;
+  if ([returnKeyType isEqualToString:@"join"])
+    return UIReturnKeyJoin;
+  if ([returnKeyType isEqualToString:@"route"])
+    return UIReturnKeyRoute;
+  if ([returnKeyType isEqualToString:@"yahoo"])
+    return UIReturnKeyYahoo;
+
+  return UIReturnKeyDefault;
+}
+
+@end

package/ios/utils/OccurenceUtils.h

@@ -0,0 +1,44 @@
+#pragma once
+#import "EnrichedTextInputView.h"
+#import "StylePair.h"
+
+@interface OccurenceUtils : NSObject
++ (BOOL)detect:(NSAttributedStringKey _Nonnull)key
+        withInput:(EnrichedTextInputView *_Nonnull)input
+          inRange:(NSRange)range
+    withCondition:(BOOL(NS_NOESCAPE ^ _Nonnull)(id _Nullable value,
+                                                NSRange range))condition;
++ (BOOL)detect:(NSAttributedStringKey _Nonnull)key
+        withInput:(EnrichedTextInputView *_Nonnull)input
+          atIndex:(NSUInteger)index
+    checkPrevious:(BOOL)checkPrev
+    withCondition:(BOOL(NS_NOESCAPE ^ _Nonnull)(id _Nullable value,
+                                                NSRange range))condition;
++ (BOOL)detectMultiple:(NSArray<NSAttributedStringKey> *_Nonnull)keys
+             withInput:(EnrichedTextInputView *_Nonnull)input
+               inRange:(NSRange)range
+         withCondition:(BOOL(NS_NOESCAPE ^ _Nonnull)(id _Nullable value,
+                                                     NSRange range))condition;
++ (BOOL)any:(NSAttributedStringKey _Nonnull)key
+        withInput:(EnrichedTextInputView *_Nonnull)input
+          inRange:(NSRange)range
+    withCondition:(BOOL(NS_NOESCAPE ^ _Nonnull)(id _Nullable value,
+                                                NSRange range))condition;
++ (BOOL)anyMultiple:(NSArray<NSAttributedStringKey> *_Nonnull)keys
+          withInput:(EnrichedTextInputView *_Nonnull)input
+            inRange:(NSRange)range
+      withCondition:(BOOL(NS_NOESCAPE ^ _Nonnull)(id _Nullable value,
+                                                  NSRange range))condition;
++ (NSArray<StylePair *> *_Nullable)all:(NSAttributedStringKey _Nonnull)key
+                             withInput:(EnrichedTextInputView *_Nonnull)input
+                               inRange:(NSRange)range
+                         withCondition:(BOOL(NS_NOESCAPE ^
+                                             _Nonnull)(id _Nullable value,
+                                                       NSRange range))condition;
++ (NSArray<StylePair *> *_Nullable)
+      allMultiple:(NSArray<NSAttributedStringKey> *_Nonnull)keys
+        withInput:(EnrichedTextInputView *_Nonnull)input
+          inRange:(NSRange)range
+    withCondition:(BOOL(NS_NOESCAPE ^ _Nonnull)(id _Nullable value,
+                                                NSRange range))condition;
+@end

package/ios/utils/OccurenceUtils.mm

@@ -0,0 +1,179 @@
+#import "OccurenceUtils.h"
+#import "StyleBase.h"
+
+@implementation OccurenceUtils
+
++ (BOOL)detect:(NSAttributedStringKey _Nonnull)key
+        withInput:(EnrichedTextInputView *_Nonnull)input
+          inRange:(NSRange)range
+    withCondition:(BOOL(NS_NOESCAPE ^ _Nonnull)(id _Nullable value,
+                                                NSRange range))condition {
+  __block NSInteger totalLength = 0;
+  [input->textView.textStorage
+      enumerateAttribute:key
+                 inRange:range
+                 options:0
+              usingBlock:^(id _Nullable value, NSRange range,
+                           BOOL *_Nonnull stop) {
+                if (condition(value, range)) {
+                  totalLength += range.length;
+                }
+              }];
+  return totalLength == range.length;
+}
+
+// checkPrevious flag is used for styles like lists or blockquotes
+// it means that first character of paragraph will be checked instead if the
+// detection is not in input's selected range and at the end of the input
++ (BOOL)detect:(NSAttributedStringKey _Nonnull)key
+        withInput:(EnrichedTextInputView *_Nonnull)input
+          atIndex:(NSUInteger)index
+    checkPrevious:(BOOL)checkPrev
+    withCondition:(BOOL(NS_NOESCAPE ^ _Nonnull)(id _Nullable value,
+                                                NSRange range))condition {
+  NSRange detectionRange = NSMakeRange(index, 0);
+  id attrValue;
+  if (NSEqualRanges(input->textView.selectedRange, detectionRange)) {
+    attrValue = input->textView.typingAttributes[key];
+  } else if (index == input->textView.textStorage.string.length) {
+    if (checkPrev) {
+      NSRange paragraphRange = [input->textView.textStorage.string
+          paragraphRangeForRange:detectionRange];
+      if (paragraphRange.location == detectionRange.location) {
+        return NO;
+      } else {
+        return [self detect:key
+                  withInput:input
+                    inRange:NSMakeRange(paragraphRange.location, 1)
+              withCondition:condition];
+      }
+    } else {
+      return NO;
+    }
+  } else {
+    NSRange attrRange = NSMakeRange(0, 0);
+    attrValue = [input->textView.textStorage attribute:key
+                                               atIndex:index
+                                        effectiveRange:&attrRange];
+  }
+  return condition(attrValue, detectionRange);
+}
+
++ (BOOL)detectMultiple:(NSArray<NSAttributedStringKey> *_Nonnull)keys
+             withInput:(EnrichedTextInputView *_Nonnull)input
+               inRange:(NSRange)range
+         withCondition:(BOOL(NS_NOESCAPE ^ _Nonnull)(id _Nullable value,
+                                                     NSRange range))condition {
+  __block NSInteger totalLength = 0;
+  for (NSString *key in keys) {
+    [input->textView.textStorage
+        enumerateAttribute:key
+                   inRange:range
+                   options:0
+                usingBlock:^(id _Nullable value, NSRange range,
+                             BOOL *_Nonnull stop) {
+                  if (condition(value, range)) {
+                    totalLength += range.length;
+                  }
+                }];
+  }
+  return totalLength == range.length;
+}
+
++ (BOOL)any:(NSAttributedStringKey _Nonnull)key
+        withInput:(EnrichedTextInputView *_Nonnull)input
+          inRange:(NSRange)range
+    withCondition:(BOOL(NS_NOESCAPE ^ _Nonnull)(id _Nullable value,
+                                                NSRange range))condition {
+  __block BOOL found = NO;
+  [input->textView.textStorage
+      enumerateAttribute:key
+                 inRange:range
+                 options:0
+              usingBlock:^(id _Nullable value, NSRange range,
+                           BOOL *_Nonnull stop) {
+                if (condition(value, range)) {
+                  found = YES;
+                  *stop = YES;
+                }
+              }];
+  return found;
+}
+
++ (BOOL)anyMultiple:(NSArray<NSAttributedStringKey> *_Nonnull)keys
+          withInput:(EnrichedTextInputView *_Nonnull)input
+            inRange:(NSRange)range
+      withCondition:(BOOL(NS_NOESCAPE ^ _Nonnull)(id _Nullable value,
+                                                  NSRange range))condition {
+  __block BOOL found = NO;
+  for (NSString *key in keys) {
+    [input->textView.textStorage
+        enumerateAttribute:key
+                   inRange:range
+                   options:0
+                usingBlock:^(id _Nullable value, NSRange range,
+                             BOOL *_Nonnull stop) {
+                  if (condition(value, range)) {
+                    found = YES;
+                    *stop = YES;
+                  }
+                }];
+    if (found) {
+      return YES;
+    }
+  }
+  return NO;
+}
+
++ (NSArray<StylePair *> *_Nullable)all:(NSAttributedStringKey _Nonnull)key
+                             withInput:(EnrichedTextInputView *_Nonnull)input
+                               inRange:(NSRange)range
+                         withCondition:
+                             (BOOL(NS_NOESCAPE ^ _Nonnull)(id _Nullable value,
+                                                           NSRange range))
+                                 condition {
+  __block NSMutableArray<StylePair *> *occurences =
+      [[NSMutableArray<StylePair *> alloc] init];
+  [input->textView.textStorage
+      enumerateAttribute:key
+                 inRange:range
+                 options:0
+              usingBlock:^(id _Nullable value, NSRange range,
+                           BOOL *_Nonnull stop) {
+                if (condition(value, range)) {
+                  StylePair *pair = [[StylePair alloc] init];
+                  pair.rangeValue = [NSValue valueWithRange:range];
+                  pair.styleValue = value;
+                  [occurences addObject:pair];
+                }
+              }];
+  return occurences;
+}
+
++ (NSArray<StylePair *> *_Nullable)
+      allMultiple:(NSArray<NSAttributedStringKey> *_Nonnull)keys
+        withInput:(EnrichedTextInputView *_Nonnull)input
+          inRange:(NSRange)range
+    withCondition:(BOOL(NS_NOESCAPE ^ _Nonnull)(id _Nullable value,
+                                                NSRange range))condition {
+  __block NSMutableArray<StylePair *> *occurences =
+      [[NSMutableArray<StylePair *> alloc] init];
+  for (NSString *key in keys) {
+    [input->textView.textStorage
+        enumerateAttribute:key
+                   inRange:range
+                   options:0
+                usingBlock:^(id _Nullable value, NSRange range,
+                             BOOL *_Nonnull stop) {
+                  if (condition(value, range)) {
+                    StylePair *pair = [[StylePair alloc] init];
+                    pair.rangeValue = [NSValue valueWithRange:range];
+                    pair.styleValue = value;
+                    [occurences addObject:pair];
+                  }
+                }];
+  }
+  return occurences;
+}
+
+@end

package/ios/utils/ParagraphAttributesUtils.h

@@ -0,0 +1,15 @@
+#import <UIKit/UIKit.h>
+#pragma once
+
+@interface ParagraphAttributesUtils : NSObject
++ (BOOL)handleBackspaceInRange:(NSRange)range
+               replacementText:(NSString *)text
+                         input:(id)input;
++ (BOOL)handleParagraphStylesMergeOnBackspace:(NSRange)range
+                              replacementText:(NSString *)text
+                                        input:(id)input;
++ (BOOL)handleResetTypingAttributesOnBackspace:(NSRange)range
+                               replacementText:(NSString *)text
+                                         input:(id)input;
++ (BOOL)isParagraphEmpty:(NSRange)range inString:(NSString *)string;
+@end