@etherisc/gif-next 0.0.2-ec436bf-674 → 0.0.2-ed3b1b0-046

package/contracts/product/PricingService.sol

@@ -0,0 +1,276 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Seconds} from "../type/Seconds.sol";
+import {UFixed, UFixedLib} from "../type/UFixed.sol";
+import {ObjectType} from "../type/ObjectType.sol";
+import {NftId} from "../type/NftId.sol";
+import {Fee} from "../type/Fee.sol";
+import {ReferralId} from "../type/Referral.sol";
+import {RiskId} from "../type/RiskId.sol";
+import {PRODUCT, DISTRIBUTION, PRICE} from "../type/ObjectType.sol";
+import {Amount} from "../type/Amount.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+
+import {IProductComponent} from "./IProductComponent.sol";
+
+import {IInstance} from "../instance/IInstance.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {IComponents} from "../instance/module/IComponents.sol";
+import {IPolicy} from "../instance/module/IPolicy.sol";
+import {IBundle} from "../instance/module/IBundle.sol";
+import {ISetup} from "../instance/module/ISetup.sol";
+import {IDistribution} from "../instance/module/IDistribution.sol";
+
+import {ComponentService} from "../shared/ComponentService.sol";
+
+import {IPricingService} from "./IPricingService.sol";
+import {IDistributionService} from "../distribution/IDistributionService.sol";
+
+
+contract PricingService is 
+    ComponentService, 
+    IPricingService
+{
+    using UFixedLib for UFixed;
+
+    IDistributionService internal _distributionService;
+
+
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        virtual override
+        initializer()
+    {
+        (
+            address registryAddress,, 
+            //address managerAddress
+            address authority
+        ) = abi.decode(data, (address, address, address));
+
+        initializeService(registryAddress, authority, owner);
+        registerInterface(type(IPricingService).interfaceId);
+
+        _distributionService = IDistributionService(_getServiceAddress(DISTRIBUTION()));
+    }
+
+
+    function getDomain() public pure override returns(ObjectType) {
+        return PRICE();
+    }
+
+    /// @dev calculates the premium amount for the specified attributes
+    /// also returns the various fee components involved with creating a policy
+    function calculatePremium(
+        NftId productNftId,
+        RiskId riskId,
+        Amount sumInsuredAmount,
+        Seconds lifetime,
+        bytes memory applicationData,
+        NftId bundleNftId,
+        ReferralId referralId
+    )
+        external
+        view
+        virtual override
+        returns (
+            IPolicy.Premium memory premium
+        )
+    {
+        InstanceReader reader;
+        Amount netPremiumAmount;
+
+        {
+            // verify product
+            (
+                IRegistry.ObjectInfo memory productInfo, 
+                IInstance instance
+            ) = _getAndVerifyComponentInfoAndInstance(productNftId, PRODUCT());
+
+            reader = instance.getInstanceReader();
+
+            // calculate net premium
+            netPremiumAmount = IProductComponent(productInfo.objectAddress).calculateNetPremium(
+                sumInsuredAmount,
+                riskId,
+                lifetime,
+                applicationData
+            );
+        }
+
+        {
+            // get configurations for all involed objects
+            ISetup.ProductSetupInfo memory productSetup = reader.getProductSetupInfo(productNftId);
+
+            bytes memory componentData = reader.getComponentInfo(productSetup.poolNftId).data;
+            IComponents.PoolInfo memory poolInfo = abi.decode(componentData, (IComponents.PoolInfo));
+
+            IBundle.BundleInfo memory bundleInfo = reader.getBundleInfo(bundleNftId);
+            if(bundleInfo.poolNftId != productSetup.poolNftId) {
+                revert ErrorIPricingServiceBundlePoolMismatch(bundleNftId, bundleInfo.poolNftId, productSetup.poolNftId);
+            }
+
+            NftId distributionNftId = productSetup.distributionNftId;
+            ISetup.DistributionSetupInfo memory distSetup = reader.getDistributionSetupInfo(distributionNftId);
+
+            // calculate premium, order is important
+            premium = _getFixedFeeAmounts(
+                netPremiumAmount,
+                productSetup,
+                poolInfo,
+                distSetup,
+                bundleInfo
+            );
+
+            premium = _calculateVariableFeeAmounts(
+                premium,
+                productSetup,
+                poolInfo,
+                distSetup,
+                bundleInfo
+            );
+
+            premium = _calculateDistributionOwnerFeeAmount(
+                premium,
+                distSetup,
+                referralId,
+                distributionNftId,
+                reader
+            );
+
+            // sanity check to validate the fee calculation
+            if (premium.distributionOwnerFeeFixAmount < distSetup.minDistributionOwnerFee.fixedFee) {
+                revert ErrorIPricingServiceFeeCalculationMismatch( 
+                    premium.distributionFeeFixAmount,
+                    premium.distributionFeeVarAmount,
+                    premium.distributionOwnerFeeFixAmount,
+                    premium.distributionOwnerFeeVarAmount,
+                    premium.commissionAmount,
+                    premium.discountAmount
+                );
+            }
+
+            if ((premium.distributionFeeVarAmount) != (premium.discountAmount + premium.distributionOwnerFeeVarAmount + premium.commissionAmount)) {
+                revert ErrorIPricingServiceFeeCalculationMismatch(
+                    premium.distributionFeeFixAmount,
+                    premium.distributionFeeVarAmount,
+                    premium.distributionOwnerFeeFixAmount,
+                    premium.distributionOwnerFeeVarAmount,
+                    premium.commissionAmount,
+                    premium.discountAmount
+                );
+            }
+        }
+    }
+
+    // internal functions
+    function _getFixedFeeAmounts(
+        Amount netPremiumAmount,
+        ISetup.ProductSetupInfo memory productInfo,
+        IComponents.PoolInfo memory poolInfo,
+        ISetup.DistributionSetupInfo memory distInfo,
+        IBundle.BundleInfo memory bundleInfo
+    )
+        internal
+        view
+        returns (
+            IPolicy.Premium memory premium
+        )
+    {
+        // initial premium amount is the net premium
+        premium.netPremiumAmount = netPremiumAmount.toInt();
+        premium.fullPremiumAmount = netPremiumAmount.toInt();
+
+        uint256 t = productInfo.productFee.fixedFee;
+        premium.productFeeFixAmount = t;
+        premium.fullPremiumAmount += t;
+
+        t = poolInfo.poolFee.fixedFee;
+        premium.poolFeeFixAmount = t;
+        premium.fullPremiumAmount += t;
+
+        t = bundleInfo.fee.fixedFee;
+        premium.bundleFeeFixAmount = t;
+        premium.fullPremiumAmount += t;
+
+        t = distInfo.distributionFee.fixedFee;
+        premium.distributionFeeFixAmount = t;
+        premium.fullPremiumAmount += t;
+    }
+
+    function _calculateVariableFeeAmounts(
+        IPolicy.Premium memory premium,
+        ISetup.ProductSetupInfo memory productInfo,
+        IComponents.PoolInfo memory poolInfo,
+        ISetup.DistributionSetupInfo memory distInfo,
+        IBundle.BundleInfo memory bundleInfo
+    )
+        internal
+        view
+        returns (
+            IPolicy.Premium memory intermadiatePremium
+        )
+    {
+        UFixed netPremiumAmount = UFixedLib.toUFixed(premium.netPremiumAmount);
+
+        uint256 t = (netPremiumAmount * productInfo.productFee.fractionalFee).toInt();
+        premium.productFeeVarAmount = t;
+        premium.fullPremiumAmount += t;
+
+        t = (netPremiumAmount * poolInfo.poolFee.fractionalFee).toInt();
+        premium.poolFeeVarAmount = t;
+        premium.fullPremiumAmount += t;
+
+        t = (netPremiumAmount * bundleInfo.fee.fractionalFee).toInt();
+        premium.bundleFeeVarAmount = t;
+        premium.fullPremiumAmount += t;
+
+        t = (netPremiumAmount * distInfo.distributionFee.fractionalFee).toInt();
+        premium.distributionFeeVarAmount = t;
+        premium.fullPremiumAmount += t;
+
+        return premium;
+    }
+
+    function _calculateDistributionOwnerFeeAmount(
+        IPolicy.Premium memory premium,
+        ISetup.DistributionSetupInfo memory distInfo,
+        ReferralId referralId,
+        NftId distributionNftId,
+        InstanceReader reader
+    )
+        internal
+        view 
+        returns (IPolicy.Premium memory finalPremium)
+    {
+        // if the referral is not valid, then the distribution owner gets everything
+        if (! _distributionService.referralIsValid(distributionNftId, referralId)) {
+            premium.distributionOwnerFeeFixAmount = premium.distributionFeeFixAmount;
+            premium.distributionOwnerFeeVarAmount = premium.distributionFeeVarAmount;
+            premium.premiumAmount = premium.fullPremiumAmount;
+            return premium;
+        }
+
+        Fee memory minDistributionOwnerFee = distInfo.minDistributionOwnerFee;
+
+        // if the referral is valid, the the commission and discount are calculated based in the full premium
+        // the remaing amount goes to the distribution owner
+        {
+            IDistribution.ReferralInfo memory referralInfo = reader.getReferralInfo(referralId);
+            IDistribution.DistributorInfo memory distributorInfo = reader.getDistributorInfo(referralInfo.distributorNftId);
+            IDistribution.DistributorTypeInfo memory distributorTypeInfo = reader.getDistributorTypeInfo(distributorInfo.distributorType);
+
+            uint256 commissionAmount = UFixedLib.toUFixed(premium.netPremiumAmount).mul(distributorTypeInfo.commissionPercentage).toInt();
+            premium.commissionAmount = commissionAmount;
+            premium.discountAmount = UFixedLib.toUFixed(premium.fullPremiumAmount).mul(referralInfo.discountPercentage).toInt();
+            premium.distributionOwnerFeeFixAmount = distInfo.minDistributionOwnerFee.fixedFee;
+            premium.distributionOwnerFeeVarAmount = premium.distributionFeeVarAmount - commissionAmount - premium.discountAmount;
+            premium.premiumAmount = premium.fullPremiumAmount - premium.discountAmount;
+        }
+
+        return premium; 
+    }
+}

