@etherisc/gif-next 0.0.2-f74fcad-685 → 0.0.2-f7b8c9f-436

package/contracts/instance/base/ModuleBase.sol

@@ -0,0 +1,57 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../registry/IRegistry.sol";
+
+import {Blocknumber, blockNumber} from "../../types/Blocknumber.sol";
+import {Key32, KeyId} from "../../types/Key32.sol";
+import {LibNftIdSet} from "../../types/NftIdSet.sol";
+import {NftId} from "../../types/NftId.sol";
+import {ObjectType, PRODUCT, ORACLE, POOL, BUNDLE, POLICY} from "../../types/ObjectType.sol";
+import {StateId, ACTIVE, PAUSED, ARCHIVED, CLOSED, APPLIED, REVOKED, DECLINED} from "../../types/StateId.sol";
+import {Timestamp, blockTimestamp, zeroTimestamp} from "../../types/Timestamp.sol";
+
+import {IKeyValueStore} from "./IKeyValueStore.sol";
+
+abstract contract ModuleBase {
+
+    IKeyValueStore private _store;
+
+    function _initialize(IKeyValueStore keyValueStore) internal {
+        _store = keyValueStore;
+    }
+
+    function _create(ObjectType objectType, Key32 key, bytes memory data) internal {
+        _store.create(
+            key, 
+            objectType,
+            data);
+    }
+
+    function _create(ObjectType objectType, NftId nftId, bytes memory data) internal {
+        _store.create(
+            nftId.toKey32(objectType), 
+            objectType,
+            data);
+    }
+
+    function _updateData(ObjectType objectType, NftId nftId, bytes memory data) internal {
+        _store.updateData(nftId.toKey32(objectType), data);
+    }
+
+    function _updateState(ObjectType objectType, NftId nftId, StateId state) internal {
+        _store.updateState(nftId.toKey32(objectType), state);
+    }
+
+    function _exists(ObjectType objectType, NftId nftId) internal view returns (bool hasData) {
+        return _store.exists(nftId.toKey32(objectType));
+    }
+
+    function _getData(ObjectType objectType, NftId nftId) internal view returns(bytes memory data) {
+        return _store.getData(nftId.toKey32(objectType));
+    }
+
+    function _getState(ObjectType objectType, NftId nftId) internal view returns(StateId) {
+        return _store.getState(nftId.toKey32(objectType));
+    }
+}

package/contracts/instance/base/ServiceBase.sol

@@ -0,0 +1,44 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {NftId, zeroNftId} from "../../types/NftId.sol";
+import {ObjectType, SERVICE} from "../../types/ObjectType.sol";
+import {Version, VersionPart, VersionLib} from "../../types/Version.sol";
+
+import {Registerable} from "../../shared/Registerable.sol";
+import {IRegistry} from "../../registry/IRegistry.sol";
+import {IVersionable} from "../../shared/IVersionable.sol";
+import {Versionable} from "../../shared/Versionable.sol";
+
+import {IService} from "./IService.sol";
+
+abstract contract ServiceBase is 
+    Registerable,
+    Versionable,
+    IService
+{
+    function getName() public pure virtual override returns(string memory name);
+
+    function getMajorVersion() public view virtual override returns(VersionPart majorVersion) {
+        return getVersion().toMajorPart(); 
+    }
+
+    // from Versionable
+    function getVersion()
+        public 
+        pure 
+        virtual override (IVersionable, Versionable)
+        returns(Version)
+    {
+        return VersionLib.toVersion(3,0,0);
+    }
+
+    function _initializeServiceBase(address registry, NftId registryNftId, address initialOwner)
+        internal 
+        //onlyInitializing //TODO uncomment when "fully" upgradeable
+    {// service must provide its name and version upon registration
+        bytes memory data = abi.encode(getName(), getMajorVersion());
+        _initializeRegisterable(registry, registryNftId, SERVICE(), false, initialOwner, data);
+        _registerInterface(type(IService).interfaceId);
+    }
+}

package/contracts/instance/module/access/Access.sol

