@etherisc/gif-next 0.0.2-ffba655 → 3.0.0-1a7e54a-113

package/contracts/shared/IRegisterable.sol

@@ -0,0 +1,36 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IAccessManaged} from "@openzeppelin/contracts/access/manager/IAccessManaged.sol";
+
+import {INftOwnable} from "./INftOwnable.sol";
+import {IRelease} from "../registry/IRelease.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+
+/// @title IRegisterable
+/// @dev Marks contracts that are intended to be registered in the registry.
+/// 
+interface IRegisterable is
+    IAccessManaged,
+    INftOwnable,
+    IRelease
+{
+    // __Registerable_init
+    error ErrorAuthorityInvalid(address authority);
+
+    // onlyActive()
+    error ErrorRegisterableNotActive();
+
+    /// @dev Returns true iff this contract managed by its authority is active.
+    /// Queries the IAccessManaged.authority().
+    function isActive() external view returns (bool active);
+
+    /// @dev retuns the object info relevant for registering for this contract 
+    /// IMPORTANT information returned by this function may only be used
+    /// before the contract is registered in the registry.
+    /// Once registered this information MUST only be accessed via the registry.
+    function getInitialInfo() 
+        external 
+        view
+        returns (IRegistry.ObjectInfo memory);
+}

package/contracts/shared/IRegistryLinked.sol

@@ -0,0 +1,11 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IRegistry} from "../registry/IRegistry.sol";
+
+interface IRegistryLinked {
+
+    error ErrorNotRegistry(address registryAddress);
+
+    function getRegistry() external view returns (IRegistry);
+}

package/contracts/shared/IService.sol

@@ -0,0 +1,23 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IAccessManaged} from "@openzeppelin/contracts/access/manager/IAccessManaged.sol";
+
+import {IRegisterable} from "./IRegisterable.sol";
+import {IVersionable} from "../upgradeability/IVersionable.sol";
+import {ObjectType} from "../type/ObjectType.sol";
+import {RoleId} from "../type/RoleId.sol";
+
+interface IService is 
+    IAccessManaged,
+    IRegisterable,
+    IVersionable
+{
+    /// @dev returns the domain for this service.
+    /// In any GIF release only one service for any given domain may be deployed.
+    function getDomain() external pure returns(ObjectType serviceDomain);
+
+    /// @dev returns the GIF release specific role id.
+    /// These role ids are used to authorize service to service communication.
+    function getRoleId() external view returns(RoleId serviceRoleId);
+}

package/contracts/shared/InitializableERC165.sol

@@ -0,0 +1,35 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
+import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol"; 
+
+contract InitializableERC165 is
+    Initializable,
+    IERC165
+{
+    mapping(bytes4 => bool) private _isSupported;
+
+    // @dev initializes with support for ERC165
+    function __ERC165_init() internal onlyInitializing() {
+        _initializeERC165();
+    }
+
+    function _initializeERC165() internal {
+        _isSupported[type(IERC165).interfaceId] = true;
+    }
+
+    // @dev register support for provided interfaceId
+    // includes initialization for ERC165_ID if not yet done
+    function _registerInterface(bytes4 interfaceId) internal onlyInitializing() {
+        _registerInterfaceNotInitializing(interfaceId);
+    }
+
+    function _registerInterfaceNotInitializing(bytes4 interfaceId) internal{
+        _isSupported[interfaceId] = true;
+    }
+
+    function supportsInterface(bytes4 interfaceId) external view override returns (bool) {
+        return _isSupported[interfaceId];
+    }
+}

package/contracts/shared/InstanceLinkedComponent.sol

