@etherisc/gif-next 0.0.2-e9a637d-547 → 0.0.2-eadf4ad-211

package/contracts/product/ApplicationService.sol

@@ -0,0 +1,187 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {AmountLib} from "../type/Amount.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {Timestamp, TimestampLib, zeroTimestamp} from "../type/Timestamp.sol";
+import {UFixed, UFixedLib} from "../type/UFixed.sol";
+import {Blocknumber, blockNumber} from "../type/Blocknumber.sol";
+import {ObjectType, DISTRIBUTION, INSTANCE, PRODUCT, POOL, APPLICATION, POLICY, BUNDLE, PRICE} from "../type/ObjectType.sol";
+import {APPLIED, REVOKED, ACTIVE, KEEP_STATE} from "../type/StateId.sol";
+import {NftId, NftIdLib, zeroNftId} from "../type/NftId.sol";
+import {Fee, FeeLib} from "../type/Fee.sol";
+import {ReferralId} from "../type/Referral.sol";
+import {RiskId} from "../type/RiskId.sol";
+import {StateId} from "../type/StateId.sol";
+import {Version, VersionLib} from "../type/Version.sol";
+import {Amount, AmountLib} from "../type/Amount.sol";
+
+import {TokenHandler} from "../shared/TokenHandler.sol";
+import {IVersionable} from "../shared/IVersionable.sol";
+import {Versionable} from "../shared/Versionable.sol";
+import {IService} from "../shared/IService.sol";
+import {Service} from "../shared/Service.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+
+import {IProductComponent} from "./IProductComponent.sol";
+import {IPoolComponent} from "../pool/IPoolComponent.sol";
+import {IDistributionComponent} from "../distribution/IDistributionComponent.sol";
+import {Product} from "./Product.sol";
+
+import {IComponents} from "../instance/module/IComponents.sol";
+import {IPolicy} from "../instance/module/IPolicy.sol";
+import {IRisk} from "../instance/module/IRisk.sol";
+import {IBundle} from "../instance/module/IBundle.sol";
+import {IProductService} from "./IProductService.sol";
+import {ITreasury} from "../instance/module/ITreasury.sol";
+import {ISetup} from "../instance/module/ISetup.sol";
+
+import {ComponentService} from "../shared/ComponentService.sol";
+
+import {IInstance} from "../instance/IInstance.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+
+import {IApplicationService} from "./IApplicationService.sol";
+import {IBundleService} from "../pool/IBundleService.sol";
+import {IDistributionService} from "../distribution/IDistributionService.sol";
+import {IPoolService} from "../pool/IPoolService.sol";
+import {IPricingService} from "./IPricingService.sol";
+
+
+contract ApplicationService is 
+    ComponentService, 
+    IApplicationService
+{
+    IDistributionService internal _distributionService;
+    IPricingService internal _pricingService;
+
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        virtual override
+        initializer()
+    {
+        (
+            address registryAddress,, 
+            //address managerAddress
+            address authority
+        ) = abi.decode(data, (address, address, address));
+
+        initializeService(registryAddress, authority, owner);
+        registerInterface(type(IApplicationService).interfaceId);
+
+        _distributionService = IDistributionService(_getServiceAddress(DISTRIBUTION()));
+        _pricingService = IPricingService(_getServiceAddress(PRICE()));
+    }
+
+
+    function getDomain() public pure override returns(ObjectType) {
+        return APPLICATION();
+    }
+
+
+    function create(
+        address applicationOwner,
+        RiskId riskId,
+        Amount sumInsuredAmount,
+        Seconds lifetime,
+        NftId bundleNftId,
+        ReferralId referralId,
+        bytes memory applicationData
+    )
+        external
+        virtual
+        returns (NftId applicationNftId)
+    {
+        (NftId productNftId,, IInstance instance) = _getAndVerifyCallingComponentAndInstance(PRODUCT());
+        // TODO: add validations (see create bundle in pool service)
+
+        applicationNftId = getRegistryService().registerPolicy(
+            IRegistry.ObjectInfo(
+                zeroNftId(),
+                productNftId,
+                POLICY(),
+                false, // intercepting property for policies is defined on product
+                address(0),
+                applicationOwner,
+                ""
+            )
+        );
+
+        // (uint256 premiumAmount,,,,,) = calculatePremium(
+        IPolicy.Premium memory premium = _pricingService.calculatePremium(
+            productNftId,
+            riskId,
+            sumInsuredAmount,
+            lifetime,
+            applicationData,
+            bundleNftId,
+            referralId
+        );
+
+        IPolicy.PolicyInfo memory policyInfo = IPolicy.PolicyInfo({
+            productNftId:       productNftId,
+            bundleNftId:        bundleNftId,
+            referralId:         referralId,
+            riskId:             riskId,
+            sumInsuredAmount:   sumInsuredAmount,
+            premiumAmount:      AmountLib.toAmount(premium.premiumAmount),
+            premiumPaidAmount:  AmountLib.zero(),
+            lifetime:           lifetime,
+            applicationData:    applicationData,
+            processData:        "",
+            claimsCount:        0,
+            openClaimsCount:    0,
+            claimAmount:        AmountLib.zero(),
+            payoutAmount:       AmountLib.zero(),
+            activatedAt:        zeroTimestamp(),
+            expiredAt:          zeroTimestamp(),
+            closedAt:           zeroTimestamp()
+        });
+        
+        instance.getInstanceStore().createApplication(applicationNftId, policyInfo);
+
+        // TODO: add logging
+    }
+
+
+    function renew(
+        NftId policyNftId, // policy to be renewd (renewal inherits policy attributes)
+        NftId bundleNftId // will likely need a newer bundle for underwriting
+    )
+        external
+        virtual override
+        returns (NftId applicationNftId)
+    {
+
+    }
+
+
+    function adjust(
+        NftId applicationNftId,
+        RiskId riskId,
+        NftId bundleNftId,
+        ReferralId referralId,
+        Amount sumInsuredAmount,
+        Seconds lifetime,
+        bytes memory applicationData
+    )
+        external
+        virtual override
+    {
+
+    }
+
+    function revoke(NftId applicationNftId)
+        external
+        virtual override
+    {
+        (,, IInstance instance) = _getAndVerifyCallingComponentAndInstance(PRODUCT());
+        instance.getInstanceStore().updateApplicationState(applicationNftId, REVOKED());
+    }
+
+    // internal functions
+}

