@etherisc/gif-next 3.0.0-f90c901-018 → 3.0.0-fb87f3a-607

package/contracts/examples/flight/FlightLib.sol

@@ -0,0 +1,337 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IPolicy} from "../../instance/module/IPolicy.sol";
+import {IPolicyService} from "../../product/IPolicyService.sol";
+
+import {Amount, AmountLib} from "../../type/Amount.sol";
+import {FlightMessageVerifier} from "./FlightMessageVerifier.sol";
+import {FlightProduct} from "./FlightProduct.sol";
+import {InstanceReader} from "../../instance/InstanceReader.sol";
+import {NftId} from "../../type/NftId.sol";
+import {RequestId} from "../../type/RequestId.sol";
+import {RiskId, RiskIdLib} from "../../type/RiskId.sol";
+import {Seconds} from "../../type/Seconds.sol";
+import {StateId} from "../../type/StateId.sol";
+import {Str} from "../../type/String.sol";
+import {Timestamp, TimestampLib} from "../../type/Timestamp.sol";
+
+
+library FlightLib {
+
+    event LogFlightProductErrorUnprocessableStatus(RequestId requestId, RiskId riskId, bytes1 status);
+    event LogFlightProductErrorUnexpectedStatus(RequestId requestId, RiskId riskId, bytes1 status, int256 delayMinutes);
+
+    error ErrorFlightProductRiskInvalid(RiskId riskId);
+    error ErrorFlightProductPremiumAmountTooSmall(Amount premiumAmount, Amount minPremium);
+    error ErrorFlightProductPremiumAmountTooLarge(Amount premiumAmount, Amount maxPremium);
+    error ErrorFlightProductArrivalBeforeDepartureTime(Timestamp departureTime, Timestamp arrivalTime);
+    error ErrorFlightProductArrivalAfterMaxFlightDuration(Timestamp arrivalTime, Timestamp maxArrivalTime, Seconds maxDuration);
+    error ErrorFlightProductDepartureBeforeMinTimeBeforeDeparture(Timestamp departureTime, Timestamp now, Seconds minTimeBeforeDeparture);
+    error ErrorFlightProductDepartureAfterMaxTimeBeforeDeparture(Timestamp departureTime, Timestamp now, Seconds maxTimeBeforeDeparture);
+    error ErrorFlightProductNotEnoughObservations(uint256 observations, uint256 minObservations);
+    error ErrorFlightProductClusterRisk(Amount totalSumInsured, Amount maxTotalPayout);
+
+    function checkApplicationData(
+        FlightProduct flightProduct,
+        Str flightData, 
+        Timestamp departureTime,
+        Timestamp arrivalTime,
+        Amount premiumAmount
+    )
+        public
+        view
+    {
+        _checkApplicationData(flightProduct, premiumAmount, arrivalTime, departureTime);
+    }
+
+
+    function _checkApplicationData(
+        FlightProduct flightProduct,
+        Amount premiumAmount,
+        Timestamp arrivalTime,
+        Timestamp departureTime
+    )
+        internal
+        view
+    {
+        bool testMode = flightProduct.isTestMode();
+
+        // solhint-disable
+        if (premiumAmount < flightProduct.MIN_PREMIUM()) {
+            revert ErrorFlightProductPremiumAmountTooSmall(premiumAmount, flightProduct.MIN_PREMIUM());
+        }
+        if (premiumAmount > flightProduct.MAX_PREMIUM()) {
+            revert ErrorFlightProductPremiumAmountTooLarge(premiumAmount, flightProduct.MAX_PREMIUM());
+        }
+        if (arrivalTime <= departureTime) {
+            revert ErrorFlightProductArrivalBeforeDepartureTime(departureTime, arrivalTime);
+        }
+        if (arrivalTime > departureTime.addSeconds(flightProduct.MAX_FLIGHT_DURATION())) {
+            revert ErrorFlightProductArrivalAfterMaxFlightDuration(arrivalTime, departureTime, flightProduct.MAX_FLIGHT_DURATION());
+        }
+
+        // test mode allows the creation for policies that are outside restricted policy creation times
+        if (!testMode && departureTime < TimestampLib.current().addSeconds(flightProduct.MIN_TIME_BEFORE_DEPARTURE())) {
+            revert ErrorFlightProductDepartureBeforeMinTimeBeforeDeparture(departureTime, TimestampLib.current(), flightProduct.MIN_TIME_BEFORE_DEPARTURE());
+        }
+        if (!testMode && departureTime > TimestampLib.current().addSeconds(flightProduct.MAX_TIME_BEFORE_DEPARTURE())) {
+            revert ErrorFlightProductDepartureAfterMaxTimeBeforeDeparture(departureTime, TimestampLib.current(), flightProduct.MAX_TIME_BEFORE_DEPARTURE());
+        }
+        // solhint-enable
+    }
+
+
+    function checkClusterRisk(
+        Amount sumOfSumInsuredAmounts,
+        Amount sumInsuredAmount,
+        Amount maxTotalPayout
+    )
+        public
+        pure
+    {
+        if (sumOfSumInsuredAmounts + sumInsuredAmount > maxTotalPayout) {
+            revert ErrorFlightProductClusterRisk(sumOfSumInsuredAmounts + sumInsuredAmount, maxTotalPayout);
+        }
+    }
+
+
+    /// @dev calculates payout option based on flight status and delay minutes.
+    /// Is not a view function as it emits log evens in case of unexpected status.
+    function checkAndGetPayoutOption(
+        RequestId requestId,
+        RiskId riskId, 
+        bytes1 status, 
+        int256 delayMinutes
+    )
+        public
+        returns (uint8 payoutOption)
+    {
+        // default: no payout
+        payoutOption = type(uint8).max;
+
+        // check status
+        if (status != "L" && status != "A" && status != "C" && status != "D") {
+            emit LogFlightProductErrorUnprocessableStatus(requestId, riskId, status);
+            return payoutOption;
+        }
+
+        if (status == "A") {
+            // todo: active, reschedule oracle call + 45 min
+            emit LogFlightProductErrorUnexpectedStatus(requestId, riskId, status, delayMinutes);
+            return payoutOption;
+        }
+
+        // trigger payout if applicable
+        if (status == "C") { payoutOption = 3; } 
+        else if (status == "D") { payoutOption = 4; } 
+        else if (delayMinutes >= 15 && delayMinutes < 30) { payoutOption = 0; } 
+        else if (delayMinutes >= 30 && delayMinutes < 45) { payoutOption = 1; } 
+        else if (delayMinutes >= 45) { payoutOption = 2; }
+    }
+
+
+    function calculateWeight(
+        FlightProduct flightProduct,
+        uint256[6] memory statistics
+    )
+        public
+        view
+        returns (uint256 weight)
+    {
+        // check we have enough observations
+        if (statistics[0] < flightProduct.MIN_OBSERVATIONS()) {
+            revert ErrorFlightProductNotEnoughObservations(statistics[0], flightProduct.MIN_OBSERVATIONS());
+        }
+
+        weight = 0;
+        for (uint256 i = 1; i < 6; i++) {
+            weight += flightProduct.WEIGHT_PATTERN(i) * statistics[i] * 10000 / statistics[0];
+        }
+
+        // To avoid div0 in the payout section, we have to make a minimal assumption on weight
+        if (weight == 0) {
+            weight = 100000 / statistics[0];
+        }
+
+        // TODO comment on intended effect
+        weight = (weight * (100 + flightProduct.MARGIN_PERCENT())) / 100;
+    }
+
+
+    // REMARK: each flight may get different payouts depending on the latest statics
+    function calculatePayoutAmounts(
+        FlightProduct flightProduct,
+        Amount premium, 
+        uint256[6] memory statistics
+    )
+        public
+        view
+        returns (
+            uint256 weight, 
+            Amount[5] memory payoutAmounts,
+            Amount sumInsuredAmount // simply the max of payoutAmounts 
+        )
+    {
+        if (premium < flightProduct.MIN_PREMIUM()) { 
+            revert ErrorFlightProductPremiumAmountTooSmall(premium, flightProduct.MIN_PREMIUM()); 
+        }
+        if (premium > flightProduct.MAX_PREMIUM()) { 
+            revert ErrorFlightProductPremiumAmountTooLarge(premium, flightProduct.MAX_PREMIUM()); 
+        }
+
+        sumInsuredAmount = AmountLib.zero();
+        weight = calculateWeight(flightProduct, statistics);
+
+        for (uint256 i = 0; i < 5; i++) {
+            Amount payoutAmount = AmountLib.toAmount(
+                premium.toInt() * flightProduct.WEIGHT_PATTERN(i + 1) * 10000 / weight);
+
+            // cap payout and update sum insured if applicable
+            if (payoutAmount > flightProduct.MAX_PAYOUT()) { payoutAmount = flightProduct.MAX_PAYOUT(); }
+            if (payoutAmount > sumInsuredAmount) { sumInsuredAmount = payoutAmount; }
+
+            payoutAmounts[i] = payoutAmount;
+        }
+    }
+
+
+    function getPayoutOption(
+        InstanceReader reader,
+        NftId productNftId,
+        RiskId riskId
+    )
+        public
+        view
+        returns (
+            bool exists,
+            bool statusAvailable,
+            uint8 payoutOption
+        )
+    {
+        FlightProduct.FlightRisk memory flightRisk;
+        (exists, flightRisk) = getFlightRisk(
+            reader, 
+            productNftId, 
+            riskId,
+            false);
+        
+        statusAvailable = flightRisk.statusUpdatedAt.gtz();
+        payoutOption = flightRisk.payoutOption;
+    }
+
+
+    function getPayoutAmount(
+        bytes memory applicationData, 
+        uint8 payoutOption
+    )
+        public
+        pure
+        returns (Amount payoutAmount)
+    {
+        if (payoutOption == type(uint8).max) {
+            return AmountLib.zero();
+        }
+
+        // retrieve payout amounts from application data
+        (, Amount[5] memory payoutAmounts) = abi.decode(
+            applicationData, (Amount, Amount[5]));
+
+        // get payout amount for selected option
+        payoutAmount = payoutAmounts[payoutOption];
+    }
+
+
+    function getFlightRisk(
+        InstanceReader reader,
+        NftId productNftId, 
+        Str flightData,
+        Timestamp departureTime, 
+        string memory departureTimeLocal,
+        Timestamp arrivalTime,
+        string memory arrivalTimeLocal
+    )
+        public
+        view
+        returns (
+            RiskId riskId,
+            bool exists,
+            FlightProduct.FlightRisk memory flightRisk
+        )
+    {
+        riskId = getRiskId(productNftId, flightData);
+        (exists, flightRisk) = getFlightRisk(reader, productNftId, riskId, false);
+
+        // create new risk if not existing
+        if (!exists) {
+            flightRisk = FlightProduct.FlightRisk({
+                flightData: flightData,
+                departureTime: departureTime,
+                departureTimeLocal: departureTimeLocal,
+                arrivalTime: arrivalTime,
+                arrivalTimeLocal: arrivalTimeLocal,
+                sumOfSumInsuredAmounts: AmountLib.toAmount(0),
+                status: bytes1(0),
+                delayMinutes: 0,
+                payoutOption: uint8(0),
+                statusUpdatedAt: TimestampLib.zero()});
+        }
+    }
+
+
+    function getFlightRisk(
+        InstanceReader reader,
+        NftId productNftId,
+        RiskId riskId,
+        bool requireRiskExists
+    )
+        public
+        view
+        returns (
+            bool exists,
+            FlightProduct.FlightRisk memory flightRisk
+        )
+    {
+        // check if risk exists
+        exists = reader.isProductRisk(productNftId, riskId);
+
+        if (!exists && requireRiskExists) {
+            revert ErrorFlightProductRiskInvalid(riskId);
+        }
+
+        // get risk data if risk exists
+        if (exists) {
+            flightRisk = abi.decode(
+                reader.getRiskInfo(riskId).data, (FlightProduct.FlightRisk));
+        }
+    }
+
+
+    function getRiskId(
+        NftId productNftId,
+        Str flightData
+    )
+        public
+        view 
+        returns (RiskId riskId)
+    {
+        bytes32 riskKey = getRiskKey(flightData);
+        riskId = getRiskId(productNftId, riskKey);
+    }
+
+
+    function getRiskKey(
+        Str flightData
+    )
+        internal
+        pure
+        returns (bytes32 riskKey)
+    {
+        return keccak256(abi.encode(flightData));
+    }
+
+
+    function getRiskId(NftId productNftId, bytes32 riskKey) internal view returns (RiskId riskId) {
+        return RiskIdLib.toRiskId(productNftId, riskKey);
+    }
+}