package/contracts/product/PricingServiceManager.sol

@@ -0,0 +1,42 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IVersionable} from "../shared/IVersionable.sol";
+import {ProxyManager} from "../shared/ProxyManager.sol";
+import {PricingService} from "./PricingService.sol";
+import {Registry} from "../registry/Registry.sol";
+import {RegistryService} from "../registry/RegistryService.sol";
+import {REGISTRY} from "../type/ObjectType.sol";
+
+contract PricingServiceManager is ProxyManager {
+
+    PricingService private _pricingService;
+
+    /// @dev initializes proxy manager with pricing service implementation and deploys instance
+    constructor(
+        address authority, 
+        address registryAddress,
+        bytes32 salt
+    )
+        ProxyManager(registryAddress)
+    {
+        PricingService pricingSrv = new PricingService{salt: salt}();
+        bytes memory data = abi.encode(registryAddress, address(this), authority);
+        IVersionable versionable = deployDetermenistic(
+            address(pricingSrv), 
+            data,
+            salt);
+
+        _pricingService = PricingService(address(versionable));
+    }
+
+    //--- view functions ----------------------------------------------------//
+    function getPricingService()
+        external
+        view
+        returns (PricingService)
+    {
+        return _pricingService;
+    }
+
+}

package/contracts/product/Product.sol

