@etherisc/gif-next 0.0.2-f752d2a-551 → 0.0.2-f7b8c9f-518

package/contracts/shared/NftOwnable.sol

@@ -0,0 +1,136 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {INftOwnable} from "./INftOwnable.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {NftId, zeroNftId} from "../types/NftId.sol";
+
+contract NftOwnable is INftOwnable {
+
+    IRegistry internal _registry;
+    NftId private _nftId;
+    address private _initialOwner; 
+
+    /// @dev enforces msg.sender is owner of nft (or initial owner of nft ownable)
+    modifier onlyOwner() {
+        address owner = getOwner();
+
+        // owner == address(0) is eg uninitialized upgradable contract
+        if (owner != address(0) && msg.sender != owner) {
+            revert ErrorNotOwner(msg.sender);
+        }
+        _;
+    }
+
+    constructor() {
+        _initialOwner = msg.sender;
+    }
+
+    /// @dev links this contract to nft after registration
+    // needs to be done once per registered contract and 
+    // reduces registry calls to check ownership
+    // does not need any protection as function can only do the "right thing"
+    function linkToRegisteredNftId() public {
+        if (_nftId.gtz()) {
+            revert ErrorAlreadyLinked(address(_registry), _nftId);
+        }
+
+        if (address(_registry) == address(0)) {
+            revert ErrorRegistryNotInitialized();
+        }
+
+        address contractAddress = address(this);
+
+        if (!_registry.isRegistered(contractAddress)) {
+            revert ErrorContractNotRegistered(contractAddress);
+        }
+
+        _nftId = _registry.getNftId(contractAddress);
+    }
+
+
+    function getRegistry() public view virtual override returns (IRegistry) {
+        return _registry;
+    }
+
+
+    function getNftId() public view virtual override returns (NftId) {
+        return _nftId;
+    }
+
+
+    function getOwner() public view virtual override returns (address) {
+        if (_nftId.gtz()) {
+            return _registry.ownerOf(_nftId);
+        }
+
+        return _initialOwner;
+    }
+
+
+    /// @dev initialization for upgradable contracts
+    // used in _initializeRegisterable
+    function _initializeNftOwnable(
+        address initialOwner,
+        address registryAddress
+    )
+        internal
+        virtual
+    {
+        _initialOwner = initialOwner;
+        _setRegistry(registryAddress);
+    }
+
+
+    /// @dev used in constructor of registry service manager
+    // links ownership of registry service manager ot nft owner of registry service
+    function _linkToNftOwnable(
+        address registryAddress,
+        address nftOwnableAddress
+    )
+        internal
+        onlyOwner()
+        returns (NftId)
+    {
+        if (_nftId.gtz()) {
+            revert ErrorAlreadyLinked(address(_registry), _nftId);
+        }
+
+        _setRegistry(registryAddress);
+
+        if (!_registry.isRegistered(nftOwnableAddress)) {
+            revert ErrorContractNotRegistered(nftOwnableAddress);
+        }
+
+        _nftId = _registry.getNftId(nftOwnableAddress);
+
+        return _nftId;
+    }
+
+
+    function _setRegistry(address registryAddress)
+        private
+    {
+        if (address(_registry) != address(0)) {
+            revert ErrorRegistryAlreadyInitialized(address(_registry));
+        }
+
+        if (registryAddress == address(0)) {
+            revert ErrorRegistryAddressZero();
+        }
+
+        if (registryAddress.code.length == 0) {
+            revert ErrorNotRegistry(registryAddress);
+        }
+
+        _registry = IRegistry(registryAddress);
+
+        try _registry.supportsInterface(type(IRegistry).interfaceId) returns (bool isRegistry) {
+            if (!isRegistry) {
+                revert ErrorNotRegistry(registryAddress);
+            }
+        } catch {
+            revert ErrorNotRegistry(registryAddress);
+        }
+    }
+}

package/contracts/shared/ProxyManager.sol