@@ -0,0 +1,232 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IAuthorization} from "../authorization/IAuthorization.sol";
+import {IComponents} from "../instance/module/IComponents.sol";
+import {IComponentService} from "./IComponentService.sol";
+import {IInstance} from "../instance/IInstance.sol";
+import {IInstanceLinkedComponent} from "./IInstanceLinkedComponent.sol";
+import {IInstanceService} from "../instance/IInstanceService.sol";
+import {IOracleService} from "../oracle/IOracleService.sol";
+
+import {Amount} from "../type/Amount.sol";
+import {Component} from "./Component.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {NftId} from "../type/NftId.sol";
+import {ObjectType, COMPONENT, INSTANCE, ORACLE, PRODUCT} from "../type/ObjectType.sol";
+import {RequestId} from "../type/RequestId.sol";
+import {RoleId, RoleIdLib} from "../type/RoleId.sol";
+import {TokenHandler} from "../shared/TokenHandler.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+import {VersionPart} from "../type/Version.sol";
+
+// then add (Distribution|Pool|Product)Upradeable that also intherit from Versionable
+// same pattern as for Service which is also upgradeable
+abstract contract InstanceLinkedComponent is
+    Component,
+    IInstanceLinkedComponent
+{
+    // keccak256(abi.encode(uint256(keccak256("gif-next.contracts.component.Component.sol")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant INSTANCE_LINKED_COMPONENT_LOCATION_V1 = 0xffe3d4462bded26a47154f4b8f6db494d2f772496965791d25bd456e342b7f00;
+
+    struct InstanceLinkedComponentStorage {
+        IInstance _instance; // instance for this component
+        InstanceReader _instanceReader; // instance reader for this component
+        IAuthorization _initialAuthorization;
+        IComponentService _componentService;
+        IOracleService _oracleService;
+    }
+
+    //--- view functions ----------------------------------------------------//
+
+    /// @inheritdoc IInstanceLinkedComponent
+    function getInstance() public view virtual override returns (IInstance instance) {
+        return _getInstanceLinkedComponentStorage()._instance;
+    }
+
+
+    /// @inheritdoc IInstanceLinkedComponent
+    function getAuthorization() external view virtual returns (IAuthorization authorization) {
+        return _getInstanceLinkedComponentStorage()._initialAuthorization;
+    }
+
+
+    /// @inheritdoc IInstanceLinkedComponent
+    function withdrawFees(Amount amount)
+        external
+        virtual
+        restricted()
+        onlyOwner()
+        returns (Amount withdrawnAmount)
+    {
+        return _withdrawFees(amount);
+    }
+
+    //--- internal functions ------------------------------------------------//
+
+    function _sendRequest(
+        NftId oracleNftId,
+        bytes memory requestData,
+        Timestamp expiryAt,
+        string memory callbackMethod
+    )
+        internal
+        virtual
+        returns (RequestId requestId)
+    {
+        return _getInstanceLinkedComponentStorage()._oracleService.request(
+            oracleNftId,
+            requestData,
+            expiryAt,
+            callbackMethod);
+    }
+
+
+    function _cancelRequest(RequestId requestId)
+        internal
+        virtual
+    {
+        _getInstanceLinkedComponentStorage()._oracleService.cancel(requestId);
+    }
+
+
+    function _resendRequest(RequestId requestId)
+        internal
+        virtual
+    {
+        _getInstanceLinkedComponentStorage()._oracleService.resend(requestId);
+    }
+
+
+    function _getInstanceLinkedComponentStorage() private pure returns (InstanceLinkedComponentStorage storage $) {
+        assembly {
+            $.slot := INSTANCE_LINKED_COMPONENT_LOCATION_V1
+        }
+    }
+
+
+    function __InstanceLinkedComponent_init(
+        address registry,
+        NftId parentNftId,
+        string memory name,
+        ObjectType componentType,
+        IAuthorization authorization,
+        bool isInterceptor,
+        address initialOwner
+    )
+        internal
+        virtual
+        onlyInitializing()
+    {
+        // validate registry, nft ids and get parent nft id
+        NftId instanceNftId = _checkAndGetInstanceNftId(
+            registry, 
+            parentNftId, 
+            componentType);
+
+        // set and check linked instance
+        InstanceLinkedComponentStorage storage $ = _getInstanceLinkedComponentStorage();
+        $._instance = IInstance(
+            IRegistry(registry).getObjectAddress(instanceNftId));
+
+        // set component specific parameters
+        __Component_init(
+            $._instance.authority(), // instance linked components need to point to instance admin
+            registry, 
+            parentNftId, 
+            name, 
+            componentType, 
+            isInterceptor, 
+            initialOwner, 
+            ""); // registry data
+
+        // set instance linked specific parameters
+        $._instanceReader = $._instance.getInstanceReader();
+        $._initialAuthorization = authorization;
+        $._componentService = IComponentService(_getServiceAddress(COMPONENT())); 
+        $._oracleService = IOracleService(_getServiceAddress(ORACLE()));
+
+        // register interfaces
+        _registerInterface(type(IInstanceLinkedComponent).interfaceId);
+    }
+
+
+    function _checkAndGetInstanceNftId(
+        address registryAddress,
+        NftId parentNftId,
+        ObjectType componentType
+    )
+        internal
+        view
+        returns (NftId instanceNftId)
+    {
+        // if product, then parent is already instance
+        if (componentType == PRODUCT()) {
+            _checkAndGetRegistry(registryAddress, parentNftId, INSTANCE());
+            return parentNftId;
+        }
+
+        // if not product parent is product, and parent of product is instance
+        IRegistry registry = _checkAndGetRegistry(registryAddress, parentNftId, PRODUCT());
+        return registry.getParentNftId(parentNftId);
+    }
+
+    /// @dev checks the and gets registry.
+    /// validates registry using a provided nft id and expected object type.
+    function _checkAndGetRegistry(
+        address registryAddress,
+        NftId objectNftId,
+        ObjectType requiredType
+    )
+        internal
+        view
+        returns (IRegistry registry)
+    {
+        registry = IRegistry(registryAddress);
+        IRegistry.ObjectInfo memory info = registry.getObjectInfo(objectNftId);
+
+        if (info.objectType != requiredType) {
+            revert ErrorInstanceLinkedComponentTypeMismatch(requiredType, info.objectType);
+        }
+    }
+
+
+    /// @dev for instance linked components the wallet address stored in the instance store.
+    /// updating needs to go throug component service
+    function _setWallet(address newWallet) internal virtual override onlyOwner {
+        IComponentService(_getServiceAddress(COMPONENT())).setWallet(newWallet);
+    }
+
+
+    function _getComponentInfo() internal virtual override view returns (IComponents.ComponentInfo memory info) {
+        NftId componentNftId = getRegistry().getNftIdForAddress(address(this));
+
+        // if registered, attempt to return component info via instance reader
+        if (componentNftId.gtz()) {
+            // component registerd with registry
+            info = _getInstanceReader().getComponentInfo(getNftId());
+
+            // check if also registered with instance
+            if (address(info.tokenHandler) != address(0)) {
+                return info;
+            }
+        }
+
+        // return data from component contract if not yet registered
+        return super._getComponentInfo();
+    }
+
+
+    /// @dev returns reader for linked instance
+    function _getInstanceReader() internal view returns (InstanceReader reader) {
+        return _getInstanceLinkedComponentStorage()._instanceReader;
+    }
+
+    function _withdrawFees(Amount amount)
+        internal
+        returns (Amount withdrawnAmount)
+    {
+        return _getInstanceLinkedComponentStorage()._componentService.withdrawFees(amount);
+    }
+}