@@ -0,0 +1,379 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {Amount, AmountLib} from "../type/Amount.sol";
+import {ClaimId} from "../type/ClaimId.sol";
+import {Component} from "../shared/Component.sol";
+import {Fee} from "../type/Fee.sol";
+import {IRisk} from "../instance/module/IRisk.sol";
+import {IApplicationService} from "./IApplicationService.sol";
+import {IPolicyService} from "./IPolicyService.sol";
+import {IProductService} from "./IProductService.sol";
+import {IClaimService} from "./IClaimService.sol";
+import {IPricingService} from "./IPricingService.sol";
+import {IProductComponent} from "./IProductComponent.sol";
+import {NftId, NftIdLib} from "../type/NftId.sol";
+import {PayoutId} from "../type/PayoutId.sol";
+import {PRODUCT, APPLICATION, POLICY, CLAIM, PRICE } from "../type/ObjectType.sol";
+import {ReferralId} from "../type/Referral.sol";
+import {RiskId, RiskIdLib} from "../type/RiskId.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {StateId} from "../type/StateId.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+
+import {TokenHandler} from "../shared/TokenHandler.sol";
+
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {IPolicy} from "../instance/module/IPolicy.sol";
+import {ISetup} from "../instance/module/ISetup.sol";
+import {IComponents} from "../instance/module/IComponents.sol";
+import {Pool} from "../pool/Pool.sol";
+import {Distribution} from "../distribution/Distribution.sol";
+
+abstract contract Product is
+    Component, 
+    IProductComponent
+{
+    // keccak256(abi.encode(uint256(keccak256("etherisc.storage.Product")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant PRODUCT_STORAGE_LOCATION_V1 = 0x0bb7aafdb8e380f81267337bc5b5dfdf76e6d3a380ecadb51ec665246d9d6800;
+
+    struct ProductStorage {
+        IProductService _productService;
+        IApplicationService _applicationService;
+        IPolicyService _policyService;
+        IClaimService _claimService;
+        IPricingService _pricingService;
+        Pool _pool;
+        Distribution _distribution;
+        Fee _initialProductFee;
+        Fee _initialProcessingFee;
+        TokenHandler _tokenHandler;
+        NftId _poolNftId;
+        NftId _distributionNftId;
+    }
+
+    function initializeProduct(
+        address registry,
+        NftId instanceNftId,
+        string memory name,
+        address token,
+        bool isInterceptor,
+        address pool,
+        address distribution,
+        Fee memory productFee,
+        Fee memory processingFee,
+        address initialOwner,
+        bytes memory registryData // writeonly data that will saved in the object info record of the registry
+    )
+        public
+        virtual
+        onlyInitializing()
+    {
+        initializeComponent(registry, instanceNftId, name, token, PRODUCT(), isInterceptor, initialOwner, registryData);
+
+        ProductStorage storage $ = _getProductStorage();
+        // TODO add validation
+        // TODO refactor to go via registry ?
+        $._productService = IProductService(_getServiceAddress(PRODUCT())); 
+        $._applicationService = IApplicationService(_getServiceAddress(APPLICATION())); 
+        $._policyService = IPolicyService(_getServiceAddress(POLICY())); 
+        $._claimService = IClaimService(_getServiceAddress(CLAIM())); 
+        $._pricingService = IPricingService(_getServiceAddress(PRICE()));
+        $._pool = Pool(pool);
+        $._distribution = Distribution(distribution);
+        $._initialProductFee = productFee;
+        $._initialProcessingFee = processingFee;  
+        $._tokenHandler = new TokenHandler(token);
+        $._poolNftId = getRegistry().getNftId(pool);
+        $._distributionNftId = getRegistry().getNftId(distribution);
+
+        registerInterface(type(IProductComponent).interfaceId);  
+    }
+
+    // from product component
+    function setFees(
+        Fee memory productFee,
+        Fee memory processingFee
+    )
+        external
+        onlyOwner
+        restricted()
+        override
+    {
+        _getProductService().setFees(productFee, processingFee);
+    }
+
+    function _createRisk(
+        RiskId id,
+        bytes memory data
+    ) internal {
+        _getProductService().createRisk(
+            id,
+            data
+        );
+    }
+
+    function _updateRisk(
+        RiskId id,
+        bytes memory data
+    ) internal {
+        _getProductService().updateRisk(
+            id,
+            data
+        );
+    }
+
+    function _updateRiskState(
+        RiskId id,
+        StateId state
+    ) internal {
+        _getProductService().updateRiskState(
+            id,
+            state
+        );
+    }
+
+    function _getRiskInfo(RiskId id) internal view returns (IRisk.RiskInfo memory info) {
+        return getInstance().getInstanceReader().getRiskInfo(id);
+    }
+
+    function _createApplication(
+        address applicationOwner,
+        RiskId riskId,
+        Amount sumInsuredAmount,
+        Seconds lifetime,
+        NftId bundleNftId,
+        ReferralId referralId,
+        bytes memory applicationData
+    )
+        internal
+        returns (NftId applicationNftId) 
+    {
+        return _getProductStorage()._applicationService.create(
+            applicationOwner,
+            riskId,
+            sumInsuredAmount,
+            lifetime,
+            bundleNftId,
+            referralId,
+            applicationData
+        );
+    }
+
+    function _collateralize(
+        NftId policyNftId,
+        bool requirePremiumPayment,
+        Timestamp activateAt
+    )
+        internal
+    {
+        _getProductStorage()._policyService.collateralize(
+            policyNftId, 
+            requirePremiumPayment, 
+            activateAt);
+    }
+
+    function _collectPremium(
+        NftId policyNftId,
+        Timestamp activateAt
+    )
+        internal
+    {
+        _getProductStorage()._policyService.collectPremium(
+            policyNftId, 
+            activateAt);
+    }
+
+    function _activate(
+        NftId policyNftId,
+        Timestamp activateAt
+    )
+        internal
+    {
+        _getProductStorage()._policyService.activate(
+            policyNftId, 
+            activateAt);
+    }
+
+    function _close(
+        NftId policyNftId
+    )
+        internal
+    {
+        _getProductStorage()._policyService.close(
+            policyNftId);
+    }
+
+    function _submitClaim(
+        NftId policyNftId,
+        Amount claimAmount,
+        bytes memory claimData
+    )
+        internal
+        returns(ClaimId)
+    {
+        return _getProductStorage()._claimService.submit(
+            policyNftId,
+            claimAmount,
+            claimData);
+    }
+
+    function _confirmClaim(
+        NftId policyNftId,
+        ClaimId claimId,
+        Amount confirmedAmount,
+        bytes memory data
+    )
+        internal
+    {
+        _getProductStorage()._claimService.confirm(
+            policyNftId,
+            claimId,
+            confirmedAmount,
+            data);
+    }
+
+    function _declineClaim(
+        NftId policyNftId,
+        ClaimId claimId,
+        bytes memory data
+    )
+        internal
+    {
+        _getProductStorage()._claimService.decline(
+            policyNftId,
+            claimId,
+            data);
+    }
+
+    function _closeClaim(
+        NftId policyNftId,
+        ClaimId claimId
+    )
+        internal
+    {
+        _getProductStorage()._claimService.close(
+            policyNftId,
+            claimId);
+    }
+
+    function _createPayout(
+        NftId policyNftId,
+        ClaimId claimId,
+        Amount amount,
+        bytes memory data
+    )
+        internal
+        returns (PayoutId)
+    {
+        return _getProductStorage()._claimService.createPayout(
+            policyNftId, 
+            claimId, 
+            amount, 
+            data);
+    }
+
+    function _processPayout(
+        NftId policyNftId,
+        PayoutId payoutId
+    )
+        internal
+    {
+        _getProductStorage()._claimService.processPayout(
+            policyNftId,
+            payoutId);
+    }
+
+    function calculatePremium(
+        Amount sumInsuredAmount,
+        RiskId riskId,
+        Seconds lifetime,
+        bytes memory applicationData,
+        NftId bundleNftId,
+        ReferralId referralId
+    )
+        external 
+        view 
+        override 
+        returns (Amount premiumAmount)
+    {
+        IPolicy.Premium memory premium = _getProductStorage()._pricingService.calculatePremium(
+            getNftId(),
+            riskId,
+            sumInsuredAmount,
+            lifetime,
+            applicationData,
+            bundleNftId,
+            referralId
+        );
+
+        return AmountLib.toAmount(premium.premiumAmount);
+    }
+
+    function calculateNetPremium(
+        Amount sumInsuredAmount,
+        RiskId riskId,
+        Seconds lifetime,
+        bytes memory applicationData
+    )
+        external
+        view
+        virtual override
+        returns (Amount netPremiumAmount)
+    {
+        // default 10% of sum insured
+        return AmountLib.toAmount(sumInsuredAmount.toInt() / 10);
+    }
+
+    function _toRiskId(string memory riskName) internal pure returns (RiskId riskId) {
+        return RiskIdLib.toRiskId(riskName);
+    }
+
+    function getPoolNftId() external view override returns (NftId poolNftId) {
+        return getRegistry().getNftId(address(_getProductStorage()._pool));
+    }
+
+    function getDistributionNftId() external view override returns (NftId distributionNftId) {
+        return getRegistry().getNftId(address(_getProductStorage()._distribution));
+    }
+
+    function getSetupInfo() public view returns (ISetup.ProductSetupInfo memory setupInfo) {
+        InstanceReader reader = getInstance().getInstanceReader();
+        setupInfo = reader.getProductSetupInfo(getNftId());
+
+        // fallback to initial setup info (wallet is always != address(0))
+        if(setupInfo.wallet == address(0)) {
+            setupInfo = _getInitialSetupInfo();
+        }
+    }
+
+    function _getInitialSetupInfo() internal view returns (ISetup.ProductSetupInfo memory setupInfo) {
+        ProductStorage storage $ = _getProductStorage();
+
+        ISetup.DistributionSetupInfo memory distributionSetupInfo = $._distribution.getSetupInfo();
+        IComponents.PoolInfo memory poolInfo = $._pool.getPoolInfo();
+
+        return ISetup.ProductSetupInfo(
+            getToken(),
+            $._tokenHandler,
+            $._distributionNftId,
+            $._poolNftId,
+            $._initialProductFee,
+            $._initialProcessingFee,
+            false,
+            getWallet()
+        );
+    }
+
+    function _getProductStorage() private pure returns (ProductStorage storage $) {
+        assembly {
+            $.slot := PRODUCT_STORAGE_LOCATION_V1
+        }
+    }
+
+    function _getProductService() internal view returns (IProductService) {
+        return _getProductStorage()._productService;
+    }
+}