@@ -0,0 +1,94 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Ownable} from "@openzeppelin5/contracts/access/Ownable.sol";
+import {ProxyAdmin} from "@openzeppelin5/contracts/proxy/transparent/ProxyAdmin.sol";
+import {ITransparentUpgradeableProxy} from "@openzeppelin5/contracts/proxy/transparent/TransparentUpgradeableProxy.sol";
+
+import {IVersionable} from "./IVersionable.sol";
+import {NftOwnable} from "./NftOwnable.sol";
+import {UpgradableProxyWithAdmin} from "./UpgradableProxyWithAdmin.sol";
+
+/// @dev manages proxy deployments for upgradable contracs of type IVersionable
+contract ProxyManager is
+    NftOwnable
+{
+
+    event LogProxyDeployed(address indexed proxy, address initialImplementation);
+    event LogProxyDeployedWithSalt(address indexed proxy, address initialImplementation);
+    event LogProxyUpgraded(address indexed proxy, address upgradedImplementation);
+
+    error ErrorAlreadyDeployed();
+    error ErrorAlreadyDeployedWithSalt();
+    error ErrorNotYetDeployed();
+
+    UpgradableProxyWithAdmin internal _proxy;
+    bool internal _isDeployed;
+
+    /// @dev only used to capture proxy owner
+    constructor()
+        NftOwnable()
+    { }
+
+    /// @dev deploy initial contract
+    function deploy(address initialImplementation, bytes memory initializationData)
+        public
+        virtual
+        onlyOwner()
+        returns (IVersionable versionable)
+    {
+        if (_isDeployed) { revert ErrorAlreadyDeployed(); }
+
+        address currentProxyOwner = getOwner(); // used by implementation
+        address initialProxyAdminOwner = address(this); // used by proxy
+        bytes memory data = getDeployData(initialImplementation, currentProxyOwner, initializationData);
+        
+        _proxy = new UpgradableProxyWithAdmin(
+            initialImplementation,
+            initialProxyAdminOwner,
+            data
+        );
+
+        _isDeployed = true;
+        versionable = IVersionable(address(_proxy));
+
+        emit LogProxyDeployed(address(_proxy), initialImplementation);
+    }
+
+    /// @dev upgrade existing contract
+    function upgrade(address newImplementation, bytes memory upgradeData)
+        public
+        virtual
+        onlyOwner()
+        returns (IVersionable versionable)
+    {
+        if (!_isDeployed) { revert ErrorNotYetDeployed(); }
+
+        address currentProxyOwner = getOwner();
+        ProxyAdmin proxyAdmin = getProxy().getProxyAdmin();
+        ITransparentUpgradeableProxy proxy = ITransparentUpgradeableProxy(address(_proxy));
+        bytes memory data = getUpgradeData(newImplementation, currentProxyOwner, upgradeData);
+
+        proxyAdmin.upgradeAndCall(
+            proxy,
+            newImplementation, 
+            data);
+
+        versionable = IVersionable(address(_proxy));
+
+        emit LogProxyUpgraded(address(_proxy), newImplementation);
+
+    }
+
+    function getDeployData(address implementation, address proxyOwner, bytes memory deployData) public pure returns (bytes memory data) {
+        return abi.encodeWithSelector(IVersionable.initialize.selector, implementation, proxyOwner, deployData);
+    }
+
+    function getUpgradeData(address implementation, address proxyOwner, bytes memory upgradeData) public pure returns (bytes memory data) {
+        return abi.encodeWithSelector(IVersionable.upgrade.selector, implementation, proxyOwner, upgradeData);
+    }
+
+    function getProxy() public returns (UpgradableProxyWithAdmin) {
+        return _proxy;
+    }
+}

package/contracts/shared/Registerable.sol

@@ -1,86 +1,89 @@
 // SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
+pragma solidity ^0.8.20;
+
+import {Initializable} from "@openzeppelin5/contracts/proxy/utils/Initializable.sol"; 
 
 import {NftId, zeroNftId} from "../types/NftId.sol";
+import {NftOwnable} from "../shared/NftOwnable.sol";
 import {ObjectType} from "../types/ObjectType.sol";
 
 import {IRegistry} from "../registry/IRegistry.sol";
 import {IRegisterable} from "./IRegisterable.sol";
+import {Versionable} from "./Versionable.sol";
 
 import {ERC165} from "./ERC165.sol";
 
-abstract contract Registerable is
+contract Registerable is
     ERC165,
