@etherisc/gif-next 0.0.2-f72939c-683 → 0.0.2-f73b68c-992

package/contracts/shared/TokenHandler.sol

@@ -0,0 +1,341 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {AccessManaged} from "@openzeppelin/contracts/access/manager/AccessManaged.sol";
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
+
+import {Amount, AmountLib} from "../type/Amount.sol";
+import {ContractLib} from "../shared/ContractLib.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {NftId} from "../type/NftId.sol";
+import {SERVICE} from "../type/ObjectType.sol";
+
+
+/// @dev Token specific transfer helper base contract.
+/// A default token contract is provided via contract constructor.
+/// Relies internally on OpenZeppelin SafeERC20.safeTransferFrom.
+/// This base contract simplifies writing tests.
+contract TokenHandlerBase {
+
+    // _setWallet
+    event LogTokenHandlerWalletAddressChanged(NftId componentNftId, address oldWallet, address newWallet);
+    event LogTokenHandlerWalletTokensTransferred(NftId componentNftId, address oldWallet, address newWallet, Amount amount);
+
+    // _approveTokenHandler
+    event LogTokenHandlerTokenApproved(NftId nftId, address tokenHandler, address token, Amount amount, bool isMaxAmount);
+
+    // _transfer
+    event LogTokenHandlerTokenTransfer(address token, address from, address to, Amount amount);
+
+    // constructor
+    error ErrorTokenHandlerNotRegistry(address registry);
+    error ErrorTokenHandlerComponentNotRegistered(address component);
+    error ErrorTokenHandlerTokenAddressZero();
+
+    // _setWallet
+    error ErrorTokenHandlerNewWalletAddressZero();
+    error ErrorTokenHandlerAddressIsSameAsCurrent();
+
+    // _approveTokenHandler
+    error ErrorTokenHandlerNotWallet(NftId nftId, address tokenHandler, address wallet);
+
+    // _checkPreconditions
+    error ErrorTokenHandlerBalanceTooLow(address token, address from, uint256 balance, uint256 expectedBalance);
+    error ErrorTokenHandlerAllowanceTooSmall(address token, address from, address spender, uint256 allowance, uint256 expectedAllowance);
+    error ErrorTokenHandlerAmountIsZero();
+
+    IRegistry public immutable REGISTRY;
+    IERC20Metadata public immutable TOKEN;
+    address public immutable COMPONENT;
+    NftId public immutable NFT_ID;
+
+    address internal _wallet;
+
+    constructor(
+        address registry,
+        address component,
+        address token
+    )
+    {
+        if (!ContractLib.isRegistry(registry)) {
+            revert ErrorTokenHandlerNotRegistry(registry);
+        }
+
+        if (token == address(0)) {
+            revert ErrorTokenHandlerTokenAddressZero();
+        }
+
+        REGISTRY = IRegistry(registry);
+        COMPONENT = component;
+        NFT_ID = REGISTRY.getNftIdForAddress(component);
+
+        if (NFT_ID.eqz()) {
+            revert ErrorTokenHandlerComponentNotRegistered(component);
+        }
+
+        TOKEN = IERC20Metadata(token);
+
+        // self approval of token handler to max amount
+        _approve(TOKEN, AmountLib.max());
+    }
+
+
+    /// @dev Checks the balance and allowance for the from address and amount.
+    /// When requiring amount > 0 set checkAmount to true.
+    function checkBalanceAndAllowance(
+        address from,
+        Amount amount,
+        bool checkAmount
+    )
+        external
+        view
+    {
+        _checkBalanceAndAllowance(from, amount, checkAmount);
+    }
+
+
+    /// @dev Returns the wallet linked to this TokenHandler.
+    function getWallet()
+        public
+        view 
+        returns (address wallet)
+    {
+        if (_wallet == address(0)) {
+            return address(this);
+        }
+
+        return _wallet;
+    }
+
+
+    /// @dev Approves token handler to spend up to the specified amount of tokens.
+    /// Sets spending limit to type(uint256).max for AmountLib.max().
+    /// Reverts if wallet is not token handler itself.
+    /// Sets approvel using SareERC20.forceApprove internally.
+    function _approve(
+        IERC20Metadata token, 
+        Amount amount
+    )
+        internal
+    {
+        // check that wallet is token handler contract itself
+        if(_wallet != address(0)) {
+            revert ErrorTokenHandlerNotWallet(NFT_ID, address(this), _wallet);
+        }
+
+        // update spending limit for AmountLib.max() to type(uint256).max
+        uint256 amountInt = amount.toInt();
+        bool isMaxAmount = false;
+        if (amount == AmountLib.max()) {
+            amountInt = type(uint256).max;
+            isMaxAmount = true;
+        }
+
+        emit LogTokenHandlerTokenApproved(NFT_ID, address(this), address(token), amount, isMaxAmount);
+
+        // execute approval
+        SafeERC20.forceApprove(
+            token, 
+            address(this), 
+            amountInt);
+    }
+
+
+    function _setWallet(address newWallet)
+        internal
+    {
+        address oldWallet = _wallet;
+        if (newWallet == oldWallet) {
+            revert ErrorTokenHandlerAddressIsSameAsCurrent();
+        }
+
+        // effects
+        address oldWalletForBalance = getWallet();
+        _wallet = newWallet;
+
+        emit LogTokenHandlerWalletAddressChanged(NFT_ID, oldWallet, newWallet);
+
+        // interactions
+        Amount balanceAmount = AmountLib.toAmount(
+            TOKEN.balanceOf(oldWalletForBalance));
+
+        if (balanceAmount.gtz()) {
+            // move tokens from old to new wallet 
+            emit LogTokenHandlerWalletTokensTransferred(NFT_ID, oldWallet, newWallet, balanceAmount);
+
+            if (oldWallet == address(0)) {
+                // transfer from the component requires an allowance
+                _transfer(address(this), newWallet, balanceAmount, true);
+            } else if (newWallet == address(0)) {
+                _transfer(oldWallet, address(this), balanceAmount, true);
+            } else {
+                _transfer(oldWallet, newWallet, balanceAmount, true);
+            }
+        }
+    }
+
+
+    function _pullToken(address from, Amount amount)
+        internal
+    {
+        _transfer(from, getWallet(), amount, true);
+    }
+
+
+    function _pushToken(address to, Amount amount)
+        internal
+    {
+        _transfer(getWallet(), to, amount, true);
+    }
+
+
+    function _transfer(
+        address from,
+        address to,
+        Amount amount,
+        bool checkPreconditions
+    )
+        internal
+    {
+        if (checkPreconditions) {
+            bool checkAmount = true;
+            _checkBalanceAndAllowance(from, amount, checkAmount);
+        }
+
+        // transfer the tokens
+        emit LogTokenHandlerTokenTransfer(address(TOKEN), from, to, amount);
+
+        SafeERC20.safeTransferFrom(
+            TOKEN, 
+            from, 
+            to, 
+            amount.toInt());
+    }
+
+
+    function _checkBalanceAndAllowance(
+        address from,
+        Amount amount,
+        bool checkAmount
+    ) 
+        internal
+        view
+    {
+        // amount must be greater than zero
+        if (checkAmount && amount.eqz()) {
+            revert ErrorTokenHandlerAmountIsZero();
+        }
+
+        // allowance must be >= amount
+        uint256 allowance = TOKEN.allowance(from, address(this));
+        if (allowance < amount.toInt()) {
+            revert ErrorTokenHandlerAllowanceTooSmall(address(TOKEN), from, address(this), allowance, amount.toInt());
+        }
+
+        // balance must be >= amount
+        uint256 balance = TOKEN.balanceOf(from);
+        if (balance < amount.toInt()) {
+            revert ErrorTokenHandlerBalanceTooLow(address(TOKEN), from, balance, amount.toInt());
+        }
+    }
+}
+
+
+/// @dev Token specific transfer helper.
+/// Contract is derived from TokenHandlerBase and adds 
+/// authorization based on OpenZeppelin AccessManaged.
+contract TokenHandler is
+    AccessManaged,
+    TokenHandlerBase
+{
+
+    // onlyService
+    error ErrorTokenHandlerNotService(address service);
+
+    modifier onlyService() {
+        if (!REGISTRY.isObjectType(msg.sender, SERVICE())) {
+            revert ErrorTokenHandlerNotService(msg.sender);
+        }
+        _;
+    }
+
+    constructor(
+        address registry,
+        address component,
+        address token, 
+        address authority
+    )
+        TokenHandlerBase(registry, component, token)
+        AccessManaged(authority)
+    { }
+
+    /// @dev sets the wallet address for the component.
+    /// if the current wallet has tokens, these will be transferred.
+    /// if the new wallet address is externally owned, an approval from the 
+    /// owner of the external wallet to the tokenhandler of the component that 
+    /// covers the current component balance must exist
+    function setWallet(address newWallet)
+        external
+        restricted()
+        onlyService()
+    {
+        _setWallet(newWallet);
+    }
+
+
+    /// @dev Approves token handler to spend up to the specified amount of tokens.
+    /// Sets spending limit to type(uint256).max for AmountLib.max().
+    /// Reverts if component wallet is not component itself.
+    /// Sets approvel using SareERC20.forceApprove internally.
+    function approve(
+        IERC20Metadata token, 
+        Amount amount
+    )
+        external
+        restricted()
+        onlyService()
+    {
+        _approve(token, amount);
+    }
+
+    /// @dev Collect tokens from outside of GIF and transfer them to the wallet.
+    /// This method also checks balance and allowance and makes sure the amount is greater than zero.
+    function pullToken(
+        address from,
+        Amount amount
+    )
+        external
+        restricted()
+        onlyService()
+    {
+        _pullToken(from, amount);
+    }
+
+
+    /// @dev Distribute tokens from a wallet within the scope of gif to some address.
+    function pushToken(
+        address to,
+        Amount amount
+    )
+        external
+        restricted()
+        onlyService()
+    {
+        _pushToken(to, amount);
+    }
+
+
+    /// @dev Distribute fee tokens from a wallet within the scope of gif to some address.
+    /// Separate push function for component service.
+    function pushFeeToken(
+        address to,
+        Amount amount
+    )
+        external
+        restricted()
+        onlyService()
+    {
+        _pushToken(to, amount);
+    }
+}

