@etherisc/gif-next 3.0.0-db9ffbc-172 → 3.0.0-eb61cc5-192

package/contracts/examples/flight/FlightNft.sol

@@ -0,0 +1,234 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ERC721} from "@openzeppelin/contracts/token/ERC721/ERC721.sol";
+import {IERC721Metadata} from "@openzeppelin/contracts/token/ERC721/extensions/IERC721Metadata.sol";
+import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
+
+import {IPolicy} from "../../instance/module/IPolicy.sol";
+import {IRegistry} from "../../registry/IRegistry.sol";
+
+import {Amount} from "../../type/Amount.sol";
+import {ChainNft} from "../../registry/ChainNft.sol";
+import {FlightProduct} from "./FlightProduct.sol";
+import {InstanceReader} from "../../instance/InstanceReader.sol";
+import {NftId, NftIdLib} from "../../type/NftId.sol";
+import {RiskId} from "../../type/RiskId.sol";
+
+
+/**
+ * @title FlightNft
+ * @dev FlightNft provides NFT data for flight delay policies.
+ */
+// contract FlightNft is IERC721Metadata {
+contract FlightNft is
+    ERC721, 
+    Ownable
+{
+
+    error ErrorFlightNftNotMinter();
+    error ErrorFlightNftAlreadyMinted(uint256 tokenId);
+    error ErrorFlightNftNotAvailable(uint256 tokenId);
+    error ErrorFlightNftNotFlightPolicy(uint256 tokenId);
+
+    ChainNft public immutable chainNft;
+    FlightProduct public immutable flightProduct;
+    InstanceReader public immutable instanceReader;
+    IRegistry public registry;
+
+    address public minter;
+    string private _baseUri;
+
+
+    modifier onlyMinter() {
+        if(msg.sender != minter) {
+            revert ErrorFlightNftNotMinter();
+        }
+        _;
+    }
+
+
+    constructor(
+        address flightProductAddress,
+        string memory nftName,
+        string memory nftSymbol,
+        string memory baseUri
+    ) 
+        ERC721(nftName, nftSymbol)
+        Ownable(msg.sender)
+    {
+        flightProduct = FlightProduct(flightProductAddress);
+        registry = flightProduct.getRegistry();
+        chainNft = ChainNft(registry.getChainNftAddress());
+        instanceReader = flightProduct.getInstance().getInstanceReader();
+
+        minter = msg.sender;
+        _baseUri = baseUri;
+    }
+
+
+    /**
+     * Set the base URI to the specified value.
+     * Once set, this results in tokenURI() to return <baseUri><tokenId>.
+     */
+    function setBaseURI(string memory baseUri)
+        public 
+        onlyOwner()
+    {
+        _baseUri = baseUri;
+    }
+
+
+    /**
+     * Set the minter address.
+     */
+    function setMinter(address minterAddress)
+        public 
+        onlyOwner()
+    {
+        minter = minterAddress;
+    }
+
+
+    /**
+     * Mints a metadata NFT for the specified chainNft NFT.
+     * Only the minter can mint such NFTs.
+     */
+    function mint(uint256 tokenId)
+        external
+        onlyMinter()
+    {
+        // verify nft does not yet exist
+        if (_ownerOf(tokenId) != address(0)) {
+            revert ErrorFlightNftAlreadyMinted(tokenId);
+        }
+
+        // verify nft on chainNft exists
+        // also checks if nft exists (ERC721NonexistentToken)
+        address nftOwner = chainNft.ownerOf(tokenId);
+
+        // verify nft is flight delay policy
+        if (registry.getParentNftId(NftIdLib.toNftId(tokenId)) != registry.getNftIdForAddress(address(flightProduct))) {
+            revert ErrorFlightNftNotFlightPolicy(tokenId);
+        }   
+
+        _mint(nftOwner, tokenId);
+    }
+
+
+    /**
+     * @dev Return the NFT token URI for the specified token.
+     * No check is performed to ensure the token exists.
+     */
+    function tokenURI(uint256 tokenId) public view override returns (string memory) {
+        string memory baseURI = _baseURI();
+        return bytes(baseURI).length > 0 ? string.concat(baseURI, toString(tokenId)) : "";
+    }
+
+
+    /**
+     * @dev Base URI for computing {tokenURI}. If set, the resulting URI for each
+     * token will be the concatenation of the `baseURI` and the `tokenId`. Empty
+     * by default, can be overridden in child contracts.
+     */
+    function _baseURI() internal override view returns (string memory) {
+        return _baseUri;
+    }
+
+
+    function approve(address to, uint256 tokenId) public override { _revert(); }
+    function safeTransferFrom(address from, address to, uint256 tokenId, bytes memory data) public override { _revert(); }
+    function setApprovalForAll(address operator, bool approved) public override { _revert(); }
+    function transferFrom(address from, address to, uint256 tokenId) public override { _revert(); }
+
+    function balanceOf(address owner) public override view returns (uint256 balance) {
+        return chainNft.balanceOf(owner);
+    }
+
+    function getApproved(uint256 tokenId) public override view returns (address operator) {
+        return chainNft.getApproved(tokenId);
+    }
+
+    function isApprovedForAll(address owner, address operator) public override view returns (bool) {
+        return chainNft.isApprovedForAll(owner, operator);
+    }
+
+    function ownerOf(uint256 tokenId) public override view returns (address owner) {
+        return chainNft.ownerOf(tokenId);
+    }
+
+    function supportsInterface(bytes4 interfaceId) public override view returns (bool) {
+        return chainNft.supportsInterface(interfaceId);
+    }
+
+
+    function getPolicyData(NftId policyNftId)
+        public
+        view
+        returns (
+            RiskId riskId,
+            string memory flightData,
+            string memory departureTimeLocal,
+            string memory arrivalTimeLocal,
+            Amount premiumAmount, 
+            Amount[5] memory payoutAmounts,
+            bytes1 status,
+            int256 delayMinutes
+        )
+    {
+        IPolicy.PolicyInfo memory info = instanceReader.getPolicyInfo(policyNftId);
+
+        // get financial data
+        premiumAmount = info.premiumAmount;
+
+        if (info.applicationData.length > 0) {
+            (, payoutAmounts) = abi.decode(info.applicationData, (Amount, Amount[5]));
+        }
+
+        // get risk data
+        riskId = info.riskId;
+        bytes memory data = instanceReader.getRiskInfo(riskId).data;
+
+        if (data.length > 0) {
+            FlightProduct.FlightRisk memory flightRisk = flightProduct.decodeFlightRiskData(data);
+            flightData = flightRisk.flightData.toString();
+            departureTimeLocal = flightRisk.departureTimeLocal;
+            arrivalTimeLocal = flightRisk.arrivalTimeLocal;
+            status = flightRisk.status;
+            delayMinutes = flightRisk.delayMinutes;
+        }
+    }
+
+
+    function toString(uint256 value) public pure returns (string memory) {
+        if (value == 0) {
+            return "0";
+        }
+
+        uint256 temp = value;
+        uint256 digits = 0;
+        while (temp != 0) {
+            digits++;
+            temp /= 10;
+        }
+
+        bytes memory buffer = new bytes(digits);
+        uint index = digits - 1;
+
+        temp = value;
+        while (temp != 0) {
+            buffer[index] = bytes1(uint8(48 + temp % 10));
+            temp /= 10;
+
+            if (index > 0) {
+                index--;
+            }
+        }
+
+        return string(buffer);
+    }
+
+    function _revert() private pure {
+        revert("FlightNft: Use GIF Chain NFT contract to interact with NFTs. See function getChainNft()");
+    }
+}

