@etherisc/gif-next 0.0.2-ebbe63d → 0.0.2-ed4dd55

package/contracts/instance/product/ProductService.sol

@@ -0,0 +1,105 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+
+// import {IProduct} from "../../components/IProduct.sol";
+// import {IOwnable, IRegistryLinked, IRegisterable, IRegistry} from "../../registry/IRegistry.sol";
+// import {IInstance} from "../IInstance.sol";
+import {IRegistry} from "../../registry/IRegistry.sol";
+import {IPolicyModule} from "../policy/IPolicy.sol";
+import {RegistryLinked} from "../../registry/Registry.sol";
+import {IProductService, IProductModule} from "./IProductService.sol";
+import {IComponentModule} from "../../instance/component/IComponent.sol";
+import {IPoolModule} from "../../instance/pool/IPoolModule.sol";
+
+// TODO or name this ProtectionService to have Product be something more generic (loan, savings account, ...)
+contract ProductService is
+    RegistryLinked,
+    IProductService
+{
+    constructor(address registry) 
+        RegistryLinked(registry)
+    { }
+
+
+    function createApplication(
+        address applicationOwner,
+        uint256 sumInsuredAmount,
+        uint256 premiumAmount,
+        uint256 lifetime,
+        uint256 bundleNftId
+    )
+        external 
+        override
+        returns(uint256 nftId)
+    {
+        // same as only registered product
+        uint256 productNftId = _registry.getNftId(msg.sender);
+        require(productNftId > 0, "ERROR_PRODUCT_UNKNOWN");
+        IRegistry.RegistryInfo memory productInfo = _registry.getInfo(productNftId);
+        require(productInfo.objectType == _registry.PRODUCT(), "ERROR_NOT_PRODUCT");
+
+        IRegistry.RegistryInfo memory instanceInfo = _registry.getInfo(productInfo.parentNftId);
+        require(instanceInfo.nftId > 0, "ERROR_INSTANCE_UNKNOWN");
+        require(instanceInfo.objectType == _registry.INSTANCE(), "ERROR_NOT_INSTANCE");
+
+        IPolicyModule policyModule = IPolicyModule(instanceInfo.objectAddress);
+        nftId = policyModule.createApplication(
+            productInfo,
+            applicationOwner,
+            sumInsuredAmount,
+            premiumAmount,
+            lifetime,
+            bundleNftId);
+
+        // add logging
+    }
+
+    function underwrite(uint256 nftId)
+        external
+        override
+    {
+        // same as only registered product
+        uint256 productNftId = _registry.getNftId(msg.sender);
+        require(productNftId > 0, "ERROR_PRODUCT_UNKNOWN");
+        IRegistry.RegistryInfo memory productInfo = _registry.getInfo(productNftId);
+        require(productInfo.objectType == _registry.PRODUCT(), "ERROR_NOT_PRODUCT");
+
+        IRegistry.RegistryInfo memory instanceInfo = _registry.getInfo(productInfo.parentNftId);
+        require(instanceInfo.nftId > 0, "ERROR_INSTANCE_UNKNOWN");
+        require(instanceInfo.objectType == _registry.INSTANCE(), "ERROR_NOT_INSTANCE");
+
+        // get responsible pool
+        IComponentModule componentModule = IComponentModule(instanceInfo.objectAddress);
+        uint256 poolNftId = componentModule.getPoolNftId(productNftId);
+
+        // lock capital (and update pool accounting)
+        IPoolModule poolModule = IPoolModule(instanceInfo.objectAddress);
+        poolModule.underwrite(
+            poolNftId,
+            nftId);
+
+        // activate policy
+        IPolicyModule policyModule = IPolicyModule(instanceInfo.objectAddress);
+        policyModule.activate(nftId);
+
+        // add logging
+    }
+
+    function close(uint256 nftId) external override {}
+}
+
+abstract contract ProductModule is
+    IProductModule
+{
+    IProductService private _productService;
+
+    constructor(address productService) {
+        _productService = IProductService(productService);
+    }
+
+    function getProductService() external view returns(IProductService) {
+        return _productService;
+    }
+
+}