@@ -0,0 +1,149 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+// role admin handling of oz doesn't fit nft ownability
+// import {AccessControlEnumerable} from "@openzeppelin/contracts/access/AccessControlEnumerable.sol";
+import "@openzeppelin/contracts/utils/structs/EnumerableSet.sol";
+
+import {RoleId, RoleIdLib} from "../../../types/RoleId.sol";
+import {DISTRIBUTION_OWNER_ROLE, ORACLE_OWNER_ROLE, POOL_OWNER_ROLE, PRODUCT_OWNER_ROLE} from "../../../types/RoleId.sol";
+import {DISTRIBUTION_OWNER_ROLE_NAME, ORACLE_OWNER_ROLE_NAME, POOL_OWNER_ROLE_NAME, PRODUCT_OWNER_ROLE_NAME} from "../../../types/RoleId.sol";
+import {IAccessModule} from "./IAccess.sol";
+
+abstract contract AccessModule is IAccessModule {
+
+    using EnumerableSet for EnumerableSet.AddressSet;
+
+    mapping(RoleId role => RoleInfo info) private _info;
+    RoleId[] private _roles;
+
+    mapping(RoleId role => mapping(address member => bool isMember))
+        private _isRoleMember;
+    mapping(RoleId role => EnumerableSet.AddressSet members) private _roleMembers;
+
+    modifier onlyAccessOwner() {
+        require(
+            msg.sender == this.getOwner(),
+            "ERROR:ACS-001:NOT_OWNER");
+        _;
+    }
+
+    modifier onlyExistingRole(RoleId role) {
+        require(
+            _info[role].id == role,
+            "ERROR:ACS-002:ROLE_NOT_EXISTING");
+        _;
+    }
+
+    constructor() {
+        _createRole(DISTRIBUTION_OWNER_ROLE(), DISTRIBUTION_OWNER_ROLE_NAME());
+        _createRole(ORACLE_OWNER_ROLE(), ORACLE_OWNER_ROLE_NAME());
+        _createRole(POOL_OWNER_ROLE(), POOL_OWNER_ROLE_NAME());
+        _createRole(PRODUCT_OWNER_ROLE(), PRODUCT_OWNER_ROLE_NAME());
+    }
+
+    function createRole(
+        string memory roleName
+    ) public override onlyAccessOwner returns (RoleId role) {
+        role = RoleIdLib.toRoleId(roleName);
+        require(
+            !roleExists(role),
+            "ERROR:ACS-010:ROLE_ALREADY_EXISTS");
+        
+        _createRole(role, roleName);
+    }
+
+    function setRoleState(RoleId role, bool active) external override onlyExistingRole(role) onlyAccessOwner {
+        RoleInfo memory info = _info[role];
+        info.isActive = active;
+        _setRoleInfo(info);
+
+        emit LogAccessRoleStateSet(role, active);
+    }
+
+    function grantRole(
+        RoleId role,
+        address member
+    ) external override onlyExistingRole(role) onlyAccessOwner {
+        require(_info[role].isActive, "ERROR:ACS-040:ROLE_NOT_ACTIVE");
+
+        _isRoleMember[role][member] = true;
+        _roleMembers[role].add(member);
+
+        emit LogAccessRoleGranted(role, member, _isRoleMember[role][member]);
+    }
+
+    function revokeRole(
+        RoleId role,
+        address member
+    ) external override onlyExistingRole(role) onlyAccessOwner {
+        delete _isRoleMember[role][member];
+        _roleMembers[role].remove(member);
+
+        emit LogAccessRoleGranted(role, member, false);
+    }
+
+    function roleExists(RoleId role) public view virtual override returns (bool) {
+        return _info[role].id == role;
+    }
+
+    function hasRole(
+        RoleId role,
+        address member
+    ) public view virtual override returns (bool) {
+        return _isRoleMember[role][member];
+    }
+
+    function getRoleId(string memory roleName) external pure override returns (RoleId role) {
+        return RoleIdLib.toRoleId(roleName);
+    }
+
+    function getRoleInfo(
+        RoleId role
+    ) external view override returns (RoleInfo memory info) {
+        return _info[role];
+    }
+
+    function getRole(
+        uint256 idx
+    ) external view override returns (RoleId role) {
+        return _roles[idx];
+    }
+
+    function getRoleCount() external view override returns (uint256 roles) {
+        return _roles.length;
+    }
+
+    function getRoleMemberCount(
+        RoleId role
+    ) public view override returns (uint256 roleMembers) {
+        return _roleMembers[role].length();
+    }
+
+    function getRoleMember(
+        RoleId role,
+        uint256 idx
+    ) public view override returns (address roleMembers) {
+        return _roleMembers[role].at(idx);
+    }
+
+    function _createRole(
+        RoleId role,
+        string memory roleName
+    ) internal {
+        RoleInfo memory info = RoleInfo(role, roleName, true);
+        _setRoleInfo(info);
+
+        emit LogAccessRoleCreated(role, roleName);
+    }
+
+    function _setRoleInfo(
+        RoleInfo memory info
+    ) internal {
+        RoleId role = info.id;
+        _info[role] = info;
+        if(!roleExists(role)) {
+            _roles.push(role);
+        }
+    }
+}