package/contracts/examples/flight/FlightOracle.sol

@@ -101,17 +101,19 @@ contract FlightOracle is
         _respond(requestId, responseData);
 
         // TODO decide if the code below should be moved to GIF
-        // check callback result
-        bool requestFulfilled = _getInstanceReader().getRequestState(
-            requestId) == FULFILLED();
-
-        // remove from active requests when successful
-        if (requestFulfilled) {
-            LibRequestIdSet.remove(_activeRequests, requestId);
-        }
+        _updateRequestState(requestId);
     }
 
 
+    function updateRequestState(
+        RequestId requestId
+    )
+        external
+        restricted()
+    {
+        _updateRequestState(requestId);
+    }
+
     //--- view functions ----------------------------------------------------//
 
     // TODO decide if the code below should be moved to GIF
@@ -172,6 +174,24 @@ contract FlightOracle is
 
     //--- internal functions ------------------------------------------------//
 
+
+    // TODO decide if the code below should be moved to GIF
+    // check callback result
+    function _updateRequestState(
+        RequestId requestId
+    )
+        internal
+    {
+        bool requestFulfilled = _getInstanceReader().getRequestState(
+            requestId) == FULFILLED();
+
+        // remove from active requests when successful
+        if (requestFulfilled && LibRequestIdSet.contains(_activeRequests, requestId)) {
+            LibRequestIdSet.remove(_activeRequests, requestId);
+        } 
+    }
+
+
     /// @dev use case specific handling of oracle requests
     /// for now only log is emitted to verify that request has been received by oracle component 
     function _request(

package/contracts/examples/flight/FlightOracleAuthorization.sol

@@ -8,7 +8,7 @@ import {IAccess} from "../../../contracts/authorization/IAccess.sol";
 import {AccessAdminLib} from "../../authorization/AccessAdminLib.sol";
 import {BasicOracleAuthorization} from "../../oracle/BasicOracleAuthorization.sol";
 import {FlightOracle} from "./FlightOracle.sol";
-import {RoleId, ADMIN_ROLE} from "../../../contracts/type/RoleId.sol";
+import {RoleId, ADMIN_ROLE, PUBLIC_ROLE} from "../../../contracts/type/RoleId.sol";
 
 contract FlightOracleAuthorization
     is BasicOracleAuthorization
@@ -48,6 +48,10 @@ contract FlightOracleAuthorization
 
         functions = _authorizeForTarget(getMainTargetName(), STATUS_PROVIDER_ROLE);
         _authorize(functions, FlightOracle.respondWithFlightStatus.selector, "respondWithFlightStatus");
+
+        // authorize public role (additional authz via onlyOwner)
+        functions = _authorizeForTarget(getMainTargetName(), PUBLIC_ROLE());
+        _authorize(functions, FlightOracle.updateRequestState.selector, "updateRequestState");
     }
 }
 

