@etherisc/gif-next 0.0.2-f619be3-760 → 0.0.2-f61d0d1-146

package/contracts/type/Key32.sol

@@ -0,0 +1,50 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ObjectType} from "./ObjectType.sol";
+
+type Key32 is bytes32;
+type KeyId is bytes31;
+
+// type bindings
+using {
+    eqKey32 as ==, 
+    neKey32 as !=,
+    Key32Lib.toKeyId,
+    Key32Lib.toObjectType
+} for Key32 global;
+
+// @dev Returns true iff keys are identical
+function eqKey32(Key32 a, Key32 b) pure returns (bool isSame) {
+    return Key32.unwrap(a) == Key32.unwrap(b);
+}
+
+// @dev Returns true iff keys are different
+function neKey32(Key32 a, Key32 b) pure returns (bool isDifferent) {
+    return Key32.unwrap(a) != Key32.unwrap(b);
+}
+
+library Key32Lib {
+
+    uint8 public constant TYPE_SHIFT = 31 * 8;
+    uint8 public constant ID_SHIFT = uint8(32 * 8 - TYPE_SHIFT);
+    bytes32 public constant TYPE_MASK = bytes32(bytes1(type(uint8).max)); // [32] byte in bytes32
+    bytes32 public constant ID_MASK = bytes32(~TYPE_MASK); // [0..31] bytes in bytes32
+
+    function toKey32(ObjectType objectType, KeyId id) public pure returns (Key32) {
+        uint256 uintObjectType = ObjectType.unwrap(objectType);
+        uint256 uintId = uint248(KeyId.unwrap(id));
+        uint256 uintKey = (uintObjectType << TYPE_SHIFT) + uintId;
+        return Key32.wrap(bytes32(uintKey));
+    }
+
+    function toObjectType(Key32 key) public pure returns (ObjectType objectType) {
+        bytes32 key32 = Key32.unwrap(key);
+        objectType = ObjectType.wrap(uint8(uint256(key32 & TYPE_MASK) >> TYPE_SHIFT));
+    }
+
+    function toKeyId(Key32 key) public pure returns (KeyId id) {
+        bytes32 key32 = Key32.unwrap(key);
+        id = KeyId.wrap(bytes31((key32 & ID_MASK) << ID_SHIFT));
+    }
+}

package/contracts/type/Key32Set.sol

@@ -0,0 +1,62 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Key32} from "../type/Key32.sol";
+
+// based on https://github.com/OpenZeppelin/openzeppelin-contracts/blob/master/contracts/utils/structs/EnumerableSet.sol
+library LibKey32Set {
+
+    struct Set {
+        Key32[] keys;
+        mapping(Key32 key => uint256 index) at;
+    }
+
+    error ErrorKey32SetAlreadyAdded(Key32 key);
+    error ErrorKey32SetNotInSet(Key32 key);
+
+
+    function add(Set storage set, Key32 key) external {
+        if (set.at[key] > 0) {
+            revert ErrorKey32SetAlreadyAdded(key);
+        }
+
+        set.keys.push(key);
+        set.at[key] = set.keys.length;
+    }
+
+    function remove(Set storage set, Key32 key) external {
+        uint256 nftIdIndex = set.at[key];
+
+        if (nftIdIndex == 0) {
+            revert ErrorKey32SetNotInSet(key);
+        }
+
+        uint256 toDeleteIndex = nftIdIndex - 1;
+        uint256 lastIndex = set.keys.length - 1;
+
+        if (lastIndex != toDeleteIndex) {
+            Key32 lastId = set.keys[lastIndex];
+            set.keys[toDeleteIndex] = lastId;
+            set.at[lastId] = nftIdIndex; // Replace lastValue's index to valueIndex
+        }
+
+        set.keys.pop();
+        delete set.at[key];
+    }
+
+    function isEmpty(Set storage set) external view returns(bool empty) {
+        return set.keys.length == 0;
+    }
+
+    function contains(Set storage set, Key32 key) external view returns(bool inSet) {
+        return set.at[key] > 0;
+    }
+
+    function size(Set storage set) external view returns(uint256 length) {
+        return set.keys.length;
+    }
+
+    function getElementAt(Set storage set, uint256 index) external view returns(Key32 key) {
+        return set.keys[index];
+    }
+}

package/contracts/type/NftId.sol

