@etherisc/gif-next 0.0.2-f626d92-602 → 0.0.2-f634e5c-828

package/contracts/staking/StakingReader.sol

@@ -0,0 +1,190 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol"; 
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IRegistryLinked} from "../shared/IRegistryLinked.sol";
+import {IStaking} from "../staking/IStaking.sol";
+
+import {Amount} from "../type/Amount.sol";
+import {Blocknumber}  from "../type/Blocknumber.sol";
+import {NftId} from "../type/NftId.sol";
+import {STAKE, TARGET} from "../type/ObjectType.sol";
+import {StakingStore} from "./StakingStore.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+import {UFixed} from "../type/UFixed.sol";
+
+contract StakingReader is
+    IRegistryLinked,
+    Initializable
+{
+
+    error ErrorStakingReaderUnauthorizedCaler();
+
+    address private _initializeOwner;
+    IRegistry private _registry;
+    IStaking private _staking;
+    StakingStore private _store;
+
+    constructor(IRegistry registry) {
+        _initializeOwner = msg.sender;
+        _registry = registry;
+    }
+
+    function initialize(
+        address stakingAddress,
+        address stakingStoreAddress
+    )
+        external
+        initializer()
+    {
+        if (msg.sender != _initializeOwner) {
+            revert ErrorStakingReaderUnauthorizedCaler();
+        }
+
+        _staking = IStaking(stakingAddress);
+        _store = StakingStore(stakingStoreAddress);
+    }
+
+    // view and pure functions 
+
+    function getRegistry() external view returns (IRegistry registry) {
+        return _registry;
+    }
+
+    function getStaking() external view returns (IStaking staking) {
+        return _staking;
+    }
+
+    function getStakingRate(uint256 chainId, address token) external view returns (UFixed stakingRate) { 
+        return _store.getStakingRate(chainId, token); 
+    }
+
+
+    function isTarget(NftId targetNftId) external view returns (bool) {
+        return _store.getTargetNftIdSet().exists(targetNftId);
+    }
+
+
+    function targets() external view returns (uint256) {
+        return _store.getTargetNftIdSet().nftIds();
+    }
+
+
+    function getTargetNftId(uint256 idx) external view returns (NftId) {
+        return _store.getTargetNftIdSet().getNftId(idx);
+    }
+
+
+    function isActive(NftId targetNftId) external view returns (bool) {
+        return _store.getTargetNftIdSet().isActive(targetNftId);
+    }
+
+
+    function activeTargets() external view returns (uint256) {
+        return _store.getTargetNftIdSet().activeNftIds();
+    }
+
+
+    function getActiveTargetNftId(uint256 idx) external view returns (NftId) {
+        return _store.getTargetNftIdSet().getActiveNftId(idx);
+    }
+
+
+    function getTargetNftId(NftId stakeNftId) public view returns (NftId targetNftId) {
+        return _registry.getObjectInfo(stakeNftId).parentNftId;
+    }
+
+
+    function getTargetInfo(NftId targetNftId) public view returns (IStaking.TargetInfo memory info) {
+        bytes memory data = _store.getData(targetNftId.toKey32(TARGET()));
+        if (data.length > 0) {
+            return abi.decode(data, (IStaking.TargetInfo));
+        }
+    }
+
+
+    function getStakeInfo(NftId stakeNftId) external view returns (IStaking.StakeInfo memory stakeInfo) {
+        bytes memory data = _store.getData(stakeNftId.toKey32(STAKE()));
+        if (data.length > 0) {
+            return abi.decode(data, (IStaking.StakeInfo));
+        }
+    }
+
+
+    /// @dev get the reward rate that applies to the specified stake nft id.
+    function getTargetRewardRate(NftId stakeNftId) external view returns (NftId targetNftId, UFixed rewardRate) {
+        targetNftId = getTargetNftId(stakeNftId);
+        rewardRate = getTargetInfo(targetNftId).rewardRate;
+    }
+
+
+    /// @dev get the reward rate for the specified target nft id.
+    function getRewardRate(NftId targetNftId) external view returns (UFixed rewardRate) {
+        return getTargetInfo(targetNftId).rewardRate;
+    }
+
+    /// @dev returns the current reward reserve balance for the specified target.
+    function getReserveBalance(NftId targetNftId) external view returns (Amount rewardReserveBalance) {
+        return _store.getReserveBalance(targetNftId); 
+    }
+
+    function getStakeBalance(NftId nftId) external view returns (Amount balanceAmount) { 
+        return _store.getStakeBalance(nftId); 
+    }
+
+    function getRewardBalance(NftId nftId) external view returns (Amount rewardAmount) {
+        return _store.getRewardBalance(nftId); 
+    }
+
+    function getBalanceUpdatedAt(NftId nftId) external view returns (Timestamp updatedAt) {
+        return _store.getBalanceUpdatedAt(nftId); 
+    }
+
+    function getBalanceUpdatedIn(NftId nftId) external view returns (Blocknumber blocknumber) {
+        return _store.getBalanceUpdatedIn(nftId); 
+    }
+
+    function getTotalValueLocked(NftId nftId, address token) external view returns (Amount totalValueLocked) {
+        return _store.getTotalValueLocked(nftId, token); 
+    }
+
+    function getRequiredStakeBalance(NftId nftId) external view returns (Amount requiredStakedAmount) {
+        return _store.getRequiredStakeBalance(nftId); 
+    }
+
+    function getTargetBalances(NftId stakeNftId) 
+        public
+        view
+        returns (
+            Amount balanceAmount,
+            Amount stakeAmount,
+            Amount rewardAmount,
+            Blocknumber lastUpdatedIn
+        )
+    {
+        (
+            balanceAmount,
+            stakeAmount,
+            rewardAmount,
+            lastUpdatedIn
+        ) = _store.getTargetBalances(stakeNftId);
+    }
+
+    function getStakeBalances(NftId stakeNftId) 
+        external
+        view
+        returns (
+            Amount stakeAmount,
+            Amount rewardAmount,
+            Timestamp lastUpdatedAt
+        )
+    {
+        (
+            stakeAmount,
+            rewardAmount,
+            lastUpdatedAt
+        ) = _store.getStakeBalances(stakeNftId);
+    }
+}

