@etherisc/gif-next 0.0.2-f619be3-760 → 0.0.2-f62dcdf-553

package/contracts/pool/BundleService.sol

@@ -0,0 +1,493 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IBundle} from "../instance/module/IBundle.sol";
+import {IBundleService} from "./IBundleService.sol";
+import {IComponents} from "../instance/module/IComponents.sol";
+import {IComponentService} from "../shared/IComponentService.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IRegistryService} from "../registry/IRegistryService.sol";
+import {IInstance} from "../instance/IInstance.sol";
+import {InstanceStore} from "../instance/InstanceStore.sol";
+import {IPolicy} from "../instance/module/IPolicy.sol";
+
+import {Amount, AmountLib} from "../type/Amount.sol";
+import {BundleSet} from "../instance/BundleSet.sol";
+import {ComponentVerifyingService} from "../shared/ComponentVerifyingService.sol";
+import {Fee} from "../type/Fee.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {NftId, NftIdLib} from "../type/NftId.sol";
+import {ObjectType, COMPONENT, POOL, BUNDLE, POLICY, REGISTRY} from "../type/ObjectType.sol";
+import {StateId, ACTIVE, PAUSED, CLOSED, KEEP_STATE} from "../type/StateId.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {Timestamp, TimestampLib, zeroTimestamp} from "../type/Timestamp.sol";
+
+string constant BUNDLE_SERVICE_NAME = "BundleService";
+
+contract BundleService is 
+    ComponentVerifyingService, 
+    IBundleService 
+{
+    
+    string public constant NAME = "BundleService";
+
+    address private _registryAddress;
+    IRegistryService private _registryService;
+    IComponentService private _componentService;
+
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        virtual override
+        initializer()
+    {
+        (
+            address registryAddress,
+            address authority
+        ) = abi.decode(data, (address, address));
+
+        _initializeService(registryAddress, authority, owner);
+
+        _registryService = IRegistryService(_getServiceAddress(REGISTRY()));
+        _componentService = IComponentService(_getServiceAddress(COMPONENT()));
+
+        _registerInterface(type(IBundleService).interfaceId);
+    }
+
+
+    function setFee(
+        NftId bundleNftId,
+        Fee memory fee
+    )
+        external
+        virtual
+    {
+        _checkNftType(bundleNftId, BUNDLE());
+
+        (NftId poolNftId,, IInstance instance) = _getAndVerifyActiveComponent(POOL());
+        InstanceReader instanceReader = instance.getInstanceReader();
+        IBundle.BundleInfo memory bundleInfo = instanceReader.getBundleInfo(bundleNftId);
+        if(bundleInfo.poolNftId.eqz()) {
+            revert ErrorBundleServiceBundleUnknown(bundleNftId);
+        }
+
+        if(bundleInfo.poolNftId != poolNftId) {
+            revert ErrorBundleServiceBundlePoolMismatch(bundleNftId, bundleInfo.poolNftId, poolNftId);
+        }
+
+        bundleInfo.fee = fee;
+        instance.getInstanceStore().updateBundle(bundleNftId, bundleInfo, KEEP_STATE());
+    }
+
+
+    function create(
+        IInstance instance,
+        NftId poolNftId,
+        address owner, 
+        Fee memory bundleFee, 
+        Amount stakingAmount, 
+        Seconds lifetime, 
+        bytes calldata filter
+    )
+        external
+        override
+        restricted
+        returns(NftId bundleNftId)
+    {
+        _checkNftType(poolNftId, POOL());
+
+        // register bundle with registry
+        bundleNftId = _registryService.registerBundle(
+            IRegistry.ObjectInfo(
+                NftIdLib.zero(), 
+                poolNftId,
+                BUNDLE(),
+                false, // intercepting property for bundles is defined on pool
+                address(0),
+                owner,
+                "" // bundle data to be stored in registry
+            )
+        );
+
+        // create bundle info in instance
+        InstanceStore instanceStore = instance.getInstanceStore();
+        instanceStore.createBundle(
+            bundleNftId, 
+            IBundle.BundleInfo({
+                poolNftId: poolNftId,
+                fee: bundleFee,
+                filter: filter,
+                activatedAt: TimestampLib.blockTimestamp(),
+                expiredAt: TimestampLib.blockTimestamp().addSeconds(lifetime),
+                closedAt: zeroTimestamp()
+            })
+        );
+
+        if (stakingAmount.gtz()) {
+            // bundle book keeping
+            _componentService.increaseBundleBalance(
+                instanceStore, 
+                bundleNftId, 
+                stakingAmount, 
+                AmountLib.zero()); // fee amount
+        }
+
+        // put bundle under bundle managemet
+        BundleSet bundleManager = instance.getBundleSet();
+        bundleManager.add(bundleNftId);
+        // TODO add logging
+    }
+
+
+    // the bundle MUST be unlocked (active) for linking (underwriting) and registered with this instance
+    function lockCollateral(
+        IInstance instance,
+        NftId policyNftId, 
+        NftId bundleNftId, 
+        Amount collateralAmount // required local amount to collateralize policy
+    ) 
+        external
+        virtual
+        restricted()
+    {
+        _checkNftType(policyNftId, POLICY());
+        _checkNftType(bundleNftId, BUNDLE());
+
+        InstanceReader instanceReader = instance.getInstanceReader();
+
+        {
+            StateId bundleState = instance.getInstanceReader().getBundleState(bundleNftId);
+            IBundle.BundleInfo memory bundleInfo = instanceReader.getBundleInfo(bundleNftId);
+
+            // ensure bundle is active and not yet expired
+            if(bundleState != ACTIVE() || bundleInfo.expiredAt < TimestampLib.blockTimestamp()) {
+                revert ErrorBundleServiceBundleNotOpen(bundleNftId, bundleState, bundleInfo.expiredAt);
+            }
+        }
+
+        InstanceStore instanceStore = instance.getInstanceStore();
+
+        {
+            // ensure bundle capacity is sufficent to collateralize policy
+            (
+                Amount balanceAmount,
+                Amount lockedAmount,
+                Amount feeAmount
+            ) = instanceStore.getAmounts(bundleNftId);
+
+            Amount capacity = balanceAmount - (lockedAmount + feeAmount);
+            if(capacity < collateralAmount) {
+                revert ErrorBundleServiceCapacityInsufficient(bundleNftId, capacity, collateralAmount);
+            }
+        }
+
+        // updated locked amount
+        instanceStore.increaseLocked(bundleNftId, collateralAmount);
+        
+        // link policy to bundle in bundle manger
+        _linkPolicy(instance, policyNftId);
+    }
+
+
+    function lock(NftId bundleNftId) 
+        external
+        virtual
+    {
+        _checkNftType(bundleNftId, BUNDLE());
+
+        (,, IInstance instance) = _getAndVerifyActiveComponent(POOL());
+
+        // udpate bundle state
+        instance.getInstanceStore().updateBundleState(bundleNftId, PAUSED());
+
+        // update set of active bundles
+        BundleSet bundleManager = instance.getBundleSet();
+        bundleManager.lock(bundleNftId);
+
+        emit LogBundleServiceBundleLocked(bundleNftId);
+    }
+
+
+    function unlock(NftId bundleNftId) 
+        external
+        virtual
+    {
+        _checkNftType(bundleNftId, BUNDLE());
+
+        (,, IInstance instance) = _getAndVerifyActiveComponent(POOL());
+
+        // udpate bundle state
+        instance.getInstanceStore().updateBundleState(bundleNftId, ACTIVE());
+
+        // update set of active bundles
+        BundleSet bundleManager = instance.getBundleSet();
+        bundleManager.unlock(bundleNftId);
+
+        emit LogBundleServiceBundleActivated(bundleNftId);
+    }
+
+
+    function close(
+        IInstance instance,
+        NftId bundleNftId
+    ) 
+        external
+        virtual
+        restricted
+        returns (Amount unstakedAmount, Amount feeAmount)
+    {
+        _checkNftType(bundleNftId, BUNDLE());
+
+        InstanceReader instanceReader = instance.getInstanceReader();
+
+        // ensure no open policies attached to bundle
+        BundleSet bundleManager = instance.getBundleSet();
+        uint256 openPolicies = bundleManager.activePolicies(bundleNftId);
+        if(openPolicies > 0) {
+            revert ErrorBundleServiceBundleWithOpenPolicies(bundleNftId, openPolicies);
+        }
+
+        {
+            // update bundle state
+            InstanceStore instanceStore = instance.getInstanceStore();
+            instanceStore.updateBundleState(bundleNftId, CLOSED());
+            bundleManager.lock(bundleNftId);
+
+            // decrease bundle counters
+            Amount balanceAmountWithFees = instanceReader.getBalanceAmount(bundleNftId);
+            feeAmount = instanceReader.getFeeAmount(bundleNftId);
+            unstakedAmount = balanceAmountWithFees - feeAmount;
+            _componentService.decreaseBundleBalance(instanceStore, bundleNftId, unstakedAmount, feeAmount);
+        }
+    }
+
+    /// @inheritdoc IBundleService
+    function stake(
+        IInstance instance,
+        NftId bundleNftId, 
+        Amount amount
+    ) 
+        external 
+        virtual
+        // TODO: restricted() (once #462 is done)
+    {
+        _checkNftType(bundleNftId, BUNDLE());
+
+        IBundle.BundleInfo memory bundleInfo = instance.getInstanceReader().getBundleInfo(bundleNftId);
+        StateId bundleState = instance.getInstanceReader().getBundleState(bundleNftId);
+
+        if( (bundleState != ACTIVE() && bundleState != PAUSED()) // locked bundles can be staked
+            || bundleInfo.expiredAt < TimestampLib.blockTimestamp() 
+            || bundleInfo.closedAt.gtz()) {
+            revert ErrorBundleServiceBundleNotOpen(bundleNftId, bundleState, bundleInfo.expiredAt);
+        }
+
+        _componentService.increaseBundleBalance(
+            instance.getInstanceStore(), 
+            bundleNftId, 
+            amount, 
+            AmountLib.zero());
+    }
+
+    /// @inheritdoc IBundleService
+    function unstake(
+        IInstance instance, 
+        NftId bundleNftId, 
+        Amount amount
+    ) 
+        external 
+        virtual
+        // TODO: restricted() (once #462 is done)
+        returns (Amount unstakedAmount)
+    {
+        _checkNftType(bundleNftId, BUNDLE());
+
+        InstanceStore instanceStore = instance.getInstanceStore();
+        (
+            Amount balanceAmount,
+            Amount lockedAmount,
+            Amount feeAmount
+        ) = instanceStore.getAmounts(bundleNftId);
+
+        unstakedAmount = amount;
+        Amount availableAmount = balanceAmount - (lockedAmount + feeAmount);
+
+        // if amount is max, then unstake all available 
+        if (amount.gte(AmountLib.max())) {
+            unstakedAmount = availableAmount;
+        }
+        
+        // ensure unstaked amount does not exceed available amount
+        if (unstakedAmount > availableAmount) {
+            revert ErrorBundleServiceUnstakeAmountExceedsLimit(amount, availableAmount);
+        }
+
+        _componentService.decreaseBundleBalance(
+            instanceStore, 
+            bundleNftId, 
+            unstakedAmount, 
+            AmountLib.zero());
+    }
+
+    /// @inheritdoc IBundleService
+    function extend(NftId bundleNftId, Seconds lifetimeExtension) 
+        external 
+        virtual
+        // TODO: restricted() (once #462 is done)
+        returns (Timestamp extendedExpiredAt) 
+    {
+        _checkNftType(bundleNftId, BUNDLE());
+
+        (NftId poolNftId,, IInstance instance) = _getAndVerifyActiveComponent(POOL());
+        IBundle.BundleInfo memory bundleInfo = instance.getInstanceReader().getBundleInfo(bundleNftId);
+        StateId bundleState = instance.getInstanceReader().getBundleState(bundleNftId);
+
+        // ensure bundle belongs to the pool
+        if (bundleInfo.poolNftId != poolNftId) {
+            revert ErrorBundleServiceBundlePoolMismatch(bundleNftId, bundleInfo.poolNftId, poolNftId);
+        }
+
+        // ensure bundle is active and not yet expired
+        if(bundleState != ACTIVE() || bundleInfo.expiredAt < TimestampLib.blockTimestamp()) {
+            revert ErrorBundleServiceBundleNotOpen(bundleNftId, bundleState, bundleInfo.expiredAt);
+        }
+
+        if (lifetimeExtension.eqz()) {
+            revert ErrorBundleServiceExtensionLifetimeIsZero();
+        }
+
+        bundleInfo.expiredAt = bundleInfo.expiredAt.addSeconds(lifetimeExtension);
+        instance.getInstanceStore().updateBundle(bundleNftId, bundleInfo, KEEP_STATE());
+
+        emit LogBundleServiceBundleExtended(bundleNftId, lifetimeExtension, bundleInfo.expiredAt);
+
+        return bundleInfo.expiredAt;
+    }
+
+
+    function releaseCollateral(
+        IInstance instance,
+        NftId policyNftId, 
+        NftId bundleNftId, 
+        Amount collateralAmount
+    ) 
+        external
+        virtual
+        restricted()
+    {
+        _checkNftType(policyNftId, POLICY());
+        _checkNftType(bundleNftId, BUNDLE());
+
+        instance.getInstanceStore().decreaseLocked(bundleNftId, collateralAmount);
+    }
+
+    /// @dev unlinks policy from bundle
+    function unlinkPolicy(
+        IInstance instance, 
+        NftId policyNftId
+    ) 
+        external
+        virtual
+        restricted
+    {
+        _checkNftType(policyNftId, POLICY());
+
+        // ensure policy is closeable
+        if (!policyIsCloseable(instance, policyNftId)) {
+            revert ErrorBundleServicePolicyNotCloseable(policyNftId);
+        }
+
+        instance.getBundleSet().unlinkPolicy(policyNftId);
+    }
+
+    /// @inheritdoc IBundleService
+    function withdrawBundleFees(NftId bundleNftId, Amount amount) 
+        public 
+        virtual
+        // TODO: restricted() (once #462 is done)
+        returns (Amount withdrawnAmount) 
+    {
+        _checkNftType(bundleNftId, BUNDLE());
+
+        (NftId poolNftId,, IInstance instance) = _getAndVerifyActiveComponent(POOL());
+        InstanceReader reader = instance.getInstanceReader();
+        
+        IComponents.ComponentInfo memory poolInfo = reader.getComponentInfo(poolNftId);
+        address poolWallet = poolInfo.wallet;
+        
+        // IBundle.BundleInfo memory bundleInfo = reader.getBundleInfo(bundleNftId);
+        
+        // determine withdrawn amount
+        withdrawnAmount = amount;
+        if (withdrawnAmount.gte(AmountLib.max())) {
+            withdrawnAmount = reader.getFeeAmount(bundleNftId);
+        } else {
+            if (withdrawnAmount.gt(reader.getFeeAmount(bundleNftId))) {
+                revert ErrorBundleServiceFeesWithdrawAmountExceedsLimit(withdrawnAmount, reader.getFeeAmount(bundleNftId));
+            }
+        }
+
+        // decrease fee counters by withdrawnAmount
+        {
+            InstanceStore store = instance.getInstanceStore();
+            // decrease fee amount of the bundle
+            _componentService.decreaseBundleBalance(store, bundleNftId, AmountLib.zero(), withdrawnAmount);
+            // decrease pool balance 
+            _componentService.decreasePoolBalance(store, poolNftId, withdrawnAmount, AmountLib.zero());
+        }
+
+        // transfer amount to bundle owner
+        {
+            address owner = getRegistry().ownerOf(bundleNftId);
+            emit LogBundleServiceFeesWithdrawn(bundleNftId, owner, address(poolInfo.token), withdrawnAmount);
+            poolInfo.tokenHandler.distributeTokens(poolWallet, owner, withdrawnAmount);
+        }
+    }
+
+    /// @inheritdoc IBundleService
+    function policyIsCloseable(IInstance instance, NftId policyNftId)
+        public
+        view
+        returns (bool isCloseable)
+    {
+        _checkNftType(policyNftId, POLICY());
+
+        IPolicy.PolicyInfo memory info = instance.getInstanceReader().getPolicyInfo(policyNftId);
+        
+        if (info.productNftId.eqz()) { return false; } // not closeable: policy does not exist (or does not belong to this instance)
+        if (info.activatedAt.eqz()) { return false; } // not closeable: not yet activated
+        if (info.closedAt.gtz()) { return false; } // not closeable: already closed
+        if (info.openClaimsCount > 0) { return false; } // not closeable: has open claims
+
+        // closeable: if sum of claims matches sum insured a policy may be closed prior to the expiry date
+        if (info.claimAmount == info.sumInsuredAmount) { return true; }
+
+        // not closeable: not yet expired
+        if (TimestampLib.blockTimestamp() < info.expiredAt) { return false; }
+
+        // all conditionsl to close the policy are met
+        return true; 
+    }
+
+    /// @dev links policy to bundle
+    function _linkPolicy(IInstance instance, NftId policyNftId) 
+        internal
+    {
+        InstanceReader instanceReader = instance.getInstanceReader();
+        IPolicy.PolicyInfo memory policyInfo = instanceReader.getPolicyInfo(policyNftId);
+
+        // ensure policy has not yet been activated in a previous tx already
+        if (policyInfo.activatedAt.gtz() && policyInfo.activatedAt < TimestampLib.blockTimestamp()) {
+            revert BundleSet.ErrorBundleSetPolicyAlreadyActivated(policyNftId);
+        }
+        
+        BundleSet bundleManager = instance.getBundleSet();
+        bundleManager.linkPolicy(policyNftId);
+    }
+
+    function _getDomain() internal pure override returns(ObjectType) {
+        return BUNDLE();
+    }
+}

