@etherisc/gif-next 0.0.2-f7be756-963 → 0.0.2-f7eda15-119

package/contracts/registry/ReleaseManager.sol

@@ -0,0 +1,332 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {AccessManaged} from "@openzeppelin/contracts/access/manager/AccessManaged.sol";
+
+import {NftId} from "../types/NftId.sol";
+import {RoleId} from "../types/RoleId.sol";
+import {ObjectType, ObjectTypeLib, zeroObjectType, REGISTRY, SERVICE} from "../types/ObjectType.sol";
+import {VersionPart, VersionPartLib} from "../types/Version.sol";
+import {Timestamp, TimestampLib} from "../types/Timestamp.sol";
+
+import {IService} from "../shared/IService.sol";
+
+import {IRegistry} from "./IRegistry.sol";
+import {Registry} from "./Registry.sol";
+import {IRegistryService} from "./IRegistryService.sol";
+import {RegistryAccessManager} from "./RegistryAccessManager.sol";
+
+
+contract ReleaseManager is AccessManaged
+{
+    using ObjectTypeLib for ObjectType;
+
+    event LogReleaseCreation(VersionPart version); 
+    event LogReleaseActivation(VersionPart version);
+
+    // createNextRelease
+    error NotRegistryService();
+    error UnexpectedServiceAuthority(address expected, address found);
+
+    // registerService
+    error NotService();
+
+    // activateNextRelease
+    error ReleaseNotCreated();
+    error ReleaseRegistrationNotFinished();
+
+    // _getAndVerifyContractInfo
+    error UnexpectedRegisterableType(ObjectType expected, ObjectType found);
+    error NotRegisterableOwner(address notOwner);
+    error SelfRegistration();
+    error RegisterableOwnerIsRegistered();
+
+    // _verifyServiceInfo
+    error UnexpectedServiceVersion(VersionPart expected, VersionPart found);
+    error UnexpectedServiceDomain(ObjectType expected, ObjectType found);
+    
+    // _verifyAndStoreConfig
+    error ConfigMissing();
+    error ConfigServiceDomainInvalid(uint configArrayIndex, ObjectType domain);
+    error ConfigSelectorZero(uint configArrayIndex);
+    error SelectorAlreadyExists(VersionPart releaseVersion, ObjectType serviceDomain);
+
+
+    RegistryAccessManager private immutable _accessManager;
+    IRegistry private immutable _registry;
+
+    VersionPart immutable _initial;// first active version    
+    VersionPart _latest;// latest active version
+    VersionPart _next;// version to create and activate 
+
+    mapping(VersionPart version => IRegistry.ReleaseInfo info) _release;
+
+    mapping(VersionPart version => mapping(ObjectType serviceDomain => bytes4)) _selector; // registry service function selector assigned to domain 
+
+    uint _awaitingRegistration; // "services left to register" counter
+
+    mapping(address registryService => bool isActive) _active;
+
+    mapping(VersionPart version => bool isValid) _valid; // TODO refactor to use _active only
+
+    constructor(
+        RegistryAccessManager accessManager, 
+        VersionPart initialVersion)
+        AccessManaged(accessManager.authority())
+    {
+        require(initialVersion.toInt() > 0, "ReleaseManager: initial version is 0");
+
+        _accessManager = accessManager;
+
+        _initial = initialVersion;
+        _next = initialVersion;
+
+        _registry = new Registry();
+    }
+
+    /// @dev skips previous release if was not activated
+    function createNextRelease()
+        external
+        restricted // GIF_ADMIN_ROLE
+    {
+        // allow to register new registry service for next version
+        VersionPartLib.toVersionPart(_next.toInt() + 1);
+        // disallow registration of regular services for next version while registry service is not registered 
+        _awaitingRegistration = 0;
+
+        emit LogReleaseCreation(_next); 
+    }
+
+    function activateNextRelease() 
+        external 
+        restricted // GIF_ADMIN_ROLE
+    {
+        VersionPart version = _next;
+        address service = _registry.getServiceAddress(REGISTRY(), version);
+
+        // release was created
+        if(service == address(0)) {
+            revert ReleaseNotCreated();
+        }
+
+        // release fully deployed
+        if(_awaitingRegistration > 0) {
+            revert ReleaseRegistrationNotFinished();
+        }
+
+        //setTargetClosed(service, false);
+
+        _latest = version;
+
+        _active[service] = true;
+        _valid[version] = true;
+
+        emit LogReleaseActivation(version);
+    }
+
+    // TODO deploy proxy and initialize with given implementation instead of using given proxy?
+    // IMPORTANT: MUST never be possible to create with access/release manager, token registry
+    // callable once per release after release creation, can not register regular services while registry service is not registered
+    function registerRegistryService(IRegistryService service)
+        external
+        restricted // GIF_MANAGER_ROLE
+        returns(NftId nftId)
+    {
+        if(!service.supportsInterface(type(IRegistryService).interfaceId)) {
+            revert NotRegistryService();
+        }
+
+        // TODO unreliable! MUST guarantee the same authority -> how?
+        address serviceAuthority = service.authority();
+        if(serviceAuthority != authority()) {
+            revert UnexpectedServiceAuthority(
+                authority(), 
+                serviceAuthority); 
+        }
+
+        IRegistry.ObjectInfo memory info = _getAndVerifyContractInfo(service, SERVICE(), msg.sender);
+
+        VersionPart version = _next;
+        ObjectType domain = REGISTRY();
+        _verifyServiceInfo(info, version, domain);
+
+        // data: config bytes
+        _createRelease(service.getFunctionConfigs());
+
+        //setTargetClosed(service, true);
+        
+        nftId = _registry.registerService(info, version, domain);
+
+        // external call
+        service.linkToRegisteredNftId();
+    }
+
+    // TODO adding service to release -> synchronized with proxy upgrades or simple addServiceToRelease(service, version, selector)?
+    // TODO removing service from release? -> set _active to false forever, but keep all other records?
+    function registerService(IService service) 
+        external
+        restricted // GIF_MANAGER_ROLE
+        returns(NftId nftId)
+    {
+        if(!service.supportsInterface(type(IService).interfaceId)) {
+            revert NotService();
+        }
+
+        IRegistry.ObjectInfo memory info = _getAndVerifyContractInfo(service, SERVICE(), msg.sender);
+        VersionPart version = getNextVersion();
+        ObjectType domain = _release[version].domains[_awaitingRegistration];// reversed registration order of services specified in RegistryService config
+        _verifyServiceInfo(info, version, domain);
+
+        // setup and grant unique role if service does registrations
+        bytes4[] memory selector = new bytes4[](1);
+        selector[0] = _selector[version][domain];
+        address registryService = _registry.getServiceAddress(REGISTRY(), version);
+        if(selector[0] != 0) {
+            _accessManager.setAndGrantUniqueRole(
+                address(service), 
+                registryService, 
+                selector);
+        }
+        
+        _awaitingRegistration--;
+
+        nftId = _registry.registerService(info, version, domain);
+
+        // external call
+        service.linkToRegisteredNftId(); 
+    }
+
+    //--- view functions ----------------------------------------------------//
+
+    function isActiveRegistryService(address service) external view returns(bool)
+    {
+        return _active[service];
+    }
+
+    function isValidRelease(VersionPart version) external view returns(bool)
+    {
+        return _valid[version];
+    }
+
+    function getRegistry() external view returns(address)
+    {
+        return (address(_registry));
+    }
+
+    function getReleaseInfo(VersionPart version) external view returns(IRegistry.ReleaseInfo memory)
+    {
+        return _release[version];
+    }
+
+    function getNextVersion() public view returns(VersionPart) 
+    {
+        return _next;
+    }
+
+    function getLatestVersion() external view returns(VersionPart) {
+        return _latest;
+    }
+
+    function getInitialVersion() external view returns(VersionPart) {
+        return _initial;
+    }
+
+    //--- private functions ----------------------------------------------------//
+
+    function _getAndVerifyContractInfo(
+        IService service,
+        ObjectType expectedType,
+        address expectedOwner // assume always valid, can not be 0
+    )
+        internal
+        // view
+        returns(
+            IRegistry.ObjectInfo memory info
+        )
+    {
+        info = service.getInitialInfo();
+        info.objectAddress = address(service);
+        info.isInterceptor = false; // service is never interceptor, at least now
+
+        if(info.objectType != expectedType) {// type is checked in registry anyway...but service logic may depend on expected value
+            revert UnexpectedRegisterableType(expectedType, info.objectType);
+        }
+
+        address owner = info.initialOwner;
+
+        if(owner != expectedOwner) { // registerable owner protection
+            revert NotRegisterableOwner(expectedOwner); 
+        }
+
+        if(owner == address(service)) {
+            revert SelfRegistration();
+        }
+        
+        if(_registry.isRegistered(owner)) { 
+            revert RegisterableOwnerIsRegistered(); 
+        }
+    }
+
+    function _verifyServiceInfo(
+        IRegistry.ObjectInfo memory info,
+        VersionPart expectedVersion,
+        ObjectType expectedDomain
+    )
+        internal
+        view
+        returns(ObjectType)
+    {
+        (
+            ObjectType domain,
+            VersionPart version
+        ) = abi.decode(info.data, (ObjectType, VersionPart));
+
+        if(version != expectedVersion) {
+            revert UnexpectedServiceVersion(expectedVersion, version);
+        }
+
+        if(domain != expectedDomain) {
+            revert UnexpectedServiceDomain(expectedDomain, domain);
+        }
+
+        return domain;
+    }
+
+    // TODO check if registry supports types specified in the config array
+    function _createRelease(IRegistryService.FunctionConfig[] memory config)
+        internal
+    {
+        VersionPart version = getNextVersion();
+
+        if(config.length == 0) {
+            revert ConfigMissing();
+        }
+        // always in release
+        _release[version].domains.push(REGISTRY());
+        for(uint idx = 0; idx < config.length; idx++)
+        {
+            ObjectType domain = config[idx].serviceDomain;
+            bytes4 selector = config[idx].selector;
+
+            // not "registry service" / zero domain
+            if(
+                domain == REGISTRY() ||
+                domain.eqz()
+            ) { revert ConfigServiceDomainInvalid(idx, domain); } 
+
+            // TODO can be zero -> e.g. duplicate domain, first with zero selector, second with non zero selector -> need to check _release[version].domains.contains(domain) instead
+            // no overwrite
+            if(_selector[version][domain] > 0) {
+                revert SelectorAlreadyExists(version, domain); 
+            }
+            
+            _selector[version][domain] = selector;
+            _release[version].domains.push(domain);
+        }
+        // TODO set when activated?
+        _release[version].createdAt = TimestampLib.blockTimestamp();
+        //_release[version].updatedAt = TimestampLib.blockTimestamp();
+
+        _awaitingRegistration = config.length;
+    }
+}