@@ -0,0 +1,85 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Key32, KeyId, Key32Lib} from "./Key32.sol";
+import {ObjectType} from "./ObjectType.sol";
+
+// uint96 allows for chain ids up to 13 digits
+type NftId is uint96;
+
+// type bindings
+using {
+    eqNftId as ==, 
+    neNftId as !=, 
+    NftIdLib.toInt,
+    NftIdLib.gtz,
+    NftIdLib.eqz,
+    NftIdLib.eq,
+    NftIdLib.toKeyId,
+    NftIdLib.toKey32
+} for NftId global;
+
+// pure free functions for operators
+function eqNftId(NftId a, NftId b) pure returns (bool isSame) {
+    return NftIdLib.eq(a, b);
+}
+
+function neNftId(NftId a, NftId b) pure returns (bool isDifferent) {
+    return NftIdLib.ne(a, b);
+}
+
+// library functions that operate on user defined type
+library NftIdLib {
+
+    /// @dev the zero nft id
+    /// is never a valid nft id and implies a non-initialized value
+    function zero() public pure returns (NftId) {
+        return NftId.wrap(0);
+    }
+
+    /// @dev Converts the uint256 to a NftId.
+    function toNftId(uint256 id) public pure returns (NftId) {
+        return NftId.wrap(uint96(id));
+    }
+
+    /// @dev Converts the NftId to a uint256.
+    function toInt(NftId nftId) public pure returns (uint96) {
+        return uint96(NftId.unwrap(nftId));
+    }
+
+    /// @dev Returns true if the value is non-zero (> 0).
+    function gtz(NftId a) public pure returns (bool) {
+        return NftId.unwrap(a) > 0;
+    }
+
+    /// @dev Returns true if the value is zero (== 0).
+    function eqz(NftId a) public pure returns (bool) {
+        return NftId.unwrap(a) == 0;
+    }
+
+    /// @dev Returns true if the values are equal (==).
+    function eq(NftId a, NftId b) public pure returns (bool isSame) {
+        return NftId.unwrap(a) == NftId.unwrap(b);
+    }
+
+    /// @dev Returns true if the values are not equal (!=).
+    function ne(NftId a, NftId b) public pure returns (bool isSame) {
+        return NftId.unwrap(a) != NftId.unwrap(b);
+    }
+
+    /// @dev Returns the key32 value for the specified nft id and object type.
+    function toKey32(NftId id, ObjectType objectType) public pure returns (Key32 key) {
+        return Key32Lib.toKey32(objectType, toKeyId(id));
+    }
+
+    /// @dev Returns the key id value for the specified nft id
+    function toKeyId(NftId id) public pure returns (KeyId keyId) {
+        return KeyId.wrap(bytes31(uint248(NftId.unwrap(id))));
+    }
+
+    function toNftId(KeyId keyId) public pure returns (NftId nftId) {
+       uint248 keyIdInt = uint248(bytes31(KeyId.unwrap(keyId)));
+       assert(keyIdInt < type(uint96).max);
+       return NftId.wrap(uint96(keyIdInt));
+    }
+}

package/contracts/type/NftIdSet.sol

@@ -0,0 +1,62 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {NftId} from "../type/NftId.sol";
+
+// based on https://github.com/OpenZeppelin/openzeppelin-contracts/blob/master/contracts/utils/structs/EnumerableSet.sol
+library LibNftIdSet {
+
+    struct Set {
+        NftId[] ids;
+        mapping(NftId nftid => uint256 index) at;
+    }
+
+    error ErrorNftIdSetAlreadyAdded(NftId nftId);
+    error ErrorNftIdSetNotInSet(NftId nftId);
+
+
+    function add(Set storage set, NftId nftId) external {
+        if (set.at[nftId] > 0) {
+            revert ErrorNftIdSetAlreadyAdded(nftId);
+        }
+
+        set.ids.push(nftId);
+        set.at[nftId] = set.ids.length;
+    }
+
+    function remove(Set storage set, NftId nftId) external {
+        uint256 nftIdIndex = set.at[nftId];
+
+        if (nftIdIndex == 0) {
+            revert ErrorNftIdSetNotInSet(nftId);
+        }
+
+        uint256 toDeleteIndex = nftIdIndex - 1;
+        uint256 lastIndex = set.ids.length - 1;
+
+        if (lastIndex != toDeleteIndex) {
+            NftId lastId = set.ids[lastIndex];
+            set.ids[toDeleteIndex] = lastId;
+            set.at[lastId] = nftIdIndex; // Replace lastValue's index to valueIndex
+        }
+
+        set.ids.pop();
+        delete set.at[nftId];
+    }
+
+    function isEmpty(Set storage set) external view returns(bool empty) {
+        return set.ids.length == 0;
+    }
+
+    function contains(Set storage set, NftId nftId) external view returns(bool inSet) {
+        return set.at[nftId] > 0;
+    }
+
+    function size(Set storage set) external view returns(uint256 length) {
+        return set.ids.length;
+    }
+
+    function getElementAt(Set storage set, uint256 index) external view returns(NftId nftId) {
+        return set.ids[index];
+    }
+}

