@etherisc/gif-next 0.0.2-f0d86c2-077 → 0.0.2-f13c010-035

package/contracts/instance/InstanceAuthorizationV3.sol

@@ -0,0 +1,194 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {
+     PRODUCT, ORACLE, POOL, INSTANCE, COMPONENT, DISTRIBUTION, APPLICATION, POLICY, CLAIM, BUNDLE
+} from "../../contracts/type/ObjectType.sol";
+
+import {BundleSet} from "../instance/BundleSet.sol"; 
+import {IAccess} from "../authorization/IAccess.sol";
+import {Instance} from "../instance/Instance.sol";
+import {InstanceAdmin} from "../instance/InstanceAdmin.sol";
+import {InstanceStore} from "../instance/InstanceStore.sol";
+import {Authorization} from "../authorization/Authorization.sol";
+
+
+contract InstanceAuthorizationV3
+     is Authorization
+{
+
+     string public constant INSTANCE_ROLE_NAME = "InstanceRole";
+
+     string public constant INSTANCE_TARGET_NAME = "Instance";
+     string public constant INSTANCE_STORE_TARGET_NAME = "InstanceStore";
+     string public constant INSTANCE_ADMIN_TARGET_NAME = "InstanceAdmin";
+     string public constant BUNDLE_SET_TARGET_NAME = "BundleSet";
+
+     constructor() Authorization(INSTANCE_TARGET_NAME) {}
+
+
+     function _setupRoles()
+          internal
+          override
+     {
+          // empty implementation
+     }
+
+
+     function _setupTargets()
+          internal
+          override
+     {
+          // instance target
+          _addTargetWithRole(
+               INSTANCE_TARGET_NAME, 
+               _toTargetRoleId(INSTANCE()),
+               INSTANCE_ROLE_NAME);
+
+          // instance supporting targets
+          _addTarget(INSTANCE_STORE_TARGET_NAME);
+          _addTarget(INSTANCE_ADMIN_TARGET_NAME);
+          _addTarget(BUNDLE_SET_TARGET_NAME);
+
+          // service targets relevant to instance
+          _addServiceTargetWithRole(INSTANCE());
+          _addServiceTargetWithRole(COMPONENT());
+          _addServiceTargetWithRole(DISTRIBUTION());
+          _addServiceTargetWithRole(ORACLE());
+          _addServiceTargetWithRole(POOL());
+          _addServiceTargetWithRole(BUNDLE());
+          _addServiceTargetWithRole(PRODUCT());
+          _addServiceTargetWithRole(APPLICATION());
+          _addServiceTargetWithRole(POLICY());
+          _addServiceTargetWithRole(CLAIM());
+     }
+
+
+     function _setupTargetAuthorizations()
+          internal
+          override
+     {
+          _setupInstanceAuthorization();
+          _setupInstanceAdminAuthorization();
+          _setupInstanceStoreAuthorization();
+          _setupBundleSetAuthorization();
+
+     }
+
+
+     function _setupBundleSetAuthorization()
+          internal
+     {
+          IAccess.FunctionInfo[] storage functions;
+
+          // authorize bundle service role
+          functions = _authorizeForTarget(BUNDLE_SET_TARGET_NAME, getServiceRole(BUNDLE()));
+          _authorize(functions, BundleSet.linkPolicy.selector, "linkPolicy");
+          _authorize(functions, BundleSet.unlinkPolicy.selector, "unlinkPolicy");
+          _authorize(functions, BundleSet.add.selector, "add");
+          _authorize(functions, BundleSet.lock.selector, "lock");
+          _authorize(functions, BundleSet.unlock.selector, "unlock");
+     }
+
+
+     function _setupInstanceAuthorization()
+          internal
+     {
+          IAccess.FunctionInfo[] storage functions;
+
+          // authorize instance service role
+          functions = _authorizeForTarget(INSTANCE_TARGET_NAME, getServiceRole(INSTANCE()));
+          _authorize(functions, Instance.setInstanceReader.selector, "setInstanceReader");
+     }
+
+
+     function _setupInstanceAdminAuthorization()
+          internal
+     {
+          IAccess.FunctionInfo[] storage functions;
+
+          // authorize instance role
+          functions = _authorizeForTarget(INSTANCE_ADMIN_TARGET_NAME, _toTargetRoleId(INSTANCE()));
+          _authorize(functions, InstanceAdmin.grantRole.selector, "grantRole");
+
+          // authorize instance service role
+          // functions = _authorizeForTarget(INSTANCE_ADMIN_TARGET_NAME, getServiceRole(INSTANCE()));
+     }
+
+
+     function _setupInstanceStoreAuthorization()
+          internal
+     {
+          IAccess.FunctionInfo[] storage functions;
+
+          // authorize component service role
+          functions = _authorizeForTarget(INSTANCE_STORE_TARGET_NAME, getServiceRole(COMPONENT()));
+          _authorize(functions, InstanceStore.createComponent.selector, "createComponent");
+          _authorize(functions, InstanceStore.updateComponent.selector, "updateComponent");
+          _authorize(functions, InstanceStore.createPool.selector, "createPool");
+          _authorize(functions, InstanceStore.createProduct.selector, "createProduct");
+          _authorize(functions, InstanceStore.updateProduct.selector, "updateProduct");
+          _authorize(functions, InstanceStore.increaseBalance.selector, "increaseBalance");
+          _authorize(functions, InstanceStore.decreaseBalance.selector, "decreaseBalance");
+          _authorize(functions, InstanceStore.increaseFees.selector, "increaseFees");
+          _authorize(functions, InstanceStore.decreaseFees.selector, "decreaseFees");
+
+          // authorize distribution service role
+          functions = _authorizeForTarget(INSTANCE_STORE_TARGET_NAME, getServiceRole(DISTRIBUTION()));
+          _authorize(functions, InstanceStore.createDistributorType.selector, "createDistributorType");
+          _authorize(functions, InstanceStore.updateDistributorType.selector, "updateDistributorType");
+          _authorize(functions, InstanceStore.updateDistributorTypeState.selector, "updateDistributorTypeState");
+          _authorize(functions, InstanceStore.createDistributor.selector, "createDistributor");
+          _authorize(functions, InstanceStore.updateDistributor.selector, "updateDistributor");
+          _authorize(functions, InstanceStore.updateDistributorState.selector, "updateDistributorState");
+          _authorize(functions, InstanceStore.createReferral.selector, "createReferral");
+          _authorize(functions, InstanceStore.updateReferral.selector, "updateReferral");
+          _authorize(functions, InstanceStore.updateReferralState.selector, "updateReferralState");
+
+          // authorize oracle service role
+          functions = _authorizeForTarget(INSTANCE_STORE_TARGET_NAME, getServiceRole(ORACLE()));
+          _authorize(functions, InstanceStore.createRequest.selector, "createRequest");
+          _authorize(functions, InstanceStore.updateRequest.selector, "updateRequest");
+          _authorize(functions, InstanceStore.updateRequestState.selector, "updateRequestState");
+
+          // authorize pool service role
+          functions = _authorizeForTarget(INSTANCE_STORE_TARGET_NAME, getServiceRole(POOL()));
+          _authorize(functions, InstanceStore.updatePool.selector, "updatePool");
+
+          // authorize bundle service role
+          functions = _authorizeForTarget(INSTANCE_STORE_TARGET_NAME, getServiceRole(BUNDLE()));
+          _authorize(functions, InstanceStore.createBundle.selector, "createBundle");
+          _authorize(functions, InstanceStore.updateBundle.selector, "updateBundle");
+          _authorize(functions, InstanceStore.updateBundleState.selector, "updateBundleState");
+          _authorize(functions, InstanceStore.increaseLocked.selector, "increaseLocked");
+          _authorize(functions, InstanceStore.decreaseLocked.selector, "decreaseLocked");
+
+          // authorize product service role
+          functions = _authorizeForTarget(INSTANCE_STORE_TARGET_NAME, getServiceRole(PRODUCT()));
+          _authorize(functions, InstanceStore.createRisk.selector, "createRisk");
+          _authorize(functions, InstanceStore.updateRisk.selector, "updateRisk");
+          _authorize(functions, InstanceStore.updateRiskState.selector, "updateRiskState");
+
+          // authorize application service role
+          functions = _authorizeForTarget(INSTANCE_STORE_TARGET_NAME, getServiceRole(APPLICATION()));
+          _authorize(functions, InstanceStore.createApplication.selector, "createApplication");
+          _authorize(functions, InstanceStore.updateApplication.selector, "updateApplication");
+          _authorize(functions, InstanceStore.updateApplicationState.selector, "updateApplicationState");
+
+          // authorize policy service role
+          functions = _authorizeForTarget(INSTANCE_STORE_TARGET_NAME, getServiceRole(POLICY()));
+          _authorize(functions, InstanceStore.updatePolicy.selector, "updatePolicy");
+          _authorize(functions, InstanceStore.updatePolicyState.selector, "updatePolicyState");
+          _authorize(functions, InstanceStore.createPremium.selector, "createPremium");
+          _authorize(functions, InstanceStore.updatePremiumState.selector, "updatePremiumState");
+
+          // authorize claim service role
+          functions = _authorizeForTarget(INSTANCE_STORE_TARGET_NAME, getServiceRole(CLAIM()));
+          _authorize(functions, InstanceStore.updatePolicyClaims.selector, "updatePolicyClaims");
+          _authorize(functions, InstanceStore.createClaim.selector, "createClaim");
+          _authorize(functions, InstanceStore.updateClaim.selector, "updateClaim");
+          _authorize(functions, InstanceStore.createPayout.selector, "createPayout");
+          _authorize(functions, InstanceStore.updatePayout.selector, "updatePayout");
+     }
+}
+