package/contracts/instance/module/access/IAccess.sol

@@ -0,0 +1,53 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {RoleId} from "../../../types/RoleId.sol";
+
+interface IAccess {
+    struct RoleInfo {
+        RoleId id;
+        string name;
+        bool isActive;
+    }
+}
+
+interface IAccessModule is
+    IAccess
+{
+    event LogAccessRoleCreated(RoleId role, string roleName);
+    event LogAccessRoleStateSet(RoleId role, bool active);
+    event LogAccessRoleGranted(RoleId role, address member, bool isMember);
+
+    function createRole(string memory roleName) external returns (RoleId role);
+
+    function setRoleState(RoleId role, bool active) external;
+
+    function grantRole(RoleId role, address member) external;
+
+    function revokeRole(RoleId role, address member) external;
+
+    function roleExists(RoleId role) external view returns (bool);
+
+    function hasRole(RoleId role, address member) external view returns (bool);
+
+    function getRoleCount() external view returns (uint256 roles);
+
+    function getRole(uint256 idx) external view returns (RoleId role);
+
+    function getRoleId(string memory roleName) external pure returns (RoleId role);
+
+    function getRoleInfo(
+        RoleId role
+    ) external view returns (RoleInfo memory info);
+
+    function getRoleMemberCount(
+        RoleId role
+    ) external view returns (uint256 roleMembers);
+
+    function getRoleMember(
+        RoleId role,
+        uint256 idx
+    ) external view returns (address roleMember);
+
+    function getOwner() external view returns (address owner);
+}

package/contracts/instance/module/bundle/BundleModule.sol

