@etherisc/gif-next 0.0.2-f99f1d2-109 → 0.0.2-fb8d07b-779

package/contracts/instance/InstanceService.sol

@@ -0,0 +1,182 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Clones} from "@openzeppelin/contracts/proxy/Clones.sol";
+
+import {AccessManagerSimple} from "./AccessManagerSimple.sol";
+import {InstanceAccessManager} from "./InstanceAccessManager.sol";
+import {Instance} from "./Instance.sol";
+import {IInstanceService} from "./IInstanceService.sol";
+import {InstanceReader} from "./InstanceReader.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {Registry} from "../registry/Registry.sol";
+import {RegistryService} from "../registry/RegistryService.sol";
+import {Service} from "../../contracts/shared/Service.sol";
+import {IService} from "../shared/IService.sol";
+import {ContractDeployerLib} from "../shared/ContractDeployerLib.sol";
+import {NftId, NftIdLib, zeroNftId} from "../../contracts/types/NftId.sol";
+import {RoleId} from "../types/RoleId.sol";
+import {VersionLib} from "../types/Version.sol";
+import {ADMIN_ROLE, INSTANCE_SERVICE_ROLE, DISTRIBUTION_SERVICE_ROLE, POOL_SERVICE_ROLE} from "../types/RoleId.sol";
+
+contract InstanceService is Service, IInstanceService {
+
+    address internal _registryAddress;
+    address internal _accessManagerMaster;
+    address internal _instanceMaster;
+    address internal _instanceReaderMaster;
+
+    // TODO update to real hash when instance is stable
+    bytes32 public constant INSTANCE_CREATION_CODE_HASH = bytes32(0);
+    string public constant NAME = "InstanceService";
+
+    function createInstanceClone()
+        external 
+        returns (
+            AccessManagerSimple clonedAccessManager, 
+            Instance clonedInstance,
+            NftId instanceNftId,
+            InstanceReader clonedInstanceReader
+        )
+    {
+        address instanceOwner = msg.sender;
+        Registry registry = Registry(_registryAddress);
+        NftId registryNftId = registry.getNftId(_registryAddress);
+        address registryServiceAddress = registry.getServiceAddress("RegistryService", VersionLib.toVersion(3, 0, 0).toMajorPart());
+        RegistryService registryService = RegistryService(registryServiceAddress);
+
+        // initially set the authority of the access managar to this (being the instance service). 
+        // This will allow the instance service to bootstrap the authorizations of the instance
+        // and then transfer the ownership of the access manager to the instance owner once everything is setup
+        clonedAccessManager = AccessManagerSimple(Clones.clone(_accessManagerMaster));
+        clonedAccessManager.initialize(address(this));
+
+        clonedInstance = Instance(Clones.clone(_instanceMaster));
+        clonedInstance.initialize(address(clonedAccessManager), _registryAddress, registryNftId, msg.sender);
+        ( IRegistry.ObjectInfo memory info, ) = registryService.registerInstance(clonedInstance);
+        instanceNftId = info.nftId;
+        
+        clonedInstanceReader = InstanceReader(Clones.clone(address(_instanceReaderMaster)));
+        clonedInstanceReader.initialize(_registryAddress, instanceNftId);
+
+        _grantInitialAuthorizations(clonedAccessManager, clonedInstance);
+
+        clonedInstance.setInstanceReader(clonedInstanceReader);
+        
+        // to complete setup switch instance ownership to the instance owner
+        // TODO: use a role less powerful than admin, maybe INSTANCE_ADMIN (does not exist yet)
+        clonedAccessManager.grantRole(ADMIN_ROLE().toInt(), instanceOwner, 0);
+        clonedAccessManager.revokeRole(ADMIN_ROLE().toInt(), address(this));
+
+        emit LogInstanceCloned(address(clonedAccessManager), address(clonedInstance), address(clonedInstanceReader), instanceNftId);
+    }
+
+    function _grantInitialAuthorizations(AccessManagerSimple clonedAccessManager, Instance clonedInstance) internal {
+        address distributionServiceAddress = _registry.getServiceAddress("DistributionService", VersionLib.toVersion(3, 0, 0).toMajorPart());
+        clonedAccessManager.grantRole(DISTRIBUTION_SERVICE_ROLE().toInt(), distributionServiceAddress, 0);
+        bytes4[] memory instanceDistributionServiceSelectors = new bytes4[](2);
+        instanceDistributionServiceSelectors[0] = clonedInstance.createDistributionSetup.selector;
+        instanceDistributionServiceSelectors[1] = clonedInstance.updateDistributionSetup.selector;
+        clonedAccessManager.setTargetFunctionRole(
+            address(clonedInstance),
+            instanceDistributionServiceSelectors, 
+            DISTRIBUTION_SERVICE_ROLE().toInt());
+
+        address poolServiceAddress = _registry.getServiceAddress("PoolService", VersionLib.toVersion(3, 0, 0).toMajorPart());
+        clonedAccessManager.grantRole(POOL_SERVICE_ROLE().toInt(), address(poolServiceAddress), 0);
+        bytes4[] memory instancePoolServiceSelectors = new bytes4[](4);
+        instancePoolServiceSelectors[0] = clonedInstance.createPoolSetup.selector;
+        instancePoolServiceSelectors[1] = clonedInstance.updatePoolSetup.selector;
+        instancePoolServiceSelectors[2] = clonedInstance.createBundle.selector;
+        instancePoolServiceSelectors[3] = clonedInstance.updateBundle.selector;
+        clonedAccessManager.setTargetFunctionRole(
+            address(clonedInstance),
+            instancePoolServiceSelectors, 
+            POOL_SERVICE_ROLE().toInt());
+
+    }
+
+    function setAccessManagerMaster(address accessManagerMaster) external {
+        require(
+            _accessManagerMaster == address(0),
+            "ERROR:CRD-001:ACCESS_MANAGER_MASTER_ALREADY_SET");
+        _accessManagerMaster = accessManagerMaster;
+    }
+
+    function setInstanceMaster(address instanceMaster) external {
+        require(
+            _instanceMaster == address(0),
+            "ERROR:CRD-002:INSTANCE_MASTER_ALREADY_SET");
+        _instanceMaster = instanceMaster;
+    }
+
+    function setInstanceReaderMaster(address instanceReaderMaster) external {
+        require(
+            _instanceReaderMaster == address(0),
+            "ERROR:CRD-003:INSTANCE_READER_MASTER_ALREADY_SET");
+        _instanceReaderMaster = instanceReaderMaster;
+    }
+
+    function getInstanceReaderMaster() external view returns (address) {
+        return _instanceReaderMaster;
+    }
+
+    function getInstanceMaster() external view returns (address) {
+        return _instanceMaster;
+    }
+
+    function getAccessManagerMaster() external view returns (address) {
+        return _accessManagerMaster;
+    }
+
+    // From IService
+    function getName() public pure override(IService, Service) returns(string memory) {
+        return NAME;
+    }
+    
+    /// @dev top level initializer
+    // 1) registry is non upgradeable -> don't need a proxy and uses constructor !
+    // 2) deploy registry service first -> from its initialization func it is easier to deploy registry then vice versa
+    // 3) deploy registry -> pass registry service address as constructor argument
+    // registry is getting instantiated and locked to registry service address forever
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        initializer
+        virtual override
+    {
+        // bytes memory encodedConstructorArguments = abi.encode(
+        //     _registryAddress);
+
+        // bytes memory instanceCreationCode = ContractDeployerLib.getCreationCode(
+        //     instanceByteCodeWithInitCode,
+        //     encodedConstructorArguments);
+
+        // address instanceAddress = ContractDeployerLib.deploy(
+        //     instanceCreationCode,
+        //     INSTANCE_CREATION_CODE_HASH);
+
+        address initialOwner = address(0);
+        (_registryAddress, initialOwner) = abi.decode(data, (address, address));
+
+        _initializeService(_registryAddress, initialOwner);
+        
+        _registerInterface(type(IService).interfaceId);
+        _registerInterface(type(IInstanceService).interfaceId);
+    }
+
+    function hasRole(address account, RoleId role, NftId instanceNftId) external view returns (bool) {
+        IRegistry.ObjectInfo memory instanceObjectInfo = getRegistry().getObjectInfo(instanceNftId);
+        address instanceAddress = instanceObjectInfo.objectAddress;
+        Instance instance = Instance(instanceAddress);
+        AccessManagerSimple accessManager = AccessManagerSimple(instance.authority());
+        (bool isMember, uint32 executionDelay) = accessManager.hasRole(role.toInt(), account);
+        if (executionDelay > 0) {
+            return false;
+        } 
+        return isMember;
+    }
+}
+

