@etherisc/gif-next 0.0.2-e94f4c7-084 → 0.0.2-e964d24-516

package/contracts/product/PolicyService.sol

@@ -0,0 +1,376 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {Product} from "./Product.sol";
+import {IComponents} from "../instance/module/IComponents.sol";
+import {IDistributionComponent} from "../distribution/IDistributionComponent.sol";
+import {IInstance} from "../instance/IInstance.sol";
+import {IPolicy} from "../instance/module/IPolicy.sol";
+import {IPoolComponent} from "../pool/IPoolComponent.sol";
+import {IRisk} from "../instance/module/IRisk.sol";
+import {IBundle} from "../instance/module/IBundle.sol";
+import {ISetup} from "../instance/module/ISetup.sol";
+
+import {TokenHandler} from "../shared/TokenHandler.sol";
+
+import {Amount, AmountLib} from "../type/Amount.sol";
+import {ClaimId, ClaimIdLib} from "../type/ClaimId.sol";
+import {Timestamp, TimestampLib, zeroTimestamp} from "../type/Timestamp.sol";
+import {UFixed, UFixedLib} from "../type/UFixed.sol";
+import {ObjectType, APPLICATION, DISTRIBUTION, PRODUCT, POOL, POLICY, BUNDLE, CLAIM, PRICE} from "../type/ObjectType.sol";
+import {APPLIED, COLLATERALIZED, ACTIVE, KEEP_STATE, CLOSED, DECLINED, CONFIRMED} from "../type/StateId.sol";
+import {NftId, NftIdLib} from "../type/NftId.sol";
+import {PayoutId, PayoutIdLib} from "../type/PayoutId.sol";
+import {StateId} from "../type/StateId.sol";
+import {VersionPart} from "../type/Version.sol";
+
+import {ComponentService} from "../shared/ComponentService.sol";
+import {IApplicationService} from "./IApplicationService.sol";
+import {IBundleService} from "../pool/IBundleService.sol";
+import {IClaimService} from "./IClaimService.sol";
+import {IDistributionService} from "../distribution/IDistributionService.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {IPolicyService} from "./IPolicyService.sol";
+import {IPoolService} from "../pool/IPoolService.sol";
+import {IPricingService} from "./IPricingService.sol";
+import {IService} from "../shared/IService.sol";
+import {Service} from "../shared/Service.sol";
+
+contract PolicyService is
+    ComponentService, 
+    IPolicyService
+{
+    using NftIdLib for NftId;
+    using TimestampLib for Timestamp;
+
+    IApplicationService internal _applicationService;
+    IBundleService internal _bundleService;
+    IClaimService internal _claimService;
+    IDistributionService internal _distributionService;
+    IPoolService internal _poolService;
+    IPricingService internal _pricingService;
+
+    event LogProductServiceSender(address sender);
+
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        virtual override
+        initializer
+    {
+        address registryAddress;
+        address initialOwner;
+        (registryAddress, initialOwner) = abi.decode(data, (address, address));
+
+        initializeService(registryAddress, address(0), owner);
+
+        VersionPart majorVersion = getVersion().toMajorPart();
+        _poolService = IPoolService(getRegistry().getServiceAddress(POOL(), majorVersion));
+        _bundleService = IBundleService(getRegistry().getServiceAddress(BUNDLE(), majorVersion));
+        _claimService = IClaimService(getRegistry().getServiceAddress(CLAIM(), majorVersion));
+        _applicationService = IApplicationService(getRegistry().getServiceAddress(APPLICATION(), majorVersion));
+        _distributionService = IDistributionService(getRegistry().getServiceAddress(DISTRIBUTION(), majorVersion));
+        _pricingService = IPricingService(getRegistry().getServiceAddress(PRICE(), majorVersion));
+
+        registerInterface(type(IPolicyService).interfaceId);
+    }
+
+
+    function getDomain() public pure override returns(ObjectType) {
+        return POLICY();
+    }
+
+
+    function _getAndVerifyInstanceAndProduct() internal view returns (Product product) {
+        IRegistry.ObjectInfo memory productInfo;
+        (, productInfo,) = _getAndVerifyCallingComponentAndInstance(PRODUCT());
+        product = Product(productInfo.objectAddress);
+    }
+
+
+    function decline(
+        NftId policyNftId
+    )
+        external
+        override
+    {
+        revert();
+    }
+
+
+    /// @dev underwites application which includes the locking of the required collateral from the pool.
+    function collateralize(
+        NftId applicationNftId, // = policyNftId
+        bool requirePremiumPayment,
+        Timestamp activateAt
+    )
+        external 
+        virtual override
+    {
+        // check caller is registered product
+        (NftId productNftId,, IInstance instance) = _getAndVerifyCallingComponentAndInstance(PRODUCT());
+        InstanceReader instanceReader = instance.getInstanceReader();
+
+        // check policy matches with calling product
+        IPolicy.PolicyInfo memory applicationInfo = instanceReader.getPolicyInfo(applicationNftId);
+        if(applicationInfo.productNftId != productNftId) {
+            revert ErrorPolicyServicePolicyProductMismatch(
+                applicationNftId, 
+                applicationInfo.productNftId, 
+                productNftId);
+        }
+
+        // check policy is in state applied
+        if (instanceReader.getPolicyState(applicationNftId) != APPLIED()) {
+            revert ErrorPolicyServicePolicyStateNotApplied(applicationNftId);
+        }
+        
+        StateId newPolicyState = COLLATERALIZED();
+
+        // optional activation of policy
+        if(activateAt > zeroTimestamp()) {
+            newPolicyState = ACTIVE();
+            applicationInfo.activatedAt = activateAt;
+            applicationInfo.expiredAt = activateAt.addSeconds(applicationInfo.lifetime);
+        }
+
+        // lock bundle collateral
+        Amount netPremiumAmount = AmountLib.zero(); // > 0 if immediate premium payment 
+
+        // optional collection of premium
+        if(requirePremiumPayment) {
+            netPremiumAmount = _processPremiumByTreasury(
+                instance, 
+                applicationNftId, 
+                applicationInfo.premiumAmount);
+
+            applicationInfo.premiumPaidAmount = applicationInfo.premiumPaidAmount + applicationInfo.premiumAmount;
+        }
+
+        // store updated policy info
+        instance.getInstanceStore().updatePolicy(applicationNftId, applicationInfo, newPolicyState);
+
+        // lock collateral and update pool and bundle book keeping
+        // pool retention level: fraction of sum insured that product will cover from pool funds directly
+        // eg retention level 30%, payouts up to 30% of the sum insured will be made from the product's pool directly
+        // for the remaining 70% the pool owns a policy that will cover claims that exceed the 30% of the sum insured
+        // might also call pool component (for isVerifyingApplications pools)
+        _poolService.lockCollateral(
+            instance,
+            productNftId,
+            applicationNftId, 
+            applicationInfo,
+            netPremiumAmount); // for pool book keeping (fee + additional capital)
+
+        // TODO: add logging
+    }
+
+
+    function calculateRequiredCollateral(
+        UFixed collateralizationLevel, 
+        Amount sumInsuredAmount
+    )
+        public 
+        pure 
+        virtual 
+        returns(Amount collateralAmount)
+    {
+        UFixed collateralUFixed =  collateralizationLevel * sumInsuredAmount.toUFixed();
+        return AmountLib.toAmount(collateralUFixed.toInt());
+    } 
+
+    function collectPremium(
+        NftId policyNftId, 
+        Timestamp activateAt
+    )
+        external 
+        virtual
+    {
+        // check caller is registered product
+        (NftId productNftId,, IInstance instance) = _getAndVerifyCallingComponentAndInstance(PRODUCT());
+        InstanceReader instanceReader = instance.getInstanceReader();
+        IPolicy.PolicyInfo memory policyInfo = instanceReader.getPolicyInfo(policyNftId);
+
+        if (policyInfo.premiumPaidAmount == policyInfo.premiumAmount) {
+            revert ErrorPolicyServicePremiumAlreadyPaid(policyNftId, policyInfo.premiumPaidAmount);
+        }
+
+        Amount unpaidPremiumAmount = policyInfo.premiumAmount - policyInfo.premiumPaidAmount;
+
+        Amount netPremiumAmount = _processPremiumByTreasury(
+                instance, 
+                policyNftId, 
+                unpaidPremiumAmount);
+
+        policyInfo.premiumPaidAmount = policyInfo.premiumPaidAmount + unpaidPremiumAmount;
+
+        _bundleService.increaseBalance(instance, policyInfo.bundleNftId, netPremiumAmount);
+        instance.getInstanceStore().updatePolicy(policyNftId, policyInfo, KEEP_STATE());
+
+        if(activateAt.gtz() && policyInfo.activatedAt.eqz()) {
+            activate(policyNftId, activateAt);
+        }
+
+        // TODO: add logging
+    }
+
+    function activate(NftId policyNftId, Timestamp activateAt) public override {
+        // check caller is registered product
+        (,, IInstance instance) = _getAndVerifyCallingComponentAndInstance(PRODUCT());
+        InstanceReader instanceReader = instance.getInstanceReader();
+
+        IPolicy.PolicyInfo memory policyInfo = instanceReader.getPolicyInfo(policyNftId);
+
+        require(
+            policyInfo.activatedAt.eqz(),
+            "ERROR:PRS-020:ALREADY_ACTIVATED");
+
+        policyInfo.activatedAt = activateAt;
+        policyInfo.expiredAt = activateAt.addSeconds(policyInfo.lifetime);
+
+        instance.getInstanceStore().updatePolicy(policyNftId, policyInfo, ACTIVE());
+
+        // TODO: add logging
+    }
+
+
+    function expire(
+        NftId policyNftId
+    )
+        external
+        override
+        // solhint-disable-next-line no-empty-blocks
+    {
+        
+    }
+
+    function close(
+        NftId policyNftId
+    )
+        external 
+        override
+    {
+        (,, IInstance instance) = _getAndVerifyCallingComponentAndInstance(PRODUCT());
+        InstanceReader instanceReader = instance.getInstanceReader();
+
+        IPolicy.PolicyInfo memory policyInfo = instanceReader.getPolicyInfo(policyNftId);
+
+        if (policyInfo.activatedAt.eqz()) {
+            revert ErrorIPolicyServicePolicyNotActivated(policyNftId);
+        }
+
+        StateId state = instanceReader.getPolicyState(policyNftId);
+        if (state != ACTIVE()) {
+            revert ErrorIPolicyServicePolicyNotActive(policyNftId, state);
+        }
+
+        if (policyInfo.closedAt.gtz()) {
+            revert ErrorIPolicyServicePolicyAlreadyClosed(policyNftId);
+        }
+
+        // TODO consider to allow for underpaid premiums (with the effects of reducing max payouts accordingly)
+        if (!(policyInfo.premiumAmount == policyInfo.premiumPaidAmount)) {
+            revert ErrorPolicyServicePremiumNotFullyPaid(policyNftId, policyInfo.premiumAmount, policyInfo.premiumPaidAmount);
+        }
+
+        if (policyInfo.openClaimsCount > 0) {
+            revert ErrorIPolicyServiceOpenClaims(policyNftId, policyInfo.openClaimsCount);
+        }
+
+        policyInfo.closedAt = TimestampLib.blockTimestamp();
+
+        _poolService.releaseCollateral(
+            instance, 
+            policyNftId, 
+            policyInfo);
+
+        instance.getInstanceStore().updatePolicy(policyNftId, policyInfo, CLOSED());
+    }
+
+
+    function _processPremiumByTreasury(
+        IInstance instance,
+        NftId policyNftId,
+        Amount premiumExpectedAmount
+    )
+        internal
+        returns (Amount netPremiumAmount)
+    {
+        // process token transfer(s)
+        if(premiumExpectedAmount.eqz()) {
+            return AmountLib.zero();
+        }
+
+        NftId productNftId = getRegistry().getObjectInfo(policyNftId).parentNftId;
+        IPolicy.PolicyInfo memory policyInfo = instance.getInstanceReader().getPolicyInfo(policyNftId);
+        IPolicy.Premium memory premium = _pricingService.calculatePremium(
+            productNftId,
+            policyInfo.riskId,
+            policyInfo.sumInsuredAmount,
+            policyInfo.lifetime,
+            policyInfo.applicationData,
+            policyInfo.bundleNftId,
+            policyInfo.referralId
+            );
+
+        if (premium.premiumAmount != premiumExpectedAmount.toInt()) {
+            revert ErrorPolicyServicePremiumMismatch(
+                policyNftId, 
+                premiumExpectedAmount, 
+                AmountLib.toAmount(premium.premiumAmount));
+        }
+
+        address policyOwner = getRegistry().ownerOf(policyNftId);
+        ISetup.ProductSetupInfo memory productSetupInfo = instance.getInstanceReader().getProductSetupInfo(productNftId);
+        TokenHandler tokenHandler = productSetupInfo.tokenHandler;
+        if (tokenHandler.getToken().allowance(policyOwner, address(tokenHandler)) < premium.premiumAmount) {
+            revert ErrorIPolicyServiceInsufficientAllowance(policyOwner, address(tokenHandler), premium.premiumAmount);
+        }
+
+        Amount productFeeAmountToTransfer = AmountLib.toAmount(premium.productFeeFixAmount + premium.productFeeVarAmount);
+        Amount distributionFeeAmountToTransfer = AmountLib.toAmount(premium.distributionFeeFixAmount + premium.distributionFeeVarAmount - premium.discountAmount);
+        uint256 poolFeeAmountToTransfer = premium.poolFeeFixAmount + premium.poolFeeVarAmount;
+        uint256 bundleFeeAmountToTransfer = premium.bundleFeeFixAmount + premium.bundleFeeVarAmount;
+        Amount poolAmountToTransfer = AmountLib.toAmount(premium.netPremiumAmount + poolFeeAmountToTransfer + bundleFeeAmountToTransfer);
+
+        netPremiumAmount = AmountLib.toAmount(premium.netPremiumAmount);
+
+        // move product fee to product wallet
+        {
+            address productWallet = productSetupInfo.wallet;
+            tokenHandler.transfer(policyOwner, productWallet, productFeeAmountToTransfer);
+        }
+
+        // move distribution fee to distribution wallet
+        {
+            ISetup.DistributionSetupInfo memory distributionSetupInfo = instance.getInstanceReader().getDistributionSetupInfo(productSetupInfo.distributionNftId);
+            address distributionWallet = distributionSetupInfo.wallet;
+            tokenHandler.transfer(policyOwner, distributionWallet, distributionFeeAmountToTransfer);
+            _distributionService.processSale(productSetupInfo.distributionNftId, policyInfo.referralId, premium, distributionFeeAmountToTransfer);
+        }
+        
+        // move netpremium, bundleFee and poolFee to pool wallet
+        {
+            address poolWallet = instance.getInstanceReader().getComponentInfo(productSetupInfo.poolNftId).wallet;
+            tokenHandler.transfer(policyOwner, poolWallet, poolAmountToTransfer);
+            _poolService.processSale(policyInfo.bundleNftId, premium, poolAmountToTransfer);
+        }
+
+        // validate total amount transferred
+        {
+            Amount totalTransferred = distributionFeeAmountToTransfer + poolAmountToTransfer + productFeeAmountToTransfer;
+
+            if (premium.premiumAmount != totalTransferred.toInt()) {
+                revert ErrorPolicyServiceTransferredPremiumMismatch(
+                    policyNftId, 
+                    AmountLib.toAmount(premium.premiumAmount), 
+                    totalTransferred);
+            }
+        }
+
+        // TODO: add logging
+    }
+}