package/contracts/registry/TokenRegistry.sol

@@ -0,0 +1,112 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+import {ERC165Checker} from "@openzeppelin/contracts/utils/introspection/ERC165Checker.sol";
+
+import {IRegisterable} from "../shared/IRegisterable.sol";
+import {IRegistry} from "./IRegistry.sol";
+import {VersionPart} from "../types/Version.sol";
+import {REGISTRY} from "../types/ObjectType.sol";
+import {NftOwnable} from "../shared/NftOwnable.sol";
+
+/// @title contract to register token per GIF major release.
+contract TokenRegistry is
+    NftOwnable
+{
+    event LogRegistered(address token, string symbol, uint256 decimals);
+    event LogTokenStateSet(address token, VersionPart majorVersion, bool active);
+
+    error NotContract(address account);
+    error NotToken(address account);
+    error TokenDecimalsZero();
+    error TokenMajorVersionInvalid(VersionPart majorVersion);
+
+    address [] internal _token;
+    mapping(address token => bool registered) internal _registered;
+    mapping(address token => mapping(VersionPart majorVersion => bool isActive)) internal _active;
+
+    constructor()
+        NftOwnable()
+    { }
+
+
+    /// @dev link ownership of token registry to nft owner of registry service
+    // TODO latter registry service will get new release, new address, new nft, TokenRegistry will not catch that -> use AccessManaged only for services
+    function linkToNftOwnable(address registryAddress) 
+        external
+        onlyOwner
+    {
+        IRegistry registry = IRegistry(registryAddress);
+        // TODO use _latest instead of _initial -> but _latest is 0 before first release activation
+        address registryServiceAddress = registry.getServiceAddress(REGISTRY(), registry.getNextVersion());
+        //address registryServiceAddress = registry.getServiceAddress(REGISTRY(), registry.getInitialVersion());
+
+        _linkToNftOwnable(registryAddress, registryServiceAddress);
+    }
+
+    /// @dev token state is informative, registry have no clue about used tokens
+    // component owner is responsible for token selection and operations
+    // service MUST deny registration of component with inactive token 
+    function setActive(address token, VersionPart majorVersion, bool active)
+        external
+        onlyOwner
+    {
+        // verify that token is registered
+        if (!_registered[token]) {
+            _registerToken(token);
+        }
+
+        // verify valid major version
+        // ensure major version increments is one
+        uint256 version = majorVersion.toInt();
+        if (!_registry.isValidRelease(majorVersion)) {
+            revert TokenMajorVersionInvalid(majorVersion);
+        }
+
+        _active[token][majorVersion] = active;
+
+        emit LogTokenStateSet(token, majorVersion, active);
+    }
+
+    function tokens() external view returns (uint256) {
+        return _token.length;
+    }
+
+    function getToken(uint256 idx) external view returns (IERC20Metadata token) {
+        return IERC20Metadata(_token[idx]);
+    }
+
+    function isRegistered(address token) external view returns (bool) {
+        return _registered[token];
+    }
+
+    function isActive(address token, VersionPart majorVersion) external view returns (bool) {
+        return _active[token][majorVersion];
+    }
+
+    /// @dev some sanity checks to prevent unintended registration
+    function _registerToken(address token) internal {
+
+        // MUST be contract
+        if(token.code.length == 0) {
+            revert NotContract(token);
+        }
+
+        // MUST not be GIF registerable
+        if(ERC165Checker.supportsInterface(token, type(IRegisterable).interfaceId)) {
+            revert NotToken(token);
+        }
+
+        // MUST have decimals > 0
+        IERC20Metadata erc20 = IERC20Metadata(token);
+        if(erc20.decimals() == 0) {
+            revert TokenDecimalsZero();
+        }
+
+        _registered[token] = true;
+        _token.push(token);
+
+        emit LogRegistered(token, erc20.symbol(), erc20.decimals());
+    }
+}