package/contracts/{instance/service → product}/ApplicationServiceManager.sol

@@ -1,8 +1,8 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity ^0.8.20;
 
-import {IVersionable} from "../../shared/IVersionable.sol";
-import {ProxyManager} from "../../shared/ProxyManager.sol";
+import {IVersionable} from "../shared/IVersionable.sol";
+import {ProxyManager} from "../shared/ProxyManager.sol";
 import {ApplicationService} from "./ApplicationService.sol";
 
 contract ApplicationServiceManager is ProxyManager {
@@ -11,15 +11,18 @@ contract ApplicationServiceManager is ProxyManager {
 
     /// @dev initializes proxy manager with service implementation 
     constructor(
-        address registryAddress
-    )
+        address authority, 
+        address registryAddress,
+        bytes32 salt
+    ) 
         ProxyManager(registryAddress)
     {
-        ApplicationService svc = new ApplicationService();
-        bytes memory data = abi.encode(registryAddress, address(this));
-        IVersionable versionable = deploy(
+        ApplicationService svc = new ApplicationService{salt: salt}();
+        bytes memory data = abi.encode(registryAddress, address(this), authority);
+        IVersionable versionable = deployDetermenistic(
             address(svc), 
-            data);
+            data,
+            salt);
 
         _applicationService = ApplicationService(address(versionable));
     }

package/contracts/product/ClaimService.sol

@@ -0,0 +1,443 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRisk} from "../instance/module/IRisk.sol";
+import {IService} from "./IApplicationService.sol";
+
+import {IComponents} from "../instance/module/IComponents.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IProductComponent} from "./IProductComponent.sol";
+import {Product} from "./Product.sol";
+import {IPoolComponent} from "../pool/IPoolComponent.sol";
+import {IDistributionComponent} from "../distribution/IDistributionComponent.sol";
+import {IInstance} from "../instance/IInstance.sol";
+import {IPolicy} from "../instance/module/IPolicy.sol";
+import {IRisk} from "../instance/module/IRisk.sol";
+import {IBundle} from "../instance/module/IBundle.sol";
+import {IProductService} from "./IProductService.sol";
+import {ITreasury} from "../instance/module/ITreasury.sol";
+import {ISetup} from "../instance/module/ISetup.sol";
+
+import {TokenHandler} from "../shared/TokenHandler.sol";
+
+import {IVersionable} from "../shared/IVersionable.sol";
+import {Versionable} from "../shared/Versionable.sol";
+
+import {Amount, AmountLib} from "../type/Amount.sol";
+import {Timestamp, TimestampLib, zeroTimestamp} from "../type/Timestamp.sol";
+import {UFixed, UFixedLib} from "../type/UFixed.sol";
+import {Blocknumber, blockNumber} from "../type/Blocknumber.sol";
+import {ObjectType, INSTANCE, PRODUCT, POOL, APPLICATION, POLICY, CLAIM, BUNDLE} from "../type/ObjectType.sol";
+import {SUBMITTED, ACTIVE, KEEP_STATE, DECLINED, CONFIRMED, CLOSED, PAID} from "../type/StateId.sol";
+import {NftId, NftIdLib, zeroNftId} from "../type/NftId.sol";
+import {Fee, FeeLib} from "../type/Fee.sol";
+import {ReferralId} from "../type/Referral.sol";
+import {RiskId} from "../type/RiskId.sol";
+import {StateId} from "../type/StateId.sol";
+import {ClaimId, ClaimIdLib} from "../type/ClaimId.sol";
+import {PayoutId, PayoutIdLib} from "../type/PayoutId.sol";
+import {Version, VersionLib} from "../type/Version.sol";
+
+import {ComponentService} from "../shared/ComponentService.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {IBundleService} from "../pool/IBundleService.sol";
+import {IClaimService} from "./IClaimService.sol";
+import {IPoolService} from "../pool/IPoolService.sol";
+import {IService} from "../shared/IService.sol";
+import {Service} from "../shared/Service.sol";
+
+
+contract ClaimService is 
+    ComponentService, 
+    IClaimService
+{
+
+    IPoolService internal _poolService;
+
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        virtual override
+        initializer()
+    {
+        (
+            address registryAddress,, 
+            //address managerAddress
+            address authority
+        ) = abi.decode(data, (address, address, address));
+
+        initializeService(registryAddress, authority, owner);
+
+        _poolService = IPoolService(getRegistry().getServiceAddress(POOL(), getVersion().toMajorPart()));
+
+        registerInterface(type(IClaimService).interfaceId);
+    }
+
+
+    function getDomain() public pure override returns(ObjectType) {
+        return CLAIM();
+    }
+
+    function submit(
+        NftId policyNftId, 
+        Amount claimAmount,
+        bytes memory claimData // claim submission data
+    )
+        external
+        virtual
+        returns (ClaimId claimId)
+    {
+        (
+            IInstance instance,
+            InstanceReader instanceReader,
+            IPolicy.PolicyInfo memory policyInfo
+        ) = _verifyCallerWithPolicy(policyNftId);
+
+        // check policy is in its active period
+        if(policyInfo.activatedAt.eqz() || TimestampLib.blockTimestamp() >= policyInfo.expiredAt) {
+            revert ErrorClaimServicePolicyNotOpen(policyNftId);
+        }
+
+        // check policy including this claim is still within sum insured
+        if(policyInfo.payoutAmount + claimAmount > policyInfo.sumInsuredAmount) {
+            revert ErrorClaimServiceClaimExceedsSumInsured(
+                policyNftId, 
+                policyInfo.sumInsuredAmount,
+                AmountLib.toAmount(policyInfo.payoutAmount.toInt() + claimAmount.toInt()));
+        }
+
+        // create new claim
+        claimId = ClaimIdLib.toClaimId(policyInfo.claimsCount + 1);
+        instance.getInstanceStore().createClaim(
+            policyNftId, 
+            claimId, 
+            IPolicy.ClaimInfo(
+                claimAmount,
+                AmountLib.zero(), // paidAmount
+                0, // payoutsCount
+                0, // openPayoutsCount
+                claimData, // claim submission data
+                "", // claim processing data
+                TimestampLib.zero())); // closedAt
+
+        // update and save policy info with instance
+        policyInfo.claimsCount += 1;
+        policyInfo.openClaimsCount += 1;
+        // policy claim amount is only updated when claim is confirmed
+        instance.getInstanceStore().updatePolicyClaims(policyNftId, policyInfo, KEEP_STATE());
+
+        emit LogClaimServiceClaimSubmitted(policyNftId, claimId, claimAmount);
+    }
+
+
+    function confirm(
+        NftId policyNftId, 
+        ClaimId claimId,
+        Amount confirmedAmount,
+        bytes memory data // claim processing data
+    )
+        external
+        virtual
+    {
+        (
+            IInstance instance,
+            InstanceReader instanceReader,
+            IPolicy.PolicyInfo memory policyInfo
+        ) = _verifyCallerWithPolicy(policyNftId);
+
+        // check/update claim info
+        IPolicy.ClaimInfo memory claimInfo = _verifyClaim(instanceReader, policyNftId, claimId, SUBMITTED());
+        claimInfo.claimAmount = confirmedAmount;
+        claimInfo.processData = data;
+        instance.getInstanceStore().updateClaim(policyNftId, claimId, claimInfo, CONFIRMED());
+
+        // update and save policy info with instance
+        policyInfo.claimAmount = policyInfo.claimAmount + confirmedAmount;
+        instance.getInstanceStore().updatePolicyClaims(policyNftId, policyInfo, KEEP_STATE());
+
+        emit LogClaimServiceClaimConfirmed(policyNftId, claimId, confirmedAmount);
+    }
+
+    function decline(
+        NftId policyNftId, 
+        ClaimId claimId,
+        bytes memory data // claim processing data
+    )
+        external
+        virtual
+    {
+        (
+            IInstance instance,
+            InstanceReader instanceReader,
+            IPolicy.PolicyInfo memory policyInfo
+        ) = _verifyCallerWithPolicy(policyNftId);
+
+        // check/update claim info
+        IPolicy.ClaimInfo memory claimInfo = _verifyClaim(instanceReader, policyNftId, claimId, SUBMITTED());
+        claimInfo.processData = data;
+        claimInfo.closedAt = TimestampLib.blockTimestamp();
+        instance.getInstanceStore().updateClaim(policyNftId, claimId, claimInfo, DECLINED());
+
+        // update and save policy info with instance
+        policyInfo.openClaimsCount -= 1;
+        instance.getInstanceStore().updatePolicyClaims(policyNftId, policyInfo, KEEP_STATE());
+
+        emit LogClaimServiceClaimDeclined(policyNftId, claimId);
+    }
+
+    function close(
+        NftId policyNftId, 
+        ClaimId claimId
+    )
+        external
+        virtual
+    {
+        (
+            IInstance instance,
+            InstanceReader instanceReader,
+            IPolicy.PolicyInfo memory policyInfo
+        ) = _verifyCallerWithPolicy(policyNftId);
+
+        // check/update claim info
+        IPolicy.ClaimInfo memory claimInfo = _verifyClaim(instanceReader, policyNftId, claimId, CONFIRMED());
+
+        // check claim has no open payouts
+        if(claimInfo.openPayoutsCount > 0) {
+            revert ErrorClaimServiceClaimWithOpenPayouts(
+                policyNftId, 
+                claimId, 
+                claimInfo.openPayoutsCount);
+        }
+
+        // check claim paid amount matches with claim amount
+        if(claimInfo.paidAmount.toInt() < claimInfo.claimAmount.toInt()) {
+            revert ErrorClaimServiceClaimWithMissingPayouts(
+                policyNftId, 
+                claimId, 
+                claimInfo.claimAmount,
+                claimInfo.paidAmount);
+        }
+
+        claimInfo.closedAt = TimestampLib.blockTimestamp();
+        instance.getInstanceStore().updateClaim(policyNftId, claimId, claimInfo, CLOSED());
+    }
+
+
+    function createPayout(
+        NftId policyNftId, 
+        ClaimId claimId,
+        Amount amount,
+        bytes memory data
+    )
+        external
+        returns (PayoutId payoutId)
+    {
+        (
+            IInstance instance,
+            InstanceReader instanceReader,
+            IPolicy.PolicyInfo memory policyInfo
+        ) = _verifyCallerWithPolicy(policyNftId);
+
+        IPolicy.ClaimInfo memory claimInfo = instanceReader.getClaimInfo(policyNftId, claimId);
+        StateId claimState = instanceReader.getClaimState(policyNftId, claimId);
+
+        // TODO add checks
+        // claim needs to be open
+        // claim.paidAmount + amount <= claim.claimAmount
+
+        // check/update claim info
+        // create payout info with instance
+        uint8 claimNo = claimInfo.payoutsCount + 1;
+        payoutId = PayoutIdLib.toPayoutId(claimId, claimNo);
+        instance.getInstanceStore().createPayout(
+            policyNftId, 
+            payoutId, 
+            IPolicy.PayoutInfo(
+                payoutId.toClaimId(),
+                amount,
+                data,
+                TimestampLib.zero()));
+
+        // update and save claim info with instance
+        claimInfo.payoutsCount += 1;
+        claimInfo.openPayoutsCount += 1;
+        instance.getInstanceStore().updateClaim(policyNftId, claimId, claimInfo, KEEP_STATE());
+
+        // update and save policy info with instance
+        policyInfo.payoutAmount.add(amount);
+        instance.getInstanceStore().updatePolicyClaims(policyNftId, policyInfo, KEEP_STATE());
+
+        emit LogClaimServicePayoutCreated(policyNftId, payoutId, amount);
+    }
+
+
+    function processPayout(
+        NftId policyNftId, 
+        PayoutId payoutId
+    )
+        external
+        virtual
+    {
+        (
+            IInstance instance,
+            InstanceReader instanceReader,
+            IPolicy.PolicyInfo memory policyInfo
+        ) = _verifyCallerWithPolicy(policyNftId);
+
+        // TODO add check that payout exists and is open
+        IPolicy.PayoutInfo memory payoutInfo = instanceReader.getPayoutInfo(policyNftId, payoutId);
+
+        // update and save payout info with instance
+        payoutInfo.paidAt = TimestampLib.blockTimestamp();
+        instance.getInstanceStore().updatePayout(policyNftId, payoutId, payoutInfo, PAID());
+
+        // TODO update and save claim info with instance
+        ClaimId claimId = payoutId.toClaimId();
+        Amount payoutAmount = payoutInfo.amount;
+        IPolicy.ClaimInfo memory claimInfo = instanceReader.getClaimInfo(policyNftId, claimId);
+        claimInfo.paidAmount = claimInfo.paidAmount.add(payoutAmount);
+        claimInfo.openPayoutsCount -= 1;
+
+        // check if this payout is closing the linked claim
+        // update claim and policy info accordingly
+        if(claimInfo.openPayoutsCount == 0 && claimInfo.paidAmount == claimInfo.claimAmount) {
+            claimInfo.closedAt == TimestampLib.blockTimestamp();
+            instance.getInstanceStore().updateClaim(policyNftId, claimId, claimInfo, CLOSED());
+
+            policyInfo.openClaimsCount -= 1;
+        } else {
+            instance.getInstanceStore().updateClaim(policyNftId, claimId, claimInfo, KEEP_STATE());
+        }
+
+        // update and save policy info with instance
+        policyInfo.payoutAmount = policyInfo.payoutAmount.add(payoutAmount);
+        instance.getInstanceStore().updatePolicyClaims(policyNftId, policyInfo, KEEP_STATE());
+
+        // inform pool about payout
+        _poolService.reduceCollateral(instance, policyNftId, policyInfo, payoutAmount);
+
+        // transfer payout token and fee
+        (
+            Amount netPayoutAmount,
+            address beneficiary
+        ) = _transferPayoutAmount(
+            instanceReader,
+            policyNftId,
+            policyInfo,
+            payoutInfo);
+
+        // TODO callback IPolicyHolder
+
+        emit LogClaimServicePayoutProcessed(policyNftId, payoutId, payoutAmount, beneficiary, netPayoutAmount);
+    }
+
+    // TODO create (I)TreasuryService that deals with all gif related token transfers
+    function _transferPayoutAmount(
+        InstanceReader instanceReader,
+        NftId policyNftId,
+        IPolicy.PolicyInfo memory policyInfo,
+        IPolicy.PayoutInfo memory payoutInfo
+    )
+        internal
+        returns (
+            Amount netPayoutAmount,
+            address beneficiary
+        )
+    {
+        Amount payoutAmount = payoutInfo.amount;
+
+        if(payoutAmount.gtz()) {
+            NftId productNftId = policyInfo.productNftId;
+            ISetup.ProductSetupInfo memory setupInfo = instanceReader.getProductSetupInfo(productNftId);
+
+            // get pool component info from policy or product
+            NftId poolNftId = getRegistry().getObjectInfo(policyInfo.bundleNftId).parentNftId;
+            IComponents.ComponentInfo memory poolInfo = instanceReader.getComponentInfo(poolNftId);
+
+            netPayoutAmount = payoutAmount;
+            beneficiary = _getBeneficiary(policyNftId, payoutInfo.claimId);
+
+            if(FeeLib.gtz(setupInfo.processingFee)) {
+                // TODO calculate net payout and processing fees
+                // TODO transfer processing fees to product wallet
+                // TODO inform product to update fee book keeping
+            }
+
+            poolInfo.tokenHandler.transfer(
+                poolInfo.wallet,
+                beneficiary,
+                netPayoutAmount);
+        }
+    }
+
+    // internal functions
+
+    function _getBeneficiary(
+        NftId policyNftId,
+        ClaimId claimId
+    )
+        internal
+        returns (address beneficiary)
+    {
+        // TODO check if owner is IPolicyHolder
+        // if so, obtain beneficiary from this contract
+
+        // default beneficiary is policy nft owner
+        beneficiary = getRegistry().ownerOf(policyNftId);
+    }
+
+
+    function _verifyCallerWithPolicy(
+        NftId policyNftId
+    )
+        internal
+        returns (
+            IInstance instance,
+            InstanceReader instanceReader,
+            IPolicy.PolicyInfo memory policyInfo
+        )
+    {
+        NftId productNftId;
+        (productNftId,, instance) = _getAndVerifyCallingComponentAndInstance(PRODUCT());
+        instanceReader = instance.getInstanceReader();
+
+        // check caller(product) policy match
+        policyInfo = instanceReader.getPolicyInfo(policyNftId);
+        if(policyInfo.productNftId != productNftId) {
+            revert ErrorClaimServicePolicyProductMismatch(policyNftId, 
+            policyInfo.productNftId, 
+            productNftId);
+        }
+    }
+
+    function _verifyClaim(
+        InstanceReader instanceReader,
+        NftId policyNftId, 
+        ClaimId claimId, 
+        StateId expectedState
+    )
+        internal
+        view
+        returns (
+            IPolicy.ClaimInfo memory claimInfo
+        )
+    {
+        // check claim is created state
+        StateId claimState = instanceReader.getClaimState(policyNftId, claimId);
+        if(claimState != expectedState) {
+            revert ErrorClaimServiceClaimNotInExpectedState(
+                policyNftId, claimId, expectedState, claimState);
+        }
+
+        // get claim info
+        claimInfo = instanceReader.getClaimInfo(policyNftId, claimId);
+    }
+
+    function _getAndVerifyInstanceAndProduct() internal view returns (Product product) {
+        IRegistry.ObjectInfo memory productInfo;
+        (, productInfo,) = _getAndVerifyCallingComponentAndInstance(PRODUCT());
+        product = Product(productInfo.objectAddress);
+    }
+}

