@etherisc/gif-next 0.0.2-ebbe63d → 0.0.2-ef2f083-203

package/contracts/instance/service/IPoolService.sol

@@ -0,0 +1,37 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {NftId} from "../../types/NftId.sol";
+import {Fee} from "../../types/Fee.sol";
+import {IService} from "../../shared/IService.sol";
+
+interface IPoolService is IService {
+    function setFees(
+        Fee memory poolFee,
+        Fee memory stakingFee,
+        Fee memory performanceFee
+    ) external;
+
+    function createBundle(
+        address owner,
+        Fee memory fee, 
+        uint256 amount,
+        uint256 lifetime, 
+        bytes calldata filter
+    ) external returns(NftId bundleNftId);
+
+    function setBundleFee(
+        NftId bundleNftId,
+        Fee memory fee
+    ) external;
+
+    // function fundBundle(NftId bundleNftId, uint256 amount) external returns(uint256 netAmount);
+
+    // function defundBundle(NftId bundleNftId, uint256 amount) external returns(uint256 netAmount);
+
+    // function lockBundle(NftId bundleNftId) external;
+
+    // function unlockBundle(NftId bundleNftId) external;
+
+    // function closeBundle(NftId bundleNftId) external;
+}

package/contracts/instance/service/IProductService.sol

@@ -0,0 +1,107 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRisk} from "../module/IRisk.sol";
+import {IService} from "../../shared/IService.sol";
+
+import {NftId} from "../../types/NftId.sol";
+import {ReferralId} from "../../types/Referral.sol";
+import {RiskId} from "../../types/RiskId.sol";
+import {StateId} from "../../types/StateId.sol";
+import {Timestamp} from "../../types/Timestamp.sol";
+import {UFixed} from "../../types/UFixed.sol";
+import {Fee} from "../../types/Fee.sol";
+
+interface IProductService is IService {
+    function setFees(
+        Fee memory productFee,
+        Fee memory processingFee
+    ) external;
+
+    function createRisk(
+        RiskId riskId,
+        bytes memory data
+    ) external;
+
+
+    function setRiskInfo(
+        RiskId riskId,
+        IRisk.RiskInfo memory data
+    ) external;
+
+
+    function updateRiskState(
+        RiskId riskId,
+        StateId state
+    ) external;
+
+
+    function calculatePremium(
+        RiskId riskId,
+        uint256 sumInsuredAmount,
+        uint256 lifetime,
+        bytes memory applicationData,
+        NftId bundleNftId,
+        ReferralId referralId
+    )
+        external
+        view
+        returns (
+            uint256 premiumAmount,
+            uint256 productFeeAmount,
+            uint256 poolFeeAmount,
+            uint256 bundleFeeAmount,
+            uint256 distributionFeeAmount
+        );
+
+
+    function createApplication(
+        address applicationOwner,
+        RiskId riskId,
+        uint256 sumInsuredAmount,
+        uint256 lifetime,
+        bytes memory applicationData,
+        NftId bundleNftId,
+        ReferralId referralId
+    ) external returns (NftId nftId);
+
+    /**
+     * @dev revokes the application represented by {policyNftId}.
+     * an application can only be revoked in applied state.
+     * only the application holder may revoke an application.
+     */
+    function revoke(NftId policyNftId) external;
+
+    /**
+     * @dev underwrites the policy represented by {policyNftId}.
+     * optionally collects premiums and activates the policy.
+     * - premium payment is only attempted if requirePremiumPayment is set to true
+     * - activation is only done if activateAt is a non-zero timestamp
+     */
+    function underwrite(
+        NftId policyNftId,
+        bool requirePremiumPayment,
+        Timestamp activateAt
+    ) external;
+
+    // function decline(uint256 nftId) external;
+    // function expire(uint256 nftId) external;
+
+    function collectPremium(NftId policyNftId, Timestamp activateAt) external;
+
+    function activate(NftId policyNftId, Timestamp activateAt) external;
+
+
+    function close(NftId nftId) external;
+
+    // function createClaim(uint256 nftId, uint256 claimAmount) external;
+    // function confirmClaim(uint256 nftId, uint256 claimId, uint256 claimAmount) external;
+    // function declineClaim(uint256 nftId, uint256 claimId) external;
+    // function closeClaim(uint256 nftId, uint256 claimId) external;
+
+    function calculateRequiredCollateral(
+        UFixed collateralizationLevel, 
+        uint256 sumInsuredAmount
+    ) external pure returns(uint256 collateralAmount);
+
+}