package/contracts/shared/ContractDeployerLib.sol

@@ -0,0 +1,72 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+library ContractDeployerLib {
+
+    event LogContractDeployed(address contractAddress);
+
+    error ErrorCreationCodeHashMismatch(bytes32 expectedHash, bytes32 actualHash);
+
+    /// @dev deploys a new contract using the provided creation code
+    function deploy(
+        bytes memory creationCode,
+        bytes32 expectedCreationCodeHash
+    ) 
+        public
+        returns (address contractAdress)
+    {
+        // check against expected hash, if provided
+        if (expectedCreationCodeHash != bytes32(0)) {
+            bytes32 creationCodeHash = getHash(creationCode);
+            if (creationCodeHash != expectedCreationCodeHash) {
+                revert ErrorCreationCodeHashMismatch(expectedCreationCodeHash, creationCodeHash);
+            }
+        }
+
+        // solhint-disable no-inline-assembly
+        assembly {
+            contractAdress := create(0, add(creationCode, 0x20), mload(creationCode))  
+
+            if iszero(extcodesize(contractAdress)) {
+                revert(0, 0)
+            }
+        }
+        // solhint enable
+
+        emit LogContractDeployed(contractAdress);
+    }
+
+    /// @dev gets the creation code for the new contract
+    // for terminology see eg https://www.rareskills.io/post/ethereum-contract-creation-code
+    function getCreationCode(
+        bytes memory byteCodeWithInitCode, // what you get with type(<Contract>).creationCode
+        bytes memory encodedConstructorArguments // what you get with 
+    )
+        public
+        pure
+        returns (bytes memory creationCode)
+    {
+        return abi.encodePacked(byteCodeWithInitCode, encodedConstructorArguments);
+    }
+
+
+    function matchesWithHash(
+        bytes memory creationCode,
+        bytes32 expectedHash
+    )
+        public
+        pure
+        returns (bool isMatching)
+    {
+        return getHash(creationCode) == expectedHash;
+    }
+
+
+    function getHash(bytes memory creationCode)
+        public
+        pure
+        returns (bytes32 hash)
+    {
+        return keccak256(creationCode);
+    }
+}