@@ -0,0 +1,134 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../../registry/IRegistry.sol";
+
+import {IProductService} from "../../service/IProductService.sol";
+import {IPoolService} from "../../service/IPoolService.sol";
+
+import {Fee} from "../../../types/Fee.sol";
+import {NftId} from "../../../types/NftId.sol";
+import {Key32, KeyId} from "../../../types/Key32.sol";
+import {LibNftIdSet} from "../../../types/NftIdSet.sol";
+import {ObjectType, PRODUCT, ORACLE, POOL, BUNDLE, POLICY} from "../../../types/ObjectType.sol";
+import {StateId, ACTIVE, PAUSED, ARCHIVED, CLOSED, APPLIED, REVOKED, DECLINED} from "../../../types/StateId.sol";
+import {Timestamp, blockTimestamp, zeroTimestamp} from "../../../types/Timestamp.sol";
+import {Blocknumber, blockNumber} from "../../../types/Blocknumber.sol";
+
+import {IKeyValueStore} from "../../base/IKeyValueStore.sol";
+import {ModuleBase} from "../../base/ModuleBase.sol";
+
+import {IBundleModule} from "./IBundle.sol";
+
+abstract contract BundleModule is 
+    ModuleBase,
+    IBundleModule
+{
+
+    using LibNftIdSet for LibNftIdSet.Set;
+
+    mapping(NftId bundleNftId => LibNftIdSet.Set policies) private _collateralizedPolicies;
+    mapping(NftId bundleNftId => mapping(NftId policyNftId => uint256 amount)) private _collateralizationAmount;
+
+    modifier onlyBundlePoolService() {
+        require(
+            msg.sender == address(this.getPoolService()),
+            "ERROR:BDL-001:NOT_POOL_SERVICE"
+        );
+        _;
+    }
+
+    modifier onlyBundleProductService() {
+        require(
+            msg.sender == address(this.getProductService()),
+            "ERROR:BDL-002:NOT_PRODUCT_SERVICE"
+        );
+        _;
+    }
+
+    modifier onlyPoolOrProductService() {
+        require(
+            msg.sender == address(this.getPoolService())
+                || msg.sender == address(this.getProductService()),
+            "ERROR:BDL-003:NOT_POOL_OR_PRODUCT_SERVICE"
+        );
+        _;
+    }
+
+    function initializeBundleModule(IKeyValueStore keyValueStore) internal {
+        _initialize(keyValueStore);
+    }
+
+    function createBundleInfo(
+        NftId bundleNftId,
+        NftId poolNftId,
+        Fee memory fee,
+        uint256 amount, 
+        uint256 lifetime, 
+        bytes calldata filter
+    )
+        external
+        onlyBundlePoolService
+        override
+    {
+        BundleInfo memory info = BundleInfo(
+            poolNftId,
+            fee,
+            filter,
+            amount, // capital
+            0, // locked capital
+            amount, // balance
+            blockTimestamp().addSeconds(lifetime), // expiredAt
+            zeroTimestamp() // closedAt
+        );
+
+        _create(BUNDLE(), bundleNftId, abi.encode(info));
+    }
+
+    function setBundleInfo(NftId bundleNftId, BundleInfo memory info)
+        external
+        override
+        onlyPoolOrProductService
+    {
+        _updateData(BUNDLE(), bundleNftId, abi.encode(info));
+    }
+
+    function updateBundleState(NftId bundleNftId, StateId state)
+        external
+        override
+        onlyBundlePoolService
+    {
+        _updateState(BUNDLE(), bundleNftId, state);
+    }
+
+    function collateralizePolicy(
+        NftId bundleNftId, 
+        NftId policyNftId, 
+        uint256 collateralAmount
+    )
+        external
+        onlyBundleProductService
+        override
+    {
+        _collateralizationAmount[bundleNftId][policyNftId] = collateralAmount;
+        _collateralizedPolicies[bundleNftId].add(policyNftId);
+    }
+
+    function releasePolicy(
+        NftId bundleNftId,
+        NftId policyNftId
+    )
+        external
+        onlyBundleProductService
+        override 
+        returns(uint256 collateralAmount)
+    {
+        collateralAmount = _collateralizationAmount[bundleNftId][policyNftId];
+        delete _collateralizationAmount[bundleNftId][policyNftId];
+        _collateralizedPolicies[bundleNftId].remove(policyNftId);
+    }
+
+    function getBundleInfo(NftId bundleNftId) external view override returns(BundleInfo memory bundleInfo) {
+        return abi.decode(_getData(BUNDLE(), bundleNftId), (BundleInfo));
+    }
+}

package/contracts/instance/module/bundle/IBundle.sol

