@etherisc/gif-next 0.0.2-f7be756-963 → 0.0.2-f7bec40-735

package/contracts/components/Product.sol

@@ -1,89 +1,375 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity ^0.8.19;
 
-import {IProductService} from "../instance/product/IProductService.sol";
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {Amount, AmountLib} from "../types/Amount.sol";
+import {ClaimId} from "../types/ClaimId.sol";
 import {Component} from "./Component.sol";
-import {IProductComponent} from "./IProduct.sol";
-import {NftId} from "../types/NftId.sol";
-import {ObjectType, PRODUCT} from "../types/ObjectType.sol";
 import {Fee} from "../types/Fee.sol";
-import {Component} from "./Component.sol";
+import {IRisk} from "../instance/module/IRisk.sol";
+import {IApplicationService} from "../instance/service/IApplicationService.sol";
+import {IPolicyService} from "../instance/service/IPolicyService.sol";
+import {IProductService} from "../instance/service/IProductService.sol";
+import {IClaimService} from "../instance/service/IClaimService.sol";
+import {IPricingService} from "../instance/service/IPricingService.sol";
+import {IProductComponent} from "./IProductComponent.sol";
+import {NftId, NftIdLib} from "../types/NftId.sol";
+import {PayoutId} from "../types/PayoutId.sol";
+import {PRODUCT, APPLICATION, POLICY, CLAIM, PRICE } from "../types/ObjectType.sol";
+import {ReferralId} from "../types/Referral.sol";
+import {RiskId, RiskIdLib} from "../types/RiskId.sol";
+import {Seconds} from "../types/Seconds.sol";
+import {StateId} from "../types/StateId.sol";
+import {Timestamp} from "../types/Timestamp.sol";
+
+import {TokenHandler} from "../shared/TokenHandler.sol";
+
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {IPolicy} from "../instance/module/IPolicy.sol";
+import {ISetup} from "../instance/module/ISetup.sol";
+import {IComponents} from "../instance/module/IComponents.sol";
+import {Pool} from "../components/Pool.sol";
+import {Distribution} from "../components/Distribution.sol";
+
+abstract contract Product is
+    Component, 
+    IProductComponent
+{
+    // keccak256(abi.encode(uint256(keccak256("etherisc.storage.Product")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant PRODUCT_STORAGE_LOCATION_V1 = 0x0bb7aafdb8e380f81267337bc5b5dfdf76e6d3a380ecadb51ec665246d9d6800;
 
-contract Product is Component, IProductComponent {
-    IProductService private _productService;
-    address private _pool;
-    Fee private _policyFee;
-    Fee private _processingFee;
+    struct ProductStorage {
+        IProductService _productService;
+        IApplicationService _applicationService;
+        IPolicyService _policyService;
+        IClaimService _claimService;
+        IPricingService _pricingService;
+        Pool _pool;
+        Distribution _distribution;
+        Fee _initialProductFee;
+        Fee _initialProcessingFee;
+        TokenHandler _tokenHandler;
+        NftId _poolNftId;
+        NftId _distributionNftId;
+    }
 
-    constructor(
+    function initializeProduct(
         address registry,
-        address instance,
+        NftId instanceNftId,
+        string memory name,
         address token,
+        bool isInterceptor,
         address pool,
-        Fee memory policyFee,
-        Fee memory processingFee
-    ) Component(registry, instance, token) {
+        address distribution,
+        Fee memory productFee,
+        Fee memory processingFee,
+        address initialOwner,
+        bytes memory registryData // writeonly data that will saved in the object info record of the registry
+    )
+        public
+        virtual
+        onlyInitializing()
+    {
+        initializeComponent(registry, instanceNftId, name, token, PRODUCT(), isInterceptor, initialOwner, registryData);
+
+        ProductStorage storage $ = _getProductStorage();
         // TODO add validation
-        _productService = _instance.getProductService();
-        _pool = pool;
-        _policyFee = policyFee;
-        _processingFee = processingFee;
+        // TODO refactor to go via registry ?
+        $._productService = IProductService(_getServiceAddress(PRODUCT())); 
+        $._applicationService = IApplicationService(_getServiceAddress(APPLICATION())); 
+        $._policyService = IPolicyService(_getServiceAddress(POLICY())); 
+        $._claimService = IClaimService(_getServiceAddress(CLAIM())); 
+        $._pricingService = IPricingService(_getServiceAddress(PRICE()));
+        $._pool = Pool(pool);
+        $._distribution = Distribution(distribution);
+        $._initialProductFee = productFee;
+        $._initialProcessingFee = processingFee;  
+        $._tokenHandler = new TokenHandler(token);
+        $._poolNftId = getRegistry().getNftId(pool);
+        $._distributionNftId = getRegistry().getNftId(distribution);
+
+        registerInterface(type(IProductComponent).interfaceId);  
+    }
+
+    // from product component
+    function setFees(
+        Fee memory productFee,
+        Fee memory processingFee
+    )
+        external
+        onlyOwner
+        restricted()
+        override
+    {
+        _getProductService().setFees(productFee, processingFee);
+    }
+
+    function _createRisk(
+        RiskId id,
+        bytes memory data
+    ) internal {
+        _getProductService().createRisk(
+            id,
+            data
+        );
+    }
+
+    function _updateRisk(
+        RiskId id,
+        bytes memory data
+    ) internal {
+        _getProductService().updateRisk(
+            id,
+            data
+        );
+    }
+
+    function _updateRiskState(
+        RiskId id,
+        StateId state
+    ) internal {
+        _getProductService().updateRiskState(
+            id,
+            state
+        );
+    }
+
+    function _getRiskInfo(RiskId id) internal view returns (IRisk.RiskInfo memory info) {
+        return getInstance().getInstanceReader().getRiskInfo(id);
     }
 
     function _createApplication(
         address applicationOwner,
-        uint256 sumInsuredAmount,
-        uint256 premiumAmount,
-        uint256 lifetime,
-        NftId bundleNftId
-    ) internal returns (NftId nftId) {
-        nftId = _productService.createApplication(
+        RiskId riskId,
+        Amount sumInsuredAmount,
+        Seconds lifetime,
+        NftId bundleNftId,
+        ReferralId referralId,
+        bytes memory applicationData
+    )
+        internal
+        returns (NftId applicationNftId) 
+    {
+        return _getProductStorage()._applicationService.create(
             applicationOwner,
+            riskId,
             sumInsuredAmount,
-            premiumAmount,
             lifetime,
-            bundleNftId
+            bundleNftId,
+            referralId,
+            applicationData
         );
     }
 
-    function _underwrite(NftId nftId) internal {
-        _productService.underwrite(nftId);
+    function _collateralize(
+        NftId policyNftId,
+        bool requirePremiumPayment,
+        Timestamp activateAt
+    )
+        internal
+    {
+        _getProductStorage()._policyService.collateralize(
+            policyNftId, 
+            requirePremiumPayment, 
+            activateAt);
     }
 
-    function _collectPremium(NftId nftId) internal {
-        _productService.collectPremium(nftId);
+    function _collectPremium(
+        NftId policyNftId,
+        Timestamp activateAt
+    )
+        internal
+    {
+        _getProductStorage()._policyService.collectPremium(
+            policyNftId, 
+            activateAt);
     }
 
-    function getPoolNftId() external view override returns (NftId poolNftId) {
-        return _registry.getNftId(_pool);
+    function _activate(
+        NftId policyNftId,
+        Timestamp activateAt
+    )
+        internal
+    {
+        _getProductStorage()._policyService.activate(
+            policyNftId, 
+            activateAt);
     }
 
-    // from product component
-    function getPolicyFee()
-        external
-        view
-        override
-        returns (Fee memory policyFee)
+    function _close(
+        NftId policyNftId
+    )
+        internal
+    {
+        _getProductStorage()._policyService.close(
+            policyNftId);
+    }
+
+    function _submitClaim(
+        NftId policyNftId,
+        Amount claimAmount,
+        bytes memory claimData
+    )
+        internal
+        returns(ClaimId)
+    {
+        return _getProductStorage()._claimService.submit(
+            policyNftId,
+            claimAmount,
+            claimData);
+    }
+
+    function _confirmClaim(
+        NftId policyNftId,
+        ClaimId claimId,
+        Amount confirmedAmount
+    )
+        internal
+    {
+        _getProductStorage()._claimService.confirm(
+            policyNftId,
+            claimId,
+            confirmedAmount);
+    }
+
+    function _declineClaim(
+        NftId policyNftId,
+        ClaimId claimId
+    )
+        internal
+    {
+        _getProductStorage()._claimService.decline(
+            policyNftId,
+            claimId);
+    }
+
+    function _closeClaim(
+        NftId policyNftId,
+        ClaimId claimId
+    )
+        internal
     {
-        return _policyFee;
+        _getProductStorage()._claimService.close(
+            policyNftId,
+            claimId);
     }
 
-    function getProcessingFee()
+    function _createPayout(
+        NftId policyNftId,
+        ClaimId claimId,
+        Amount amount,
+        bytes memory data
+    )
+        internal
+        returns (PayoutId)
+    {
+        return _getProductStorage()._claimService.createPayout(
+            policyNftId, 
+            claimId, 
+            amount, 
+            data);
+    }
+
+    function _processPayout(
+        NftId policyNftId,
+        PayoutId payoutId
+    )
+        internal
+    {
+        _getProductStorage()._claimService.processPayout(
+            policyNftId,
+            payoutId);
+    }
+
+    function calculatePremium(
+        Amount sumInsuredAmount,
+        RiskId riskId,
+        Seconds lifetime,
+        bytes memory applicationData,
+        NftId bundleNftId,
+        ReferralId referralId
+    )
+        external 
+        view 
+        override 
+        returns (Amount premiumAmount)
+    {
+        IPolicy.Premium memory premium = _getProductStorage()._pricingService.calculatePremium(
+            getNftId(),
+            riskId,
+            sumInsuredAmount,
+            lifetime,
+            applicationData,
+            bundleNftId,
+            referralId
+        );
+
+        return AmountLib.toAmount(premium.premiumAmount);
+    }
+
+    function calculateNetPremium(
+        Amount sumInsuredAmount,
+        RiskId riskId,
+        Seconds lifetime,
+        bytes memory applicationData
+    )
         external
         view
-        override
-        returns (Fee memory processingFee)
+        virtual override
+        returns (Amount netPremiumAmount)
     {
-        return _processingFee;
+        // default 10% of sum insured
+        return AmountLib.toAmount(sumInsuredAmount.toInt() / 10);
+    }
+
+    function _toRiskId(string memory riskName) internal pure returns (RiskId riskId) {
+        return RiskIdLib.toRiskId(riskName);
+    }
+
+    function getPoolNftId() external view override returns (NftId poolNftId) {
+        return getRegistry().getNftId(address(_getProductStorage()._pool));
+    }
+
+    function getDistributionNftId() external view override returns (NftId distributionNftId) {
+        return getRegistry().getNftId(address(_getProductStorage()._distribution));
+    }
+
+    function getSetupInfo() public view returns (ISetup.ProductSetupInfo memory setupInfo) {
+        InstanceReader reader = getInstance().getInstanceReader();
+        setupInfo = reader.getProductSetupInfo(getNftId());
+
+        // fallback to initial setup info (wallet is always != address(0))
+        if(setupInfo.wallet == address(0)) {
+            setupInfo = _getInitialSetupInfo();
+        }
+    }
+
+    function _getInitialSetupInfo() internal view returns (ISetup.ProductSetupInfo memory setupInfo) {
+        ProductStorage storage $ = _getProductStorage();
+
+        ISetup.DistributionSetupInfo memory distributionSetupInfo = $._distribution.getSetupInfo();
+        IComponents.PoolInfo memory poolInfo = $._pool.getPoolInfo();
+
+        return ISetup.ProductSetupInfo(
+            getToken(),
+            $._tokenHandler,
+            $._distributionNftId,
+            $._poolNftId,
+            $._initialProductFee,
+            $._initialProcessingFee,
+            false,
+            getWallet()
+        );
     }
 
-    // from registerable
-    function getType() public pure override returns (ObjectType) {
-        return PRODUCT();
+    function _getProductStorage() private pure returns (ProductStorage storage $) {
+        assembly {
+            $.slot := PRODUCT_STORAGE_LOCATION_V1
+        }
     }
 
-    // from registerable
-    function getData() external view override returns (bytes memory data) {
-        return bytes(abi.encode(getInstance().getNftId()));
+    function _getProductService() internal view returns (IProductService) {
+        return _getProductStorage()._productService;
     }
-}
+}

package/contracts/instance/BundleManager.sol

@@ -0,0 +1,126 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IInstance} from "./IInstance.sol";
+import {INSTANCE} from "../types/ObjectType.sol";
+import {InstanceReader} from "./InstanceReader.sol";
+import {IPolicy} from "../instance/module/IPolicy.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {LibNftIdSet} from "../types/NftIdSet.sol";
+import {NftId} from "../types/NftId.sol";
+import {TimestampLib} from "../types/Timestamp.sol";
+
+import {ObjectManager} from "./ObjectManager.sol";
+
+contract BundleManager is 
+    ObjectManager
+{
+
+    event LogBundleManagerPolicyLinked(NftId bundleNftId, NftId policyNftId);
+    event LogBundleManagerPolicyUnlinked(NftId bundleNftId, NftId policyNftId);
+
+    event LogBundleManagerBundleAdded(NftId poolNftId, NftId bundleNftId);
+    event LogBundleManagerBundleUnlocked(NftId poolNftId, NftId bundleNftId);
+    event LogBundleManagerBundleLocked(NftId poolNftId, NftId bundleNftId);
+    event LogBundleManagerBundleClosed(NftId poolNftId, NftId bundleNftId);
+
+    error ErrorBundleManagerPolicyAlreadyActivated(NftId policyNftId);
+    error ErrorBundleManagerBundleLocked(NftId bundleNftId, NftId policyNftId);
+    error ErrorBundleManagerPolicyWithOpenClaims(NftId policyNftId, uint256 openClaimsCount);
+    error ErrorBundleManagerPolicyNotCloseable(NftId policyNftId);
+    error ErrorBundleManagerBundleUnknown(NftId bundleNftId);
+    error ErrorBundleManagerBundleNotRegistered(NftId bundleNftId);
+
+    mapping(NftId bundleNftId => LibNftIdSet.Set policies) internal _activePolicies;
+
+    /// @dev links a policy to its bundle
+    // to link a policy it MUST NOT yet have been linked
+    function linkPolicy(NftId policyNftId) external restricted() {
+        NftId bundleNftId = _instance.getInstanceReader().getPolicyInfo(policyNftId).bundleNftId;
+        // decision will likely depend on the decision what to check here and what in the service
+        NftId poolNftId = _instance.getInstanceReader().getBundleInfo(bundleNftId).poolNftId;
+
+        // ensure bundle is unlocked (in active set) and registered with this instance
+        if (!_isActive(poolNftId, bundleNftId)) {
+            revert ErrorBundleManagerBundleLocked(bundleNftId, policyNftId);
+        }
+
+        LibNftIdSet.add(_activePolicies[bundleNftId], policyNftId);
+        emit LogBundleManagerPolicyLinked(bundleNftId, policyNftId);
+    }
+
+
+    /// @dev unlinks a policy from its bundle
+    // to unlink a policy it must closable, ie. meet one of the following criterias
+    // - the policy MUST be past its expiry period and it MUST NOT have any open claims
+    // - the policy's payoutAmount MUST be equal to its sumInsuredAmount and MUST NOT have any open claims
+    function unlinkPolicy(NftId policyNftId) external restricted() {
+        IPolicy.PolicyInfo memory policyInfo = _instance.getInstanceReader().getPolicyInfo(policyNftId);
+
+        NftId bundleNftId = policyInfo.bundleNftId;
+        // decision will likely depend on the decision what to check here and what in the service
+        NftId poolNftId = _instance.getInstanceReader().getBundleInfo(bundleNftId).poolNftId;
+
+        // ensure bundle is registered with this instance
+        if (!_contains(poolNftId, bundleNftId)) {
+            revert ErrorBundleManagerBundleUnknown(bundleNftId);
+        }
+
+        LibNftIdSet.remove(_activePolicies[bundleNftId], policyNftId);
+        emit LogBundleManagerPolicyUnlinked(policyInfo.bundleNftId, policyNftId);
+    }
+
+
+    /// @dev add a new bundle to a pool registerd with this instance
+    // the corresponding pool is fetched via instance reader
+    function add(NftId bundleNftId) external restricted() {
+        NftId poolNftId = _instance.getInstanceReader().getBundleInfo(bundleNftId).poolNftId;
+
+        // ensure pool is registered with instance
+        if(poolNftId.eqz()) {
+            revert ErrorBundleManagerBundleNotRegistered(bundleNftId);
+        }
+
+        _add(poolNftId, bundleNftId);
+        emit LogBundleManagerBundleAdded(poolNftId, bundleNftId);
+    }
+
+
+    /// @dev unlocked (active) bundles are available to collateralize new policies
+    function unlock(NftId bundleNftId) external restricted() {
+        NftId poolNftId = _instance.getInstanceReader().getBundleInfo(bundleNftId).poolNftId;
+        _activate(poolNftId, bundleNftId);
+        emit LogBundleManagerBundleUnlocked(poolNftId, bundleNftId);
+    }
+
+    /// @dev locked (deactivated) bundles may not collateralize any new policies
+    function lock(NftId bundleNftId) external restricted() {
+        NftId poolNftId = _instance.getInstanceReader().getBundleInfo(bundleNftId).poolNftId;
+        _deactivate(poolNftId, bundleNftId);
+        emit LogBundleManagerBundleLocked(poolNftId, bundleNftId);
+    }
+
+    function bundles(NftId poolNftId) external view returns(uint256) {
+        return _objects(poolNftId);
+    }
+
+    function getBundleNftId(NftId poolNftId, uint256 idx) external view returns(NftId bundleNftId) {
+        return _getObject(poolNftId, idx);
+    }
+
+    function activeBundles(NftId poolNftId) external view returns(uint256) {
+        return _activeObjs(poolNftId);
+    }
+
+    function getActiveBundleNftId(NftId poolNftId, uint256 idx) external view returns(NftId bundleNftId) {
+        return _getActiveObject(poolNftId, idx);
+    }
+
+    function activePolicies(NftId bundleNftId) external view returns(uint256) {
+        return LibNftIdSet.size(_activePolicies[bundleNftId]);
+    }
+
+    function getActivePolicy(NftId bundleNftId, uint256 idx) external view returns(NftId policyNftId) {
+        return LibNftIdSet.getElementAt(_activePolicies[bundleNftId], idx);
+    }
+}

package/contracts/instance/Cloneable.sol

@@ -0,0 +1,51 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
+import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+
+abstract contract Cloneable is 
+    AccessManagedUpgradeable
+{
+    event CloneableInitialized(address authority, address registry);
+    
+    error CloneableAuthorityZero();
+    error CloneableRegistryInvalid(address registry);
+
+    IRegistry internal _registry;
+
+    constructor() {
+        _registry = IRegistry(address(0));
+    }
+
+    /// @dev call to initialize MUST be made in the same transaction as cloning of the contract
+    function initialize(
+        address authority,
+        address registry
+    )
+        public 
+        onlyInitializing
+    {
+        // check/handle access managed
+        if(authority == address(0)) {
+            revert CloneableAuthorityZero();
+        }
+        
+        __AccessManaged_init(authority);
+
+        // check/handle registry
+        if (registry.code.length == 0) {
+            revert CloneableRegistryInvalid(registry);
+        }
+
+        _registry = IRegistry(registry);
+
+        emit CloneableInitialized(authority, registry);
+    }
+
+    function getRegistry() external view returns (IRegistry) {
+        return _registry;
+    }
+}