@etherisc/gif-next 0.0.2-ebbe63d → 0.0.2-f9905e1

package/contracts/instance/access/Access.sol

@@ -0,0 +1,218 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+// role admin handling of oz doesn't fit nft ownability
+// import {AccessControlEnumerable} from "@openzeppelin/contracts/access/AccessControlEnumerable.sol";
+import "@openzeppelin/contracts/utils/structs/EnumerableSet.sol";
+
+import {IAccessModule} from "./IAccess.sol";
+
+
+abstract contract AccessModule is
+    IAccessModule
+{
+    string constant public PRODUCT_OWNER = "ProductOwner";
+    string constant public ORACLE_OWNER = "OracleOwner";
+    string constant public POOL_OWNER = "PoolOwner";
+
+    using EnumerableSet for EnumerableSet.AddressSet;
+
+    event LogAccessRoleGranted(bytes32 role, address member, bool isMember);
+
+    mapping(bytes32 role => RoleInfo info) private _info;
+    bytes32 [] private _roles;
+
+    bytes32 private immutable _productOwnerRole;
+    bytes32 private immutable _oracleOwnerRole;
+    bytes32 private immutable _poolOwnerRole;
+
+    mapping(bytes32 role => mapping(address member => bool isMember)) private _isRoleMember;
+    mapping(bytes32 role => EnumerableSet.AddressSet) private _roleMembers;
+
+    modifier onlyOwner() {
+        require(msg.sender == this.getOwner(), "ERROR:ACM-001:NOT_OWNER");
+        _;
+    }
+
+    constructor() {
+        _productOwnerRole = _createRole(PRODUCT_OWNER);
+        _oracleOwnerRole = _createRole(ORACLE_OWNER);
+        _poolOwnerRole = _createRole(POOL_OWNER);
+    }
+
+    function PRODUCT_OWNER_ROLE() public view override returns(bytes32 role) { return _productOwnerRole; }
+    function ORACLE_OWNER_ROLE() public view override returns(bytes32 role) { return _oracleOwnerRole; }
+    function POOL_OWNER_ROLE() public view override returns(bytes32 role) { return _poolOwnerRole; }
+
+
+    function createRole(string memory roleName) 
+        external
+        override
+        onlyOwner
+        returns(bytes32 role)
+    {
+        return _createRole(roleName);
+    }
+
+    function _createRole(string memory roleName) 
+        internal
+        returns(bytes32 role)
+    {
+        RoleInfo memory info = RoleInfo(
+            0,
+            roleName,
+            true
+        );
+
+        role = _setRoleInfo(info);
+
+        
+    }
+
+    // TODO move to module
+    function disableRole(bytes32 role) 
+        external
+        override
+        onlyOwner
+    {
+        RoleInfo memory info = _info[role];
+        require(info.id == role, "ERROR:AOS-001:ROLE_DOES_NOT_EXIST");
+
+        info.isActive = false;
+        _setRoleInfo(info);
+
+        
+    }   
+
+    // TODO move to module
+    function enableRole(bytes32 role) 
+        external
+        override       
+        onlyOwner
+    {
+        RoleInfo memory info = _info[role];
+        require(info.id == role, "ERROR:AOS-002:ROLE_DOES_NOT_EXIST");
+
+        info.isActive = true;
+        _setRoleInfo(info);
+
+        
+    }   
+
+    function grantRole(bytes32 role, address member) 
+        external
+        override     
+        onlyOwner
+    {
+        require(_info[role].id == role, "ERROR:ACM-010:ROLE_NOT_EXISTING");
+        require(_info[role].isActive, "ERROR:ACM-011:ROLE_NOT_ACTIVE");
+
+        _isRoleMember[role][member] = true;
+        _roleMembers[role].add(member);
+
+        emit LogAccessRoleGranted(role, member, _isRoleMember[role][member]);
+    }
+
+
+    function revokeRole(bytes32 role, address member) 
+        external
+        override     
+        onlyOwner
+    {
+        require(_info[role].id == role, "ERROR:ACM-020:ROLE_NOT_EXISTING");
+
+        _isRoleMember[role][member] = false;
+        _roleMembers[role].remove(member);
+
+        
+    }
+
+
+    function hasRole(bytes32 role, address member)
+        external
+        view
+        override
+        returns(bool)
+    {
+        return _isRoleMember[role][member];
+    }
+
+
+    function getRoleInfo(bytes32 role)
+        external
+        override
+        view
+        returns(RoleInfo memory info)
+    {
+        return _info[role];
+    }
+
+
+    function getRole(uint256 idx)
+        external
+        override
+        view
+        returns(bytes32 role)
+    {
+        return _roles[idx];
+    }
+
+
+    function getRoleCount()
+        external
+        override
+        view
+        returns(uint256 roles)
+    {
+        return _roles.length;
+    }        
+
+    function getRoleMemberCount(bytes32 role)
+        public
+        override
+        view
+        returns(uint256 roleMembers)
+    {
+        return _roleMembers[role].length();
+    }
+
+    function getRoleMember(bytes32 role, uint256 idx)
+        public
+        override
+        view
+        returns(address roleMembers)
+    {
+        return _roleMembers[role].at(idx);
+    }
+
+    function getRoleForName(string memory roleName)
+        public
+        override
+        pure
+        returns(bytes32 role)
+    {
+        return keccak256(abi.encode(roleName));
+    }
+
+
+    function _setRoleInfo(RoleInfo memory info)
+        internal
+        returns(bytes32 role)
+    {
+        role = info.id;
+
+        if(role == bytes32(0)) {
+            role = getRoleForName(info.name);
+            // TODO check that this is a new role id
+
+            info.id = role;
+            _roles.push(role);
+
+            
+        }
+
+        _info[role] = info;
+
+        
+    }
+}