package/contracts/shared/ERC165.sol

@@ -0,0 +1,25 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
+
+contract ERC165 is IERC165 {
+    mapping(bytes4 => bool) private _isSupported;
+
+    constructor() {
+        _initializeERC165();
+    }
+
+    function supportsInterface(bytes4 interfaceId) external view override returns (bool) {
+        return _isSupported[interfaceId];
+    }
+
+    // @dev register support for ERC165 itself
+    function _initializeERC165() internal {
+        _isSupported[type(IERC165).interfaceId] = true;
+    }
+
+    function _registerInterface(bytes4 interfaceId) internal {
+        _isSupported[interfaceId] = true;
+    }
+}

package/contracts/shared/INftOwnable.sol

@@ -0,0 +1,22 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {NftId} from "../types/NftId.sol";
+
+interface INftOwnable {
+    error ErrorNotOwner(address account);
+
+    error ErrorAlreadyLinked(address registry, NftId nftId);
+    error ErrorRegistryAlreadyInitialized(address registry);
+    error ErrorRegistryNotInitialized();
+    error ErrorRegistryAddressZero();
+    error ErrorNotRegistry(address registryAddress);
+    error ErrorContractNotRegistered(address contractAddress);
+
+    function linkToRegisteredNftId() external;
+
+    function getRegistry() external view returns (IRegistry);
+    function getNftId() external view returns (NftId);
+    function getOwner() external view returns (address);
+}