package/contracts/instance/InstanceServiceManager.sol

@@ -0,0 +1,56 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Instance} from "./Instance.sol";
+import {IVersionable} from "../shared/IVersionable.sol";
+import {ProxyManager} from "../shared/ProxyManager.sol";
+import {InstanceService} from "./InstanceService.sol";
+import {Registry} from "../registry/Registry.sol";
+import {RegistryService} from "../registry/RegistryService.sol";
+import {VersionLib} from "../types/Version.sol";
+
+contract InstanceServiceManager is ProxyManager {
+
+    InstanceService private _instanceService;
+
+    /// @dev initializes proxy manager with instance service implementation and deploys instance
+    constructor(
+        address registryAddress
+    )
+        ProxyManager()
+    {
+        InstanceService instSrv = new InstanceService();
+        // bytes memory initCode = type(InstanceService).creationCode;
+        bytes memory data = abi.encode(registryAddress, address(this));
+        IVersionable versionable = deploy(
+            address(instSrv), 
+            data);
+
+        _instanceService = InstanceService(address(versionable));
+
+        Registry registry = Registry(registryAddress);
+        address registryServiceAddress = registry.getServiceAddress("RegistryService", VersionLib.toVersion(3, 0, 0).toMajorPart());
+        RegistryService registryService = RegistryService(registryServiceAddress);
+
+        registryService.registerService(_instanceService);
+        // RegistryService registryService = _instanceService.getRegistryService();
+
+        // link ownership of instance service manager ot nft owner of instance service
+        _linkToNftOwnable(
+            address(registryAddress),
+            address(_instanceService));
+
+        // implies that after this constructor call only upgrade functionality is available
+        _isDeployed = true;
+    }
+
+    //--- view functions ----------------------------------------------------//
+    function getInstanceService()
+        external
+        view
+        returns (InstanceService instanceService)
+    {
+        return _instanceService;
+    }
+
+}