package/contracts/registry/ChainNft.sol

@@ -0,0 +1,173 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {ERC721, ERC721Enumerable} from "@openzeppelin/contracts/token/ERC721/extensions/ERC721Enumerable.sol";
+import {IChainNft} from "./IChainNft.sol";
+
+contract ChainNft is
+    ERC721Enumerable,
+    IChainNft
+{
+    string public constant NAME = "Dezentralized Insurance Protocol Registry";
+    string public constant SYMBOL = "DIPR";
+
+    // remember token uri
+    mapping(uint256 tokenId => string uri) private _uri;
+
+    // remember registry
+    address private _registry;
+
+    // only used for _getNextTokenId
+    uint256 internal _chainIdInt; 
+    uint256 internal _chainIdDigits;
+    uint256 internal _chainIdMultiplier;
+    uint256 internal _idNext;
+    uint256 internal _totalMinted;
+
+
+    modifier onlyRegistry() {
+        require(msg.sender == _registry, "ERROR:NFT-001:CALLER_NOT_REGISTRY");
+        _;
+    }
+
+
+    constructor(address registry)
+        ERC721(NAME, SYMBOL)
+    {
+        require(registry != address(0), "ERROR:NFT-010:REGISTRY_ZERO");
+
+        _registry = registry;
+
+        _chainIdInt = block.chainid;
+        _chainIdDigits = _countDigits(_chainIdInt);
+        _chainIdMultiplier = 10 ** _chainIdDigits;
+
+        // on mainnet/goerli start /1 (reserved for protocol nft) on other chains with 2
+        if(block.chainid == 1 || block.chainid == 5) {
+            _idNext = 1;
+        } else {
+            _idNext = 2;
+        }
+    }
+
+
+    function mint(
+        address to,
+        string memory uri
+    )
+        external
+        override
+        onlyRegistry
+        returns(uint256 tokenId)
+    {
+        tokenId = _getNextTokenId();
+        _totalMinted++;
+
+        _safeMint(to, tokenId);
+
+        if(bytes(uri).length > 0) {
+            _uri[tokenId] = uri;
+        }
+    }
+
+
+    function burn(uint256 tokenId)
+        external
+        override
+        onlyRegistry
+    {
+        _requireMinted(tokenId);
+        _burn(tokenId);
+        delete _uri[tokenId];
+    }
+
+
+    function setURI(uint256 tokenId, string memory uri)
+        external
+        override
+        onlyRegistry
+    {
+        require(bytes(uri).length > 0, "ERROR:CRG-011:URI_EMPTY");
+
+        _requireMinted(tokenId);
+        _uri[tokenId] = uri;
+    }
+
+
+    function exists(uint256 tokenId)
+        external
+        view
+        override
+        returns(bool)
+    {
+        return _exists(tokenId);
+    }
+
+
+    function tokenURI(uint256 tokenId)
+        public
+        view
+        override 
+        returns(string memory)
+    {
+        _requireMinted(tokenId);
+        return _uri[tokenId];
+    }
+
+
+    function getRegistryAddress()
+        external
+        view
+        override
+        returns(address)
+    {
+        return _registry;
+    }
+
+    function totalMinted() external override view returns(uint256) {
+        return _totalMinted;
+    }
+
+    // requirement: each chain registry produces token ids that
+    // are guaranteed to not collide with any token id genereated
+    // on a different chain
+    //
+    // format concat(counter,chainid,2 digits for len-of-chain-id)
+    // restriction chainid up to 99 digits
+    // decode: from right to left:
+    // - 2 right most digits encode length of chainid
+    // - move number of digits to left as determined above (-> chainid)
+    // - the reminder to the left is the counter
+    // examples
+    // 1101
+    // ^^ ^
+    // || +- 1-digit chain id
+    // |+-- chain id = 1 (mainnet)
+    // +-- 1st token id on mainnet
+    // (1 * 10 ** 1 + 1) * 100 + 1
+    // 42987654321010
+    // ^ ^          ^
+    // | |          +- 10-digit chain id
+    // | +-- chain id = 9876543210 (hypothetical chainid)
+    // +-- 42nd token id on this chain
+    // (42 * 10 ** 10 + 9876543210) * 100 + 10
+    // (index * 10 ** digits + chainid) * 100 + digits (1 < digits < 100)
+
+    function _getNextTokenId() private returns(uint256 id) {
+        id = (_idNext * _chainIdMultiplier + _chainIdInt) * 100 + _chainIdDigits;
+        _idNext++;
+    }
+
+
+    function _countDigits(uint256 num)
+        private 
+        pure 
+        returns (uint256 count)
+    {
+        count = 0;
+        while (num != 0) {
+            count++;
+            num /= 10;
+        }
+    }
+}