@@ -0,0 +1,53 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../../registry/IRegistry.sol";
+import {IInstance} from "../../IInstance.sol";
+import {Fee} from "../../../types/Fee.sol";
+import {Key32} from "../../../types/Key32.sol";
+import {NftId} from "../../../types/NftId.sol";
+import {StateId} from "../../../types/StateId.sol";
+import {Timestamp} from "../../../types/Timestamp.sol";
+import {Blocknumber} from "../../../types/Blocknumber.sol";
+
+import {IKeyValueStore} from "../../base/IKeyValueStore.sol";
+import {IProductService} from "../../service/IProductService.sol";
+import {IPoolService} from "../../service/IPoolService.sol";
+
+interface IBundle {
+
+    struct BundleInfo {
+        NftId poolNftId;
+        Fee fee; // bundle fee on net premium amounts
+        bytes filter; // required conditions for applications to be considered for collateralization by this bundle
+        uint256 capitalAmount; // net investment capital amount (<= balance)
+        uint256 lockedAmount; // capital amount linked to collateralizaion of non-closed policies (<= balance)
+        uint256 balanceAmount; // total amount of funds: net investment capital + net premiums - payouts
+        Timestamp expiredAt; // no new policies
+        Timestamp closedAt;
+    }
+}
+
+interface IBundleModule is IBundle {
+
+    function createBundleInfo(
+        NftId bundleNftId,
+        NftId poolNftId,
+        Fee memory fee,
+        uint256 amount, 
+        uint256 lifetime, 
+        bytes calldata filter
+    ) external;
+
+    function setBundleInfo(NftId nftId, BundleInfo memory bundleInfo) external;
+    function updateBundleState(NftId nftId, StateId state) external;
+
+    function collateralizePolicy(NftId bundleNftId, NftId policyNftId, uint256 amount) external;
+    function releasePolicy(NftId bundleNftId, NftId policyNftId) external returns(uint256 collateralAmount);
+
+    function getBundleInfo(NftId nftId) external view returns(BundleInfo memory bundleInfo);
+
+    // repeat service linked signatures to avoid linearization issues
+    function getProductService() external returns(IProductService);
+    function getPoolService() external returns(IPoolService);
+}

package/contracts/instance/module/component/ComponentModule.sol

@@ -0,0 +1,71 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC20Metadata} from "@openzeppelin5/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+import {IKeyValueStore} from "../../base/IKeyValueStore.sol";
+import {IComponentModule} from "./IComponent.sol";
+
+import {NftId} from "../../../types/NftId.sol";
+import {ObjectType, COMPONENT} from "../../../types/ObjectType.sol";
+import {StateId} from "../../../types/StateId.sol";
+import {ModuleBase} from "../../base/ModuleBase.sol";
+
+abstract contract ComponentModule is 
+    ModuleBase,
+    IComponentModule
+{
+
+    NftId[] private _nftIds;
+
+    // TODO try to keep 1 modifier in 1 place...
+    modifier onlyComponentOwnerService() virtual {
+        require(
+            msg.sender == address(this.getComponentOwnerService()),
+            "ERROR:CMP-001:NOT_COMPONENT_OWNER_SERVICE"
+        );
+        _;
+    }
+
+    function initializeComponentModule(IKeyValueStore keyValueStore) internal {
+        _initialize(keyValueStore);
+    }
+
+    function registerComponent(
+        NftId nftId,
+        IERC20Metadata token,
+        address wallet
+    )
+        external
+        onlyComponentOwnerService
+        override
+    {
+        ComponentInfo memory info = ComponentInfo(token, wallet);
+        _nftIds.push(nftId);
+        _create(COMPONENT(), nftId, abi.encode(info));
+    }
+
+    function getComponentToken(NftId nftId) external view override returns(IERC20Metadata token) {
+        ComponentInfo memory info = abi.decode(_getData(COMPONENT(), nftId), (ComponentInfo));
+        return info.token;
+    }
+
+    function getComponentWallet(NftId nftId) external view override returns (address wallet) {
+        ComponentInfo memory info = abi.decode(_getData(COMPONENT(), nftId), (ComponentInfo));
+        return info.wallet;
+    }
+
+    function getComponentCount()
+        external
+        view
+        override
+        returns (uint256 numberOfCompnents)
+    {
+        return _nftIds.length;
+    }
+
+    function getComponentId(
+        uint256 idx
+    ) external view override returns (NftId componentNftId) {
+        return _nftIds[idx];
+    }
+}

package/contracts/instance/module/component/IComponent.sol