package/contracts/shared/TokenHandlerDeployerLib.sol

@@ -0,0 +1,20 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {TokenHandler} from "./TokenHandler.sol";
+
+library TokenHandlerDeployerLib {
+
+    function deployTokenHandler(
+        address registry,
+        address component,
+        address token, 
+        address authority
+    )
+        public 
+        returns (TokenHandler)
+    {
+        return new TokenHandler(registry, component, token, authority);
+    }
+
+}

package/contracts/staking/IStaking.sol

@@ -0,0 +1,165 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Amount} from "../type/Amount.sol";
+import {IComponent} from "../shared/IComponent.sol";
+import {IVersionable} from "../upgradeability/IVersionable.sol";
+import {NftId} from "../type/NftId.sol";
+import {ObjectType} from "../type/ObjectType.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {StakingReader} from "./StakingReader.sol";
+import {StakingStore} from "./StakingStore.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+import {UFixed} from "../type/UFixed.sol";
+
+interface IStaking is 
+    IComponent,
+    IVersionable
+{
+    // staking rate
+    event LogStakingStakingRateSet(uint256 chainId, address token, UFixed oldStakingRate, UFixed newStakingRate);
+
+    // target parameters
+    event LogStakingLockingPeriodSet(NftId targetNftId, Seconds oldLockingPeriod, Seconds lockingPeriod);
+    event LogStakingRewardRateSet(NftId targetNftId, UFixed oldRewardRate, UFixed rewardRate);
+
+    // modifiers
+    error ErrorStakingNotStake(NftId stakeNftId);
+    error ErrorStakingNotTarget(NftId targetNftId);
+
+    error ErrorStakingNotStakingOwner();
+    error ErrorStakingNotNftOwner(NftId nftId);
+
+    // initializeTokenHandler
+    error ErrorStakingNotRegistry(address registry);
+
+    // staking rate
+    error ErrorStakingTokenNotRegistered(uint256 chainId, address token);
+
+    // check dip balance and allowance
+    error ErrorStakingDipBalanceInsufficient(address owner, uint256 amount, uint256 dipBalance);
+    error ErrorStakingDipAllowanceInsufficient(address owner, address tokenHandler, uint256 amount, uint256 dipAllowance);
+
+    error ErrorStakingStakingReaderStakingMismatch(address stakingByStakingReader);
+    error ErrorStakingTargetAlreadyRegistered(NftId targetNftId);
+    error ErrorStakingTargetNftIdZero();
+    error ErrorStakingTargetTypeNotSupported(NftId targetNftId, ObjectType objectType);
+    error ErrorStakingTargetUnexpectedObjectType(NftId targetNftId, ObjectType expectedObjectType, ObjectType actualObjectType);
+    error ErrorStakingLockingPeriodTooShort(NftId targetNftId, Seconds minLockingPeriod, Seconds lockingPeriod);
+    error ErrorStakingLockingPeriodTooLong(NftId targetNftId, Seconds maxLockingPeriod, Seconds lockingPeriod);
+    error ErrorStakingStakeLocked(NftId stakeNftId, Timestamp lockedUntil);
+    error ErrorStakingRewardRateTooHigh(NftId targetNftId, UFixed maxRewardRate, UFixed rewardRate);
+    error ErrorStakingTargetNotFound(NftId targetNftId);
+    error ErrorStakingTargetTokenNotFound(NftId targetNftId, uint256 chainId, address token);
+
+    error ErrorStakingTargetNotActive(NftId targetNftId);
+    error ErrorStakingStakeAmountZero(NftId targetNftId);
+
+    // info for individual stake
+    struct StakeInfo {
+        Timestamp lockedUntil;
+    }
+
+    struct TargetInfo {
+        ObjectType objectType;
+        uint256 chainId;
+        Seconds lockingPeriod;
+        UFixed rewardRate;
+    }
+
+    function initializeTokenHandler() external;
+
+    // staking rate management 
+
+    /// @dev sets the rate that converts 1 token of total value locked into the
+    /// the required staked dip amount to back up the locked token value
+    function setStakingRate(uint256 chainId, address token, UFixed stakingRate) external;
+
+
+    // target management
+
+    function registerTarget(
+        NftId targetNftId,
+        ObjectType expectedObjectType,
+        uint256 chainId,
+        Seconds initialLockingPeriod,
+        UFixed initialRewardRate
+    ) external;
+
+
+    /// @dev set the stake locking period to the specified duration.
+    /// permissioned: only the staking service may call this function
+    function setLockingPeriod(NftId targetNftId, Seconds lockingPeriod) external;
+
+    /// @dev update the target specific reward rate.
+    /// permissioned: only the staking service may call this function
+    function setRewardRate(NftId targetNftId, UFixed rewardRate) external;
+
+    /// @dev (re)fills the staking reward reserves for the specified target
+    /// unpermissioned: anybody may fill up staking reward reserves
+    function refillRewardReserves(NftId targetNftId, Amount dipAmount) external returns (Amount newBalance);
+
+    /// @dev defunds the staking reward reserves for the specified target
+    /// permissioned: only the staking service may call this function
+    function withdrawRewardReserves(NftId targetNftId, Amount dipAmount) external returns (Amount newBalance);
+
+
+    /// @dev increases the total value locked amount for the specified target by the provided token amount.
+    /// function is called when a new policy is collateralized.
+    /// function restricted to the pool service.
+    function increaseTotalValueLocked(NftId targetNftId, address token, Amount amount) external returns (Amount newBalance);
+
+
+    /// @dev decreases the total value locked amount for the specified target by the provided token amount.
+    /// function is called when a new policy is closed or payouts are executed.
+    /// function restricted to the pool service.
+    function decreaseTotalValueLocked(NftId targetNftId, address token, Amount amount) external returns (Amount newBalance);
+
+
+    function updateRemoteTvl(NftId targetNftId, address token, Amount amount) external;
+
+    // staking functions
+
+    /// @dev creat a new stake info object
+    /// permissioned: only staking service may call this function.
+    function createStake(NftId stakeNftId, NftId targetNftId, Amount dipAmount) external;
+
+    /// @dev increase the staked dip by dipAmount for the specified stake.
+    /// staking rewards are updated and added to the staked dips as well.
+    /// the function returns the new total amount of staked dips.
+    function stake(NftId stakeNftId, Amount dipAmount) external returns (Amount stakeBalance);
+
+    /// @dev restakes the dips to a new target.
+    /// the sum of the staked dips and the accumulated rewards will be restaked.
+    /// permissioned: only staking service may call this function.
+    function restake(NftId stakeNftId, NftId newTargetNftId) external returns (NftId newStakeNftId);
+
+    /// @dev retuns the specified amount of dips to the holder of the specified stake nft.
+    /// if dipAmount is set to Amount.max() all staked dips and all rewards are transferred to 
+    /// permissioned: only staking service may call this function.
+    function unstake(NftId stakeNftId)
+        external
+        returns (
+            Amount unstakedAmount,
+            Amount rewardsClaimedAmount
+        );
+
+    /// @dev update stake rewards for current time.
+    /// may be called before an announement of a decrease of a reward rate reduction.
+    /// calling this functions ensures that reward balance is updated using the current (higher) reward rate.
+    /// unpermissioned.
+    function updateRewards(NftId stakeNftId) external;
+
+    /// @dev transfers all rewards accumulated so far to the holder of the specified stake nft.
+    /// permissioned: only staking service may call this function.
+    function claimRewards(NftId stakeNftId)
+        external
+        returns (
+            Amount rewardsClaimedAmount
+        );
+
+    //--- view and pure functions -------------------------------------------//
+
+    function getStakingStore() external view returns (StakingStore stakingStore);
+    function getStakingReader() external view returns (StakingReader reader);
+}