package/contracts/registry/IChainNft.sol

@@ -0,0 +1,18 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IERC721Enumerable} from "@openzeppelin/contracts/token/ERC721/extensions/IERC721Enumerable.sol";
+
+interface IChainNft is 
+    IERC721Enumerable 
+{
+
+    function mint(address to, string memory uri) external returns(uint256 tokenId);
+    function burn(uint256 tokenId) external;
+    function setURI(uint256 tokenId, string memory uri) external;
+
+    function exists(uint256 tokenId) external view returns(bool);
+    function totalMinted() external view returns(uint256);
+
+    function getRegistryAddress() external view returns(address registry);
+}

package/contracts/registry/IRegistry.sol

@@ -0,0 +1,68 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+interface IOwnable {
+    function getOwner() external view returns(address owner);
+}
+
+interface IRegistryLinked {
+
+    event LogDebug(uint256 idx, address module, string comment);
+
+    function getRegistry() external view returns(IRegistry registry);
+}
+
+interface IRegisterable is 
+    IOwnable,
+    IRegistryLinked
+{
+
+    function register() external returns(uint256 nftId);
+    
+    function getNftId() external view returns(uint256 nftId);
+    function getParentNftId() external view returns(uint256 parentNftId);
+    function getType() external view returns(uint256 objectType);
+    function getData() external view returns(bytes memory data);
+    function isRegisterable() external pure returns(bool);
+    function getInitialOwner() external view returns(address initialOwner);
+
+    function isRegistered() external view returns(bool);
+}
+
+
+interface IRegistry {
+
+    struct RegistryInfo {
+        uint256 nftId;
+        uint256 parentNftId;
+        uint256 objectType;
+        address objectAddress;
+        address initialOwner;
+    }
+
+    function TOKEN() external pure returns(uint256);
+    function INSTANCE() external pure returns(uint256);
+    function PRODUCT() external pure returns(uint256);
+    function ORACLE() external pure returns(uint256);
+    function POOL() external pure returns(uint256);
+    function POLICY() external pure returns(uint256);
+    function BUNDLE() external pure returns(uint256);
+
+    function register(address objectAddress) external returns(uint256 nftId);
+    function registerObjectForInstance(
+        uint256 parentNftid,
+        uint256 objectType,
+        address initialOwner
+    )
+        external returns(uint256 nftId);
+
+    function getObjectCount() external view returns(uint256);
+
+    function getNftId(address objectAddress) external view returns(uint256 nftId);
+    function getInfo(uint256 nftId) external view returns(RegistryInfo memory info);
+    function getOwner(uint256 nftId) external view returns(address ownerAddress);
+
+    function isRegistered(address objectAddress) external view returns(bool);
+
+    function getNftAddress() external view returns(address nft);
+}

package/contracts/registry/Registry.sol

