@expensify/react-native-live-markdown 0.1.192 → 0.1.193

package/apple/MarkdownParser.h

@@ -0,0 +1,12 @@
+#import <Foundation/Foundation.h>
+#import <RNLiveMarkdown/MarkdownRange.h>
+
+NS_ASSUME_NONNULL_BEGIN
+
+@interface MarkdownParser : NSObject
+
+- (NSArray<MarkdownRange *> *)parse:(NSString *)text withParserId:(NSNumber *)parserId;
+
+NS_ASSUME_NONNULL_END
+
+@end

package/apple/MarkdownParser.mm

@@ -0,0 +1,68 @@
+#import "MarkdownParser.h"
+#import <RNLiveMarkdown/MarkdownGlobal.h>
+#import <React/RCTLog.h>
+#import <mutex>
+
+@implementation MarkdownParser {
+  NSString *_prevText;
+  NSNumber *_prevParserId;
+  NSArray<MarkdownRange *> *_prevMarkdownRanges;
+}
+
+- (NSArray<MarkdownRange *> *)parse:(NSString *)text withParserId:(nonnull NSNumber *)parserId {
+  @synchronized (self) {
+    if ([text isEqualToString:_prevText] && [parserId isEqualToNumber:_prevParserId]) {
+      return _prevMarkdownRanges;
+    }
+
+    static std::mutex workletRuntimeMutex; // this needs to be global since the worklet runtime is also global
+    const auto lock = std::lock_guard<std::mutex>(workletRuntimeMutex);
+
+    const auto &markdownRuntime = expensify::livemarkdown::getMarkdownRuntime();
+    jsi::Runtime &rt = markdownRuntime->getJSIRuntime();
+
+    const auto &markdownWorklet = expensify::livemarkdown::getMarkdownWorklet([parserId intValue]);
+
+    const auto &input = jsi::String::createFromUtf8(rt, [text UTF8String]);
+
+    jsi::Value output;
+    try {
+      output = markdownRuntime->runGuarded(markdownWorklet, input);
+    } catch (const jsi::JSError &error) {
+      // Skip formatting, runGuarded will show the error in LogBox
+      _prevText = text;
+      _prevParserId = parserId;
+      _prevMarkdownRanges = @[];
+      return _prevMarkdownRanges;
+    }
+
+    NSMutableArray<MarkdownRange *> *markdownRanges = [[NSMutableArray alloc] init];
+    try {
+      const auto &ranges = output.asObject(rt).asArray(rt);
+      for (size_t i = 0, n = ranges.size(rt); i < n; ++i) {
+        const auto &item = ranges.getValueAtIndex(rt, i).asObject(rt);
+        const auto &type = item.getProperty(rt, "type").asString(rt).utf8(rt);
+        const auto &start = static_cast<int>(item.getProperty(rt, "start").asNumber());
+        const auto &length = static_cast<int>(item.getProperty(rt, "length").asNumber());
+        const auto &depth = item.hasProperty(rt, "depth") ? static_cast<int>(item.getProperty(rt, "depth").asNumber()) : 1;
+
+        NSRange range = NSMakeRange(start, length);
+        MarkdownRange *markdownRange = [[MarkdownRange alloc] initWithType:@(type.c_str()) range:range depth:depth];
+        [markdownRanges addObject:markdownRange];
+      }
+    } catch (const jsi::JSError &error) {
+      RCTLogWarn(@"[react-native-live-markdown] Incorrect schema of worklet parser output: %s", error.getMessage().c_str());
+      _prevText = text;
+      _prevParserId = parserId;
+      _prevMarkdownRanges = @[];
+      return _prevMarkdownRanges;
+    }
+
+    _prevText = text;
+    _prevParserId = parserId;
+    _prevMarkdownRanges = markdownRanges;
+    return _prevMarkdownRanges;
+  }
+}
+
+@end

package/apple/RCTMarkdownUtils.mm