package/contracts/examples/flight/FlightMessageVerifier.sol

@@ -0,0 +1,128 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
+import {MessageHashUtils} from "@openzeppelin/contracts/utils/cryptography/MessageHashUtils.sol";
+import {ECDSA} from "@openzeppelin/contracts/utils/cryptography/ECDSA.sol";
+
+
+import {Amount} from "../../type/Amount.sol";
+import {Str} from "../../type/String.sol";
+import {Timestamp} from "../../type/Timestamp.sol";
+
+contract FlightMessageVerifier is 
+    Ownable
+{
+
+    error ErrorFlightMessageVerifierSignerZero();
+    error ErrorFlightMessageVerifierContractSignerNotSupported();
+
+    address private _expectedSigner;
+
+
+    constructor() Ownable(msg.sender) { }
+
+
+    function setExpectedSigner(address signer) external onlyOwner {
+        if (signer == address(0)) { revert ErrorFlightMessageVerifierSignerZero(); }
+        if (signer.code.length > 0) { revert ErrorFlightMessageVerifierContractSignerNotSupported(); }
+        _expectedSigner = signer;
+    }
+
+
+    function getExpectedSigner() external view returns(address) {
+        return _expectedSigner;
+    }
+
+    /// @dev creates digest hash based on application parameters
+    /// proposal:
+    /// use "LX 180 ZRH BKK 20241104" (23 chars, should be enough for all flights)
+    /// carriers, airports: https://www.iata.org/en/publications/directories/code-search/
+    /// flight numbers: https://en.wikipedia.org/wiki/Flight_number
+    /// instead of separate strings, coding/decoding done anyway off-chain
+    function getRatingsHash(
+        Str flightData,
+        Timestamp departureTime,
+        Timestamp arrivalTime,
+        Amount premiumAmount,
+        uint256[6] memory statistics
+    )
+        public
+        view
+        returns(bytes32)
+    {
+        return MessageHashUtils.toEthSignedMessageHash(
+            abi.encode(
+                flightData,
+                departureTime,
+                arrivalTime,
+                premiumAmount,
+                statistics));
+    }
+
+
+    function verifyRatingsHash(
+        Str flightData,
+        Timestamp departureTime,
+        Timestamp arrivalTime,
+        Amount premiumAmount,
+        uint256[6] memory statistics,
+        // bytes memory signature,
+        uint8 v, 
+        bytes32 r, 
+        bytes32 s
+    )
+        public
+        view
+        returns (
+            address actualSigner,
+            ECDSA.RecoverError errorStatus,
+            bool success
+        )
+    {
+        bytes32 messageHash = getRatingsHash(
+            flightData,
+            departureTime,
+            arrivalTime,
+            premiumAmount,
+            statistics);
+
+        (
+            actualSigner, 
+            errorStatus, 
+        ) = ECDSA.tryRecover(messageHash, v, r, s);
+
+        success = (
+            errorStatus == ECDSA.RecoverError.NoError 
+            && actualSigner == _expectedSigner);
+    }
+
+
+    // TODO re-enable or cleanup
+    // function checkAndRegisterSignature (
+    //     address policyHolder,
+    //     address protectedWallet,
+    //     uint256 protectedBalance,
+    //     uint256 duration,
+    //     uint256 bundleId,
+    //     bytes32 signatureId,
+    //     bytes calldata signature
+    // )
+    //     external 
+    // {
+    //     bytes32 signatureHash = keccak256(abi.encode(signature));
+    //     require(!_signatureIsUsed[signatureHash], "ERROR:DMH-001:SIGNATURE_USED");
+
+    //     address signer = getSignerFromDigestAndSignature(
+    //         protectedWallet,
+    //         protectedBalance,
+    //         duration,
+    //         bundleId,
+    //         signatureId,
+    //         signature);
+
+    //     require(policyHolder == signer, "ERROR:DMH-002:SIGNATURE_INVALID");
+
+    //     _signatureIsUsed[signatureHash] = true;
+    // }
+}