package/contracts/instance/access/IAccess.sol

@@ -0,0 +1,83 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IOwnable, IRegistryLinked} from "../../registry/IRegistry.sol";
+
+interface IAccess {
+
+    struct RoleInfo {
+        bytes32 id;
+        string name;
+        bool isActive;
+    }
+}
+
+interface IAccessCheckRole {
+
+    function hasRole(bytes32 role, address member)
+        external
+        view
+        returns(bool);
+}
+
+interface IAccessComponentTypeRoles {
+    function PRODUCT_OWNER_ROLE() external view returns(bytes32 role);
+    function ORACLE_OWNER_ROLE() external view returns(bytes32 role);
+    function POOL_OWNER_ROLE() external view returns(bytes32 role);
+}
+
+
+interface IAccessModule is 
+    IOwnable,
+    IRegistryLinked,
+    IAccess,
+    IAccessComponentTypeRoles,
+    IAccessCheckRole
+{
+
+    function createRole(string memory roleName)
+        external
+        returns(bytes32 role);
+
+    function enableRole(bytes32 role)
+        external;       
+
+    function disableRole(bytes32 role)
+        external;       
+
+    function grantRole(bytes32 role, address member)
+        external;       
+
+    function revokeRole(bytes32 role, address member)
+        external;       
+
+    function getRole(uint256 idx)
+        external
+        view
+        returns(bytes32 role);
+
+    function getRoleInfo(bytes32 role)
+        external
+        view
+        returns(RoleInfo memory info);
+
+    function getRoleForName(string memory roleName)
+        external
+        pure
+        returns(bytes32 role);
+
+    function getRoleCount()
+        external
+        view
+        returns(uint256 roles);
+
+    function getRoleMemberCount(bytes32 role)
+        external
+        view
+        returns(uint256 roleMembers);
+
+    function getRoleMember(bytes32 role, uint256 idx)
+        external
+        view
+        returns(address roleMembers);
+}

package/contracts/instance/component/ComponentModule.sol