package/contracts/instance/base/ComponentServiceBase.sol

@@ -0,0 +1,125 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../registry/IRegistry.sol";
+import {IRegistryService} from "../../registry/IRegistryService.sol";
+import {IInstance} from "../../instance/IInstance.sol";
+import {ObjectType, INSTANCE, PRODUCT, POOL, DISTRIBUTION, ORACLE} from "../../types/ObjectType.sol";
+import {NftId, NftIdLib} from "../../types/NftId.sol";
+import {RoleId, PRODUCT_OWNER_ROLE, POOL_OWNER_ROLE, DISTRIBUTION_OWNER_ROLE, ORACLE_OWNER_ROLE} from "../../types/RoleId.sol";
+
+import {BaseComponent} from "../../components/BaseComponent.sol";
+import {INftOwnable} from "../../shared/INftOwnable.sol";
+import {Service} from "../../shared/Service.sol";
+import {InstanceService} from "../InstanceService.sol";
+import {Version, VersionPart, VersionLib} from "../../types/Version.sol";
+
+abstract contract ComponentServiceBase is Service {
+
+    error ExpectedRoleMissing(RoleId expected, address caller);
+    error ComponentTypeInvalid(ObjectType componentType);
+
+    mapping (ObjectType => RoleId) internal _objectTypeToExpectedRole;
+
+    /// @dev modifier to check if caller has a role on the instance the component is registered in
+    modifier onlyComponentOwnerRole(address componentAddress) {
+        BaseComponent component = BaseComponent(componentAddress);
+        ObjectType objectType = _getObjectType(component);
+        RoleId expectedRole = _objectTypeToExpectedRole[objectType];
+
+        address componentOwner = msg.sender;
+        INftOwnable nftOwnable = INftOwnable(address(component.getInstance()));
+        if(! getInstanceService().hasRole(componentOwner, expectedRole, nftOwnable.getNftId())) {
+            revert ExpectedRoleMissing(expectedRole, componentOwner);
+        }
+        _;
+    }
+
+    function _initializeService(
+        address registry, 
+        address initialOwner
+    )
+        internal
+        override
+    {
+        super._initializeService(registry, initialOwner);
+        _objectTypeToExpectedRole[PRODUCT()] = PRODUCT_OWNER_ROLE();
+        _objectTypeToExpectedRole[POOL()] = POOL_OWNER_ROLE();
+        _objectTypeToExpectedRole[DISTRIBUTION()] = DISTRIBUTION_OWNER_ROLE();
+        _objectTypeToExpectedRole[ORACLE()] = ORACLE_OWNER_ROLE();
+    }
+
+    function getInstanceService() public view returns (InstanceService) {
+        return InstanceService(getRegistry().getServiceAddress("InstanceService", getMajorVersion()));
+    }
+
+    function register(address componentAddress) 
+        external 
+        onlyComponentOwnerRole(componentAddress)
+        returns (NftId componentNftId)
+    {
+        address componentOwner = msg.sender;
+        BaseComponent component = BaseComponent(componentAddress);
+        ObjectType objectType = _getObjectType(component);
+        IRegistryService registryService = getRegistryService();
+
+        IRegistry.ObjectInfo memory objInfo;
+        bytes memory initialObjData;
+
+        if (objectType == DISTRIBUTION()) {
+            (objInfo, initialObjData) = registryService.registerDistribution(component, componentOwner);
+        } else if (objectType == PRODUCT()) {
+            (objInfo, initialObjData) = registryService.registerProduct(component, componentOwner);
+        } else if (objectType == POOL()) {
+            (objInfo, initialObjData) = registryService.registerPool(component, componentOwner);
+        // TODO: implement this for oracle - currently missing in registry
+        // } else if (objectType == ORACLE()) {
+        //     (objInfo, initialObjData) = registryService.registerOracle(component, componentOwner);
+        } else {
+            revert ComponentTypeInvalid(objectType);
+        }
+
+        componentNftId = objInfo.nftId;
+        IInstance instance = _getInstanceFromComponentNft(componentNftId);
+        _finalizeComponentRegistration(componentNftId, initialObjData, instance);
+    }
+
+    function _finalizeComponentRegistration(NftId componentNftId, bytes memory initialObjData, IInstance instance) internal virtual;
+
+    function _getObjectType(BaseComponent component) internal view returns (ObjectType) {
+        (IRegistry.ObjectInfo memory compInitialInfo, )  = component.getInitialInfo();
+        return compInitialInfo.objectType;
+    }
+    
+    function _getInstanceFromComponentNft(NftId componentNftId) internal view returns (IInstance) {
+        IRegistry registry = getRegistry();
+        IRegistry.ObjectInfo memory compInfo = registry.getObjectInfo(componentNftId);
+        IRegistry.ObjectInfo memory instanceInfo = registry.getObjectInfo(compInfo.parentNftId);
+        return IInstance(instanceInfo.objectAddress);
+    }
+
+    function _getAndVerifyComponentInfoAndInstance(
+        ObjectType objectType
+    )
+        internal
+        view
+        returns(
+            IRegistry.ObjectInfo memory info, 
+            IInstance instance
+        )
+    {
+        NftId componentNftId = _registry.getNftId(msg.sender);
+        require(componentNftId.gtz(), "ERROR_COMPONENT_UNKNOWN");
+
+        info = getRegistry().getObjectInfo(componentNftId);
+        require(info.objectType == objectType, "OBJECT_TYPE_INVALID");
+
+        address instanceAddress = getRegistry().getObjectInfo(info.parentNftId).objectAddress;
+        instance = IInstance(instanceAddress);
+    }
+
+    function getRegistryService() public view virtual returns (IRegistryService) {
+        address service = getRegistry().getServiceAddress("RegistryService", getMajorVersion());
+        return IRegistryService(service);
+    }
+}