package/contracts/type/ObjectType.sol

@@ -0,0 +1,307 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {VersionPart} from "./Version.sol";
+
+type ObjectType is uint8;
+
+// type bindings
+using {
+    eqObjectType as ==,
+    neObjectType as !=,
+    ObjectTypeLib.toInt,
+    ObjectTypeLib.toName,
+    ObjectTypeLib.eqz,
+    ObjectTypeLib.eq,
+    ObjectTypeLib.gtz
+} for ObjectType global;
+
+
+//--- GIF object types/domains (rage: 1 - 99) -------------------------------//
+
+function PROTOCOL() pure returns (ObjectType) {
+    return ObjectType.wrap(1);
+}
+
+function REGISTRY() pure returns (ObjectType) {
+    return ObjectType.wrap(2);
+}
+
+function STAKING() pure returns (ObjectType) {
+    return ObjectType.wrap(3);
+}
+
+function RELEASE() pure returns (ObjectType) {
+    return ObjectType.wrap(6);
+}
+
+function ROLE() pure returns (ObjectType) {
+    return ObjectType.wrap(7);
+}
+
+function SERVICE() pure returns (ObjectType) {
+    return ObjectType.wrap(8);
+}
+
+function INSTANCE() pure returns (ObjectType) {
+    return ObjectType.wrap(10);
+}
+
+/// @dev Generic component object type.
+/// Component role id range is 11-19.
+/// Stick to this range for new component object types.
+function COMPONENT() pure returns (ObjectType) {
+    return ObjectType.wrap(11);
+}
+
+/// @dev Product object type.
+/// IMPORTANT the actual value has an influence on the corresponding role id (RoleIdLib.sol). 
+/// Do not change this value without updating the corresponding role id calculation.
+function PRODUCT() pure returns (ObjectType) {
+    return ObjectType.wrap(12);
+}
+
+function ORACLE() pure returns (ObjectType) {
+    return ObjectType.wrap(13);
+}
+
+function DISTRIBUTION() pure returns (ObjectType) {
+    return ObjectType.wrap(14);
+}
+
+function POOL() pure returns (ObjectType) {
+    return ObjectType.wrap(15);
+}
+
+/// @dev Application object type.
+/// Range for NFT objects created thorugh components is 20-29.
+function APPLICATION() pure returns (ObjectType) {
+    return ObjectType.wrap(20);
+}
+
+function POLICY() pure returns (ObjectType) {
+    return ObjectType.wrap(21);
+}
+
+function BUNDLE() pure returns (ObjectType) {
+    return ObjectType.wrap(22);
+}
+
+function DISTRIBUTOR() pure returns (ObjectType) {
+    return ObjectType.wrap(23);
+}
+
+/// @dev Stake object type.
+/// NFT object type is 30
+function STAKE() pure returns (ObjectType) {
+    return ObjectType.wrap(30);
+}
+
+/// @dev Staking target object type.
+function TARGET() pure returns (ObjectType) {
+    return ObjectType.wrap(31);
+}
+
+/// @dev Accounting object type.
+/// Range for non-NFT types created through components is 40+
+function ACCOUNTING() pure returns (ObjectType) {
+    return ObjectType.wrap(40);
+}
+
+function FEE() pure returns (ObjectType) {
+    return ObjectType.wrap(41);
+}
+
+function PRICE() pure returns (ObjectType) {
+    return ObjectType.wrap(42);
+}
+
+function PREMIUM() pure returns (ObjectType) {
+    return ObjectType.wrap(43);
+}
+
+function RISK() pure returns (ObjectType) {
+    return ObjectType.wrap(44);
+}
+
+function CLAIM() pure returns (ObjectType) {
+    return ObjectType.wrap(45);
+}
+
+function PAYOUT() pure returns (ObjectType) {
+    return ObjectType.wrap(46); 
+}
+
+function REQUEST() pure returns (ObjectType) {
+    return ObjectType.wrap(47);
+}
+
+function DISTRIBUTOR_TYPE() pure returns (ObjectType) {
+    return ObjectType.wrap(48);
+}
+
+function REFERRAL() pure returns (ObjectType) {
+    return ObjectType.wrap(49);
+}
+
+/// @dev Object type for GIF core target roles.
+function CORE() pure returns (ObjectType) {
+    return ObjectType.wrap(97);
+}
+
+/// @dev Object type for target roles of contracts outside the GIF framework.
+/// Example: Custom supporting contracts for a product component.
+function CUSTOM() pure returns (ObjectType) {
+    return ObjectType.wrap(98);
+}
+
+/// @dev Object type that includes any other object type.
+/// Note that eq()/'==' does not take this property into account.
+function ALL() pure returns (ObjectType) {
+    return ObjectType.wrap(99);
+}
+
+// other pure free functions for operators
+function eqObjectType(ObjectType a, ObjectType b) pure returns (bool isSame) {
+    return ObjectType.unwrap(a) == ObjectType.unwrap(b);
+}
+
+function neObjectType(ObjectType a, ObjectType b) pure returns (bool isSame) {
+    return ObjectType.unwrap(a) != ObjectType.unwrap(b);
+}
+
+// library functions that operate on user defined type
+library ObjectTypeLib {
+
+    function zero() public pure returns (ObjectType) {
+        return ObjectType.wrap(0);
+    }
+
+    /// @dev Converts the uint256 into ObjectType.
+    function toObjectType(uint256 objectType) public pure returns (ObjectType) {
+        return ObjectType.wrap(uint8(objectType));
+    }
+
+    /// @dev Converts the NftId to a uint256.
+    function toInt(ObjectType objectType) public pure returns (uint96) {
+        return uint96(ObjectType.unwrap(objectType));
+    }
+
+    /// @dev Returns true if the value is non-zero (> 0).
+    function gtz(ObjectType a) public pure returns (bool) {
+        return ObjectType.unwrap(a) > 0;
+    }
+
+    /// @dev Returns true if the value is zero (== 0).
+    function eqz(ObjectType a) public pure returns (bool) {
+        return ObjectType.unwrap(a) == 0;
+    }
+
+    /// @dev Returns true if the values are equal (==).
+    function eq(ObjectType a, ObjectType b) public pure returns (bool isSame) {
+        return ObjectType.unwrap(a) == ObjectType.unwrap(b);
+    }
+
+    /// @dev Returns true if the values are not equal (!=).
+    function ne(ObjectType a, ObjectType b) public pure returns (bool isSame) {
+        return ObjectType.unwrap(a) != ObjectType.unwrap(b);
+    }
+
+    /// @dev Returns the type/domain name for the provided object type
+    function toName(ObjectType objectType) public pure returns (string memory name) {
+        if (objectType == REGISTRY()) {
+            return "Registry";
+        } else if (objectType == STAKING()) {
+            return "Staking";
+        } else if (objectType == RELEASE()) {
+            return "Release";
+        } else if (objectType == INSTANCE()) {
+            return "Instance";
+        } else if (objectType == COMPONENT()) {
+            return "Component";
+        } else if (objectType == PRODUCT()) {
+            return "Product";
+        } else if (objectType == ORACLE()) {
+            return "Oracle";
+        } else if (objectType == DISTRIBUTION()) {
+            return "Distribution";
+        } else if (objectType == POOL()) {
+            return "Pool";
+        } else if (objectType == APPLICATION()) {
+            return "Application";
+        } else if (objectType == POLICY()) {
+            return "Policy";
+        } else if (objectType == CLAIM()) {
+            return "Claim";
+        } else if (objectType == PRICE()) {
+            return "Price";
+        } else if (objectType == BUNDLE()) {
+            return "Bundle";
+        } else if (objectType == RISK()) {
+            return "Risk";
+        } else if (objectType == ACCOUNTING()) {
+            return "Accounting";
+        }
+
+        // fallback: ObjectType<obect-type-int>
+        return string(
+            abi.encodePacked(
+                "ObjectType",
+                toString(
+                    toInt(objectType))));
+    }
+
+    // TODO move to IService
+    function toVersionedName(
+        string memory name, 
+        string memory suffix, 
+        VersionPart release
+    )
+        external
+        pure
+        returns (string memory versionedName)
+    {
+        string memory versionName = "V0";
+
+        if (release.toInt() >= 10) {
+            versionName = "V";
+        }
+
+        versionedName = string(
+            abi.encodePacked(
+                name,
+                suffix,
+                versionName,
+                release.toString()));
+    }
+
+    /// @dev returns the provied int as a string
+    function toString(uint256 value) public pure returns (string memory name) {
+
+        if (value == 0) {
+            return "0";
+        }
+
+        uint256 temp = value;
+        uint256 digits = 0;
+        while (temp != 0) {
+            digits++;
+            temp /= 10;
+        }
+
+        bytes memory buffer = new bytes(digits);
+        uint256 index = digits - 1;
+
+        temp = value;
+        while (temp != 0) {
+            buffer[index] = bytes1(uint8(48 + temp % 10));
+            temp /= 10;
+
+            if (index > 0) {
+                index--;
+            }
+        }
+
+        return string(buffer);
+    }
+}