@@ -0,0 +1,176 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IChainNft} from "./IChainNft.sol";
+import {IRegistry, IRegistryLinked, IRegisterable} from "./IRegistry.sol";
+
+contract RegistryLinked is IRegistryLinked {
+
+    IRegistry internal _registry;
+    
+    constructor(address registry) {
+        _registry = IRegistry(registry);
+    }
+
+    function getRegistry() external view override returns(IRegistry registry) {
+        return _registry;
+    }
+
+}
+
+
+abstract contract Registerable is 
+    RegistryLinked,
+    IRegisterable
+{
+
+    address private _initialOwner;
+    
+    constructor(address registry)
+        RegistryLinked(registry)
+    {
+        _initialOwner = msg.sender;
+    }
+
+    // getType, getData and register need to be implemented by concrete contract
+
+    function isRegisterable() external pure override returns(bool) {
+        return true;
+    }
+
+    function getInitialOwner() public view override returns(address deployer) {
+        return _initialOwner;
+    }
+
+    function isRegistered() public view override returns(bool) {
+        return _registry.getNftId(address(this)) > 0;
+    }
+
+    function getNftId() public view override returns(uint256 id) {
+        return _registry.getNftId(address(this));
+    }
+
+    function getOwner() public view override returns(address owner) {
+        uint256 id = _registry.getNftId(address(this));
+        owner = _registry.getOwner(id);
+        return owner != address(0) ? owner : _initialOwner;
+    }
+
+}
+
+contract Registry is IRegistry {
+
+    string public constant EMPTY_URI = "";
+
+    mapping(uint256 id => RegistryInfo info) private _info;
+    mapping(uint256 id => address owner) private _owner;
+    mapping(address object => uint256 id) private _idByAddress;
+
+    IChainNft private _chainNft;
+
+    function initialize(address chainNft) external {
+        require(address(_chainNft) == address(0), "ERROR:REG-001:ALREADY_INITIALIZED");
+        _chainNft = IChainNft(chainNft);
+    }
+
+    function TOKEN() public pure override returns(uint256) { return 30; }
+    function INSTANCE() public pure override returns(uint256) { return 40; }
+    function PRODUCT() public pure override returns(uint256) { return 50; }
+    function ORACLE() public pure override returns(uint256) { return 60; }
+    function POOL() public pure override returns(uint256) { return 70; }
+    function POLICY() public pure override returns(uint256) { return 80; }
+    function BUNDLE() public pure override returns(uint256) { return 90; }
+
+    function register(address objectAddress) external override returns(uint256 nftId) {
+        require(_idByAddress[objectAddress] == 0, "ERROR:REG-001:ALREADY_REGISTERED");
+
+        IRegisterable registerable = IRegisterable(objectAddress);
+        require(registerable.isRegisterable(), "ERROR:REG-002:NOT_REGISTERABLE");
+
+        // check parent exists (for objects not instances)
+        if(registerable.getType() != INSTANCE()) {
+            RegistryInfo memory parentInfo = _info[registerable.getParentNftId()];
+            require(parentInfo.nftId > 0, "ERROR:REG-003:PARENT_NOT_FOUND");
+            // check validity of parent relation, valid relations are
+            // policy -> product, bundle -> pool, product -> instance, pool -> instance
+        }
+
+        nftId = _chainNft.mint(
+            registerable.getInitialOwner(), 
+            EMPTY_URI);
+    
+        RegistryInfo memory info = RegistryInfo(
+            nftId,
+            registerable.getParentNftId(),
+            registerable.getType(),
+            objectAddress,
+            registerable.getInitialOwner()
+        );
+
+        _info[nftId] = info;
+        _idByAddress[objectAddress] = nftId;
+
+        // add logging
+    }
+
+
+    function registerObjectForInstance(
+        uint256 parentNftId,
+        uint256 objectType,
+        address initialOwner
+    )
+        external 
+        override
+        // TODO add onlyRegisteredInstance
+        returns(uint256 nftId)
+    {
+        // TODO add more validation
+        require(
+            objectType == POLICY() || objectType == BUNDLE(),
+            "ERROR:REG-005:TYPE_INVALID");
+
+        nftId = _chainNft.mint(
+            initialOwner,
+            EMPTY_URI);
+
+        RegistryInfo memory info = RegistryInfo(
+            nftId,
+            parentNftId,
+            objectType,
+            address(0),
+            initialOwner
+        );
+
+        _info[nftId] = info;
+
+        // add logging
+    }
+
+
+    function getObjectCount() external view override returns(uint256) {
+        return _chainNft.totalSupply();
+    }
+
+
+    function getNftId(address object) external view override returns(uint256 id) {
+        return _idByAddress[object];
+    }
+
+
+    function isRegistered(address object) external view override returns(bool) {
+        return _idByAddress[object] > 0;
+    }
+
+
+    function getInfo(uint256 nftId) external view override returns(RegistryInfo memory info) {
+        return _info[nftId];
+    }
+
+    function getOwner(uint256 nftId) external view override returns(address) {
+        return _chainNft.ownerOf(nftId);
+    }
+
+    function getNftAddress() external view override returns(address nft) {
+        return address(_chainNft);
+    }
+}