@@ -0,0 +1,28 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC20Metadata} from "@openzeppelin5/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+import {IComponentOwnerService} from "../../service/IComponentOwnerService.sol";
+
+import {StateId} from "../../../types/StateId.sol";
+import {NftId} from "../../../types/NftId.sol";
+
+interface IComponent {
+    struct ComponentInfo {
+        IERC20Metadata token;
+        address wallet;
+    }
+}
+
+interface IComponentModule is IComponent {
+
+    function registerComponent(NftId nftId, IERC20Metadata token, address wallet) external;
+    function getComponentToken(NftId nftId) external view returns (IERC20Metadata token);
+    function getComponentWallet(NftId nftId) external view returns (address wallet);
+
+    function getComponentCount() external view returns (uint256 numberOfCompnents);
+    function getComponentId(uint256 idx) external view returns (NftId nftId);
+
+    // repeat service linked signaturea to avoid linearization issues
+    function getComponentOwnerService() external view returns(IComponentOwnerService);
+}

package/contracts/instance/module/distribution/DistributionModule.sol

@@ -0,0 +1,17 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IDistributionModule} from "./IDistribution.sol";
+import {IKeyValueStore} from "../../base/IKeyValueStore.sol";
+import {ModuleBase} from "../../base/ModuleBase.sol";
+
+contract DistributionModule is
+    ModuleBase,
+    IDistributionModule
+{
+
+    function initializeDistributionModule(IKeyValueStore keyValueStore) internal {
+        _initialize(keyValueStore);
+    }
+
+}

package/contracts/instance/module/distribution/IDistribution.sol

@@ -0,0 +1,10 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+interface IDistribution {
+
+}
+
+interface IDistributionModule is IDistribution {
+    
+}

package/contracts/instance/module/policy/IPolicy.sol

@@ -0,0 +1,63 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../../registry/IRegistry.sol";
+import {IInstance} from "../../IInstance.sol";
+import {IProductService} from "../../service/IProductService.sol";
+import {NftId} from "../../../types/NftId.sol";
+import {ReferralId} from "../../../types/ReferralId.sol";
+import {RiskId} from "../../../types/RiskId.sol";
+import {StateId} from "../../../types/StateId.sol";
+import {Timestamp} from "../../../types/Timestamp.sol";
+
+// TODO check if there is value to introuce IContract and let IPolicy derive from IContract
+interface IPolicy {
+    struct PolicyInfo {
+        NftId productNftId;
+        NftId bundleNftId;
+        ReferralId referralId;
+        address beneficiary;
+        RiskId riskId;
+        uint256 sumInsuredAmount;
+        uint256 premiumAmount;
+        uint256 premiumPaidAmount;
+        uint256 lifetime;
+        bytes applicationData;
+        bytes policyData;
+        Timestamp activatedAt; // time of underwriting
+        Timestamp expiredAt; // no new claims (activatedAt + lifetime)
+        Timestamp closedAt; // no locked capital
+    }
+}
+
+interface IPolicyModule is IPolicy {
+    function createPolicyInfo(
+        NftId policyNftId,
+        NftId productNftId,
+        ReferralId referralId,
+        RiskId riskId,
+        uint256 sumInsuredAmount,
+        uint256 premiumAmount,
+        uint256 lifetime,
+        NftId bundleNftId
+    ) external;
+
+    function setPolicyInfo(NftId policyNftId, PolicyInfo memory info) external;
+    function updatePolicyState(NftId nftId, StateId state) external;
+
+    // function underwrite(NftId nftId) external;
+
+    // function processPremium(NftId nftId, uint256 amount) external;
+
+    // function activate(NftId nftId, Timestamp activateAt) external;
+
+    function getPolicyInfo(
+        NftId nftId
+    ) external view returns (PolicyInfo memory info);
+
+    // repeat registry linked signature
+    // function getRegistry() external view returns (IRegistry registry);
+
+    // repeat service linked signature to avoid linearization issues
+    function getProductService() external  returns(IProductService);
+}