package/contracts/registry/ChainNft.sol

@@ -0,0 +1,202 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ERC721, ERC721Enumerable} from "@openzeppelin/contracts/token/ERC721/extensions/ERC721Enumerable.sol";
+import {IERC721} from "@openzeppelin/contracts/token/ERC721/IERC721.sol";
+
+import {ITransferInterceptor} from "./ITransferInterceptor.sol";
+
+contract ChainNft is ERC721Enumerable {
+
+    // constants
+    string public constant NAME = "Dezentralized Insurance Protocol NFT";
+    string public constant SYMBOL = "DIPNFT";
+
+    uint256 public constant PROTOCOL_NFT_ID = 1101;
+    uint256 public constant GLOBAL_REGISTRY_ID = 2101;
+
+    // custom errors
+    error CallerNotRegistry(address caller);
+    error RegistryAddressZero();
+    error NftUriEmpty();
+    error NftUriAlreadySet();
+
+    // contract state
+
+    // remember interceptors
+    mapping(uint256 tokenId => address interceptor) private _interceptor;
+
+    // remember token uri
+    mapping(uint256 tokenId => string uri) private _uri;
+
+    // remember registry
+    address private _registry;
+
+    // only used for _getNextTokenId
+    uint256 internal _chainIdInt;
+    uint256 internal _chainIdDigits;
+    uint256 internal _chainIdMultiplier;
+    uint256 internal _idNext;
+    uint256 internal _totalMinted;
+
+    modifier onlyRegistry() {
+        if (msg.sender != _registry) { revert CallerNotRegistry(msg.sender); }
+        _;
+    }
+
+    constructor(address registry) ERC721(NAME, SYMBOL) {
+        if (registry == address(0)) { revert RegistryAddressZero(); }
+
+        _registry = registry;
+        _chainIdInt = block.chainid;
+        _chainIdDigits = 0;
+
+        // count digis
+        uint256 num = _chainIdInt;
+        while (num != 0) {
+            _chainIdDigits++;
+            num /= 10;
+        }
+
+        _chainIdMultiplier = 10 ** _chainIdDigits;
+        _idNext = 4;
+    }
+
+    /**
+    * @dev mints a token for a specified token id
+    * not part of the IRegistry interface only needed for
+    * initial registry setup (protocol and global registry objects)
+    */
+    function mint(address to, uint256 tokenId) external onlyRegistry {
+        _totalMinted++;
+        _safeMint(to, tokenId);
+    }
+
+
+    /**
+    * @dev mints the next token to register new objects
+    * non-zero transferInterceptors are recorded and called during nft token transfers.
+    * the contract receiving such a notification may decides to revert or record the transfer
+    */
+    function mint(
+        address to,
+        address interceptor,
+        string memory uri
+    ) public onlyRegistry returns (uint256 tokenId) {
+        tokenId = _getNextTokenId();
+
+        if (interceptor != address(0)) {
+            _interceptor[tokenId] = interceptor;
+        }
+
+        if (bytes(uri).length > 0) {
+            _uri[tokenId] = uri;
+        }
+
+        _totalMinted++;
+        _safeMint(to, tokenId);
+    }
+
+
+    /**
+     * @dev amend the open zeppelin transferFrom function by an interceptor call if such an interceptor is defined for the nft token id
+     * this allows distribution, product and pool components to be notified when distributors, policies and bundles are transferred.
+     */
+    function transferFrom(address from, address to, uint256 tokenId) public override (ERC721, IERC721) {
+        super.transferFrom(from, to, tokenId);
+
+        if (_interceptor[tokenId] != address(0)) {
+            ITransferInterceptor(_interceptor[tokenId]).nftTransferFrom(from, to, tokenId);
+        }
+    }
+
+
+    function burn(uint256 tokenId) external onlyRegistry {
+        _requireOwned(tokenId);
+        _burn(tokenId);
+        delete _uri[tokenId];
+    }
+
+    function setURI(
+        uint256 tokenId,
+        string memory uri
+    ) external onlyRegistry {
+        if (bytes(uri).length == 0) { revert NftUriEmpty(); }
+        if (bytes(_uri[tokenId]).length > 0) { revert NftUriAlreadySet(); }
+
+        _requireOwned(tokenId);
+        _uri[tokenId] = uri;
+    }
+
+    function exists(uint256 tokenId) external view returns (bool) {
+        return _ownerOf(tokenId) != address(0);
+    }
+
+    function tokenURI(
+        uint256 tokenId
+    ) public view override returns (string memory) {
+        // gif generally does not revert for view functions
+        // this is an exception to keep the openzeppelin nft semantics
+        _requireOwned(tokenId);
+        return _uri[tokenId];
+    }
+
+    function getInterceptor(uint256 tokenId) external view returns (address) {
+        return _interceptor[tokenId];
+    }
+
+    function getRegistryAddress() external view returns (address) {
+        return _registry;
+    }
+
+    function totalMinted() external view returns (uint256) {
+        return _totalMinted;
+    }
+
+    /**
+    * @dev token id calculation based on an index value that is supposed
+    * to increase with every minted token
+    *
+    * requirement: each chain registry produces token ids that
+    * are guaranteed to not collide with any token id genereated
+    * on a different chain
+    *
+    * format concat(counter,chainid,2 digits for len-of-chain-id)
+    * restriction chainid up to 99 digits
+    * decode: from right to left:
+    * - 2 right most digits encode length of chainid
+    * - move number of digits to left as determined above (-> chainid)
+    * - the reminder to the left is the counter
+    *
+    * special cases
+    * 1101 -> decentralized insurance protocol
+    * 2102 -> global registry
+    * 2xxxxx -> chain registry, where xxxxx = <chain-part> 
+    *
+    * examples
+    * 1101
+    * ^^ ^
+    * || +- 1-digit chain id
+    * |+-- chain id = 1 (mainnet)
+    * +-- 1st token id on mainnet
+    * (1 * 10 ** 1 + 1) * 100 + 1
+    * 42987654321010
+    * ^ ^          ^
+    * | |          +- 10-digit chain id
+    * | +-- chain id = 9876543210 (hypothetical chainid)
+    * +-- 42nd token id on this chain
+    * (42 * 10 ** 10 + 9876543210) * 100 + 10
+    * (index * 10 ** digits + chainid) * 100 + digits (1 < digits < 100)
+    */
+    function calculateTokenId(uint256 idIndex) public view returns (uint256 id) {
+        id =
+            (idIndex * _chainIdMultiplier + _chainIdInt) *
+            100 +
+            _chainIdDigits;
+    }
+
+    function _getNextTokenId() private returns (uint256 id) {
+        id = calculateTokenId(_idNext);
+        _idNext++;
+    }
+}

