@etherisc/gif-next 0.0.2-e9a637d-547 → 0.0.2-e9c5694-914

package/contracts/registry/ReleaseRegistry.sol

@@ -0,0 +1,501 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Clones} from "@openzeppelin/contracts/proxy/Clones.sol";
+import {AccessManaged} from "@openzeppelin/contracts/access/manager/AccessManaged.sol";
+
+import {NftId} from "../type/NftId.sol";
+import {ObjectType, ObjectTypeLib, POOL, RELEASE, REGISTRY, SERVICE, STAKING} from "../type/ObjectType.sol";
+import {TimestampLib, zeroTimestamp} from "../type/Timestamp.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {StateId, SCHEDULED, DEPLOYING, DEPLOYED, SKIPPED, ACTIVE, PAUSED} from "../type/StateId.sol";
+import {VersionPart, VersionPartLib} from "../type/Version.sol";
+
+import {IService} from "../shared/IService.sol";
+import {IRegisterable} from "../shared/IRegisterable.sol";
+
+import {IRegistry} from "./IRegistry.sol";
+import {IRegistryLinked} from "../shared/IRegistryLinked.sol";
+import {IServiceAuthorization} from "../authorization/IServiceAuthorization.sol";
+import {RegistryAdmin} from "./RegistryAdmin.sol";
+import {Registry} from "./Registry.sol";
+import {ReleaseLifecycle} from "./ReleaseLifecycle.sol";
+
+
+contract ReleaseRegistry is 
+    AccessManaged,
+    ReleaseLifecycle, 
+    IRegistryLinked
+{
+    uint256 public constant INITIAL_GIF_VERSION = 3;// first active version  
+
+    event LogReleaseCreation(VersionPart version, bytes32 salt); 
+    event LogReleaseActivation(VersionPart version);
+    event LogReleaseDisabled(VersionPart version);
+    event LogReleaseEnabled(VersionPart version);
+
+    // constructor
+    error ErrorReleaseRegistryNotRegistry(Registry registry);
+
+    // _verifyServiceAuthorization
+    error ErrorReleaseRegistryNotServiceAuth(address notAuth);
+    error ErrorReleaseRegistryServiceAuthVersionMismatch(IServiceAuthorization auth, VersionPart expected, VersionPart actual);
+    error ErrorReleaseRegistryServiceAuthDomainsZero(IServiceAuthorization auth, VersionPart version);
+
+    // registerService
+    error ErrorReleaseRegistryServiceAddressMismatch(address expected, address actual);
+
+    // activateNextRelease
+    error ErrorReleaseRegistryRegistryServiceMissing(VersionPart releaseVersion);
+
+    // _verifyService
+    error ErrorReleaseRegistryNotService(address notService);
+    error ErrorReleaseRegistryServiceAuthorityMismatch(IService service, address serviceAuthority, address releaseAuthority);
+    error ErrorReleaseRegistryServiceVersionMismatch(IService service, VersionPart serviceVersion, VersionPart releaseVersion);
+    error ErrorReleaseRegistryServiceDomainMismatch(IService service, ObjectType expectedDomain, ObjectType actualDomain);
+
+    // _verifyServiceInfo
+    error ErrorReleaseRegistryServiceInfoAddressInvalid(IService service, address expected);
+    error ErrorReleaseRegistryServiceInfoInterceptorInvalid(IService service, bool isInterceptor);
+    error ErrorReleaseRegistryServiceInfoTypeInvalid(IService service, ObjectType expected, ObjectType found);
+    error ErrorReleaseRegistryServiceInfoOwnerInvalid(IService service, address expected, address found);
+    error ErrorReleaseRegistryServiceSelfRegistration(IService service);
+    error ErrorReleaseRegistryServiceOwnerRegistered(IService service, address owner);
+
+    RegistryAdmin public immutable _admin;
+    Registry public immutable _registry;
+
+    mapping(VersionPart version => IRegistry.ReleaseInfo info) internal _releaseInfo;
+    VersionPart [] internal _release; // array of all created releases
+    VersionPart internal _latest; // latest active version
+    VersionPart internal _next; // version to create and activate 
+
+    uint256 internal _registeredServices;
+    uint256 internal _servicesToRegister;
+
+    constructor(Registry registry)
+        AccessManaged(msg.sender)
+    {
+        // TODO move this part to RegistryLinked constructor
+        if(!_isRegistry(address(registry))) {
+            revert ErrorReleaseRegistryNotRegistry(registry);
+        }
+
+        setAuthority(registry.getAuthority());
+
+        _registry = registry;
+        _admin = RegistryAdmin(_registry.getRegistryAdminAddress());
+
+        _next = VersionPartLib.toVersionPart(INITIAL_GIF_VERSION - 1);
+    }
+
+    /// @dev sets previous release into SKIPPED state if it was created but not activated
+    /// sets next release into state SCHEDULED
+    function createNextRelease()
+        external
+        restricted() // GIF_ADMIN_ROLE
+        returns(VersionPart)
+    {
+        VersionPart version = _next;
+
+        if(isValidTransition(RELEASE(), _releaseInfo[version].state, SKIPPED())) {
+            _releaseInfo[version].state = SKIPPED();
+        }
+
+        version = VersionPartLib.toVersionPart(version.toInt() + 1);
+        _release.push(version);
+
+        _next = version;
+        _releaseInfo[version].version = version;
+        _releaseInfo[version].state = getInitialState(RELEASE());
+        _servicesToRegister = 0;
+        _registeredServices = 0;
+
+        return _next;
+    }
+
+    function prepareNextRelease(
+        IServiceAuthorization serviceAuthorization,
+        bytes32 salt
+    )
+        external
+        restricted() // GIF_MANAGER_ROLE
+        returns(
+            address releaseAuthority, 
+            VersionPart releaseVersion, 
+            bytes32 releaseSalt
+        )
+    {
+        releaseVersion = _next;
+
+        // release can transition into DEPLOYING state
+        checkTransition(_releaseInfo[releaseVersion].state, RELEASE(), SCHEDULED(), DEPLOYING());
+
+        uint256 serviceDomainsCount = _verifyServiceAuthorization(serviceAuthorization, releaseVersion, salt);
+
+        releaseAuthority = _admin.authority();
+        releaseSalt = salt;
+        // ensures unique salt
+        // TODO CreateX have clones capability also
+        // what would releaseSalt look like if used with CreateX in pemissioned mode?
+        /*releaseSalt = keccak256(
+            bytes.concat(
+                bytes32(releaseVersion.toInt()),
+                salt));*/
+
+        _servicesToRegister = serviceDomainsCount;
+        _releaseInfo[releaseVersion].state = DEPLOYING();
+        _releaseInfo[releaseVersion].salt = releaseSalt;
+        // TODO allow for the same serviceAuthorization address to be used for multiple releases?
+        _releaseInfo[releaseVersion].auth = serviceAuthorization;
+        //_releaseInfo[releaseVersion].authority = releaseAuthority;
+
+        emit LogReleaseCreation(releaseVersion, releaseSalt);
+    }
+
+    function registerService(IService service) 
+        external
+        restricted // GIF_MANAGER_ROLE
+        returns(NftId nftId)
+    {
+        VersionPart releaseVersion = _next;
+
+        // release can transition to DEPLOYED state
+        checkTransition(_releaseInfo[releaseVersion].state, RELEASE(), DEPLOYING(), DEPLOYED());
+
+        address releaseAuthority = _admin.authority();
+        IServiceAuthorization serviceAuth = _releaseInfo[releaseVersion].auth;
+        ObjectType expectedDomain = serviceAuth.getServiceDomain(_registeredServices);
+
+        // service can work with release registry and release version
+        (
+            IRegistry.ObjectInfo memory info,
+            ObjectType serviceDomain,
+            VersionPart serviceVersion
+            //,string memory serviceName
+        ) = _verifyService(
+            service, 
+            releaseAuthority, 
+            releaseVersion, 
+            expectedDomain
+        );
+
+        //_releaseInfo[releaseVersion].addresses.push(address(service)); // TODO get this info from auth contract?
+        //_releaseInfo[releaseVersion].domains.push(serviceDomain);
+        //_releaseInfo[releaseVersion].names.push(serviceName); // TODO if needed read in _verifyService()
+
+        _registeredServices++; // TODO use releaseInfo.someArray.length instead of _registeredServices
+
+        // release fully deployed
+        if(_servicesToRegister == _registeredServices) {
+            _releaseInfo[releaseVersion].state = DEPLOYED();
+        }
+
+        // TODO: service address matches defined in release auth (precalculated one)
+        // revert ErrorReleaseRegistryServiceAddressMismatch()
+
+        // setup service authorization
+        _admin.authorizeService(
+            serviceAuth, 
+            service,
+            serviceDomain,
+            releaseVersion);
+
+        // register service with registry
+        nftId = _registry.registerService(info, serviceVersion, serviceDomain);
+        service.linkToRegisteredNftId();
+    }
+    // TODO return activated version
+    function activateNextRelease() 
+        external 
+        restricted // GIF_ADMIN_ROLE
+    {
+        VersionPart version = _next;
+
+        // release can transition to ACTIVE state
+        checkTransition(_releaseInfo[version].state, RELEASE(), DEPLOYED(), ACTIVE());
+
+        _latest = version;
+        _releaseInfo[version].state = ACTIVE();
+        _releaseInfo[version].activatedAt = TimestampLib.blockTimestamp();
+
+        // grant special roles for registry/staking/pool services
+        // this will enable access to core contracts functions
+
+        // registry service MUST be registered for each release
+        address service = _registry.getServiceAddress(REGISTRY(), version);
+        if(service == address(0)) {
+            revert ErrorReleaseRegistryRegistryServiceMissing(version);
+        }
+
+        _admin.grantServiceRoleForAllVersions(IService(service), REGISTRY());
+
+        service = _registry.getServiceAddress(STAKING(), version);
+        if(service != address(0)) {
+            _admin.grantServiceRoleForAllVersions(IService(service), STAKING());
+        }
+
+        service = _registry.getServiceAddress(POOL(), version);
+        if(service != address(0)) {
+            _admin.grantServiceRoleForAllVersions(IService(service), POOL());
+        }
+
+        // TODO may run out of gas
+        // TODO test how many service can be locked in one transaction
+        // -> add to docs + each release must test for this -> add to release version tests (in test call with some gas limit?)
+        _setReleaseLocked(version, false);
+
+        emit LogReleaseActivation(version);
+    }
+
+    /// @dev stop all operations with release services
+    function pauseRelease(VersionPart version)
+        external 
+        restricted // GIF_ADMIN_ROLE
+    {
+        // release can transition to PAUSED state
+        checkTransition(_releaseInfo[version].state, RELEASE(), ACTIVE(), PAUSED());
+
+        _releaseInfo[version].state = PAUSED();
+        _releaseInfo[version].disabledAt = TimestampLib.blockTimestamp();
+
+        _setReleaseLocked(version, true);
+
+        emit LogReleaseDisabled(version);
+    }
+
+    /// @dev resume operations with release services
+    function unpauseRelease(VersionPart version)
+        external
+        restricted // GIF_ADMIN_ROLE
+    {
+        // release can transition to ACTIVE state
+        checkTransition(_releaseInfo[version].state, RELEASE(), PAUSED(), ACTIVE());
+        
+        _releaseInfo[version].state = ACTIVE();
+        _releaseInfo[version].disabledAt = zeroTimestamp();
+
+        _setReleaseLocked(version, false);
+
+        emit LogReleaseEnabled(version);
+    }
+
+    //--- view functions ----------------------------------------------------//
+
+    function predictDeterministicAddress(
+        address implementation,
+        bytes32 salt,
+        address deployer
+    ) external pure returns (address predicted) {
+        return Clones.predictDeterministicAddress(implementation, salt, deployer);
+    }
+
+    function isActiveRelease(VersionPart version) public view returns(bool) {
+        return _releaseInfo[version].state == ACTIVE();
+    }
+
+    function getReleaseInfo(VersionPart version) external view returns(IRegistry.ReleaseInfo memory) {
+        return _releaseInfo[version];
+    }
+
+    /// @dev Returns the number of created releases.
+    /// Releases might be in another state than ACTIVE.
+    function releases() external view returns (uint) {
+        return _release.length;
+    }
+
+    /// @dev Returns the n-th release version.
+    /// Valid values for idx [0 .. releases() - 1]
+    function getVersion(uint256 idx) external view returns (VersionPart version) {
+        // return _releases;
+        return _release[idx];
+    }
+
+    function getNextVersion() public view returns(VersionPart) {
+        return _next;
+    }
+
+    /// @dev Returns the latest activated relase version.
+    /// There is no guarantee that the release is not currently paused.
+    function getLatestVersion() external view returns(VersionPart) {
+        return _latest;
+    }
+
+    function getState(VersionPart version) external view returns (StateId stateId) {
+        return _releaseInfo[version].state;
+    }
+
+    function getRemainingServicesToRegister() external view returns (uint256 services) {
+        return _servicesToRegister - _registeredServices;
+    }
+
+    function getServiceAuthorization(VersionPart version)
+        external
+        view
+        returns (IServiceAuthorization serviceAuthorization)
+    {
+        return _releaseInfo[version].auth;
+    }
+
+    function getRegistryAdmin() external view returns (address) {
+        return address(_admin);
+    }
+
+    //--- IRegistryLinked ------------------------------------------------------//
+
+    function getRegistry() external view returns (IRegistry) {
+        return _registry;
+    }
+
+    //--- private functions ----------------------------------------------------//
+
+    // close / open service targets instead of revoking / granting roles
+    function _setReleaseLocked(VersionPart version, bool locked)
+        private
+    {
+        address service;
+        ObjectType domain;
+        IServiceAuthorization auth = _releaseInfo[version].auth;
+
+        ObjectType[] memory domains = auth.getServiceDomains();
+        for(uint idx = 0; idx < domains.length; idx++)
+        {
+            domain = domains[idx];
+            service = _registry.getServiceAddress(domain, version);
+            assert(service != address(0));
+
+            _admin.setServiceLocked(IService(service), locked);
+        }
+
+        // TODO add check for active/disabled release to core contracts functions interacting with releases
+    }
+
+    function _verifyServiceAuthorization(
+        IServiceAuthorization serviceAuthorization,
+        VersionPart releaseVersion,
+        bytes32 salt
+    )
+        private
+        view
+        returns (uint256 serviceDomainsCount)
+    {
+        // authorization contract supports IServiceAuthorization interface
+        if(!serviceAuthorization.supportsInterface(type(IServiceAuthorization).interfaceId)) {
+                revert ErrorReleaseRegistryNotServiceAuth(address(serviceAuthorization));
+        }
+
+        // authorizaions contract version matches with release version
+        VersionPart authVersion = serviceAuthorization.getRelease();
+        if (releaseVersion != authVersion) {
+            revert ErrorReleaseRegistryServiceAuthVersionMismatch(serviceAuthorization, releaseVersion, authVersion);
+        }
+
+        // sanity check to ensure service domain list is not empty
+        serviceDomainsCount = serviceAuthorization.getServiceDomains().length;
+        if (serviceDomainsCount == 0) {
+            revert ErrorReleaseRegistryServiceAuthDomainsZero(serviceAuthorization, releaseVersion);
+        }
+    }
+
+    // TODO get service names 
+    function _verifyService(
+        IService service, 
+        address expectedAuthority, 
+        VersionPart expectedVersion,
+        ObjectType expectedDomain
+    )
+        internal
+        view
+        returns(
+            IRegistry.ObjectInfo memory serviceInfo,
+            ObjectType serviceDomain, 
+            VersionPart serviceVersion
+        )
+    {
+        if(!service.supportsInterface(type(IService).interfaceId)) {
+            revert ErrorReleaseRegistryNotService(address(service));
+        }
+
+        address owner = msg.sender;
+        address serviceAuthority = service.authority();
+        serviceVersion = service.getVersion().toMajorPart();
+        serviceDomain = service.getDomain();// checked in registry
+        serviceInfo = service.getInitialInfo();
+
+        _verifyServiceInfo(service, serviceInfo, owner);
+
+        if(serviceAuthority != expectedAuthority) {
+            revert ErrorReleaseRegistryServiceAuthorityMismatch(
+                service,
+                serviceAuthority,
+                expectedAuthority);
+        }
+
+        if(serviceVersion != expectedVersion) {
+            revert ErrorReleaseRegistryServiceVersionMismatch(
+                service,
+                serviceVersion,
+                expectedVersion);            
+        }
+
+        if(serviceDomain != expectedDomain) {
+            revert ErrorReleaseRegistryServiceDomainMismatch(
+                service,
+                expectedDomain,
+                serviceDomain);
+        }
+    }
+
+
+    function _verifyServiceInfo(
+        IService service,
+        IRegistry.ObjectInfo memory info,
+        address expectedOwner // assume always valid, can not be 0
+    )
+        internal
+        view
+    {
+        if(info.objectAddress != address(service)) {
+            revert ErrorReleaseRegistryServiceInfoAddressInvalid(service, info.objectAddress);
+        }
+
+        if(info.isInterceptor != false) { // service is never interceptor
+            revert ErrorReleaseRegistryServiceInfoInterceptorInvalid(service, info.isInterceptor);
+        }
+
+        if(info.objectType != SERVICE()) {
+            revert ErrorReleaseRegistryServiceInfoTypeInvalid(service, SERVICE(), info.objectType);
+        }
+
+        address owner = info.initialOwner;
+
+        if(owner != expectedOwner) { // registerable owner protection
+            revert ErrorReleaseRegistryServiceInfoOwnerInvalid(service, expectedOwner, owner); 
+        }
+
+        if(owner == address(service)) {
+            revert ErrorReleaseRegistryServiceSelfRegistration(service);
+        }
+        
+        if(_registry.isRegistered(owner)) { 
+            revert ErrorReleaseRegistryServiceOwnerRegistered(service, owner);
+        }
+    }
+
+    /// @dev returns true iff a the address passes some simple proxy tests.
+    function _isRegistry(address registryAddress) internal view returns (bool) {
+
+        // zero address is certainly not registry
+        if (registryAddress == address(0)) {
+            return false;
+        }
+        // TODO try catch and return false in case of revert or just panic
+        // check if contract returns a zero nft id for its own address
+        if (IRegistry(registryAddress).getNftIdForAddress(registryAddress).eqz()) {
+            return false;
+        }
+
+        return true;
+    }
+}
+