package/contracts/{instance/service → product}/ClaimServiceManager.sol

@@ -1,8 +1,8 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity ^0.8.20;
 
-import {IVersionable} from "../../shared/IVersionable.sol";
-import {ProxyManager} from "../../shared/ProxyManager.sol";
+import {IVersionable} from "../shared/IVersionable.sol";
+import {ProxyManager} from "../shared/ProxyManager.sol";
 import {ClaimService} from "./ClaimService.sol";
 
 contract ClaimServiceManager is ProxyManager {
@@ -11,15 +11,18 @@ contract ClaimServiceManager is ProxyManager {
 
     /// @dev initializes proxy manager with service implementation 
     constructor(
-        address registryAddress
-    )
+        address authority, 
+        address registryAddress,
+        bytes32 salt
+    ) 
         ProxyManager(registryAddress)
     {
-        ClaimService svc = new ClaimService();
-        bytes memory data = abi.encode(registryAddress, address(this));
-        IVersionable versionable = deploy(
+        ClaimService svc = new ClaimService{salt: salt}();
+        bytes memory data = abi.encode(registryAddress, address(this), authority);
+        IVersionable versionable = deployDetermenistic(
             address(svc), 
-            data);
+            data,
+            salt);
 
         _claimService = ClaimService(address(versionable));
     }