package/contracts/types/ChainId.sol

@@ -0,0 +1,24 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+// bytes5 (uint40) allows for chain ids up to 13 digits
+type ChainId is bytes5;
+
+// type bindings
+using {
+    eqChainId as ==,
+    neChainId as !=,
+    ChainIdLib.toInt
+} for ChainId global;
+
+// general pure free functions
+function toChainId(uint256 chainId) pure returns(ChainId) { return ChainId.wrap(bytes5(uint40(chainId))); }
+
+// pure free functions for operators
+function eqChainId(ChainId a, ChainId b) pure returns(bool isSame) { return ChainId.unwrap(a) == ChainId.unwrap(b); }
+function neChainId(ChainId a, ChainId b) pure returns(bool isDifferent) { return ChainId.unwrap(a) != ChainId.unwrap(b); }
+
+// library functions that operate on user defined type
+library ChainIdLib {
+    function toInt(ChainId chainId) internal pure returns(uint256) { return uint256(uint40(ChainId.unwrap(chainId))); }
+}

package/contracts/types/NftId.sol

@@ -0,0 +1,25 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+// uint96 allows for chain ids up to 13 digits
+type NftId is uint96;
+
+// type bindings
+using {
+    eqNftId as ==,
+    neNftId as !=,
+    NftIdLib.toInt
+} for NftId global;
+
+// general pure free functions
+function toNftId(uint256 id) pure returns(NftId) { return NftId.wrap(uint96(id)); }
+function gtz(NftId a) pure returns(bool) { return NftId.unwrap(a) > 0; }
+
+// pure free functions for operators
+function eqNftId(NftId a, NftId b) pure returns(bool isSame) { return NftId.unwrap(a) == NftId.unwrap(b); }
+function neNftId(NftId a, NftId b) pure returns(bool isDifferent) { return NftId.unwrap(a) != NftId.unwrap(b); }
+
+// library functions that operate on user defined type
+library NftIdLib {
+    function toInt(NftId nftId) internal pure returns(uint256) { return uint256(NftId.unwrap(nftId)); }
+}

package/package.json

@@ -1,14 +1,14 @@
 {
   "name": "@etherisc/gif-next",
-  "version": "0.0.2-ebbe63d",
+  "version": "0.0.2-ed4dd55",
   "description": "This is the repository for the next version of the Generic Insurance Framework (GIF) smart contracts. ",
   "main": "index.js",
   "scripts": {
-    "build": "hardhat compile",
-    "test": "hardhat test",
-    "ptest": "hardhat test --parallel",
-    "test-with-gas": "REPORT_GAS=true hardhat test",
-    "coverage": "hardhat coverage"
+    "build": "hh compile",
+    "test": "hh test",
+    "ptest": "hh test --parallel",
+    "test-with-gas": "REPORT_GAS=true hh test",
+    "coverage": "hh coverage"
   },
   "repository": {
     "type": "git",
@@ -27,6 +27,7 @@
   "devDependencies": {
     "@nomicfoundation/hardhat-foundry": "^1.0.3",
     "@nomicfoundation/hardhat-toolbox": "^3.0.0",
+    "dotenv": "^16.3.1",
     "hardhat": "^2.17.1"
   },
   "dependencies": {

package/artifacts/contracts/Dip.sol/DIP.dbg.json

@@ -1,4 +0,0 @@
-{
-  "_format": "hh-sol-dbg-1",
-  "buildInfo": "../../build-info/d6ddc31c8d0f29d05ebcf7dbd3184aca.json"
-}