package/contracts/shared/Lifecycle.sol

@@ -0,0 +1,88 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ObjectType} from "../type/ObjectType.sol";
+import {StateId, zeroStateId} from "../type/StateId.sol";
+import {ILifecycle} from "./ILifecycle.sol";
+
+abstract contract Lifecycle is
+    ILifecycle
+{
+    mapping(ObjectType objectType => StateId initialState)
+        private _initialState;
+
+    mapping(ObjectType objectType => mapping(StateId stateFrom => mapping(StateId stateTo => bool isValid)))
+        private _isValidTransition;
+
+    /// @dev child class must implement and CALL setup func at deployment/initializaton time
+    function _setupLifecycle() internal virtual;
+
+    function setInitialState(ObjectType ttype, StateId state) internal virtual {
+        assert(_initialState[ttype] == zeroStateId());
+        _initialState[ttype] = state;
+    }
+
+    function setStateTransition(ObjectType ttype, StateId oldState, StateId newState) internal virtual {
+        assert(_isValidTransition[ttype][oldState][newState] == false);
+        _isValidTransition[ttype][oldState][newState] = true;
+    }
+
+    function hasLifecycle(
+        ObjectType objectType
+    )
+        public
+        view
+        override
+        returns (bool)
+    {
+        return _initialState[objectType].gtz();
+    }
+
+    function getInitialState(
+        ObjectType objectType
+    )
+        public
+        view
+        returns (StateId)
+    {
+        return _initialState[objectType];
+    }
+
+    function checkTransition(
+        StateId stateId,
+        ObjectType objectType,
+        StateId expectedFromId,
+        StateId toId
+    )
+        public
+        view
+    {
+        // revert if no life cycle support
+        if (_initialState[objectType].eqz()) {
+            revert ErrorNoLifecycle(address(this), objectType);
+        }
+
+        // revert if current state is not expected `from` state
+        if(stateId != expectedFromId) {
+            revert ErrorFromStateMissmatch(address(this), objectType, stateId, expectedFromId);
+        }
+
+        // enforce valid state transition
+        if (!_isValidTransition[objectType][stateId][toId]) {
+            revert ErrorInvalidStateTransition(
+                address(this),
+                objectType, 
+                stateId, 
+                toId
+            );
+        }
+    }
+
+    function isValidTransition(
+        ObjectType objectType,
+        StateId fromId,
+        StateId toId
+    ) public view returns (bool) {
+        return _isValidTransition[objectType][fromId][toId];
+    }
+}