package/contracts/{instance/service → product}/PolicyServiceManager.sol

@@ -1,12 +1,12 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity ^0.8.20;
 
-import {IVersionable} from "../../shared/IVersionable.sol";
-import {ProxyManager} from "../../shared/ProxyManager.sol";
+import {IVersionable} from "../shared/IVersionable.sol";
+import {ProxyManager} from "../shared/ProxyManager.sol";
 import {PolicyService} from "./PolicyService.sol";
-import {Registry} from "../../registry/Registry.sol";
-import {RegistryService} from "../../registry/RegistryService.sol";
-import {VersionLib} from "../../types/Version.sol";
+import {Registry} from "../registry/Registry.sol";
+import {RegistryService} from "../registry/RegistryService.sol";
+import {VersionLib} from "../type/Version.sol";
 
 contract PolicyServiceManager is ProxyManager {
 

package/contracts/product/PricingService.sol

@@ -0,0 +1,275 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Seconds} from "../type/Seconds.sol";
+import {UFixed, UFixedLib} from "../type/UFixed.sol";
+import {ObjectType} from "../type/ObjectType.sol";
+import {NftId} from "../type/NftId.sol";
+import {Fee} from "../type/Fee.sol";
+import {ReferralId} from "../type/Referral.sol";
+import {RiskId} from "../type/RiskId.sol";
+import {PRODUCT, DISTRIBUTION, PRICE} from "../type/ObjectType.sol";
+import {Amount} from "../type/Amount.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+
+import {IProductComponent} from "./IProductComponent.sol";
+
+import {IInstance} from "../instance/IInstance.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {IComponents} from "../instance/module/IComponents.sol";
+import {IPolicy} from "../instance/module/IPolicy.sol";
+import {IBundle} from "../instance/module/IBundle.sol";
+import {ISetup} from "../instance/module/ISetup.sol";
+import {IDistribution} from "../instance/module/IDistribution.sol";
+
+import {ComponentService} from "../shared/ComponentService.sol";
+
+import {IPricingService} from "./IPricingService.sol";
+import {IDistributionService} from "../distribution/IDistributionService.sol";
+
+
+contract PricingService is 
+    ComponentService, 
+    IPricingService
+{
+    using UFixedLib for UFixed;
+
+    IDistributionService internal _distributionService;
+
+
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        virtual override
+        initializer()
+    {
+        // TODO check this, might no longer be the way, refactor if necessary
+        address registryAddress;
+        address initialOwner;
+        (registryAddress, initialOwner) = abi.decode(data, (address, address));
+
+        initializeService(registryAddress, address(0), owner);
+        registerInterface(type(IPricingService).interfaceId);
+
+        _distributionService = IDistributionService(_getServiceAddress(DISTRIBUTION()));
+    }
+
+
+    function getDomain() public pure override returns(ObjectType) {
+        return PRICE();
+    }
+
+    /// @dev calculates the premium amount for the specified attributes
+    /// also returns the various fee components involved with creating a policy
+    function calculatePremium(
+        NftId productNftId,
+        RiskId riskId,
+        Amount sumInsuredAmount,
+        Seconds lifetime,
+        bytes memory applicationData,
+        NftId bundleNftId,
+        ReferralId referralId
+    )
+        external
+        view
+        virtual override
+        returns (
+            IPolicy.Premium memory premium
+        )
+    {
+        InstanceReader reader;
+        Amount netPremiumAmount;
+
+        {
+            // verify product
+            (
+                IRegistry.ObjectInfo memory productInfo, 
+                IInstance instance
+            ) = _getAndVerifyComponentInfoAndInstance(productNftId, PRODUCT());
+
+            reader = instance.getInstanceReader();
+
+            // calculate net premium
+            netPremiumAmount = IProductComponent(productInfo.objectAddress).calculateNetPremium(
+                sumInsuredAmount,
+                riskId,
+                lifetime,
+                applicationData
+            );
+        }
+
+        {
+            // get configurations for all involed objects
+            ISetup.ProductSetupInfo memory productSetup = reader.getProductSetupInfo(productNftId);
+
+            bytes memory componentData = reader.getComponentInfo(productSetup.poolNftId).data;
+            IComponents.PoolInfo memory poolInfo = abi.decode(componentData, (IComponents.PoolInfo));
+
+            IBundle.BundleInfo memory bundleInfo = reader.getBundleInfo(bundleNftId);
+            if(bundleInfo.poolNftId != productSetup.poolNftId) {
+                revert ErrorIPricingServiceBundlePoolMismatch(bundleNftId, bundleInfo.poolNftId, productSetup.poolNftId);
+            }
+
+            NftId distributionNftId = productSetup.distributionNftId;
+            ISetup.DistributionSetupInfo memory distSetup = reader.getDistributionSetupInfo(distributionNftId);
+
+            // calculate premium, order is important
+            premium = _getFixedFeeAmounts(
+                netPremiumAmount,
+                productSetup,
+                poolInfo,
+                distSetup,
+                bundleInfo
+            );
+
+            premium = _calculateVariableFeeAmounts(
+                premium,
+                productSetup,
+                poolInfo,
+                distSetup,
+                bundleInfo
+            );
+
+            premium = _calculateDistributionOwnerFeeAmount(
+                premium,
+                distSetup,
+                referralId,
+                distributionNftId,
+                reader
+            );
+
+            // sanity check to validate the fee calculation
+            if (premium.distributionOwnerFeeFixAmount < distSetup.minDistributionOwnerFee.fixedFee) {
+                revert ErrorIPricingServiceFeeCalculationMismatch( 
+                    premium.distributionFeeFixAmount,
+                    premium.distributionFeeVarAmount,
+                    premium.distributionOwnerFeeFixAmount,
+                    premium.distributionOwnerFeeVarAmount,
+                    premium.commissionAmount,
+                    premium.discountAmount
+                );
+            }
+
+            if ((premium.distributionFeeVarAmount) != (premium.discountAmount + premium.distributionOwnerFeeVarAmount + premium.commissionAmount)) {
+                revert ErrorIPricingServiceFeeCalculationMismatch(
+                    premium.distributionFeeFixAmount,
+                    premium.distributionFeeVarAmount,
+                    premium.distributionOwnerFeeFixAmount,
+                    premium.distributionOwnerFeeVarAmount,
+                    premium.commissionAmount,
+                    premium.discountAmount
+                );
+            }
+        }
+    }
+
+    // internal functions
+    function _getFixedFeeAmounts(
+        Amount netPremiumAmount,
+        ISetup.ProductSetupInfo memory productInfo,
+        IComponents.PoolInfo memory poolInfo,
+        ISetup.DistributionSetupInfo memory distInfo,
+        IBundle.BundleInfo memory bundleInfo
+    )
+        internal
+        view
+        returns (
+            IPolicy.Premium memory premium
+        )
+    {
+        // initial premium amount is the net premium
+        premium.netPremiumAmount = netPremiumAmount.toInt();
+        premium.fullPremiumAmount = netPremiumAmount.toInt();
+
+        uint256 t = productInfo.productFee.fixedFee;
+        premium.productFeeFixAmount = t;
+        premium.fullPremiumAmount += t;
+
+        t = poolInfo.poolFee.fixedFee;
+        premium.poolFeeFixAmount = t;
+        premium.fullPremiumAmount += t;
+
+        t = bundleInfo.fee.fixedFee;
+        premium.bundleFeeFixAmount = t;
+        premium.fullPremiumAmount += t;
+
+        t = distInfo.distributionFee.fixedFee;
+        premium.distributionFeeFixAmount = t;
+        premium.fullPremiumAmount += t;
+    }
+
+    function _calculateVariableFeeAmounts(
+        IPolicy.Premium memory premium,
+        ISetup.ProductSetupInfo memory productInfo,
+        IComponents.PoolInfo memory poolInfo,
+        ISetup.DistributionSetupInfo memory distInfo,
+        IBundle.BundleInfo memory bundleInfo
+    )
+        internal
+        view
+        returns (
+            IPolicy.Premium memory intermadiatePremium
+        )
+    {
+        UFixed netPremiumAmount = UFixedLib.toUFixed(premium.netPremiumAmount);
+
+        uint256 t = (netPremiumAmount * productInfo.productFee.fractionalFee).toInt();
+        premium.productFeeVarAmount = t;
+        premium.fullPremiumAmount += t;
+
+        t = (netPremiumAmount * poolInfo.poolFee.fractionalFee).toInt();
+        premium.poolFeeVarAmount = t;
+        premium.fullPremiumAmount += t;
+
+        t = (netPremiumAmount * bundleInfo.fee.fractionalFee).toInt();
+        premium.bundleFeeVarAmount = t;
+        premium.fullPremiumAmount += t;
+
+        t = (netPremiumAmount * distInfo.distributionFee.fractionalFee).toInt();
+        premium.distributionFeeVarAmount = t;
+        premium.fullPremiumAmount += t;
+
+        return premium;
+    }
+
+    function _calculateDistributionOwnerFeeAmount(
+        IPolicy.Premium memory premium,
+        ISetup.DistributionSetupInfo memory distInfo,
+        ReferralId referralId,
+        NftId distributionNftId,
+        InstanceReader reader
+    )
+        internal
+        view 
+        returns (IPolicy.Premium memory finalPremium)
+    {
+        // if the referral is not valid, then the distribution owner gets everything
+        if (! _distributionService.referralIsValid(distributionNftId, referralId)) {
+            premium.distributionOwnerFeeFixAmount = premium.distributionFeeFixAmount;
+            premium.distributionOwnerFeeVarAmount = premium.distributionFeeVarAmount;
+            premium.premiumAmount = premium.fullPremiumAmount;
+            return premium;
+        }
+
+        Fee memory minDistributionOwnerFee = distInfo.minDistributionOwnerFee;
+
+        // if the referral is valid, the the commission and discount are calculated based in the full premium
+        // the remaing amount goes to the distribution owner
+        {
+            IDistribution.ReferralInfo memory referralInfo = reader.getReferralInfo(referralId);
+            IDistribution.DistributorInfo memory distributorInfo = reader.getDistributorInfo(referralInfo.distributorNftId);
+            IDistribution.DistributorTypeInfo memory distributorTypeInfo = reader.getDistributorTypeInfo(distributorInfo.distributorType);
+
+            uint256 commissionAmount = UFixedLib.toUFixed(premium.netPremiumAmount).mul(distributorTypeInfo.commissionPercentage).toInt();
+            premium.commissionAmount = commissionAmount;
+            premium.discountAmount = UFixedLib.toUFixed(premium.fullPremiumAmount).mul(referralInfo.discountPercentage).toInt();
+            premium.distributionOwnerFeeFixAmount = distInfo.minDistributionOwnerFee.fixedFee;
+            premium.distributionOwnerFeeVarAmount = premium.distributionFeeVarAmount - commissionAmount - premium.discountAmount;
+            premium.premiumAmount = premium.fullPremiumAmount - premium.discountAmount;
+        }
+
+        return premium; 
+    }
+}