package/contracts/registry/IRegistry.sol

@@ -0,0 +1,94 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
+
+import {ChainNft} from "./ChainNft.sol";
+import {NftId} from "../types/NftId.sol";
+import {ObjectType} from "../types/ObjectType.sol";
+import {VersionPart} from "../types/Version.sol";
+
+interface IRegistry is IERC165 {
+
+    event LogInitialMajorVersionSet(VersionPart majorVersion);
+    event LogMajorVersionSet(VersionPart majorVersionMax);
+    event LogRegistration(ObjectInfo info);
+    event LogTokenStateSet(address token, VersionPart majorVersion, bool active);
+    event LogServiceNameRegistration(string serviceName, VersionPart majorVersion); 
+
+    // supported versions
+    error MajorVersionMaxIncreaseInvalid(VersionPart newMajorVersionMax, VersionPart existingMaxMajorVersion);
+
+    // token whitelisting
+    error TokenNotRegistered(address token);
+    error NotToken(address token);
+    error TokenMajorVersionInvalid(VersionPart majorVersion);
+
+    // register
+    error NotRegistryService();
+    error ZeroParentAddress();
+    error ContractAlreadyRegistered(address objectAddress);
+    error InvalidServiceVersion(VersionPart majorVersion);
+    error ServiceNameAlreadyRegistered(string name, VersionPart majorVersion);
+            
+    // approve
+    error NotOwner(address account);
+    error NotRegisteredContract(NftId registrarNftId);
+    error NotService(NftId registrarNftId);
+    error InvalidTypesCombination(ObjectType objectType, ObjectType parentType);
+
+
+    struct ObjectInfo {
+        NftId nftId;
+        NftId parentNftId;
+        ObjectType objectType;
+        bool isInterceptor;
+        address objectAddress;
+        address initialOwner;
+        bytes data;
+    }// TODO delete nftId and initialOwner(if not used) from struct
+    // TODO strong disagree, keep nftId there (lets keep get object info return object consistent)
+
+    function setMajorVersion(VersionPart newMajorVersionMax) external;
+
+    function register(ObjectInfo memory info) external returns (NftId nftId);
+
+    function setTokenActive(address token, VersionPart majorVersion, bool active) external;
+
+    function getMajorVersionMin() external view returns (VersionPart);
+
+    function getMajorVersionMax() external view returns (VersionPart);
+
+    function getMajorVersion() external view returns (VersionPart);
+
+    function getObjectCount() external view returns (uint256);
+
+    function getNftId() external view returns (NftId nftId);
+
+    function getNftId(address objectAddress) external view returns (NftId nftId);
+
+    function ownerOf(NftId nftId) external view returns (address);
+
+    function ownerOf(address contractAddress) external view returns (address);
+
+    function getObjectInfo(NftId nftId) external view returns (ObjectInfo memory info);
+
+    function getObjectInfo(address object) external view returns (ObjectInfo memory info);
+
+    function isRegistered(NftId nftId) external view returns (bool);
+
+    function isRegistered(address contractAddress) external view returns (bool);
+
+    function isTokenActive(address token, VersionPart majorVersion) external view returns (bool);
+
+    function getServiceName(NftId nftId) external view returns (string memory name);
+
+    function getServiceAddress(
+        string memory serviceName, 
+        VersionPart majorVersion
+    ) external view returns (address serviceAddress);
+
+    function getChainNft() external view returns (ChainNft);
+
+    function getOwner() external view returns (address);
+}