package/contracts/instance/InstanceReader.sol

@@ -0,0 +1,495 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Amount} from "../type/Amount.sol";
+import {ClaimId, ClaimIdLib} from "../type/ClaimId.sol";
+import {DistributorType} from "../type/DistributorType.sol";
+import {Key32} from "../type/Key32.sol";
+import {NftId} from "../type/NftId.sol";
+import {COMPONENT, DISTRIBUTOR, DISTRIBUTION, PREMIUM, PRODUCT, POLICY, POOL, BUNDLE} from "../type/ObjectType.sol";
+import {PayoutId, PayoutIdLib} from "../type/PayoutId.sol";
+import {ReferralId, ReferralStatus, ReferralLib, REFERRAL_OK, REFERRAL_ERROR_UNKNOWN, REFERRAL_ERROR_EXPIRED, REFERRAL_ERROR_EXHAUSTED} from "../type/Referral.sol";
+import {RequestId} from "../type/RequestId.sol";
+import {RiskId} from "../type/RiskId.sol";
+import {RoleId} from "../type/RoleId.sol";
+import {StateId} from "../type/StateId.sol";
+import {UFixed, UFixedLib} from "../type/UFixed.sol";
+
+import {IBundle} from "../instance/module/IBundle.sol";
+import {IComponents} from "../instance/module/IComponents.sol";
+import {IDistribution} from "../instance/module/IDistribution.sol";
+import {IInstance} from "./IInstance.sol";
+import {IKeyValueStore} from "../shared/IKeyValueStore.sol";
+import {IOracle} from "../oracle/IOracle.sol";
+import {IPolicy} from "../instance/module/IPolicy.sol";
+import {IRisk} from "../instance/module/IRisk.sol";
+import {TimestampLib} from "../type/Timestamp.sol";
+
+import {InstanceStore} from "./InstanceStore.sol";
+import {BundleSet} from "./BundleSet.sol";
+
+
+contract InstanceReader {
+
+    error ErrorInstanceReaderAlreadyInitialized();
+    error ErrorInstanceReaderInstanceAddressZero();
+
+    bool private _initialized = false;
+
+    IInstance internal _instance;
+    InstanceStore internal _store;
+    BundleSet internal _bundleSet;
+
+    /// @dev This initializer needs to be called from the instance itself.
+    function initialize() public {
+        if(_initialized) {
+            revert ErrorInstanceReaderAlreadyInitialized();
+        }
+
+        initializeWithInstance(msg.sender);
+    }
+
+    /// @dev This initializer needs to be called from the instance itself.
+    function initializeWithInstance(address instanceAddress) public {
+        if(_initialized) {
+            revert ErrorInstanceReaderAlreadyInitialized();
+        }
+
+        _initialized = true;
+        _instance = IInstance(instanceAddress);
+        _store = _instance.getInstanceStore();
+        _bundleSet = _instance.getBundleSet();
+    }
+
+
+    // module specific functions
+
+    function getPolicyInfo(NftId policyNftId)
+        public
+        view
+        returns (IPolicy.PolicyInfo memory info)
+    {
+        bytes memory data = _store.getData(toPolicyKey(policyNftId));
+        if (data.length > 0) {
+            return abi.decode(data, (IPolicy.PolicyInfo));
+        }
+    }
+
+    function getPolicyState(NftId policyNftId)
+        public
+        view
+        returns (StateId state)
+    {
+        return _store.getState(toPolicyKey(policyNftId));
+    }
+
+    function getPremiumInfo(NftId policyNftId) 
+        public
+        view
+        returns (IPolicy.PremiumInfo memory info)
+    {
+        bytes memory data = _store.getData(toPremiumKey(policyNftId));
+        if (data.length > 0) {
+            return abi.decode(data, (IPolicy.PremiumInfo));
+        }
+    }
+
+    function getPremiumInfoState(NftId policyNftId) 
+        public
+        view
+        returns (StateId state)
+    {
+        return _store.getState(toPremiumKey(policyNftId));
+    }
+
+    function activeBundles(NftId poolNftId)
+        public
+        view
+        returns (uint256 bundles)
+    {
+        return _bundleSet.activeBundles(poolNftId);
+    }
+
+    function getActiveBundleNftId(NftId poolNftId, uint256 idx)
+        public
+        view
+        returns (NftId bundleNftId)
+    {
+        return _bundleSet.getActiveBundleNftId(poolNftId, idx);
+    }
+
+    function getBundleState(NftId bundleNftId)
+        public
+        view
+        returns (StateId state)
+    {
+        return _store.getState(toBundleKey(bundleNftId));
+    }
+
+    /// @dev Returns true iff policy is active.
+    function policyIsActive(NftId policyNftId)
+        public
+        view
+        returns (bool isCloseable)
+    {
+        IPolicy.PolicyInfo memory info = getPolicyInfo(policyNftId);
+
+        if (info.productNftId.eqz()) { return false; } // not closeable: policy does not exist (or does not belong to this instance)
+        if (info.activatedAt.eqz()) { return false; } // not closeable: not yet activated
+        if (info.activatedAt > TimestampLib.blockTimestamp()) { return false; } // not yet active
+        if (info.expiredAt <= TimestampLib.blockTimestamp()) { return false; } // already expired
+
+        return true;
+    }
+
+    function claims(NftId policyNftId)
+        public
+        view
+        returns (uint16 claims)
+    {
+        return getPolicyInfo(policyNftId).claimsCount;
+    }
+
+
+    function getClaimId(uint idx)
+        public
+        view
+        returns (ClaimId claimId)
+    {
+        return ClaimIdLib.toClaimId(idx + 1);
+    }
+
+    function getClaimInfo(NftId policyNftId, ClaimId claimId)
+        public
+        view
+        returns (IPolicy.ClaimInfo memory info)
+    {
+        bytes memory data = _store.getData(claimId.toKey32(policyNftId));
+        if (data.length > 0) {
+            return abi.decode(data, (IPolicy.ClaimInfo));
+        }
+    }
+
+
+    function getClaimState(NftId policyNftId, ClaimId claimId)
+        public
+        view
+        returns (StateId state)
+    {
+        return _store.getState(claimId.toKey32(policyNftId));
+    }
+
+
+    function payouts(NftId policyNftId, ClaimId claimId)
+        public
+        view
+        returns (uint24 payouts)
+    {
+        return getClaimInfo(policyNftId, claimId).payoutsCount;
+    }
+
+
+    function getPayoutId(ClaimId claimId, uint24 idx)
+        public
+        view
+        returns (PayoutId payoutId)
+    {
+        return PayoutIdLib.toPayoutId(claimId, idx + 1);
+    }
+
+
+    function getRemainingClaimableAmount(NftId policyNftId)
+        public
+        view
+        returns (Amount remainingClaimableAmount)
+    {
+        IPolicy.PolicyInfo memory info = getPolicyInfo(policyNftId);
+        return info.sumInsuredAmount - info.claimAmount;
+    }
+
+    function getPayoutInfo(NftId policyNftId, PayoutId payoutId)
+        public
+        view
+        returns (IPolicy.PayoutInfo memory info)
+    {
+        bytes memory data = _store.getData(payoutId.toKey32(policyNftId));
+        if (data.length > 0) {
+            return abi.decode(data, (IPolicy.PayoutInfo));
+        }
+    }
+
+    function getPayoutState(NftId policyNftId, PayoutId payoutId)
+        public
+        view
+        returns (StateId state)
+    {
+        return _store.getState(payoutId.toKey32(policyNftId));
+    }
+
+    function getRiskInfo(RiskId riskId)
+        public 
+        view 
+        returns (IRisk.RiskInfo memory info)
+    {
+        bytes memory data = _store.getData(riskId.toKey32());
+        if (data.length > 0) {
+            return abi.decode(data, (IRisk.RiskInfo));
+        }
+    }
+
+    function getWallet(NftId componentNftId)
+        public
+        view
+        returns (address tokenHandler)
+    {
+        bytes memory data = _store.getData(toComponentKey(componentNftId));
+
+        if (data.length > 0) {
+            IComponents.ComponentInfo memory info = abi.decode(data, (IComponents.ComponentInfo));
+            return info.wallet;
+        }
+    }
+
+    function getTokenHandler(NftId componentNftId)
+        public
+        view
+        returns (address tokenHandler)
+    {
+        bytes memory data = _store.getData(toComponentKey(componentNftId));
+
+        if (data.length > 0) {
+            IComponents.ComponentInfo memory info = abi.decode(data, (IComponents.ComponentInfo));
+            return address(info.tokenHandler);
+        }
+    }
+
+    function getBundleInfo(NftId bundleNftId)
+        public 
+        view 
+        returns (IBundle.BundleInfo memory info)
+    {
+        bytes memory data = _store.getData(toBundleKey(bundleNftId));
+        if (data.length > 0) {
+            return abi.decode(data, (IBundle.BundleInfo));
+        }
+    }
+
+    function getDistributorTypeInfo(DistributorType distributorType)
+        public 
+        view 
+        returns (IDistribution.DistributorTypeInfo memory info)
+    {
+        bytes memory data = _store.getData(distributorType.toKey32());
+        if (data.length > 0) {
+            return abi.decode(data, (IDistribution.DistributorTypeInfo));
+        }
+    }
+
+    function getDistributorInfo(NftId distributorNftId)
+        public
+        view
+        returns (IDistribution.DistributorInfo memory info)
+    {
+        bytes memory data = _store.getData(toDistributorKey(distributorNftId));
+        if (data.length > 0) {
+            return abi.decode(data, (IDistribution.DistributorInfo));
+        }
+    }
+
+    function getBalanceAmount(NftId targetNftId) external view returns (Amount) { 
+        return _store.getBalanceAmount(targetNftId);
+    }
+
+    function getLockedAmount(NftId targetNftId) external view returns (Amount) { 
+        return _store.getLockedAmount(targetNftId);
+    }
+
+    function getFeeAmount(NftId targetNftId) external view returns (Amount) { 
+        return _store.getFeeAmount(targetNftId);
+    }
+
+    function getComponentInfo(NftId componentNftId)
+        public
+        view
+        returns (IComponents.ComponentInfo memory info)
+    {
+        bytes memory data = _store.getData(toComponentKey(componentNftId));
+        if (data.length > 0) {
+            return abi.decode(data, (IComponents.ComponentInfo));
+        }
+    }
+
+    function getProductInfo(NftId productNftId)
+        public
+        view
+        returns (IComponents.ProductInfo memory info)
+    {
+        bytes memory data = _store.getData(toProductKey(productNftId));
+        if (data.length > 0) {
+            return abi.decode(data, (IComponents.ProductInfo));
+        }
+    }
+
+    function getPoolInfo(NftId poolNftId)
+        public
+        view
+        returns (IComponents.PoolInfo memory info)
+    {
+        bytes memory data = _store.getData(toPoolKey(poolNftId));
+        if (data.length > 0) {
+            return abi.decode(data, (IComponents.PoolInfo));
+        }
+    }
+
+    function getReferralInfo(ReferralId referralId)
+        public 
+        view 
+        returns (IDistribution.ReferralInfo memory info)
+    {
+        bytes memory data = _store.getData(referralId.toKey32());
+        if (data.length > 0) {
+            return abi.decode(data, (IDistribution.ReferralInfo));
+        }
+    }
+
+    function getRequestInfo(RequestId requestId)
+        public
+        view
+        returns (IOracle.RequestInfo memory requestInfo)
+    {
+        bytes memory data = _store.getData(requestId.toKey32());
+        if (data.length > 0) {
+            return abi.decode(data, (IOracle.RequestInfo));
+        }
+    }
+
+    function getMetadata(Key32 key)
+        public 
+        view 
+        returns (IKeyValueStore.Metadata memory metadata)
+    {
+        return _store.getMetadata(key);
+    }
+
+    function getState(Key32 key)
+        public 
+        view 
+        returns (StateId state)
+    {
+        return _store.getMetadata(key).state;
+    }
+
+
+    function toReferralId(
+        NftId distributionNftId,
+        string memory referralCode
+    )
+        public
+        pure 
+        returns (ReferralId referralId)
+    {
+        return ReferralLib.toReferralId(
+            distributionNftId, 
+            referralCode);      
+    }
+
+
+    function getDiscountPercentage(ReferralId referralId)
+        public
+        view
+        returns (
+            UFixed discountPercentage, 
+            ReferralStatus status
+        )
+    {
+        IDistribution.ReferralInfo memory info = getReferralInfo(
+            referralId);        
+
+        if (info.expiryAt.eqz()) {
+            return (
+                UFixedLib.zero(),
+                REFERRAL_ERROR_UNKNOWN());
+        }
+
+        if (info.expiryAt < TimestampLib.blockTimestamp()) {
+            return (
+                UFixedLib.zero(),
+                REFERRAL_ERROR_EXPIRED());
+        }
+
+        if (info.usedReferrals >= info.maxReferrals) {
+            return (
+                UFixedLib.zero(),
+                REFERRAL_ERROR_EXHAUSTED());
+        }
+
+        return (
+            info.discountPercentage,
+            REFERRAL_OK()
+        );
+    }
+
+
+    function hasRole(address account, RoleId roleId) public view returns (bool isMember) {
+        return _instance.getInstanceAdmin().hasRole(account, roleId);
+    }
+
+
+    function hasAdminRole(address account, RoleId roleId) public view returns (bool isMember) {
+        return _instance.getInstanceAdmin().hasAdminRole(account, roleId);
+    }
+
+
+    function isTargetLocked(address target) public view returns (bool) {
+        return _instance.getInstanceAdmin().isTargetLocked(target);
+    }
+
+    function toPolicyKey(NftId policyNftId) public pure returns (Key32) { 
+        return policyNftId.toKey32(POLICY());
+    }
+
+    function toPremiumKey(NftId policyNftId) public pure returns (Key32) { 
+        return policyNftId.toKey32(PREMIUM());
+    }
+
+    function toDistributorKey(NftId distributorNftId) public pure returns (Key32) { 
+        return distributorNftId.toKey32(DISTRIBUTOR());
+    }
+
+    function toBundleKey(NftId poolNftId) public pure returns (Key32) { 
+        return poolNftId.toKey32(BUNDLE());
+    }
+
+    function toComponentKey(NftId componentNftId) public pure returns (Key32) { 
+        return componentNftId.toKey32(COMPONENT());
+    }
+
+    function toDistributionKey(NftId distributionNftId) public pure returns (Key32) { 
+        return distributionNftId.toKey32(DISTRIBUTION());
+    }
+
+    function toPoolKey(NftId poolNftId) public pure returns (Key32) { 
+        return poolNftId.toKey32(POOL());
+    }
+
+    function toProductKey(NftId productNftId) public pure returns (Key32) { 
+        return productNftId.toKey32(PRODUCT());
+    }
+
+    // low level function
+    function getInstance() external view returns (IInstance instance) {
+        return _instance;
+    }
+
+    function getInstanceStore() external view returns (IKeyValueStore store) {
+        return _store;
+    }
+
+    function toUFixed(uint256 value, int8 exp) public pure returns (UFixed) {
+        return UFixedLib.toUFixed(value, exp);
+    }
+
+    function toInt(UFixed value) public pure returns (uint256) {
+        return UFixedLib.toInt(value);
+    }
+}