package/contracts/staking/StakingService.sol

@@ -0,0 +1,440 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {Amount} from "../type/Amount.sol";
+import {IRegisterable} from "../shared/IRegisterable.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {RegistryService} from "../registry/RegistryService.sol";
+import {IStaking} from "./IStaking.sol";
+import {IStakingService} from "./IStakingService.sol";
+import {NftId, NftIdLib} from "../type/NftId.sol";
+import {ObjectType, INSTANCE, REGISTRY, STAKE, STAKING} from "../type/ObjectType.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {Service} from "../shared/Service.sol";
+import {TokenHandler} from "../shared/TokenHandler.sol";
+import {UFixed} from "../type/UFixed.sol";
+
+
+contract StakingService is 
+    Service, 
+    IStakingService
+{
+    // TODO decide and implement string spec for location calculation
+    // keccak256(abi.encode(uint256(keccak256("gif-next.contracts.shared.StakingService.sol")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant STAKING_SERVICE_LOCATION_V1 = 0x6548005c3f4340f82f348c576c0ff69f7f529cadd5ad41f96aae61abceeaa300;
+
+    struct StakingServiceStorage {
+        RegistryService _registryService;
+        IStaking _staking;
+        IERC20Metadata _dip;
+        TokenHandler _tokenHandler;
+    }
+
+    function createInstanceTarget(
+        NftId targetNftId,
+        Seconds initialLockingPeriod,
+        UFixed initialRewardRate
+    )
+        external
+        virtual
+        restricted()
+    {
+        uint256 chainId = block.chainid;
+        _getStakingServiceStorage()._staking.registerTarget(
+            targetNftId,
+            INSTANCE(),
+            chainId,
+            initialLockingPeriod,
+            initialRewardRate);
+
+        emit LogStakingServiceInstanceTargetRegistered(targetNftId, chainId);
+    }
+
+
+    function setInstanceLockingPeriod(NftId instanceNftId, Seconds lockingPeriod)
+        external
+        virtual
+        restricted()
+    {
+        _checkNftType(instanceNftId, INSTANCE());
+        _getStakingServiceStorage()._staking.setLockingPeriod(
+            instanceNftId, 
+            lockingPeriod);
+    }
+
+
+    function setInstanceRewardRate(NftId instanceNftId, UFixed rewardRate)
+        external
+        virtual
+        restricted()
+    {
+        _checkNftType(instanceNftId, INSTANCE());
+        _getStakingServiceStorage()._staking.setRewardRate(
+            instanceNftId, 
+            rewardRate);
+    }
+
+
+    function refillInstanceRewardReserves(NftId instanceNftId, address rewardProvider, Amount dipAmount)
+        external
+        virtual
+        restricted()
+        returns (Amount newBalance)
+    {
+        _checkNftType(instanceNftId, INSTANCE());
+        return _refillRewardReserves(instanceNftId, rewardProvider, dipAmount);
+    }
+
+
+    function refillRewardReservesBySender(NftId targetNftId, Amount dipAmount)
+        external
+        virtual
+        restricted()
+        returns (Amount newBalance)
+    {
+        address rewardProvider = msg.sender;
+        return _refillRewardReserves(targetNftId, rewardProvider, dipAmount);
+    }
+
+
+    function withdrawInstanceRewardReserves(NftId instanceNftId, Amount dipAmount)
+        external
+        virtual
+        restricted()
+        returns (Amount newBalance)
+    {
+        _checkNftType(instanceNftId, INSTANCE());
+        // update reward reserve book keeping
+        StakingServiceStorage storage $ = _getStakingServiceStorage();
+        newBalance = $._staking.withdrawRewardReserves(instanceNftId, dipAmount);
+
+        // transfer withdrawal amount to target owner
+        address instanceOwner = getRegistry().ownerOf(instanceNftId);
+        emit LogStakingServiceRewardReservesDecreased(instanceNftId, instanceOwner, dipAmount, newBalance);
+        _distributeToken(
+            $._staking.getTokenHandler(),
+            instanceOwner,
+            dipAmount);
+    }
+
+
+    /// @dev creates a new stake to the specified target nft id with the provided dip amount
+    /// the target nft id must have been registered as an active staking target prior to this call
+    /// the sender of this transaction becomes the stake owner via the minted nft.
+    /// to create the new stake balance and allowance of the staker need to cover the dip amount
+    /// the allowance needs to be on the token handler of the staking contract (getTokenHandler())
+    /// this is a permissionless function.
+    function create(
+        NftId targetNftId,
+        Amount dipAmount
+    )
+        external
+        virtual
+        restricted()
+        returns (
+            NftId stakeNftId
+        )
+    {
+        StakingServiceStorage storage $ = _getStakingServiceStorage();
+        address stakeOwner = msg.sender;
+
+        // target nft id checks are performed in $._staking.createStake() below
+        // register new stake object with registry
+        stakeNftId = $._registryService.registerStake(
+            IRegistry.ObjectInfo({
+                nftId: NftIdLib.zero(),
+                parentNftId: targetNftId,
+                objectType: STAKE(),
+                isInterceptor: false,
+                objectAddress: address(0),
+                initialOwner: stakeOwner,
+                data: ""
+            }));
+
+        // create stake info with staking
+        $._staking.createStake(
+            stakeNftId, 
+            targetNftId,
+            dipAmount);
+
+        emit LogStakingServiceStakeCreated(stakeNftId, targetNftId, stakeOwner, dipAmount);
+
+        // collect staked dip by staking
+        _collectToken(
+            $._staking.getTokenHandler(),
+            stakeOwner, 
+            dipAmount);
+    }
+
+    function _collectToken(
+        TokenHandler tokenHandler,
+        address from,
+        Amount amount
+    )
+        internal
+        virtual
+    {
+        tokenHandler.collectTokens(
+            from, 
+            amount);
+    }
+
+    function _distributeToken(
+        TokenHandler tokenHandler,
+        address to,
+        Amount amount
+    )
+        internal
+        virtual
+    {
+        tokenHandler.distributeTokens(
+            tokenHandler.getWallet(), 
+            to, 
+            amount);
+    }
+
+
+    function stake(
+        NftId stakeNftId,
+        Amount dipAmount
+    )
+        external
+        virtual
+        restricted()
+        onlyNftOwner(stakeNftId)
+    {
+        _checkNftType(stakeNftId, STAKE());
+
+        StakingServiceStorage storage $ = _getStakingServiceStorage();
+        address stakeOwner = msg.sender;
+
+        // add additional staked dips by staking 
+        Amount stakeBalance = $._staking.stake(
+            stakeNftId, 
+            dipAmount);
+
+        // collect staked dip by staking
+        if (dipAmount.gtz()) {
+            emit LogStakingServiceStakeIncreased(stakeNftId, stakeOwner, dipAmount, stakeBalance);
+            _collectToken(
+                $._staking.getTokenHandler(),
+                stakeOwner,
+                dipAmount);
+        }
+    }
+
+
+    function restakeToNewTarget(
+        NftId stakeNftId,
+        NftId newTargetNftId
+    )
+        external
+        virtual
+        restricted()
+        onlyNftOwner(stakeNftId)
+        returns (
+            NftId newStakeNftId
+        )
+    {
+        _checkNftType(stakeNftId, STAKE());
+
+        StakingServiceStorage storage $ = _getStakingServiceStorage();
+        // TODO implement
+    } 
+
+
+    function updateRewards(
+        NftId stakeNftId
+    )
+        external
+        virtual
+        restricted()
+    {
+        _checkNftType(stakeNftId, STAKE());
+
+        StakingServiceStorage storage $ = _getStakingServiceStorage();
+        $._staking.updateRewards(stakeNftId);
+
+        emit LogStakingServiceRewardsUpdated(stakeNftId);
+    }
+
+
+    function claimRewards(NftId stakeNftId)
+        external
+        virtual
+        restricted()
+        onlyNftOwner(stakeNftId)
+    {
+        _checkNftType(stakeNftId, STAKE());
+
+        StakingServiceStorage storage $ = _getStakingServiceStorage();
+        address stakeOwner = msg.sender;
+
+        Amount rewardsClaimedAmount = $._staking.claimRewards(stakeNftId);
+        emit LogStakingServiceRewardsClaimed(stakeNftId, stakeOwner, rewardsClaimedAmount);
+        _distributeToken(
+            $._staking.getTokenHandler(),
+            stakeOwner,
+            rewardsClaimedAmount);
+    }
+
+
+    function unstake(NftId stakeNftId)
+        external
+        virtual
+        restricted()
+        onlyNftOwner(stakeNftId)
+    {
+        _checkNftType(stakeNftId, STAKE());
+        
+        StakingServiceStorage storage $ = _getStakingServiceStorage();
+        address stakeOwner = msg.sender;
+
+        (
+            Amount unstakedAmount,
+            Amount rewardsClaimedAmount
+        ) = $._staking.unstake(stakeNftId);
+
+        Amount totalAmount = unstakedAmount + rewardsClaimedAmount;
+        emit LogStakingServiceUnstaked(stakeNftId, stakeOwner, totalAmount);
+
+        $._staking.getTokenHandler().pushToken(
+            stakeOwner, 
+            totalAmount);
+    }
+
+
+    function setTotalValueLocked(
+        NftId targetNftId,
+        address token,
+        Amount amount
+    )
+        external
+        virtual
+        restricted()
+    {
+        // TODO implement
+
+    }
+
+    //--- view functions ----------------------------------------------------//
+
+    function getDipToken()
+        external
+        virtual
+        returns (IERC20Metadata dip)
+    {
+        return _getStakingServiceStorage()._dip;
+    }
+
+
+    function getTokenHandler()
+        external
+        virtual
+        returns (TokenHandler tokenHandler)
+    {
+        return _getStakingServiceStorage()._tokenHandler;
+    }
+
+
+    function getStaking()
+        external
+        virtual
+        returns (IStaking staking)
+    {
+        return _getStakingServiceStorage()._staking;
+    }
+
+    //--- internal functions ------------------------------------------------//
+
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        virtual override
+        initializer()
+    {
+        (
+            address authority,
+            address registryAddress,
+            address stakingAddress
+        ) = abi.decode(data, (address, address, address));
+
+        _initializeService(registryAddress, authority, owner);
+
+        StakingServiceStorage storage $ = _getStakingServiceStorage();
+        $._registryService = RegistryService(_getServiceAddress(REGISTRY()));
+        $._staking = _registerStaking(stakingAddress);
+        $._dip = $._staking.getToken();
+        $._tokenHandler = $._staking.getTokenHandler();
+
+        _registerInterface(type(IStakingService).interfaceId);
+    }
+
+
+    function _registerStaking(
+        address stakingAddress
+    )
+        internal
+        returns (IStaking staking)
+    {
+        // check if provided staking contract is already registred
+        // staking contract may have been already registered by a previous major relase
+        IRegistry.ObjectInfo memory stakingInfo = getRegistry().getObjectInfo(stakingAddress);
+        if (stakingInfo.nftId.gtz()) {
+            // registered object but wrong type
+            if (stakingInfo.objectType != STAKING()) {
+                revert ErrorStakingServiceNotStaking(stakingAddress);
+            }
+
+            // return correctly registered staking contract
+            return IStaking(stakingAddress);
+        }
+
+        // check that contract implements IStaking
+        if(!IStaking(stakingAddress).supportsInterface(type(IStaking).interfaceId)) {
+            revert ErrorStakingServiceNotSupportingIStaking(stakingAddress);
+        }
+
+        address owner = msg.sender;
+        _getStakingServiceStorage()._registryService.registerStaking(
+            IRegisterable(stakingAddress),
+            owner);
+
+        return IStaking(stakingAddress);
+    }
+
+
+    function _refillRewardReserves(NftId targetNftId, address rewardProvider, Amount dipAmount)
+        internal
+        virtual
+        returns (Amount newBalance)
+    {
+        // update reward reserve book keeping
+        StakingServiceStorage storage $ = _getStakingServiceStorage();
+        newBalance = $._staking.refillRewardReserves(targetNftId, dipAmount);
+
+        emit LogStakingServiceRewardReservesIncreased(targetNftId, rewardProvider, dipAmount, newBalance);
+
+        // collect reward dip from provider
+        _collectToken(
+            $._staking.getTokenHandler(),
+            rewardProvider,
+            dipAmount);
+    }
+
+
+    function _getStakingServiceStorage() private pure returns (StakingServiceStorage storage $) {
+        assembly {
+            $.slot := STAKING_SERVICE_LOCATION_V1
+        }
+    }
+
+
+    function _getDomain() internal pure override returns(ObjectType) {
+        return STAKING();
+    }
+}

package/contracts/staking/StakingServiceManager.sol

@@ -0,0 +1,44 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IVersionable} from "../upgradeability/IVersionable.sol";
+import {ProxyManager} from "../upgradeability/ProxyManager.sol";
+import {StakingService} from "./StakingService.sol";
+
+contract StakingServiceManager is
+    ProxyManager
+{
+
+    StakingService private _stakingService;
+
+    /// @dev initializes proxy manager with service implementation 
+    constructor(
+        address authority,
+        address registryAddress,
+        bytes32 salt
+    )
+    {
+        StakingService svc = new StakingService();
+        bytes memory data = abi.encode(
+            authority, 
+            registryAddress, 
+            IRegistry(registryAddress).getStakingAddress());
+        IVersionable versionable = initialize(
+            registryAddress,
+            address(svc), 
+            data,
+            salt);
+
+        _stakingService = StakingService(address(versionable));
+    }
+
+    //--- view functions ----------------------------------------------------//
+    function getStakingService()
+        external
+        view
+        returns (StakingService)
+    {
+        return _stakingService;
+    }
+}