package/contracts/instance/base/IInstanceBase.sol

@@ -0,0 +1,23 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Key32} from "../../types/Key32.sol";
+import {StateId} from "../../types/StateId.sol";
+
+import {IKeyValueStore} from "./IKeyValueStore.sol";
+
+import {IComponentOwnerService} from "../service/IComponentOwnerService.sol";
+import {IDistributionService} from "../service/IDistributionService.sol";
+import {IProductService} from "../service/IProductService.sol";
+import {IPoolService} from "../service/IPoolService.sol";
+
+interface IInstanceBase {
+    function getKeyValueStore() external view returns (IKeyValueStore keyValueStore);
+    function updateState(Key32 key, StateId state) external;
+    function getState(Key32 key) external view returns (StateId state);
+
+    function getComponentOwnerService() external view returns(IComponentOwnerService);
+    function getDistributionService() external view returns(IDistributionService);
+    function getProductService() external view returns(IProductService service);
+    function getPoolService() external view returns(IPoolService service);
+}

package/contracts/instance/base/IKeyValueStore.sol

@@ -0,0 +1,49 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Blocknumber, blockBlocknumber, zeroBlocknumber} from "../../types/Blocknumber.sol";
+import {Key32, KeyId} from "../../types/Key32.sol";
+import {NftId} from "../../types/NftId.sol";
+import {ObjectType} from "../../types/ObjectType.sol";
+import {StateId} from "../../types/StateId.sol";
+
+import {ILifecycle} from "./ILifecycle.sol";
+
+// TODO remove - internal only?
+interface IKeyValueStore is ILifecycle {
+
+    struct Value {
+        Metadata metadata;
+        bytes data;
+    }
+
+    struct Metadata {
+        ObjectType objectType;
+        StateId state;
+        // TODO updatedBy needs concept that says what value should go here
+        // eg account outside gif objects that initiated the tx
+        // implies the caller needs to be propagated through all calls up to key values store itself
+        // to always have the instance address there doesn't seem to make sense
+        address updatedBy;
+        Blocknumber updatedIn;
+        Blocknumber createdIn;
+    }
+
+    event LogInfoCreated(ObjectType objectType, KeyId keyId, StateId state, address createdBy, address txOrigin);
+    event LogInfoUpdated(ObjectType objectType, KeyId keyId, StateId state, address updatedBy, address txOrigin, Blocknumber lastUpdatedIn);
+    event LogStateUpdated(ObjectType objectType, KeyId keyId, StateId stateOld, StateId stateNew, address updatedBy, address txOrigin, Blocknumber lastUpdatedIn);
+
+    // generic state changing functions
+    // function create(Key32 key, bytes memory data) external;
+    // function update(Key32 key, bytes memory data, StateId state) external;
+    // function updateData(Key32 key, bytes memory data) external;
+    // function updateState(Key32 key, StateId state) external;
+
+    function exists(Key32 key) external view returns (bool);
+    function get(Key32 key) external view returns (Value memory value);
+    function getData(Key32 key) external view returns (bytes memory data);
+    function getMetadata(Key32 key) external view returns (Metadata memory metadata);
+    function getState(Key32 key) external view returns (StateId state);
+
+    function toKey32(ObjectType objectType, KeyId id) external pure returns(Key32);
+}