@@ -0,0 +1,259 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {RegistryLinked} from "../../registry/Registry.sol";
+import {IRegistry, IRegistryLinked} from "../../registry/IRegistry.sol";
+import {IAccessComponentTypeRoles, IAccessCheckRole} from "../access/IAccess.sol";
+import {IInstance} from "../IInstance.sol";
+
+import {IComponent, IComponentContract, IComponentModule, IComponentOwnerService} from "./IComponent.sol";
+import {IProductComponent} from "../../components/IProduct.sol";
+import {IPoolModule} from "../pool/IPoolModule.sol";
+
+
+abstract contract ComponentModule is 
+    IRegistryLinked,
+    IAccessComponentTypeRoles,
+    IAccessCheckRole,
+    IComponentModule
+{
+
+    mapping(uint256 nftId => ComponentInfo info) private _componentInfo;
+    mapping(uint256 nftId => uint256 poolNftId) private _poolNftIdForProduct;
+    mapping(address cAddress => uint256 id) private _idByAddress;
+    uint256 [] private _ids;
+
+    mapping(uint256 cType => bytes32 role) private _componentOwnerRole;
+
+    IComponentOwnerService private _componentOwnerService;
+
+    modifier onlyComponentOwnerService() {
+        require(address(_componentOwnerService) == msg.sender, "ERROR:CMP-001:NOT_OWNER_SERVICE");
+        _;
+    }
+
+    constructor(address componentOwnerService) {
+        _componentOwnerService = ComponentOwnerService(componentOwnerService);
+    }
+
+    function registerComponent(IComponentContract component)
+        external
+        override
+        onlyComponentOwnerService
+        returns(uint256 nftId)
+    {
+        bytes32 typeRole = getRoleForType(component.getType());
+        require(
+            this.hasRole(typeRole, component.getInitialOwner()),
+            "ERROR:CMP-004:TYPE_ROLE_MISSING");
+        
+        nftId = this.getRegistry().register(address(component));
+
+        _componentInfo[nftId] = ComponentInfo(
+            nftId,
+            CState.Active);
+
+        // special case product -> persist product - pool assignment
+        if(component.getType() == this.getRegistry().PRODUCT()) {
+            IProductComponent product = IProductComponent(address(component));
+            uint256 poolNftId = product.getPoolNftId();
+            require(poolNftId > 0, "ERROR:CMP-005:POOL_UNKNOWN");
+            // add more validation (type, token, ...)
+
+            _poolNftIdForProduct[nftId] = poolNftId;
+
+            // add creation of productInfo
+        }
+        else if(component.getType() == this.getRegistry().POOL()) {
+            IPoolModule poolModule = IPoolModule(address(this));
+            poolModule.createPoolInfo(
+                nftId,
+                address(component), // set pool as its wallet
+                address(0) // don't deal with token yet
+            );
+        }
+
+        _idByAddress[address(component)] = nftId;
+        _ids.push(nftId);
+
+        // add logging
+    }
+
+    function getPoolNftId(uint256 productNftId)
+        external
+        view
+        override
+        returns(uint256 poolNftId)
+    {
+        poolNftId = _poolNftIdForProduct[productNftId];
+    }
+
+
+    function getComponentOwnerService()
+        external
+        override
+        view
+        returns(IComponentOwnerService)
+    {
+        return _componentOwnerService;
+    }
+
+    function setComponentInfo(ComponentInfo memory info)
+        external
+        onlyComponentOwnerService
+        returns(uint256 nftId)
+    {
+        uint256 id = info.nftId;
+        require(
+            id > 0 && _componentInfo[id].nftId == id,
+            "ERROR:CMP-005:COMPONENT_UNKNOWN");
+
+        _componentInfo[id] = info;
+
+        // add logging
+    }
+
+    function getComponentInfo(uint256 id)
+        external
+        override
+        view
+        returns(ComponentInfo memory)
+    {
+        return _componentInfo[id];
+    }
+
+    function getComponentOwner(uint256 id)
+        external
+        view
+        returns(address owner)
+    {
+
+    }
+
+    function getComponentId(address componentAddress)
+        external
+        view
+        returns(uint256 id)
+    {
+        return _idByAddress[componentAddress];
+    }
+
+
+    function getComponentId(uint256 idx)
+        external
+        override
+        view
+        returns(uint256 id)
+    {
+        return _ids[idx];
+    }
+
+
+    function components()
+        external
+        override
+        view
+        returns(uint256 numberOfCompnents)
+    {
+        return _ids.length;
+    }
+
+    function getRoleForType(uint256 cType)
+        public
+        view
+        returns(bytes32 role)
+    {
+        if(cType == this.getRegistry().PRODUCT()) {
+            return this.PRODUCT_OWNER_ROLE();
+        }
+        if(cType == this.getRegistry().POOL()) {
+            return this.POOL_OWNER_ROLE();
+        }
+        if(cType == this.getRegistry().ORACLE()) {
+            return this.ORACLE_OWNER_ROLE();
+        }
+
+    }
+}
+
+
+// this is actually the component owner service
+contract ComponentOwnerService is
+    RegistryLinked,
+    IComponent,
+    IComponentOwnerService
+{
+
+    modifier onlyComponentOwner(IComponentContract component) {
+        uint256 nftId = _registry.getNftId(address(component));
+        require(
+            nftId > 0, 
+            "ERROR:COS-001:COMPONENT_UNKNOWN");
+        require(
+            msg.sender == _registry.getOwner(nftId),
+            "ERROR:COS-002:NOT_OWNER"
+        );
+        _;
+    }
+
+    constructor(address registry)
+        RegistryLinked(registry)
+    { }
+
+
+    // modifier onlyComponentOwnerRole(IComponentContract component) {
+    //     IInstance instance = component.getInstance();
+    //     // TODO add set/getComponentOwnerRole to IComonentModule
+    //     bytes32 typeRole = instance.getComponentTypeRole(component.getType());
+    //     require(
+    //         instance.hasRole(typeRole, msg.sender),
+    //         "ERROR:COS-003:COMPONENT_ROLE_MISSING"
+    //     );
+    //     _;
+    // }
+
+
+    function register(IComponentContract component)
+        external
+        override
+        returns(uint256 nftId)
+    {
+        require(
+            msg.sender == component.getInitialOwner(), 
+            "ERROR:COS-003:NOT_OWNER");
+
+        IInstance instance = component.getInstance();
+        nftId = instance.registerComponent(component);
+    }
+
+
+    function lock(IComponentContract component)
+        external
+        override
+        onlyComponentOwner(component)
+    {
+        IInstance instance = component.getInstance();
+        ComponentInfo memory info = instance.getComponentInfo(component.getNftId());
+        require(info.nftId > 0, "ERROR_COMPONENT_UNKNOWN");
+        // TODO add state change validation
+
+        info.state = CState.Locked;
+        instance.setComponentInfo(info);
+    }
+
+
+    function unlock(IComponentContract component)
+        external
+        override
+        onlyComponentOwner(component)
+    {
+        IInstance instance = component.getInstance();
+        ComponentInfo memory info = instance.getComponentInfo(component.getNftId());
+        require(info.nftId > 0, "ERROR_COMPONENT_UNKNOWN");
+        // TODO state change validation
+
+        info.state = CState.Active;
+        instance.setComponentInfo(info);
+    }
+
+}