package/contracts/examples/flight/FlightPool.sol

@@ -35,7 +35,7 @@ contract FlightPool is
                 maxBalanceAmount: AmountLib.max(),
                 isInterceptingBundleTransfers: false,
                 isProcessingConfirmedClaims: false,
-                isExternallyManaged: false,
+                isExternallyManaged: true,
                 isVerifyingApplications: false,
                 collateralizationLevel: UFixedLib.one(),
                 retentionLevel: UFixedLib.one()

package/contracts/registry/ChainNft.sol

@@ -11,7 +11,7 @@ contract ChainNft is ERC721Enumerable {
     event LogTokenInterceptorAddress(uint256 tokenId, address interceptor);
 
     // constants
-    string public constant NAME = "Dezentralized Insurance Protocol NFT";
+    string public constant NAME = "Decentralized Insurance Protocol NFT";
     string public constant SYMBOL = "DIPNFT";
 
     uint256 public constant PROTOCOL_NFT_ID = 1101;

package/contracts/shared/ComponentService.sol

@@ -543,6 +543,11 @@ contract ComponentService is
             address(component), // initially, component is its own wallet
             token, 
             instanceAdmin.authority());
+
+        emit LogComponentServiceTokenHandlerDeployed(
+            componentNftId, 
+            address(componentInfo.tokenHandler), 
+            token);
         
         // register component with instance
         instanceStore.createComponent(

package/contracts/shared/IComponentService.sol

@@ -46,6 +46,7 @@ interface IComponentService is
     error ErrorComponentServiceWalletAllowanceTooSmall(address wallet, address spender, uint256 allowance, uint256 amount);
 
     event LogComponentServiceComponentLocked(address component, bool locked);
+    event LogComponentServiceTokenHandlerDeployed(NftId componentNftId, address tokenHandler, address token);
     event LogComponentServiceRegistered(NftId instanceNftId, NftId componentNftId, ObjectType componentType, address component, address token, address initialOwner); 
     event LogComponentServiceWalletAddressChanged(NftId componentNftId, address currentWallet, address newWallet);
     event LogComponentServiceWalletTokensTransferred(NftId componentNftId, address currentWallet, address newWallet, uint256 currentBalance);

package/contracts/staking/IStaking.sol

@@ -25,6 +25,8 @@ interface IStaking is
     IVersionable
 {
 
+    event LogStakingTokenHandlerDeployed(NftId componentNftId, address tokenHandler, address token);
+    
     // owner functions
     event LogStakingStakingRateSet(ChainId chainId, address token, UFixed newStakingRate, UFixed oldStakingRate, Blocknumber lastUpdateIn);
     event LogStakingStakingServiceSet(address stakingService, VersionPart release, address oldStakingService);

package/contracts/staking/Staking.sol

@@ -86,6 +86,7 @@ contract Staking is
             address(this),
             dipToken, 
             getRegistry().getAuthority());
+        emit LogStakingTokenHandlerDeployed(getNftId(), address($._tokenHandler), dipToken);
     }
 
 

package/package.json

@@ -1,6 +1,6 @@
 {
   "name": "@etherisc/gif-next",
-  "version": "3.0.0-db9ffbc-172",
+  "version": "3.0.0-eb61cc5-192",
   "description": "This is the repository for the next version of the Generic Insurance Framework (GIF) smart contracts. ",
   "main": "index.js",
   "scripts": {