package/contracts/shared/NftIdSet.sol

@@ -0,0 +1,65 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {LibNftIdSet} from "../type/NftIdSet.sol";
+import {NftId} from "../type/NftId.sol";
+
+contract NftIdSet {
+
+    error ErrorNftIdSetManagerNotOwner(address owner, address sender);
+    error ErrorNftIdSetManagerOwnerAlreadySet(address owner);
+    error ErrorNftIdSetManagerNftIdInvalid(NftId objectNftId);
+    error ErrorNftIdSetManagerAlreadyAdded(NftId objectNftId);
+
+    LibNftIdSet.Set private _allObjects;
+    LibNftIdSet.Set private _activeObjects;
+    address private _owner;
+
+    modifier onlyOwner() {
+        if(msg.sender != _owner) {
+            revert ErrorNftIdSetManagerNotOwner(_owner, msg.sender);
+        }
+        _;
+    }
+
+    constructor() {
+        _owner = msg.sender;
+    }
+
+    function add(NftId objectNftId) external onlyOwner {
+        LibNftIdSet.add(_allObjects, objectNftId);
+        LibNftIdSet.add(_activeObjects, objectNftId);
+    }
+
+    function activate(NftId componentNftId, NftId objectNftId) external onlyOwner {
+        LibNftIdSet.add(_activeObjects, objectNftId);
+    }
+
+    function deactivate(NftId componentNftId, NftId objectNftId) external onlyOwner {
+        LibNftIdSet.remove(_activeObjects, objectNftId);
+    }
+
+    function nftIds() external view returns (uint256 ids) {
+        return LibNftIdSet.size(_allObjects);
+    }
+
+    function getNftId(uint256 idx) external view returns (NftId) {
+        return LibNftIdSet.getElementAt(_allObjects, idx);
+    }
+
+    function exists(NftId objectNftId) external view returns (bool) {
+        return LibNftIdSet.contains(_allObjects, objectNftId);
+    }
+
+    function activeNftIds() external view returns (uint256 ids) {
+        return LibNftIdSet.size(_activeObjects);
+    }
+
+    function getActiveNftId(uint256 idx) external view returns (NftId) {
+        return LibNftIdSet.getElementAt(_activeObjects, idx);
+    }
+
+    function isActive(NftId objectNftId) external view returns (bool) {
+        return LibNftIdSet.contains(_activeObjects, objectNftId);
+    }
+}

package/contracts/shared/NftOwnable.sol