+    Initializable,
+    NftOwnable,
     IRegisterable
 {
-    IRegistry internal immutable _registry;
-    NftId internal immutable _parentNftId;
-    address internal immutable _initialOwner;
+    // keccak256(abi.encode(uint256(keccak256("gif-next.contracts.shared.Registerable.sol")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant REGISTERABLE_LOCATION_V1 = 0x6548007c3f4340f82f348c576c0ff69f4f529cadd5ad41f96aae61abceeaa300;
 
-    modifier onlyOwner() virtual {
-        require(
-            msg.sender == getOwner(),
-            "ERROR:RGB-001:NOT_OWNER"
-        );
-        _;
+    error ErrorRegisterableNotRegistry(address registryAddress);
+
+    struct RegisterableStorage {
+        NftId _parentNftId;
+        ObjectType _objectType;
+        bool _isInterceptor;
+        bytes _data;
+    }
+
+    function _getRegisterableStorage() private pure returns (RegisterableStorage storage $) {
+        assembly {
+            $.slot := REGISTERABLE_LOCATION_V1
+        }
     }
 
-    constructor(
+    function _initializeRegisterable(
         address registryAddress,
-        NftId parentNftId
+        NftId parentNftId,
+        ObjectType objectType,
+        bool isInterceptor,
+        address initialOwner,
+        bytes memory data
     )
-        ERC165()
+        internal
+        //onlyInitializing//TODO uncomment when "fully" upgradeable
+        virtual
     {
-        require(
-            address(registryAddress) != address(0),
-            "ERROR:RGB-010:REGISTRY_ZERO"
-        );
-
-        _registry = IRegistry(registryAddress);
-        require(
-            _registry.supportsInterface(type(IRegistry).interfaceId),
-            "ERROR:RGB-011:NOT_REGISTRY"
-        );
+        _initializeNftOwnable(
+            initialOwner,
+            registryAddress);
 
-        _parentNftId = parentNftId;
-        require(
-            _registry.isRegistered(_parentNftId),
-            "ERROR:RGB-012:PARENT_NOT_REGISTERED"
-        );
+        // TODO check parentNftId -> registry.isRegistered(parentNftId)
+        // TODO check object-parent type pair -> registry.isValidTypeCombo() or something...verify with registry that setup will be able to register...
 
-        _initialOwner = msg.sender;
+        RegisterableStorage storage $ = _getRegisterableStorage();
+        $._parentNftId = parentNftId;
+        $._objectType = objectType;
+        $._isInterceptor = isInterceptor;
+        $._data = data;
 
-        // register support for IRegisterable
         _registerInterface(type(IRegisterable).interfaceId);
     }
 
-    // from IRegistryLinked
-    function register() public onlyOwner virtual override returns (NftId nftId) {
-        return _registry.register(address(this));
-    }
 
-    function getRegistry() public view virtual override returns (IRegistry registry) {
-        return _registry;
-    }
-
-    function getOwner() public view virtual override returns (address owner) {
-        NftId nftId = _registry.getNftId(address(this));
-        if(nftId == zeroNftId()) {
-            return _initialOwner;
-        }
-
-        return _registry.getOwner(nftId);
-    }
-
-    function getNftId() public view override returns (NftId nftId) {
-        return _registry.getNftId(address(this));
-    }
-
-    function getParentNftId() public view override returns (NftId nftId) {
-        return _parentNftId;
-    }
-
-    function getData() public view virtual override returns (bytes memory data) {
-        return "";
+    function getInitialInfo() 
+        public 
+        view 
+        virtual 
+        returns (IRegistry.ObjectInfo memory, bytes memory data) 
+    {
+        RegisterableStorage storage $ = _getRegisterableStorage();
+        return (
+            IRegistry.ObjectInfo(
+                zeroNftId(),
+                $._parentNftId,
+                $._objectType,
+                $._isInterceptor,
+                address(this), 
+                getOwner(),
+                $._data
+            ),
+            bytes("")
+        );
     }
-}
+}

package/contracts/shared/UpgradableProxyWithAdmin.sol

@@ -0,0 +1,16 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ProxyAdmin} from "@openzeppelin5/contracts/proxy/transparent/ProxyAdmin.sol";
+import {TransparentUpgradeableProxy, ITransparentUpgradeableProxy} from "@openzeppelin5/contracts/proxy/transparent/TransparentUpgradeableProxy.sol";
+
+import {IVersionable} from "./IVersionable.sol";
+
+contract UpgradableProxyWithAdmin is TransparentUpgradeableProxy {
+
+    constructor(address implementation, address initialProxyAdminOwner, bytes memory data)
+        TransparentUpgradeableProxy(implementation, initialProxyAdminOwner, data)
+    {}
+
+    function getProxyAdmin() external returns (ProxyAdmin) { return ProxyAdmin(_proxyAdmin()); }
+}

package/contracts/shared/Versionable.sol

@@ -1,89 +1,147 @@
 // SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
+pragma solidity ^0.8.20;
+
+import {Initializable} from "@openzeppelin5/contracts/proxy/utils/Initializable.sol";
 
 import {Blocknumber, blockNumber} from "../types/Blocknumber.sol";
 import {Timestamp, blockTimestamp} from "../types/Timestamp.sol";
-import {Version, VersionPart} from "../types/Version.sol";
+import {Version, VersionPart, VersionLib} from "../types/Version.sol";
 
 import {IVersionable} from "./IVersionable.sol";
 
-abstract contract Versionable is IVersionable {
 
-    mapping(Version version => VersionInfo info) private _versionHistory;
-    Version [] private _versions;
 
+abstract contract Versionable is 
+    Initializable,
+    IVersionable 
+{
+    // keccak256(abi.encode(uint256(keccak256("gif-next.contracts.shared.Versionable.sol")) - 1)) & ~bytes32(uint256(0xff))
+    bytes32 private constant VERSIONABLE_LOCATION_V1 = 0x4f61291a8ac3d020d0a7d919a76b8592aa88385744dee3f8b4f3873b969ed900;
 
-    // controlled activation for controller contract
-    constructor() {
-        _activate(address(0), msg.sender);
-    }
 
-    // IMPORTANT this function needs to be implemented by each new version
-    // and needs to call internal function call _activate() 
-    function activate(address implementation, address activatedBy)
-        external
-        override
-    { 
-        _activate(implementation, activatedBy);
+    /// @custom:storage-location erc7201:gif-next.contracts.shared.Versionable.sol
+    struct VersionableStorage {
+        mapping(Version version => VersionInfo info) _versionHistory;
+        Version [] _versions;
+        Version _v1;
     }
 
 
-    // can only be called once per contract
-    // needs bo be called inside the proxy upgrade tx
-    function _activate(
+    constructor() {
+        _disableInitializers();
+    }
+    // TODO write test where new version of private _updateVersionHistory is added and used... 
+    function initialize(
         address implementation,
-        address activatedBy
+        address activatedBy,
+        bytes memory data
     )
-        internal
+        public
+        initializer
     {
-        Version thisVersion = getVersion();
-        require(
-            !isActivated(thisVersion),
-            "ERROR:VRN-001:VERSION_ALREADY_ACTIVATED"
-        );
-        
-        // require increasing version number
-        if(_versions.length > 0) {
-            Version lastVersion = _versions[_versions.length - 1];
-            require(
-                thisVersion > lastVersion,
-                "ERROR:VRN-002:VERSION_NOT_INCREASING"
-            );
-        }
+        _updateVersionHistory(implementation, activatedBy);
+        _initialize(activatedBy, data);
+    }
 
-        // update version history
-        _versions.push(thisVersion);
-        _versionHistory[thisVersion] = VersionInfo(
-            thisVersion,
-            implementation,
-            activatedBy,
-            blockTimestamp(),
-            blockNumber()
-        );
+    // TODO activatedBy MUST ALWAYS be an owner?
+    function upgrade(
+        address implementation,
+        address activatedBy,
+        bytes memory data
+    )
+        external
+        reinitializer(VersionLib.toUint64(getVersion()))
+    {
+        _updateVersionHistory(implementation, activatedBy);
+        _upgrade(data);
+    }
 
-        emit LogVersionableActivated(thisVersion, implementation, activatedBy);
+    function isInitialized(Version _version) public override view returns(bool) {
+        return _getVersionableStorage()._versionHistory[_version].activatedIn.toInt() > 0;
     }
 
+    function getVersion() public pure virtual returns(Version);
 
-    function isActivated(Version _version) public override view returns(bool) {
-        return _versionHistory[_version].activatedIn.toInt() > 0;
+    function getVersionCount() public view override returns(uint256) {
+        return _getVersionableStorage()._versions.length;
     }
 
+    function getVersion(uint256 idx) public view override returns(Version) {
+        return _getVersionableStorage()._versions[idx];
+    }
 
-    function getVersion() public pure virtual returns(Version);
+    function getVersionInfo(Version _version) public override view returns(VersionInfo memory) {
+        return _getVersionableStorage()._versionHistory[_version];
+    }
+
+    function getInitializedVersion() public view returns(uint64) {
+        return _getInitializedVersion();
+    }
 
 
-    function getVersionCount() external view override returns(uint256) {
-        return _versions.length;
+
+    // IMPORTANT each version must implement this function 
+    // each implementation MUST use onlyInitialising modifier
+    // each implementation MUST call intializers of all base contracts...
+    function _initialize(address owner, bytes memory data) 
+        internal
+        onlyInitializing
+        virtual 
+    {
+        revert();
     }
 
 
-    function getVersion(uint256 idx) external view override returns(Version) {
-        return _versions[idx];
+    // IMPORTANT each version except version "1" must implement this function 
+    // each implementation MUST use onlyInitialising modifier
+    function _upgrade(bytes memory data)
+        internal
+        onlyInitializing
+        virtual
+    {
+        revert();
     }
 
+    function _getVersionableStorage() private pure returns (VersionableStorage storage $) {
+        assembly {
+            $.slot := VERSIONABLE_LOCATION_V1
+        }
+    }
+
+    // can only be called once per contract
+    // needs to be called inside the proxy upgrade tx
+    // TODO run reinitializer(version().toUint64()) modifier after "version()" is checked, 
+    function _updateVersionHistory(
+        address implementation,
+        address activatedBy
+    )
+        private
+        onlyInitializing
+    {
+        VersionableStorage storage $ = _getVersionableStorage();
+
+        uint64 version = _getInitializedVersion();
+
+        Version thisVersion = getVersion();
+
+        if(version == 1) {
+            // thisVersion is alias to version "1"
+            $._v1 = thisVersion;
+        }
+        else {
+            require(thisVersion > $._v1, "INVALID VERSION");
+        }
+
+        // update version history
+        $._versions.push(thisVersion);
+        $._versionHistory[thisVersion] = VersionInfo(
+            thisVersion,
+            implementation,
+            activatedBy,
+            blockTimestamp(),
+            blockNumber()
+        );
 
-    function getVersionInfo(Version _version) external override view returns(VersionInfo memory) {
-        return _versionHistory[_version];
+        emit LogVersionableInitialized(thisVersion, implementation, activatedBy);
     }
 }

package/contracts/test/TestDistribution.sol

@@ -0,0 +1,22 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Fee} from "../../contracts/types/Fee.sol";
+import {NftId} from "../../contracts/types/NftId.sol";
+import {Distribution} from "../../contracts/components/Distribution.sol";
+
+
+contract TestDistribution is Distribution {
+
+    constructor(
+        address registry,
+        NftId instanceNftid,
+        address token,
+        bool isVerifying,
+        Fee memory distributionFee,
+        address initialOwner
+    )
+        Distribution(registry, instanceNftid, token, isVerifying, distributionFee, initialOwner)
+    // solhint-disable-next-line no-empty-blocks
+    {}
+}

package/contracts/test/TestPool.sol

@@ -13,10 +13,15 @@ contract TestPool is Pool {
         address registry,
         NftId instanceNftid,
         address token,
+        bool isInterceptor,
         bool isVerifying,
-        UFixed collateralizationLevel
+        UFixed collateralizationLevel,
+        Fee memory poolFee,
+        Fee memory stakingFee,
+        Fee memory performanceFee,
+        address initialOwner
     )
-        Pool(registry, instanceNftid, token, isVerifying, collateralizationLevel)
+        Pool(registry, instanceNftid, token, isInterceptor, isVerifying, collateralizationLevel, poolFee, stakingFee, performanceFee, initialOwner)
     // solhint-disable-next-line no-empty-blocks
     {}
 }