package/contracts/examples/flight/FlightNft.sol

@@ -0,0 +1,234 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ERC721} from "@openzeppelin/contracts/token/ERC721/ERC721.sol";
+import {IERC721Metadata} from "@openzeppelin/contracts/token/ERC721/extensions/IERC721Metadata.sol";
+import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
+
+import {IPolicy} from "../../instance/module/IPolicy.sol";
+import {IRegistry} from "../../registry/IRegistry.sol";
+
+import {Amount} from "../../type/Amount.sol";
+import {ChainNft} from "../../registry/ChainNft.sol";
+import {FlightProduct} from "./FlightProduct.sol";
+import {InstanceReader} from "../../instance/InstanceReader.sol";
+import {NftId, NftIdLib} from "../../type/NftId.sol";
+import {RiskId} from "../../type/RiskId.sol";
+
+
+/**
+ * @title FlightNft
+ * @dev FlightNft provides NFT data for flight delay policies.
+ */
+// contract FlightNft is IERC721Metadata {
+contract FlightNft is
+    ERC721, 
+    Ownable
+{
+
+    error ErrorFlightNftNotMinter();
+    error ErrorFlightNftAlreadyMinted(uint256 tokenId);
+    error ErrorFlightNftNotAvailable(uint256 tokenId);
+    error ErrorFlightNftNotFlightPolicy(uint256 tokenId);
+
+    ChainNft public immutable chainNft;
+    FlightProduct public immutable flightProduct;
+    InstanceReader public immutable instanceReader;
+    IRegistry public registry;
+
+    address public minter;
+    string private _baseUri;
+
+
+    modifier onlyMinter() {
+        if(msg.sender != minter) {
+            revert ErrorFlightNftNotMinter();
+        }
+        _;
+    }
+
+
+    constructor(
+        address flightProductAddress,
+        string memory nftName,
+        string memory nftSymbol,
+        string memory baseUri
+    ) 
+        ERC721(nftName, nftSymbol)
+        Ownable(msg.sender)
+    {
+        flightProduct = FlightProduct(flightProductAddress);
+        registry = flightProduct.getRegistry();
+        chainNft = ChainNft(registry.getChainNftAddress());
+        instanceReader = flightProduct.getInstance().getInstanceReader();
+
+        minter = msg.sender;
+        _baseUri = baseUri;
+    }
+
+
+    /**
+     * Set the base URI to the specified value.
+     * Once set, this results in tokenURI() to return <baseUri><tokenId>.
+     */
+    function setBaseURI(string memory baseUri)
+        public 
+        onlyOwner()
+    {
+        _baseUri = baseUri;
+    }
+
+
+    /**
+     * Set the minter address.
+     */
+    function setMinter(address minterAddress)
+        public 
+        onlyOwner()
+    {
+        minter = minterAddress;
+    }
+
+
+    /**
+     * Mints a metadata NFT for the specified chainNft NFT.
+     * Only the minter can mint such NFTs.
+     */
+    function mint(uint256 tokenId)
+        external
+        onlyMinter()
+    {
+        // verify nft does not yet exist
+        if (_ownerOf(tokenId) != address(0)) {
+            revert ErrorFlightNftAlreadyMinted(tokenId);
+        }
+
+        // verify nft on chainNft exists
+        // also checks if nft exists (ERC721NonexistentToken)
+        address nftOwner = chainNft.ownerOf(tokenId);
+
+        // verify nft is flight delay policy
+        if (registry.getParentNftId(NftIdLib.toNftId(tokenId)) != registry.getNftIdForAddress(address(flightProduct))) {
+            revert ErrorFlightNftNotFlightPolicy(tokenId);
+        }   
+
+        _mint(nftOwner, tokenId);
+    }
+
+
+    /**
+     * @dev Return the NFT token URI for the specified token.
+     * No check is performed to ensure the token exists.
+     */
+    function tokenURI(uint256 tokenId) public view override returns (string memory) {
+        string memory baseURI = _baseURI();
+        return bytes(baseURI).length > 0 ? string.concat(baseURI, toString(tokenId)) : "";
+    }
+
+
+    /**
+     * @dev Base URI for computing {tokenURI}. If set, the resulting URI for each
+     * token will be the concatenation of the `baseURI` and the `tokenId`. Empty
+     * by default, can be overridden in child contracts.
+     */
+    function _baseURI() internal override view returns (string memory) {
+        return _baseUri;
+    }
+
+
+    function approve(address to, uint256 tokenId) public override { _revert(); }
+    function safeTransferFrom(address from, address to, uint256 tokenId, bytes memory data) public override { _revert(); }
+    function setApprovalForAll(address operator, bool approved) public override { _revert(); }
+    function transferFrom(address from, address to, uint256 tokenId) public override { _revert(); }
+
+    function balanceOf(address owner) public override view returns (uint256 balance) {
+        return chainNft.balanceOf(owner);
+    }
+
+    function getApproved(uint256 tokenId) public override view returns (address operator) {
+        return chainNft.getApproved(tokenId);
+    }
+
+    function isApprovedForAll(address owner, address operator) public override view returns (bool) {
+        return chainNft.isApprovedForAll(owner, operator);
+    }
+
+    function ownerOf(uint256 tokenId) public override view returns (address owner) {
+        return chainNft.ownerOf(tokenId);
+    }
+
+    function supportsInterface(bytes4 interfaceId) public override view returns (bool) {
+        return chainNft.supportsInterface(interfaceId);
+    }
+
+
+    function getPolicyData(NftId policyNftId)
+        public
+        view
+        returns (
+            RiskId riskId,
+            string memory flightData,
+            string memory departureTimeLocal,
+            string memory arrivalTimeLocal,
+            Amount premiumAmount, 
+            Amount[5] memory payoutAmounts,
+            bytes1 status,
+            int256 delayMinutes
+        )
+    {
+        IPolicy.PolicyInfo memory info = instanceReader.getPolicyInfo(policyNftId);
+
+        // get financial data
+        premiumAmount = info.premiumAmount;
+
+        if (info.applicationData.length > 0) {
+            (, payoutAmounts) = abi.decode(info.applicationData, (Amount, Amount[5]));
+        }
+
+        // get risk data
+        riskId = info.riskId;
+        bytes memory data = instanceReader.getRiskInfo(riskId).data;
+
+        if (data.length > 0) {
+            FlightProduct.FlightRisk memory flightRisk = flightProduct.decodeFlightRiskData(data);
+            flightData = flightRisk.flightData.toString();
+            departureTimeLocal = flightRisk.departureTimeLocal;
+            arrivalTimeLocal = flightRisk.arrivalTimeLocal;
+            status = flightRisk.status;
+            delayMinutes = flightRisk.delayMinutes;
+        }
+    }
+
+
+    function toString(uint256 value) public pure returns (string memory) {
+        if (value == 0) {
+            return "0";
+        }
+
+        uint256 temp = value;
+        uint256 digits = 0;
+        while (temp != 0) {
+            digits++;
+            temp /= 10;
+        }
+
+        bytes memory buffer = new bytes(digits);
+        uint index = digits - 1;
+
+        temp = value;
+        while (temp != 0) {
+            buffer[index] = bytes1(uint8(48 + temp % 10));
+            temp /= 10;
+
+            if (index > 0) {
+                index--;
+            }
+        }
+
+        return string(buffer);
+    }
+
+    function _revert() private pure {
+        revert("FlightNft: Use GIF Chain NFT contract to interact with NFTs. See function getChainNft()");
+    }
+}