@etherisc/gif-next 0.0.2-fe88ad7-208 → 0.0.2-ff282a4-523

package/contracts/pool/BundleService.sol

@@ -0,0 +1,382 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IBundle} from "../instance/module/IBundle.sol";
+import {IComponents} from "../instance/module/IComponents.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IInstance} from "../instance/IInstance.sol";
+import {TokenHandler} from "../instance/module/ITreasury.sol";
+import {ISetup} from "../instance/module/ISetup.sol";
+import {IPolicy} from "../instance/module/IPolicy.sol";
+
+import {IVersionable} from "../shared/IVersionable.sol";
+import {INftOwnable} from "../shared/INftOwnable.sol";
+import {NftId, NftIdLib, zeroNftId} from "../type/NftId.sol";
+import {ObjectType, POOL, BUNDLE} from "../type/ObjectType.sol";
+import {POOL_OWNER_ROLE, RoleId} from "../type/RoleId.sol";
+import {Pool} from "./Pool.sol";
+
+import {Amount, AmountLib} from "../type/Amount.sol";
+import {Fee, FeeLib} from "../type/Fee.sol";
+import {StateId, ACTIVE, PAUSED, CLOSED, KEEP_STATE} from "../type/StateId.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {TimestampLib, zeroTimestamp} from "../type/Timestamp.sol";
+import {Version, VersionLib} from "../type/Version.sol";
+import {Versionable} from "../shared/Versionable.sol";
+
+import {IService} from "../shared/IService.sol";
+import {Service} from "../shared/Service.sol";
+import {BundleManager} from "../instance/BundleManager.sol";
+import {ComponentService} from "../shared/ComponentService.sol";
+import {IBundleService} from "./IBundleService.sol";
+import {IRegistryService} from "../registry/IRegistryService.sol";
+import {InstanceService} from "../instance/InstanceService.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+
+string constant BUNDLE_SERVICE_NAME = "BundleService";
+
+contract BundleService is 
+    ComponentService, 
+    IBundleService 
+{
+    using NftIdLib for NftId;
+
+    string public constant NAME = "BundleService";
+
+    address internal _registryAddress;
+
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        initializer
+        virtual override
+    {
+        address registryAddress;
+        address initialOwner;
+        (registryAddress, initialOwner) = abi.decode(data, (address, address));
+        // TODO while PoolService is not deployed in PoolServiceManager constructor
+        //      owner is PoolServiceManager deployer
+        initializeService(registryAddress, address(0), owner);
+        registerInterface(type(IBundleService).interfaceId);
+    }
+
+    function getDomain() public pure override returns(ObjectType) {
+        return BUNDLE();
+    }
+
+    // TODO staking/unstaking as well as collateralize need to go to pool service
+    // it will also be the pool service that is updating the pool info data
+    // collateralize -> potentially accumulate pool fees
+    // collateralize: additional reason to move to pool, pool might has retential level < 1 ...
+    // staking -> potentially accumulate staking fees
+    // unstaking -> potentially accumulate performance fees
+    function _updatePoolWithStakes(
+        IInstance instance,
+        NftId poolNftId,
+        Amount stakingAmount
+    )
+        internal
+        returns (
+            TokenHandler tokenHandler,
+            address wallet,
+            Amount netStakingAmount
+        )
+    {
+        if(stakingAmount.gtz()) {
+            InstanceReader instanceReader = instance.getInstanceReader();
+            IComponents.ComponentInfo memory componentInfo = instanceReader.getComponentInfo(poolNftId);
+
+            tokenHandler = componentInfo.tokenHandler;
+            wallet = componentInfo.wallet;
+
+            IComponents.PoolInfo memory poolInfo = abi.decode(componentInfo.data, (IComponents.PoolInfo));
+            Amount poolFeeAmount;
+
+            // calculate pool fee and net staking amount
+            (poolFeeAmount, netStakingAmount) = FeeLib.calculateFee(poolInfo.stakingFee, stakingAmount);
+
+            // update pool balance and fee amount
+            poolInfo.balanceAmount = poolInfo.balanceAmount + netStakingAmount;
+
+            if(poolFeeAmount.gtz()) {
+                poolInfo.feeAmount = poolInfo.feeAmount + poolFeeAmount;
+            }
+
+            // save updated pool info
+            componentInfo.data = abi.encode(poolInfo);
+            instance.getInstanceStore().updatePoolSetup(poolNftId, componentInfo, KEEP_STATE());
+        }
+    }
+
+
+    function create(
+        IInstance instance,
+        NftId poolNftId,
+        address owner, 
+        Fee memory bundleFee, 
+        Amount stakingAmount, 
+        Seconds lifetime, 
+        bytes calldata filter
+    )
+        external
+        override
+        // TODO add restricted and add authz for pool service
+        returns(NftId bundleNftId)
+    {
+        // register bundle with registry
+        bundleNftId = getRegistryService().registerBundle(
+            IRegistry.ObjectInfo(
+                zeroNftId(), 
+                poolNftId,
+                BUNDLE(),
+                false, // intercepting property for bundles is defined on pool
+                address(0),
+                owner,
+                "" // bundle data to be stored in registry
+            )
+        );
+
+        // create bundle info in instance
+        instance.getInstanceStore().createBundle(
+            bundleNftId, 
+            IBundle.BundleInfo(
+                poolNftId,
+                bundleFee,
+                filter,
+                stakingAmount,
+                AmountLib.zero(),
+                AmountLib.zero(),
+                lifetime,
+                TimestampLib.blockTimestamp().addSeconds(lifetime),
+                zeroTimestamp()));
+
+        // put bundle under bundle managemet
+        BundleManager bundleManager = instance.getBundleManager();
+        bundleManager.add(bundleNftId);
+
+        // TODO add logging
+    }
+
+
+    function setFee(
+        NftId bundleNftId,
+        Fee memory fee
+    )
+        external
+        override
+    {
+        (NftId poolNftId,, IInstance instance) = _getAndVerifyCallingComponentAndInstance(POOL());
+        InstanceReader instanceReader = instance.getInstanceReader();
+        IBundle.BundleInfo memory bundleInfo = instanceReader.getBundleInfo(bundleNftId);
+        if(bundleInfo.poolNftId.eqz()) {
+            revert ErrorBundleServiceBundleUnknown(bundleNftId);
+        }
+
+        if(bundleInfo.poolNftId != poolNftId) {
+            revert ErrorBundleServiceBundlePoolMismatch(bundleNftId, bundleInfo.poolNftId, poolNftId);
+        }
+
+        bundleInfo.fee = fee;
+        instance.getInstanceStore().updateBundle(bundleNftId, bundleInfo, KEEP_STATE());
+    }
+
+
+    // the bundle MUST be unlocked (active) for linking (underwriting) and registered with this instance
+    function lockCollateral(
+        IInstance instance,
+        NftId policyNftId, 
+        NftId bundleNftId, 
+        Amount collateralAmount, // required amount to collateralize policy
+        Amount premiumAmount // premium part that reaches bundle for this policy
+    ) 
+        external
+        onlyService // TODO replace with restricted + appropriate granting
+    {
+        InstanceReader instanceReader = instance.getInstanceReader();
+        StateId bundleState = instanceReader.getMetadata(bundleNftId.toKey32(BUNDLE())).state;
+        IBundle.BundleInfo memory bundleInfo = instanceReader.getBundleInfo(bundleNftId);
+
+        // ensure bundle is active and not yet expired
+        if(bundleState != ACTIVE() || bundleInfo.expiredAt < TimestampLib.blockTimestamp()) {
+            revert ErrorBundleServiceBundleNotOpen(bundleNftId, bundleState, bundleInfo.expiredAt);
+        }
+
+        // ensure bundle capacity is sufficent to collateralize policy
+        Amount capacity = bundleInfo.capitalAmount + premiumAmount - bundleInfo.lockedAmount;
+        if(capacity < collateralAmount) {
+            revert ErrorBundleServiceCapacityInsufficient(bundleNftId, capacity, collateralAmount);
+        }
+
+        // TODO add more validation
+        
+        // updated locked amount
+        bundleInfo.lockedAmount = bundleInfo.lockedAmount + collateralAmount;
+
+        // update capital and fees when premiums are involved
+        _updateBundleWithPremium(instance, bundleNftId, bundleInfo, premiumAmount);
+        
+        // link policy to bundle in bundle manger
+        _linkPolicy(instance, policyNftId);
+    }
+
+
+    function _updateBundleWithPremium(
+        IInstance instance,
+        NftId bundleNftId,
+        IBundle.BundleInfo memory bundleInfo,
+        Amount premiumAmount
+    )
+        internal
+    {
+        // update bundle capital and fee amounts
+        if(premiumAmount.gtz()) {
+            // calculate fees and net premium amounts
+            (
+                , 
+                Amount netPremiumAmount
+            ) = FeeLib.calculateFee(bundleInfo.fee, premiumAmount);
+
+            // update bundle info with additional capital
+            bundleInfo.capitalAmount = bundleInfo.capitalAmount + netPremiumAmount;
+        }
+
+        // save updated bundle info
+        instance.getInstanceStore().updateBundle(bundleNftId, bundleInfo, KEEP_STATE());
+    }
+
+    function updateBundleFees(
+        IInstance instance,
+        NftId bundleNftId,
+        Amount feeAmount
+    )
+        external
+    {
+        IBundle.BundleInfo memory bundleInfo = instance.getInstanceReader().getBundleInfo(bundleNftId);
+        bundleInfo.feeAmount = bundleInfo.feeAmount.add(feeAmount);
+        instance.getInstanceStore().updateBundle(bundleNftId, bundleInfo, KEEP_STATE());
+    }
+
+    function lock(NftId bundleNftId) 
+        external
+        virtual
+    {
+        (,, IInstance instance) = _getAndVerifyCallingComponentAndInstance(POOL());
+
+        // udpate bundle state
+        instance.getInstanceStore().updateBundleState(bundleNftId, PAUSED());
+
+        // update set of active bundles
+        BundleManager bundleManager = instance.getBundleManager();
+        bundleManager.lock(bundleNftId);
+
+        emit LogBundleServiceBundleLocked(bundleNftId);
+    }
+
+
+    function unlock(NftId bundleNftId) 
+        external
+        virtual
+    {
+        (,, IInstance instance) = _getAndVerifyCallingComponentAndInstance(POOL());
+
+        // udpate bundle state
+        instance.getInstanceStore().updateBundleState(bundleNftId, ACTIVE());
+
+        // update set of active bundles
+        BundleManager bundleManager = instance.getBundleManager();
+        bundleManager.unlock(bundleNftId);
+
+        emit LogBundleServiceBundleActivated(bundleNftId);
+    }
+
+
+    function close(
+        IInstance instance,
+        NftId bundleNftId
+    ) 
+        external
+        virtual
+        // TODO add restricted and autz for pool service
+    {
+        // udpate bundle state
+        instance.getInstanceStore().updateBundleState(bundleNftId, CLOSED());
+
+        // ensure no open policies attached to bundle
+        BundleManager bundleManager = instance.getBundleManager();
+        uint256 openPolicies = bundleManager.activePolicies(bundleNftId);
+        if(openPolicies > 0) {
+            revert ErrorBundleServiceBundleWithOpenPolicies(bundleNftId, openPolicies);
+        }
+
+        // update set of active bundles
+        bundleManager.lock(bundleNftId);
+    }
+
+
+    function increaseBalance(
+        IInstance instance,
+        NftId bundleNftId, 
+        Amount premiumAmount
+    ) 
+        external
+        onlyService 
+    {
+        InstanceReader instanceReader = instance.getInstanceReader();
+        IBundle.BundleInfo memory bundleInfo = instanceReader.getBundleInfo(bundleNftId);
+
+        // update capital and fees when premiums are involved
+        _updateBundleWithPremium(instance, bundleNftId, bundleInfo, premiumAmount);
+
+        // TODO add logging (?)
+    }
+
+    function releaseCollateral(IInstance instance,
+        NftId policyNftId, 
+        NftId bundleNftId, 
+        Amount collateralAmount
+    ) 
+        external
+        onlyService 
+    {
+        InstanceReader instanceReader = instance.getInstanceReader();
+        IBundle.BundleInfo memory bundleInfo = instanceReader.getBundleInfo(bundleNftId);
+
+        // reduce locked amount by released collateral amount
+        bundleInfo.lockedAmount = bundleInfo.lockedAmount - collateralAmount;
+        instance.getInstanceStore().updateBundle(bundleNftId, bundleInfo, KEEP_STATE());
+    }
+
+    /// @dev links policy to bundle
+    function _linkPolicy(IInstance instance, NftId policyNftId) 
+        internal
+    {
+        InstanceReader instanceReader = instance.getInstanceReader();
+        IPolicy.PolicyInfo memory policyInfo = instanceReader.getPolicyInfo(policyNftId);
+
+        // ensure policy has not yet been activated in a previous tx already
+        if (policyInfo.activatedAt.gtz() && policyInfo.activatedAt < TimestampLib.blockTimestamp()) {
+            revert BundleManager.ErrorBundleManagerPolicyAlreadyActivated(policyNftId);
+        }
+        
+        BundleManager bundleManager = instance.getBundleManager();
+        bundleManager.linkPolicy(policyNftId);
+    }
+
+    /// @dev unlinks policy from bundle
+    function unlinkPolicy(
+        IInstance instance, 
+        NftId policyNftId
+    ) 
+        external
+        virtual
+    {
+        // ensure policy is closeable
+        if (!instance.getInstanceReader().policyIsCloseable(policyNftId)) {
+            revert ErrorBundleServicePolicyNotCloseable(policyNftId);
+        }
+
+        instance.getBundleManager().unlinkPolicy(policyNftId);
+    }
+}