package/contracts/instance/component/IComponent.sol

@@ -0,0 +1,94 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+
+import {IOwnable, IRegistryLinked, IRegisterable} from "../../registry/IRegistry.sol";
+import {IInstance} from "../IInstance.sol";
+
+interface IComponent {
+
+    // TODO decide if enum or uints with constants (as in IRegistry.PRODUCT())
+    enum CState {
+        Undefined,
+        Active,
+        Locked
+    }
+
+    // component dynamic info (static info kept in registry)
+    struct ComponentInfo {
+        uint256 nftId;
+        CState state;
+    }
+}
+
+
+interface IInstanceLinked {
+    // function setInstance(address instance) external;
+    function getInstance() external view returns(IInstance instance);
+}
+
+
+interface IComponentContract is
+    IRegisterable,
+    IInstanceLinked,
+    IComponent
+{ }
+
+
+interface IComponentOwnerService is IRegistryLinked{
+
+    function register(IComponentContract component) external returns(uint256 id);
+    function lock(IComponentContract component) external;
+    function unlock(IComponentContract component) external;
+}
+
+
+interface IComponentModule is
+    IOwnable,
+    IRegistryLinked,
+    IComponent
+{
+
+    function registerComponent(IComponentContract component)
+        external
+        returns(uint256 nftInfo);
+
+    function setComponentInfo(ComponentInfo memory info)
+        external
+        returns(uint256 componentId);
+
+    function getComponentInfo(uint256 id)
+        external
+        view
+        returns(ComponentInfo memory info);
+
+    function getComponentOwner(uint256 id)
+        external
+        view
+        returns(address owner);
+
+    function getComponentId(address componentAddress)
+        external
+        view
+        returns(uint256 id);
+
+    function getComponentId(uint256 idx)
+        external
+        view
+        returns(uint256 id);
+
+    function getPoolNftId(uint256 productNftId)
+        external
+        view
+        returns(uint256 poolNftId);
+
+    function components()
+        external
+        view
+        returns(uint256 numberOfCompnents);
+
+    function getComponentOwnerService()
+        external
+        view
+        returns(IComponentOwnerService);
+}

package/contracts/instance/policy/IPolicy.sol

@@ -0,0 +1,66 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+
+import {IOwnable, IRegistryLinked, IRegisterable, IRegistry} from "../../registry/IRegistry.sol";
+import {IInstance} from "../IInstance.sol";
+
+import {IProductService} from "../product/IProductService.sol";
+
+// TODO check if there is value to introuce IContract and let IPolicy derive from IContract
+interface IPolicy {
+
+    enum PolicyState {
+        Undefined,
+        Applied,
+        Rejected,
+        Active,
+        Closed
+    }
+
+    struct PolicyInfo {
+        uint256 nftId;
+        PolicyState state; // applied, withdrawn, rejected, active, closed
+
+        uint256 sumInsuredAmount;
+        uint256 premiumAmount;
+        uint256 lifetime; // activatedAt + lifetime >= expiredAt
+
+        uint256 createdAt;
+        uint256 activatedAt; // time of underwriting
+        uint256 expiredAt; // no new claims
+        uint256 closedAt; // no locked capital
+    }
+}
+
+interface IPolicyModule is
+    IOwnable,
+    IRegistryLinked,
+    IPolicy
+{
+
+    function createApplication(
+        IRegistry.RegistryInfo memory productInfo,
+        address applicationOwner,
+        uint256 sumInsuredAmount,
+        uint256 premiumAmount,
+        uint256 lifetime,
+        uint256 bundleNftId
+    )
+        external
+        returns(uint256 nftId);
+
+    function activate(uint256 nftId)
+        external;
+
+    function getBundleNftForPolicy(uint256 nftId)
+        external
+        view
+        returns(uint256 bundleNft);
+
+    function getPolicyInfo(uint256 nftId)
+        external
+        view
+        returns(PolicyInfo memory info);
+
+}