package/contracts/registry/IRegistryService.sol

@@ -0,0 +1,33 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {NftId} from "../types/NftId.sol";
+import {ObjectType} from "../types/ObjectType.sol";
+import {RoleId} from "../types/RoleId.sol";
+import {IService} from "../shared/IService.sol";
+import {IRegistry} from "./IRegistry.sol";
+
+import {IRegisterable} from "../shared/IRegisterable.sol";
+import {IBaseComponent} from "../components/IBaseComponent.sol";
+
+interface IRegistryService is IService {
+
+    function registerService(IService service)  external returns(IRegistry.ObjectInfo memory info, bytes memory data);
+
+    function registerInstance(IRegisterable instance)
+        external returns(IRegistry.ObjectInfo memory info, bytes memory data); 
+
+    function registerProduct(IBaseComponent product, address owner)
+         external returns(IRegistry.ObjectInfo memory info, bytes memory data);
+
+    function registerPool(IBaseComponent pool, address owner)
+         external returns(IRegistry.ObjectInfo memory info, bytes memory data);
+
+    function registerDistribution(IBaseComponent distribution, address owner)
+         external returns(IRegistry.ObjectInfo memory info, bytes memory data);
+
+    function registerPolicy(IRegistry.ObjectInfo memory info) external returns(NftId nftId); // -> easy to upgrade
+
+    function registerBundle(IRegistry.ObjectInfo memory info) external returns(NftId nftId); 
+}
+

package/contracts/registry/ITransferInterceptor.sol

@@ -0,0 +1,6 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+interface ITransferInterceptor {
+    function nftTransferFrom(address from, address to, uint256 tokenId) external;
+}