@@ -0,0 +1,129 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {InitializableERC165} from "./InitializableERC165.sol";
+import {INftOwnable} from "./INftOwnable.sol";
+import {NftId} from "../type/NftId.sol";
+import {ObjectType} from "../type/ObjectType.sol";
+import {RegistryLinked} from "./RegistryLinked.sol";
+
+contract NftOwnable is
+    InitializableERC165,
+    RegistryLinked,
+    INftOwnable
+{
+    // keccak256(abi.encode(uint256(keccak256("etherisc.storage.NftOwnable")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant NFT_OWNABLE_STORAGE_LOCATION_V1 = 0x07ebcf49758b6ed3af50fa146bec0abe157c0218fe65dc0874c286e9d5da4f00;
+
+    struct NftOwnableStorage {
+        NftId _nftId;
+        address _initialOwner; 
+    }
+
+    /// @dev enforces msg.sender is owner of nft (or initial owner of nft ownable)
+    modifier onlyOwner() {
+        if (msg.sender != getOwner()) {
+            revert ErrorNftOwnableNotOwner(msg.sender);
+        }
+        _;
+    }
+
+    modifier onlyNftOwner(NftId nftId) {
+        if(!getRegistry().isOwnerOf(nftId, msg.sender)) {
+            revert ErrorNftOwnableNotOwner(msg.sender);
+        }
+        _;
+    }
+
+    modifier onlyNftOfType(NftId nftId, ObjectType expectedObjectType) {
+        _checkNftType(nftId, expectedObjectType);
+        _;
+    }
+
+    function _checkNftType(NftId nftId, ObjectType expectedObjectType) internal view {
+        if(expectedObjectType.eqz() || !getRegistry().isObjectType(nftId, expectedObjectType)) {
+            revert ErrorNftOwnableInvalidType(nftId, expectedObjectType);
+        }
+    }
+
+
+    /// @dev Initialization for upgradable contracts.
+    // used in __Registerable_init, ProxyManager._preDeployChecksAndSetup
+    function __NftOwnable_init(
+        address registry,
+        address initialOwner
+    )
+        internal
+        virtual
+        onlyInitializing()
+    {
+        __ERC165_init();
+        __RegistryLinked_init(registry);
+
+        if(initialOwner == address(0)) {
+            revert ErrorNftOwnableInitialOwnerZero();
+        }
+
+        _getNftOwnableStorage()._initialOwner = initialOwner;
+    }
+
+
+    /// @dev links this contract to nft after registration
+    // needs to be done once per registered contract and 
+    // reduces registry calls to check ownership
+    // does not need any protection as function can only do the "right thing"
+    function linkToRegisteredNftId()
+        public
+        virtual
+        returns (NftId nftId)
+    {
+        return _linkToNftOwnable(address(this));
+    }
+
+    function getNftId() public view virtual override returns (NftId) {
+        return _getNftOwnableStorage()._nftId;
+    }
+
+    function getOwner() public view virtual override returns (address) {
+        NftOwnableStorage storage $ = _getNftOwnableStorage();
+
+        if ($._nftId.gtz()) {
+            return getRegistry().ownerOf($._nftId);
+        }
+
+        return $._initialOwner;
+    }
+
+    /// @dev used in constructor of registry service manager
+    // links ownership of registry service manager ot nft owner of registry service
+    function _linkToNftOwnable(
+        address nftOwnableAddress
+    )
+        internal
+        returns (NftId)
+    {
+        NftOwnableStorage storage $ = _getNftOwnableStorage();
+
+        if ($._nftId.gtz()) {
+            revert ErrorNftOwnableAlreadyLinked($._nftId);
+        }
+
+        if (!getRegistry().isRegistered(nftOwnableAddress)) {
+            revert ErrorNftOwnableContractNotRegistered(nftOwnableAddress);
+        }
+
+        $._nftId = getRegistry().getNftIdForAddress(nftOwnableAddress);
+
+        emit LogNftOwnableNftLinkedToAddress($._nftId, getOwner());
+
+        return $._nftId;
+    }
+
+
+    function _getNftOwnableStorage() private pure returns (NftOwnableStorage storage $) {
+        // solhint-disable-next-line no-inline-assembly
+        assembly {
+            $.slot := NFT_OWNABLE_STORAGE_LOCATION_V1
+        }
+    }
+}

package/contracts/shared/PolicyHolder.sol

@@ -0,0 +1,63 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC721Receiver} from "@openzeppelin/contracts/token/ERC721/IERC721Receiver.sol";
+
+import {IPolicyHolder} from "./IPolicyHolder.sol";
+
+import {Amount} from "../type/Amount.sol";
+import {ClaimId} from "../type/ClaimId.sol";
+import {InitializableERC165} from "./InitializableERC165.sol";
+import {NftId} from "../type/NftId.sol";
+import {PayoutId} from "../type/PayoutId.sol";
+import {RegistryLinked} from "./RegistryLinked.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+
+/// @dev template implementation for IPolicyHolder
+contract PolicyHolder is
+    InitializableERC165,
+    RegistryLinked,
+    IPolicyHolder
+{
+    // TODO add modifier to protect callback functions from unauthorized access
+    // callbacks must only be allowed from the policy and claim services
+    // will need a release parameter to fetch the right service addresses for the modifiers
+
+    function _initializePolicyHolder(
+        address registryAddress
+    )
+        internal
+        virtual
+        onlyInitializing()
+    {
+        __RegistryLinked_init(registryAddress);
+        _initializeERC165();
+        _registerInterface(type(IPolicyHolder).interfaceId);
+    }
+
+    /// @dev empty default implementation
+    function policyActivated(NftId policyNftId, Timestamp activatedAt) external virtual {}
+
+    /// @dev empty default implementation
+    function policyExpired(NftId policyNftId, Timestamp expiredAt) external virtual {}
+
+    /// @dev empty default implementation
+    function claimConfirmed(NftId policyNftId, ClaimId claimId, Amount amount) external virtual {}
+
+    /// @dev empty default implementation
+    function payoutExecuted(NftId policyNftId, PayoutId payoutId, Amount amount, address beneficiary) external virtual {}
+
+    //--- IERC165 functions ---------------// 
+    function onERC721Received(
+        address, // operator
+        address, // from
+        uint256, // tokenId
+        bytes calldata // data
+    )
+        external
+        virtual
+        returns (bytes4)
+    {
+        return IERC721Receiver.onERC721Received.selector;
+    }
+}