package/contracts/shared/IRegisterable.sol

@@ -0,0 +1,15 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
+
+import {INftOwnable} from "./INftOwnable.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+
+interface IRegisterable is IERC165, INftOwnable {
+
+    function getInitialInfo() 
+        external 
+        view
+        returns (IRegistry.ObjectInfo memory);
+}

package/contracts/shared/IService.sol

@@ -0,0 +1,16 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {VersionPart} from "../types/Version.sol";
+import {ObjectType} from "../types/ObjectType.sol";
+
+import {IRegisterable} from "./IRegisterable.sol";
+import {IVersionable} from "./IVersionable.sol";
+
+interface IService is 
+    IRegisterable,
+    IVersionable
+{
+    function getDomain() external pure returns(ObjectType serviceDomain);
+    function getMajorVersion() external view returns(VersionPart majorVersion);
+}

package/contracts/shared/IVersionable.sol

@@ -0,0 +1,96 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Blocknumber} from "../types/Blocknumber.sol";
+import {Timestamp} from "../types/Timestamp.sol";
+import {Version} from "../types/Version.sol";
+
+
+/// IMPORTANT
+// Upgradeable contract MUST:
+// 1) inherit from Versionable
+// 2) implement version() function
+// 3) implement internal _initialize() function with onlyInitializing modifier 
+// 4) implement internal _upgrade() function with onlyInitializing modifier (1st version MUST revert)
+// 5) have onlyInitialising modifier for each function callable inside _initialize()/_upgrade() (MUST use different functions for initialization/upgrade and normal operations)
+// 6) use default empty constructor -> _disableInitializer() is called from Versionable contructor
+// 7) use namespace storage
+// 8) since now inheritance is used for upgradability, contract MUST BE inherited ONLY by the next version 
+// Upgradeable contract SHOULD:
+// 9) define all non private methods as virtual (in order to be able to upgrade them latter)
+//    otherwise, it is still possible to upgrade contract, but everyone who is using it will have to switch to a new fucntions
+//    in some cases this ok but not in the others...
+//
+// IMPORTANT
+// Each version MUST:
+// 1) define namespace storage struct if accessing storage
+//      - DO NOT use structs inside, except
+//      - CAN use structs ONLY inside mappings
+// 2) ALWAYS define private getter if accessing storage
+//      - MUST use default implementation, CAN change ONLY return type
+//      - MUST use the same "LOCATION_V1"
+
+interface IVersionable {
+
+    struct VersionInfo {
+        Version version;
+        address implementation;
+        address activatedBy;
+        Timestamp activatedAt;
+        Blocknumber activatedIn;
+    }
+
+    event LogVersionableInitialized(Version version, address implementation, address activatedBy);
+
+    // TODO uncomment when all implementations are ready
+    /**
+     * @dev IMPORTANT
+     * implementation MUST be guarded by initializer modifier
+     * implementation MUST call internal function Versionable._updateVersionHistory 
+     * new version MUST inherit from previous version
+     */
+    function initialize(address implementation, address activatedBy, bytes memory activationData) external;
+
+    /**
+     * @dev
+     * implementation MUST be guarded by reinitializer(version().toUint64()) modifier
+     * implementation MUST call internal function Versionable._updateVersionHistory
+     * new version MUST inherit from previous version
+     * the first verion MUST revert 
+     */
+    function upgrade(address implementation, address activatedBy, bytes memory upgradeData) external;
+
+    /**
+     * @dev returns true if the specified version has been activated for the current contract
+     */
+    function isInitialized(Version version) external view returns(bool);
+
+    /**
+     * @dev returns version of this contract
+     * each new implementation MUST implement this function
+     * version number MUST increase 
+     */
+    function getVersion() external pure returns(Version);
+
+    /**
+     * @dev returns the number of all deployed versions of this contract
+     */
+    function getVersionCount() external view returns(uint256 numberOfVersions);
+
+    /**
+     * @dev returns the i-th (index) version of this contract
+     */
+    function getVersion(uint256 index) external view returns(Version version);
+
+    /**
+     * @dev returns the i-th (index) version info of this contract
+     */
+    function getVersionInfo(Version version) external view returns(VersionInfo memory versionInfo);
+
+    // TODO make sure it is needed here
+    /**
+     * @dev returns currently active version
+     */
+    function getInitializedVersion() external view returns(uint64);
+
+}