package/contracts/type/PayoutId.sol

@@ -0,0 +1,82 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+// uint40 allows for 65'535 claims with 16'777'216 payouts each per policy
+type PayoutId is uint40;
+
+import {ClaimId} from "./ClaimId.sol";
+import {PAYOUT} from "./ObjectType.sol";
+import {Key32, KeyId, Key32Lib} from "./Key32.sol";
+import {NftId} from "./NftId.sol";
+
+// type bindings
+using {
+    eqPayoutId as ==, 
+    nePayoutId as !=, 
+    PayoutIdLib.eqz,
+    PayoutIdLib.gtz,
+    PayoutIdLib.toInt,
+    PayoutIdLib.toClaimId,
+    PayoutIdLib.toPayoutNo,
+    PayoutIdLib.toKey32
+} for PayoutId global;
+
+
+// pure free functions for operators
+function eqPayoutId(PayoutId a, PayoutId b) pure returns (bool isSame) {
+    return PayoutId.unwrap(a) == PayoutId.unwrap(b);
+}
+
+function nePayoutId(PayoutId a, PayoutId b) pure returns (bool isDifferent) {
+    return PayoutId.unwrap(a) != PayoutId.unwrap(b);
+}
+
+// library functions that operate on user defined type
+library PayoutIdLib {
+    /// @dev Converts the PayoutId to a uint.
+    function zero() public pure returns (PayoutId) {
+        return PayoutId.wrap(0);
+    }
+
+    /// @dev Converts an uint into a PayoutId.
+    function toPayoutId(ClaimId claimId, uint24 payoutNo) public pure returns (PayoutId) {
+        return PayoutId.wrap((uint40(ClaimId.unwrap(claimId)) << 24) + payoutNo);
+    }
+
+    function toClaimId(PayoutId payoutId) public pure returns (ClaimId) {
+        return ClaimId.wrap(uint16(PayoutId.unwrap(payoutId) >> 24));
+    }
+
+    function toPayoutNo(PayoutId payoutId) public pure returns (uint24) {
+        return uint24(PayoutId.unwrap(payoutId) & 16777215);
+    }
+
+    /// @dev Converts the PayoutId to a uint.
+    function toInt(PayoutId a) public pure returns (uint40) {
+        return PayoutId.unwrap(a);
+    }
+
+    /// @dev Returns true if the value is non-zero (> 0).
+    function gtz(PayoutId a) public pure returns (bool) {
+        return PayoutId.unwrap(a) > 0;
+    }
+
+    /// @dev Returns true if the value is zero (== 0).
+    function eqz(PayoutId a) public pure returns (bool) {
+        return PayoutId.unwrap(a) == 0;
+    }
+
+    /// @dev Converts the PayoutId and NftId to a Key32.
+    function toKey32(PayoutId payoutId, NftId policyNftId) public pure returns (Key32) {
+        return Key32Lib.toKey32(PAYOUT(), toKeyId(payoutId, policyNftId));
+    }
+
+    /// @dev Converts the PayoutId and NftId to a Key32.
+    function toKeyId(PayoutId payoutId, NftId policyNftId) public pure returns (KeyId) {
+        return KeyId.wrap(
+            bytes31(
+                bytes15(
+                    uint120(
+                        (NftId.unwrap(policyNftId) << 40) + PayoutId.unwrap(payoutId)))));
+    }
+}