package/contracts/pool/BundleServiceManager.sol

@@ -0,0 +1,39 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IVersionable} from "../upgradeability/IVersionable.sol";
+import {ProxyManager} from "../upgradeability/ProxyManager.sol";
+import {BundleService} from "./BundleService.sol";
+
+contract BundleServiceManager is ProxyManager {
+
+    BundleService private _bundleService;
+
+    /// @dev initializes proxy manager with pool service implementation 
+    constructor(
+        address authority, 
+        address registry,
+        bytes32 salt
+    ) 
+    {
+        BundleService svc = new BundleService{salt: salt}();
+        bytes memory data = abi.encode(registry, authority);
+        IVersionable versionable = initialize(
+            registry,
+            address(svc), 
+            data,
+            salt);
+
+        _bundleService = BundleService(address(versionable));
+    }
+
+    //--- view functions ----------------------------------------------------//
+    function getBundleService()
+        external
+        view
+        returns (BundleService)
+    {
+        return _bundleService;
+    }
+
+}

package/contracts/pool/IBundleService.sol

@@ -0,0 +1,143 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Amount} from "../type/Amount.sol";
+import {NftId} from "../type/NftId.sol";
+import {Fee} from "../type/Fee.sol";
+import {IService} from "../shared/IService.sol";
+import {IBundle} from "../instance/module/IBundle.sol";
+import {IInstance} from "../instance/IInstance.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {StateId} from "../type/StateId.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+
+interface IBundleService is IService {
+
+    event LogBundleServiceBundleActivated(NftId bundleNftId);
+    event LogBundleServiceBundleLocked(NftId bundleNftId);
+
+    error ErrorBundleServiceInsufficientAllowance(address bundleOwner, address tokenHandlerAddress, Amount amount);
+    error ErrorBundleServiceBundleNotOpen(NftId bundleNftId, StateId state, Timestamp expiredAt);
+    error ErrorBundleServiceCapacityInsufficient(NftId bundleNftId, Amount capacityAmount, Amount collateralAmount);
+    error ErrorBundleServiceBundleWithOpenPolicies(NftId bundleNftId, uint256 openPoliciesCount);
+
+    error ErrorBundleServiceBundleUnknown(NftId bundleNftId);
+    error ErrorBundleServiceBundlePoolMismatch(NftId bundleNftId, NftId expectedPool, NftId actualPool);
+
+    error ErrorBundleServicePolicyNotCloseable(NftId policyNftId);
+
+    error ErrorBundleServiceFeesWithdrawAmountExceedsLimit(Amount amount, Amount limit);
+    
+    error ErrorBundleServiceUnstakeAmountExceedsLimit(Amount amount, Amount limit);
+
+    error ErrorBundleServiceExtensionLifetimeIsZero();
+
+    event LogBundleServiceFeesWithdrawn(NftId bundleNftId, address recipient, address tokenAddress, Amount amount);
+    event LogBundleServiceBundleExtended(NftId bundleNftId, Seconds lifetimeExtension, Timestamp extendedExpiredAt);
+
+    /// @dev create a new bundle for the specified attributes
+    /// may only be called by pool service
+    function create(
+        IInstance instance, // instance relevant for bundle
+        NftId poolNftId, // the pool the bundle will be linked to
+        address owner, // initial bundle owner
+        Fee memory fee, // fees deducted from premium that go to bundle owner
+        Amount stakingAmount, // staking amount - staking fees result in initial bundle capital
+        Seconds lifetime, // initial duration for which new policies are covered
+        bytes calldata filter // optional use case specific criteria that define if a policy may be covered by this bundle
+    )
+        external 
+        returns(NftId bundleNftId); // the nft id of the newly created bundle
+
+
+    /// @dev increase bundle stakes by the specified amount. bundle must not be expired or closed
+    /// may only be called by the pool service
+    function stake(IInstance instance, NftId bundleNftId, Amount amount) external;
+
+    /// @dev decrease bundle stakes by the specified amount
+    /// may only be called by the pool service
+    /// @param instance the instance relevant for the bundle
+    /// @param bundleNftId the bundle nft id
+    /// @param amount the amount to unstake (set to AmountLib.max() to unstake all available stakes)
+    /// @return unstakedAmount the effective unstaked amount
+    function unstake(IInstance instance, NftId bundleNftId, Amount amount) external returns (Amount unstakedAmount);
+
+    /// @dev extend the lifetime of the bundle by the specified time in seconds
+    function extend(NftId bundleNftId, Seconds lifetimeExtension) external returns (Timestamp extendedExpiredAt);
+
+    /// @dev locks the specified bundle, locked bundles are not available to collateralize new policies
+    /// only active bundles may be locked
+    /// may only be called by registered and unlocked pool components
+    function lock(NftId bundleNftId) external;
+
+    /// @dev activates the specified bundle
+    /// only locked bundles may be unlocked
+    /// may only be called by registered and unlocked pool components
+    function unlock(NftId bundleNftId) external;
+
+    /// @dev closes the specified bundle
+    /// only open bundles (active or locked) may be closed
+    /// to close a bundle it may not have any non-closed polices attached to it
+    /// may only be called by registered and unlocked pool components
+    /// @return balanceAmount the unstaked amount that was remaining in the bundle
+    /// @return feeAmount the fee amount that was remaining for the bundle
+    function close(
+        IInstance instance, 
+        NftId bundleNftId
+    ) external returns (Amount balanceAmount, Amount feeAmount);
+
+    /// @dev set bundle fee to provided value
+    /// may only be called by registered and unlocked pool components
+    function setFee(
+        NftId bundleNftId,
+        Fee memory fee
+    ) external;
+
+
+    /// @dev locks the specified collateral in the bundle
+    /// the locked collateral is added to the bundle locked capital
+    /// the bundles' fees are updated with the fees for this premium
+    /// the premium (minus bundle fee) is added to the bundle capital
+    /// may only be called by pool service
+    function lockCollateral(
+        IInstance instance, 
+        NftId policyNftId, 
+        NftId bundleNftId, 
+        Amount collateralAmount
+    ) external;
+
+
+    /// @dev releases the specified collateral in the bundle
+    /// may only be called by pool service
+    function releaseCollateral(
+        IInstance instance, 
+        NftId policyNftId, 
+        NftId bundleNftId, 
+        Amount collateralAmount
+    ) external;
+
+    /// @dev unlink policy from bundle
+    /// policy may only be unlinked if policy is closeable
+    /// may only be called by pool service
+    function unlinkPolicy(
+        IInstance instance, 
+        NftId policyNftId
+    ) external;
+
+    // FIXME: move to pool service
+    /// @dev Withdraw bundle feeds for the given bundle
+    /// @param bundleNftId the bundle Nft Id
+    /// @param amount the amount to withdraw. If set to AMOUNT_MAX, the full commission available is withdrawn
+    /// @return withdrawnAmount the effective withdrawn amount
+    function withdrawBundleFees(NftId bundleNftId, Amount amount) external returns (Amount withdrawnAmount);
+
+    /// @dev returns true iff policy may be closed
+    /// a policy can be closed all conditions below are met
+    /// - policy exists
+    /// - has been activated
+    /// - is not yet closed
+    /// - has no open claims
+    /// - claim amount matches sum insured amount or is expired
+    function policyIsCloseable(IInstance instance, NftId policyNftId) external view returns (bool isCloseable);
+
+}