package/contracts/staking/IStakingService.sol

@@ -0,0 +1,165 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {Amount} from "../type/Amount.sol";
+import {IService} from "../shared/IService.sol";
+import {IStaking} from "./IStaking.sol";
+import {NftId} from "../type/NftId.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {TokenHandler} from "../shared/TokenHandler.sol";
+import {UFixed} from "../type/UFixed.sol";
+
+
+interface IStakingService is IService
+{
+
+    event LogStakingServiceProtocolTargetRegistered(NftId protocolNftId);
+    event LogStakingServiceInstanceTargetRegistered(NftId instanceNftId, uint256 chainId);
+    event LogStakingServiceLockingPeriodSet(NftId targetNftId, Seconds oldLockingDuration, Seconds lockingDuration);
+    event LogStakingServiceRewardRateSet(NftId targetNftId, UFixed oldRewardRate, UFixed rewardRate);
+
+    event LogStakingServiceRewardReservesIncreased(NftId targetNftId, address rewardProvider, Amount dipAmount, Amount newBalance);
+    event LogStakingServiceRewardReservesDecreased(NftId targetNftId, address targetOwner, Amount dipAmount, Amount newBalance);
+
+    event LogStakingServiceStakeCreated(NftId stakeNftId, NftId targetNftId, address owner, Amount stakedAmount);
+    event LogStakingServiceStakeIncreased(NftId stakeNftId, address owner, Amount stakedAmount, Amount stakeBalance);
+    event LogStakingServiceUnstaked(NftId stakeNftId, address stakeOwner, Amount totalAmount);
+
+    event LogStakingServiceRewardsUpdated(NftId stakeNftId);
+    event LogStakingServiceRewardsClaimed(NftId stakeNftId, address stakeOwner, Amount rewardsClaimedAmount);
+
+    // modifiers
+    error ErrorStakingServiceNotStakingOwner(address account);
+    error ErrorStakingServiceNotStaking(address stakingAddress);
+    error ErrorStakingServiceNotSupportingIStaking(address stakingAddress);
+
+    // create
+    error ErrorStakingServiceZeroTargetNftId();
+    error ErrorStakingServiceNotTargetNftId(NftId targetNftId);
+    error ErrorStakingServiceNotActiveTargetNftId(NftId targetNftId);
+    error ErrorStakingServiceDipBalanceInsufficient(NftId targetNftId, uint256 amount, uint256 balance);
+    error ErrorStakingServiceDipAllowanceInsufficient(NftId targetNftId, address tokenHandler, uint256 amount, uint256 allowance);
+
+    /// @dev Set the protocol reward rate stake locking period to the specified duration.
+    /// Permissioned: only staking owner
+    // TODO implement
+    // function setProtocolRewardRate(UFixed rewardRate) external;
+    // function setProtocolLockingPeriod(Seconds lockingPeriod) external;
+    // TODO also make sure that protocol rewards can be refilled and withdrawn
+
+    /// @dev Approves the staking token handler.
+    /// Reverts if the staking token handler wallet is not the token handler itself.
+    function approveTokenHandler(
+        IERC20Metadata token,
+        Amount amount
+    ) external;
+
+    /// @dev creates/registers an on-chain instance staking target.
+    /// function granted to instance service
+    function createInstanceTarget(
+        NftId targetNftId,
+        Seconds initialLockingPeriod,
+        UFixed initialRewardRate
+    ) external;
+
+    /// @dev Set the instance stake locking period to the specified duration.
+    /// Permissioned: Only owner of the specified target.
+    function setInstanceLockingPeriod(NftId instanceNftId, Seconds lockingPeriod) external;
+
+    /// @dev Set the instance reward rate to the specified value.
+    /// Permissioned: Only owner of the specified target.
+    function setInstanceRewardRate(NftId instanceNftId, UFixed rewardRate) external;
+
+    /// @dev (Re)fills the staking reward reserves for the specified target using the dips provided by the reward provider.
+    /// unpermissioned: anybody may fill up staking reward reserves
+    function refillInstanceRewardReserves(NftId instanceNftId, address rewardProvider, Amount dipAmount) external returns (Amount newBalance);
+
+    /// @dev (Re)fills the staking reward reserves for the specified target using the dips provided by the sender
+    /// unpermissioned: anybody may fill up staking reward reserves
+    function refillRewardReservesBySender(NftId targetNftId, Amount dipAmount) external returns (Amount newBalance);
+
+    /// @dev Defunds the staking reward reserves for the specified target
+    /// Permissioned: only the target owner may call this function
+    function withdrawInstanceRewardReserves(NftId instanceNftId, Amount dipAmount) external returns (Amount newBalance);
+
+    /// @dev create a new stake with amount DIP to the specified target
+    /// returns the id of the newly minted stake nft
+    /// permissionless function
+    function create(
+        NftId targetNftId,
+        Amount amount
+    )
+        external
+        returns (
+            NftId stakeNftId
+        );
+
+
+    /// @dev increase an existing stake by amount DIP
+    /// updates and restakes the staking reward amount
+    /// function restricted to the current stake owner
+    function stake(
+        NftId stakeNftId,
+        Amount amount
+    )
+        external;
+
+
+    /// @dev re-stakes the current staked DIP as well as all accumulated rewards to the new stake target.
+    /// all related stakes and all accumulated reward DIP are transferred to the current stake holder
+    /// function restricted to the current stake owner
+    function restakeToNewTarget(
+        NftId stakeNftId,
+        NftId newTargetNftId
+    )
+        external
+        returns (
+            NftId newStakeNftId
+        );
+
+
+    /// @dev updates the reward balance of the stake using the current reward rate.
+    function updateRewards(
+        NftId stakeNftId
+    )
+        external;
+
+
+    /// @dev claims all available rewards.
+    function claimRewards(
+        NftId stakeNftId
+    )
+        external;
+
+
+    /// @dev unstakes all dips (stakes and rewards) of an existing stake.
+    /// function restricted to the current stake owner
+    function unstake(
+        NftId stakeNftId
+    )
+        external;
+
+
+    /// @dev sets total value locked data for a target contract on a different chain.
+    /// this is done via CCIP (cross chain communication) 
+    function setTotalValueLocked(
+        NftId targetNftId,
+        address token,
+        Amount amount
+    )
+        external;
+
+    function getDipToken()
+        external
+        returns (IERC20Metadata dip);
+
+    function getTokenHandler()
+        external
+        returns (TokenHandler tokenHandler);
+
+    function getStaking()
+        external
+        returns (IStaking staking);
+}