package/contracts/registry/ServiceAuthorizationV3.sol

@@ -0,0 +1,194 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {
+     ALL, REGISTRY, PRODUCT, ORACLE, POOL, INSTANCE, COMPONENT, DISTRIBUTION, DISTRIBUTOR, APPLICATION, POLICY, CLAIM, BUNDLE, STAKING, PRICE
+} from "../../contracts/type/ObjectType.sol";
+
+import {IAccess} from "../authorization/IAccess.sol";
+import {IBundleService} from "../pool/IBundleService.sol";
+import {IDistributionService} from "../distribution/IDistributionService.sol";
+import {IInstanceService} from "../instance/IInstanceService.sol";
+import {IPoolService} from "../pool/IPoolService.sol";
+import {IStakingService} from "../staking/IStakingService.sol";
+import {IRegistryService} from "./IRegistryService.sol";
+import {ServiceAuthorization} from "../authorization/ServiceAuthorization.sol";
+
+
+contract ServiceAuthorizationV3
+     is ServiceAuthorization
+{
+
+     constructor(string memory commitHash)
+          ServiceAuthorization(commitHash, 3)
+     {}
+
+     function _setupDomains()
+          internal
+          override
+     {
+          _authorizeDomain(REGISTRY(), address(1));
+          _authorizeDomain(STAKING(), address(2));
+          _authorizeDomain(INSTANCE(), address(3));
+          _authorizeDomain(COMPONENT(), address(4));
+          _authorizeDomain(DISTRIBUTION(), address(5));
+          _authorizeDomain(PRICE(), address(6));
+          _authorizeDomain(BUNDLE(), address(7));
+          _authorizeDomain(POOL(), address(8));
+          _authorizeDomain(ORACLE(), address(9));
+          _authorizeDomain(PRODUCT(), address(10));
+          _authorizeDomain(POLICY(), address(11));
+          _authorizeDomain(CLAIM(), address(12));
+          _authorizeDomain(APPLICATION(), address(13));
+     }
+
+
+     function _setupDomainAuthorizations()
+          internal
+          override
+     {
+          _setupIRegistryServiceAuthorization();
+          _setupStakingServiceAuthorization();
+          _setupInstanceServiceAuthorization();
+          _setupComponentServiceAuthorization();
+          _setupDistributionServiceAuthorization();
+          _setupPoolServiceAuthorization();
+          _setupBundleServiceAuthorization();
+     }
+
+
+     /// @dev registry service authorization.
+     /// authorized functions MUST be implemented with a restricted modifier
+     function _setupIRegistryServiceAuthorization()
+          internal
+     {
+          IAccess.FunctionInfo[] storage functions;
+
+          functions = _authorizeForService(REGISTRY(), APPLICATION());
+          _authorize(functions, IRegistryService.registerPolicy.selector, "registerPolicy");
+
+          functions = _authorizeForService(REGISTRY(), BUNDLE());
+          _authorize(functions, IRegistryService.registerBundle.selector, "registerBundle");
+
+          functions = _authorizeForService(REGISTRY(), COMPONENT());
+          _authorize(functions, IRegistryService.registerProduct.selector, "registerProduct");
+          _authorize(functions, IRegistryService.registerProductLinkedComponent.selector, "registerProductLinkedComponent");
+
+          functions = _authorizeForService(REGISTRY(), DISTRIBUTION());
+          _authorize(functions, IRegistryService.registerDistributor.selector, "registerDistributor");
+
+          functions = _authorizeForService(REGISTRY(), INSTANCE());
+          _authorize(functions, IRegistryService.registerInstance.selector, "registerInstance");
+
+          functions = _authorizeForService(REGISTRY(), STAKING());
+          _authorize(functions, IRegistryService.registerStake.selector, "registerStake");
+     }
+
+
+     /// @dev staking service authorization.
+     /// authorized functions MUST be implemented with a restricted modifier
+     function _setupStakingServiceAuthorization()
+          internal
+     {
+          IAccess.FunctionInfo[] storage functions;
+
+          functions = _authorizeForService(STAKING(), INSTANCE());
+          _authorize(functions, IStakingService.createInstanceTarget.selector, "createInstanceTarget");
+          _authorize(functions, IStakingService.setInstanceLockingPeriod.selector, "setInstanceLockingPeriod");
+          _authorize(functions, IStakingService.setInstanceRewardRate.selector, "setInstanceRewardRate");
+          _authorize(functions, IStakingService.refillInstanceRewardReserves.selector, "refillInstanceRewardReserves");
+          _authorize(functions, IStakingService.withdrawInstanceRewardReserves.selector, "withdrawInstanceRewardReserves");
+
+          functions = _authorizeForService(STAKING(), ALL());
+          _authorize(functions, IStakingService.create.selector, "create");
+          _authorize(functions, IStakingService.stake.selector, "stake");
+          _authorize(functions, IStakingService.restakeToNewTarget.selector, "restakeToNewTarget");
+          _authorize(functions, IStakingService.updateRewards.selector, "updateRewards");
+          _authorize(functions, IStakingService.claimRewards.selector, "claimRewards");
+          _authorize(functions, IStakingService.unstake.selector, "unstake");
+     }
+
+
+     /// @dev Instance service function authorization.
+     function _setupInstanceServiceAuthorization()
+          internal
+     {
+          // TODO cleanup
+          // IAccess.FunctionInfo[] storage functions;
+
+          // functions = _authorizeForService(INSTANCE(), COMPONENT());
+          // _authorize(functions, IInstanceService.initializeAuthorization.selector, "initializeAuthorization");
+     }
+
+
+     /// @dev Component service function authorization.
+     function _setupComponentServiceAuthorization()
+          internal
+     {
+          // TODO cleanup
+          // authz.authorizations = new DomainAuthorization[](4);
+
+          // authz.authorizations[0].domain = POLICY();
+          // _functions = new IAccessAdmin.Function[](1);
+          // __authorize(ComponentService.increaseProductFees.selector, "increaseProductFees"));
+          // authz.authorizations[0].functions = _functions;
+
+          // authz.authorizations[1].domain = DISTRIBUTION();
+          // _functions = new IAccessAdmin.Function[](1);
+          // __authorize(ComponentService.increaseDistributionBalance.selector, "increaseDistributionBalance"));
+          // authz.authorizations[1].functions = _functions;
+
+          // authz.authorizations[2].domain = POOL();
+          // _functions = new IAccessAdmin.Function[](1);
+          // __authorize(ComponentService.increasePoolBalance.selector, "increasePoolBalance"));
+          // authz.authorizations[2].functions = _functions;
+
+          // authz.authorizations[3].domain = BUNDLE();
+          // _functions = new IAccessAdmin.Function[](1);
+          // __authorize(ComponentService.increaseBundleBalance.selector, "increaseBundleBalance"));
+          // authz.authorizations[3].functions = _functions;
+     }
+
+     /// @dev Distribution service function authorization.
+     function _setupDistributionServiceAuthorization()
+          internal
+     {
+          IAccess.FunctionInfo[] storage functions;
+
+          functions = _authorizeForService(DISTRIBUTION(), POLICY());
+          _authorize(functions, IDistributionService.processSale.selector, "processSale");
+          _authorize(functions, IDistributionService.processReferral.selector, "processReferral");
+     }
+
+
+     /// @dev Pool service function authorization.
+     function _setupPoolServiceAuthorization()
+          internal
+     {
+          IAccess.FunctionInfo[] storage functions;
+
+          functions = _authorizeForService(POOL(), POLICY());
+          _authorize(functions, IPoolService.lockCollateral.selector, "lockCollateral");
+          _authorize(functions, IPoolService.releaseCollateral.selector, "releaseCollateral");
+          _authorize(functions, IPoolService.processSale.selector, "processSale");
+
+          functions = _authorizeForService(POOL(), CLAIM());
+          _authorize(functions, IPoolService.processPayout.selector, "processPayout");
+     }
+
+
+     /// @dev Instance service function authorization.
+     function _setupBundleServiceAuthorization()
+          internal
+     {
+          IAccess.FunctionInfo[] storage functions;
+
+          functions = _authorizeForService(BUNDLE(), POOL());
+          _authorize(functions, IBundleService.create.selector, "create");
+          _authorize(functions, IBundleService.close.selector, "close");
+          _authorize(functions, IBundleService.lockCollateral.selector, "lockCollateral");
+          _authorize(functions, IBundleService.releaseCollateral.selector, "releaseCollateral");
+          _authorize(functions, IBundleService.unlinkPolicy.selector, "unlinkPolicy");
+     }
+}
+