package/contracts/instance/base/ILifecycle.sol

@@ -0,0 +1,30 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {NftId} from "../../types/NftId.sol";
+import {ObjectType} from "../../types/ObjectType.sol";
+import {StateId} from "../../types/StateId.sol";
+
+interface ILifecycle {
+
+    error ErrorNoLifecycle(NftId nftId, ObjectType objectType);
+    error ErrorInvalidStateTransition(
+        ObjectType objectType,
+        StateId fromStateId,
+        StateId toStateId
+    );
+
+    function hasLifecycle(
+        ObjectType objectType
+    ) external view returns (bool);
+
+    function getInitialState(
+        ObjectType objectType
+    ) external view returns (StateId);
+
+    function isValidTransition(
+        ObjectType objectType,
+        StateId fromId,
+        StateId toId
+    ) external view returns (bool);
+}

package/contracts/instance/base/KeyValueStore.sol

@@ -0,0 +1,172 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Blocknumber, blockBlocknumber, zeroBlocknumber} from "../../types/Blocknumber.sol";
+import {Key32, KeyId, Key32Lib} from "../../types/Key32.sol";
+import {NftId} from "../../types/NftId.sol";
+import {ObjectType} from "../../types/ObjectType.sol";
+import {StateId, ACTIVE} from "../../types/StateId.sol";
+import {Timestamp, TimestampLib} from "../../types/Timestamp.sol";
+
+import {Lifecycle} from "./Lifecycle.sol";
+import {IKeyValueStore} from "./IKeyValueStore.sol";
+
+contract KeyValueStore is Lifecycle, IKeyValueStore {
+
+    mapping(Key32 key32 => Value value) private _value;
+
+    function create(
+        Key32 key32, 
+        bytes memory data
+    )
+        internal
+    {
+        _create(key32, data);
+    }
+
+    function _create(
+        Key32 key32, 
+        bytes memory data
+    )
+        internal
+    {
+        ObjectType objectType = key32.toObjectType();
+        require(objectType.gtz(), "ERROR:KVS-010:TYPE_UNDEFINED");
+
+        Metadata storage metadata = _value[key32].metadata;
+        require(metadata.state.eqz(), "ERROR:KVS-012:ALREADY_CREATED");
+
+        address createdBy = msg.sender;
+        Blocknumber blocknumber = blockBlocknumber();
+        StateId initialState = hasLifecycle(objectType) ? getInitialState(objectType) : ACTIVE();
+
+        // set metadata
+        metadata.objectType = objectType;
+        metadata.state = initialState;
+        metadata.updatedBy = createdBy;
+        metadata.updatedIn = blocknumber;
+        metadata.createdIn = blocknumber;
+
+        // set data
+        _value[key32].data = data;
+
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogInfoCreated(key32.toObjectType(), key32.toKeyId(), initialState, createdBy, tx.origin);
+    }
+
+    function update(
+        Key32 key32, 
+        bytes memory data,
+        StateId state
+    ) 
+        internal
+    {
+        _update(key32, data, state);
+    }
+
+    function _update(
+        Key32 key32, 
+        bytes memory data,
+        StateId state
+    ) 
+        internal
+    {
+        require(state.gtz(), "ERROR:KVS-020:STATE_UNDEFINED");
+        Metadata storage metadata = _value[key32].metadata;
+        StateId stateOld = metadata.state;
+        require(stateOld.gtz(), "ERROR:KVS-021:NOT_EXISTING");
+
+        // update data
+        _value[key32].data = data;
+
+        // update metadata (and state)
+        address updatedBy = msg.sender;
+        Blocknumber lastUpdatedIn = metadata.updatedIn;
+        metadata.state = state;
+        metadata.updatedBy = updatedBy;
+        metadata.updatedIn = blockBlocknumber();
+
+        // create log entries
+        // solhint-disable avoid-tx-origin
+        emit LogStateUpdated(key32.toObjectType(), key32.toKeyId(), state, stateOld, updatedBy, tx.origin, lastUpdatedIn);
+        emit LogInfoUpdated(key32.toObjectType(), key32.toKeyId(), state, updatedBy, tx.origin, lastUpdatedIn);
+        // solhing-enable
+    }
+
+    function updateData(Key32 key32, bytes memory data) 
+        internal
+    {
+        _updateData(key32, data);
+    }
+
+    function _updateData(Key32 key32, bytes memory data) 
+        internal
+    {
+        Metadata storage metadata = _value[key32].metadata;
+        StateId state = metadata.state;
+        require(state.gtz(), "ERROR:KVS-030:NOT_EXISTING");
+
+        // update data
+        _value[key32].data = data;
+
+        // update metadata
+        address updatedBy = msg.sender;
+        Blocknumber lastUpdatedIn = metadata.updatedIn;
+        metadata.updatedBy = updatedBy;
+        metadata.updatedIn = blockBlocknumber();
+
+        // create log entry
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogInfoUpdated(key32.toObjectType(), key32.toKeyId(), state, updatedBy, tx.origin, lastUpdatedIn);
+    }
+
+    function updateState(Key32 key32, StateId state)
+        internal
+    {
+        _updateState(key32, state);
+    }
+
+    function _updateState(Key32 key32, StateId state)
+        internal
+    {
+        require(state.gtz(), "ERROR:KVS-040:STATE_UNDEFINED");
+        Metadata storage metadata = _value[key32].metadata;
+        StateId stateOld = metadata.state;
+        require(stateOld.gtz(), "ERROR:KVS-041:NOT_EXISTING");
+
+        // update metadata (and state)
+        address updatedBy = msg.sender;
+        Blocknumber lastUpdatedIn = metadata.updatedIn;
+        metadata.state = state;
+        metadata.updatedBy = updatedBy;
+        metadata.updatedIn = blockBlocknumber();
+
+        // create log entry
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogStateUpdated(key32.toObjectType(), key32.toKeyId(), state, stateOld, updatedBy, tx.origin, lastUpdatedIn);
+    }
+
+    function exists(Key32 key32) public view returns (bool) {
+        return _value[key32].metadata.state.gtz();
+    }
+
+    function get(Key32 key32) public view returns (Value memory value) {
+        return _value[key32];
+    }
+
+    function getMetadata(Key32 key32) public view returns (Metadata memory metadata) {
+        return _value[key32].metadata;
+    }
+
+    function getData(Key32 key32) public view returns (bytes memory data) {
+        return _value[key32].data;
+    }
+
+    function getState(Key32 key32) public view returns (StateId state) {
+        return _value[key32].metadata.state;
+    }
+
+    function toKey32(ObjectType objectType, KeyId id) external pure override returns(Key32) {
+        return Key32Lib.toKey32(objectType, id);
+    }
+}