package/contracts/{instance/service → pool}/BundleServiceManager.sol

@@ -1,12 +1,12 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity ^0.8.20;
 
-import {IVersionable} from "../../shared/IVersionable.sol";
-import {ProxyManager} from "../../shared/ProxyManager.sol";
+import {IVersionable} from "../shared/IVersionable.sol";
+import {ProxyManager} from "../shared/ProxyManager.sol";
 import {BundleService} from "./BundleService.sol";
-import {Registry} from "../../registry/Registry.sol";
-import {RegistryService} from "../../registry/RegistryService.sol";
-import {ObjectType, REGISTRY} from "../../types/ObjectType.sol";
+import {Registry} from "../registry/Registry.sol";
+import {RegistryService} from "../registry/RegistryService.sol";
+import {ObjectType, REGISTRY} from "../type/ObjectType.sol";
 
 contract BundleServiceManager is ProxyManager {
 
@@ -16,7 +16,7 @@ contract BundleServiceManager is ProxyManager {
     constructor(
         address registryAddress
     )
-        ProxyManager()
+        ProxyManager(registryAddress)
     {
         BundleService bundleSrv = new BundleService();
         bytes memory data = abi.encode(registryAddress, address(this));

package/contracts/pool/IBundleService.sol

@@ -0,0 +1,118 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Amount} from "../type/Amount.sol";
+import {NftId} from "../type/NftId.sol";
+import {Fee} from "../type/Fee.sol";
+import {IService} from "../shared/IService.sol";
+import {IBundle} from "../instance/module/IBundle.sol";
+import {IInstance} from "../instance/IInstance.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {StateId} from "../type/StateId.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+
+interface IBundleService is IService {
+
+    event LogBundleServiceBundleActivated(NftId bundleNftId);
+    event LogBundleServiceBundleLocked(NftId bundleNftId);
+
+    error ErrorBundleServiceInsufficientAllowance(address bundleOwner, address tokenHandlerAddress, Amount amount);
+    error ErrorBundleServiceBundleNotOpen(NftId bundleNftId, StateId state, Timestamp expiredAt);
+    error ErrorBundleServiceCapacityInsufficient(NftId bundleNftId, Amount capacityAmount, Amount collateralAmount);
+    error ErrorBundleServiceBundleWithOpenPolicies(NftId bundleNftId, uint256 openPoliciesCount);
+
+    error ErrorBundleServiceBundleUnknown(NftId bundleNftId);
+    error ErrorBundleServiceBundlePoolMismatch(NftId bundleNftId, NftId expectedPool, NftId actualPool);
+
+    error ErrorBundleServicePolicyNotCloseable(NftId policyNftId);
+
+    /// @dev create a new bundle for the specified attributes
+    /// may only be called by pool service
+    function create(
+        IInstance instance, // instance relevant for bundle
+        NftId poolNftId, // the pool the bundle will be linked to
+        address owner, // initial bundle owner
+        Fee memory fee, // fees deducted from premium that go to bundle owner
+        Amount stakingAmount, // staking amount - staking fees result in initial bundle capital
+        Seconds lifetime, // initial duration for which new policies are covered
+        bytes calldata filter // optional use case specific criteria that define if a policy may be covered by this bundle
+    )
+        external 
+        returns(NftId bundleNftId); // the nft id of the newly created bundle
+
+
+    /// @dev increase bundle stakes by the specified amount
+    /// may only be called by the bundle owner
+    // function stake(NftId bundleNftId, uint256 amount) external returns(uint256 netAmount);
+
+    // function unstake(NftId bundleNftId, uint256 amount) external returns(uint256 netAmount);
+
+    /// @dev locks the specified bundle, locked bundles are not available to collateralize new policies
+    /// only active bundles may be locked
+    /// may only be called by registered and unlocked pool components
+    function lock(NftId bundleNftId) external;
+
+    /// @dev activates the specified bundle
+    /// only locked bundles may be unlocked
+    /// may only be called by registered and unlocked pool components
+    function unlock(NftId bundleNftId) external;
+
+    /// @dev closes the specified bundle
+    /// only open bundles (active or locked) may be closed
+    /// to close a bundle it may not have any non-closed polices attached to it
+    /// may only be called by registered and unlocked pool components
+    function close(
+        IInstance instance, 
+        NftId bundleNftId
+    ) external;
+
+    /// @dev set bundle fee to provided value
+    /// may only be called by registered and unlocked pool components
+    function setFee(
+        NftId bundleNftId,
+        Fee memory fee
+    ) external;
+
+
+    /// @dev locks the specified collateral in the bundle
+    /// the locked collateral is added to the bundle locked capital
+    /// the bundles' fees are updated with the fees for this premium
+    /// the premium (minus bundle fee) is added to the bundle capital
+    /// may only be called by pool service
+    function lockCollateral(
+        IInstance instanceNftId, 
+        NftId policyNftId, 
+        NftId bundleNftId, 
+        Amount collateralAmount, 
+        Amount premiumAmount // premium after pool fee
+    ) external;
+
+    /// @dev releases the specified collateral in the bundle
+    /// may only be called by pool service
+    function releaseCollateral(
+        IInstance instance, 
+        NftId policyNftId, 
+        NftId bundleNftId, 
+        Amount collateralAmount
+    ) external;
+
+    /// @dev unlink policy from bundle
+    /// policy may only be unlinked if policy is closeable
+    /// may only be called by pool service
+    function unlinkPolicy(
+        IInstance instance, 
+        NftId policyNftId
+    ) external;
+
+    /// @dev updates the bundle's fees of with the provided fee amount
+    function updateBundleFees(
+        IInstance instance,
+        NftId bundleNftId,
+        Amount feeAmount
+    ) external;
+
+    function increaseBalance(
+        IInstance instance, 
+        NftId bundleNftId,  
+        Amount amount) external;
+}

package/contracts/pool/IPoolComponent.sol

@@ -0,0 +1,114 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Amount} from "../type/Amount.sol";
+import {Fee} from "../type/Fee.sol";
+import {IComponent} from "../shared/IComponent.sol";
+import {IComponents} from "../instance/module/IComponents.sol";
+import {NftId} from "../type/NftId.sol";
+import {RoleId} from "../type/RoleId.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {UFixed} from "../type/UFixed.sol";
+
+/// @dev pool components hold and manage the collateral to cover active policies
+/// pools come in different flavors
+interface IPoolComponent is IComponent {
+
+    error ErrorPoolNotBundleOwner(NftId bundleNftId, address caller);
+    error ErrorPoolNotPoolService(address caller);
+
+    error ErrorPoolApplicationBundleMismatch(NftId applicationNftId);
+
+    event LogPoolVerifiedByPool(address pool, NftId applicationNftId, Amount collateralizationAmount);
+
+    /// @dev increases the staked tokens by the specified amount
+    /// only the bundle owner may stake tokens
+    /// bundle MUST be in active or locked state
+    function stake(NftId bundleNftId, Amount amount) external;
+
+    /// @dev decreases the staked tokens by the specified amount
+    /// only the bundle owner may unstake tokens from the bundle
+    /// bundle MUST be in active, locked or closed state
+    function unstake(NftId bundleNftId, Amount amount) external;
+
+    /// @dev extends the bundle lifetime of the bundle by the specified time
+    /// only the bundle owner may extend the bundle's lifetime
+    /// bundle MUST be in active or locked state
+    function extend(NftId bundleNftId, Seconds lifetimeExtension) external;
+
+    /// @dev locks the specified bundle
+    /// a bundle to be locked MUST be in active state
+    /// locked bundles may not be used to collateralize any new policy
+    function lockBundle(NftId bundleNftId) external;
+
+    /// @dev unlocks the specified bundle
+    /// a bundle to be unlocked MUST be in locked state
+    function unlockBundle(NftId bundleNftId) external;
+
+    /// @dev close the specified bundle
+    /// a bundle to be closed MUST be in active or locked state
+    /// to close a bundle all all linked policies MUST be in closed state as well
+    /// closing a bundle finalizes the bundle bookkeeping including overall profit calculation
+    /// once a bundle is closed this action cannot be reversed
+    function close(NftId bundleNftId) external;
+
+    /// @dev sets the fee for the specified bundle
+    /// the fee is added on top of the poolFee and deducted from the premium amounts
+    /// via these fees individual bundler owner may earn income per policy in the context of peer to peer pools
+    function setBundleFee(
+        NftId bundleNftId, 
+        Fee memory fee
+    ) external;
+
+    /// @dev sets the maximum overall capital amound held by this pool
+    /// function may only be called by pool owner
+    function setMaxCapitalAmount(Amount maxCapitalAmount) external;
+
+    /// @dev sets the required role to create/own bundles
+    /// may only be called once after setting up a pool
+    /// may only be called by pool owner 
+    function setBundleOwnerRole(RoleId bundleOwnerRole) external;
+
+    /// @dev update pool fees to the specified values
+    /// pool fees: are deducted from the premium amount and goes to the pool owner
+    /// staking fees: are deducted from the staked tokens by a bundle owner and goes to the pool owner
+    /// performance fees: when a bundle is closed a bundle specific profit is calculated
+    /// the performance fee is deducted from this profit and goes to the pool owner
+    function setFees(
+        Fee memory poolFee,
+        Fee memory stakingFee,
+        Fee memory performanceFee
+    ) external;
+
+    /// @dev this is a callback function that is called by the product service when underwriting a policy.
+    /// the pool has the option to check the details and object to underwriting by reverting.
+    /// the function is only called for "active" pools that ask to be involved/notified
+    /// by product related state changes.
+    function verifyApplication(
+        NftId applicationNftId, 
+        bytes memory applicationData,
+        NftId bundleNftId, 
+        bytes memory bundleFilter,
+        Amount collateralizationAmount
+    ) external;
+
+    /// @dev returns true iff the application matches with the bundle 
+    /// this is a callback function that is only called if a pool declares itself as a verifying pool
+    /// default implementation returns true
+    function applicationMatchesBundle(
+        NftId applicationNftId, 
+        bytes memory applicationData,
+        NftId bundleNftId, 
+        bytes memory bundleFilter,
+        Amount collateralizationAmount
+    )
+        external
+        view
+        returns (bool isMatching);
+
+    /// @dev returns pool specific infos for this pool
+    /// when registered with an instance the info is obtained from the data stored in the instance
+    /// when not registered the function returns the info from the component contract
+    function getPoolInfo() external view returns (IComponents.PoolInfo memory info);
+
+}