@@ -1,12 +1,13 @@
 #import <RNLiveMarkdown/RCTMarkdownUtils.h>
 #import <RNLiveMarkdown/MarkdownGlobal.h>
-#import <RNLiveMarkdown/MarkdownRange.h>
+#import <RNLiveMarkdown/MarkdownParser.h>
 #import "react_native_assert.h"
 #import <React/RCTAssert.h>
 #import <React/RCTFont.h>
 #include <jsi/jsi.h>
 
 @implementation RCTMarkdownUtils {
+  MarkdownParser *_markdownParser;
   NSString *_prevInputString;
   NSAttributedString *_prevAttributedString;
   NSDictionary<NSAttributedStringKey, id> *_prevTextAttributes;
@@ -14,6 +15,15 @@
   __weak NSNumber *_prevParserId;
 }
 
+- (instancetype)init
+{
+  if (self = [super init]) {
+    _markdownParser = [MarkdownParser new];
+  }
+
+  return self;
+}
+
 - (NSAttributedString *)parseMarkdown:(nullable NSAttributedString *)input withAttributes:(nullable NSDictionary<NSAttributedStringKey,id> *)attributes
 {
     @synchronized (self) {
@@ -26,43 +36,8 @@
             return _prevAttributedString;
         }
 
-        static std::mutex runtimeMutex;
-        auto lock = std::lock_guard<std::mutex>(runtimeMutex);
-
-        auto markdownRuntime = expensify::livemarkdown::getMarkdownRuntime();
-        jsi::Runtime &rt = markdownRuntime->getJSIRuntime();
-
-        auto markdownWorklet = expensify::livemarkdown::getMarkdownWorklet([_parserId intValue]);
-        
-        NSMutableArray *markdownRanges = [[NSMutableArray alloc] init];
-
-        try {
-            const auto &text = jsi::String::createFromUtf8(rt, [inputString UTF8String]);
-            const auto &output = markdownRuntime->runGuarded(markdownWorklet, text);
-            const auto &ranges = output.asObject(rt).asArray(rt);
-
-            for (size_t i = 0, n = ranges.size(rt); i < n; ++i) {
-                const auto &item = ranges.getValueAtIndex(rt, i).asObject(rt);
-                const auto &type = item.getProperty(rt, "type").asString(rt).utf8(rt);
-                const auto &start = static_cast<int>(item.getProperty(rt, "start").asNumber());
-                const auto &length = static_cast<int>(item.getProperty(rt, "length").asNumber());
-                const auto &depth = item.hasProperty(rt, "depth") ? static_cast<int>(item.getProperty(rt, "depth").asNumber()) : 1;
-
-                NSRange range = NSMakeRange(start, length);
-                MarkdownRange *markdownRange = [[MarkdownRange alloc] initWithType:@(type.c_str()) range:range depth:depth];
-                [markdownRanges addObject:markdownRange];
-            }
-        } catch (const jsi::JSError &error) {
-            RCTLogWarn(@"[react-native-live-markdown] Incorrect schema of worklet parser output: %s", error.getMessage().c_str());
-            NSAttributedString *attributedString = [[NSAttributedString alloc] initWithString:inputString attributes:attributes];
-            _prevInputString = inputString;
-            _prevAttributedString = attributedString;
-            _prevTextAttributes = attributes;
-            _prevMarkdownStyle = _markdownStyle;
-            _prevParserId = _parserId;
-            return attributedString;
-        }
-    
+        NSArray<MarkdownRange *> *markdownRanges = [_markdownParser parse:inputString withParserId:_parserId];
+
         NSMutableAttributedString *attributedString = [[NSMutableAttributedString alloc] initWithString:inputString attributes:attributes];
         [attributedString beginEditing];
 

package/package.json

@@ -1,6 +1,6 @@
 {
   "name": "@expensify/react-native-live-markdown",
-  "version": "0.1.192",
+  "version": "0.1.193",
   "description": "Drop-in replacement for React Native's TextInput component with Markdown formatting.",
   "main": "lib/commonjs/index",
   "module": "lib/module/index",