@etherisc/gif-next 0.0.2-e875d61-189 → 0.0.2-e9148e0-933

package/contracts/registry/RegistryService.sol

@@ -0,0 +1,358 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ERC165Checker} from "@openzeppelin/contracts/utils/introspection/ERC165Checker.sol";
+import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
+
+import {IRegistry} from "./IRegistry.sol";
+import {IInstance} from "../instance/IInstance.sol";
+
+import {ContractDeployerLib} from "../shared/ContractDeployerLib.sol";
+import {IBaseComponent} from "../../contracts/components/IBaseComponent.sol";
+import {IPoolComponent} from "../../contracts/components/IPoolComponent.sol";
+import {IProductComponent} from "../../contracts/components/IProductComponent.sol";
+import {IDistributionComponent} from "../../contracts/components/IDistributionComponent.sol";
+
+import {IVersionable} from "../../contracts/shared/IVersionable.sol";
+import {Versionable} from "../../contracts/shared/Versionable.sol";
+import {IRegisterable} from "../../contracts/shared/IRegisterable.sol";
+
+import {RoleId, PRODUCT_OWNER_ROLE, POOL_OWNER_ROLE, ORACLE_OWNER_ROLE} from "../../contracts/types/RoleId.sol";
+import {ObjectType, REGISTRY, SERVICE, PRODUCT, ORACLE, POOL, INSTANCE, DISTRIBUTION, POLICY, BUNDLE, STAKE} from "../../contracts/types/ObjectType.sol";
+import {StateId, ACTIVE, PAUSED} from "../../contracts/types/StateId.sol";
+import {NftId, NftIdLib, zeroNftId} from "../../contracts/types/NftId.sol";
+import {Fee, FeeLib} from "../../contracts/types/Fee.sol";
+import {Version, VersionPart, VersionLib} from "../../contracts/types/Version.sol";
+
+import {Service} from "../shared/Service.sol";
+import {IService} from "../shared/IService.sol";
+import {IRegistryService} from "./IRegistryService.sol";
+import {Registry} from "./Registry.sol";
+
+contract RegistryService is
+    AccessManagedUpgradeable,
+    Service,
+    IRegistryService
+{
+    using NftIdLib for NftId;
+
+
+    // Initial value for constant variable has to be compile-time constant
+    // TODO define types as constants?
+    //ObjectType public constant SERVICE_TYPE = REGISTRY(); 
+    string public constant NAME = "RegistryService";
+
+    // TODO update to real hash when registry is stable
+    bytes32 public constant REGISTRY_CREATION_CODE_HASH = bytes32(0);
+
+    address public constant NFT_LOCK_ADDRESS = address(0x1);
+
+    /// @dev 
+    //  msg.sender - ONLY registry owner
+    //      CAN NOT register itself
+    //      CAN register ONLY valid object-parent types combinations for SERVICE
+    //      CAN register ONLY IRegisterable address he owns
+    // IMPORTANT: MUST NOT check owner before calling external contract
+    function registerService(IService service)
+        external
+        restricted
+        returns(
+            IRegistry.ObjectInfo memory info,
+            bytes memory data
+        ) 
+    {
+
+        // CAN revert if no ERC165 support -> will revert with empty message 
+        if(!service.supportsInterface(type(IService).interfaceId)) {
+            revert NotService();
+        }
+
+        (
+            info, 
+            data
+        ) = _getAndVerifyContractInfo(service, SERVICE(), msg.sender);
+
+        info.nftId = _registry.register(info);
+        service.linkToRegisteredNftId();
+        return (info, data);
+    }
+
+    function registerInstance(IRegisterable instance)
+        external
+        returns(
+            IRegistry.ObjectInfo memory info,
+            bytes memory data
+        ) 
+    {
+        if(!instance.supportsInterface(type(IInstance).interfaceId)) {
+            revert NotInstance();
+        }
+
+        (
+            info, 
+            data
+        ) = _getAndVerifyContractInfo(instance, INSTANCE(), msg.sender);
+
+        info.nftId = _registry.register(info);
+        instance.linkToRegisteredNftId(); // asume safe
+        
+        return (info, data);
+    }
+
+    function registerProduct(IBaseComponent product, address owner)
+        external
+        restricted
+        returns(
+            IRegistry.ObjectInfo memory info,
+            bytes memory data
+        ) 
+    {
+        // CAN revert if no ERC165 support -> will revert with empty message 
+        if(!product.supportsInterface(type(IProductComponent).interfaceId)) {
+            revert NotProduct();
+        }
+
+        (
+            info, 
+            data
+        ) = _getAndVerifyContractInfo(product, PRODUCT(), owner);
+
+        info.nftId = _registry.register(info);
+        // TODO unsafe, let component or its owner derive nftId latter, when state assumptions and modifications of GIF contracts are finished  
+        product.linkToRegisteredNftId();
+
+        return (info, data);  
+    }
+
+    function registerPool(IBaseComponent pool, address owner)
+        external
+        restricted
+        returns(
+            IRegistry.ObjectInfo memory info,
+            bytes memory data
+        ) 
+    {
+        if(!pool.supportsInterface(type(IPoolComponent).interfaceId)) {
+            revert NotPool();
+        }
+
+        (
+            info, 
+            data
+        ) = _getAndVerifyContractInfo(pool, POOL(), owner);
+
+        info.nftId = _registry.register(info);
+        pool.linkToRegisteredNftId();
+
+        return (info, data);  
+    }
+
+    function registerDistribution(IBaseComponent distribution, address owner)
+        external
+        restricted
+        returns(
+            IRegistry.ObjectInfo memory info,
+            bytes memory data
+        ) 
+    {
+        if(!distribution.supportsInterface(type(IDistributionComponent).interfaceId)) {
+            revert NotDistribution();
+        }
+
+        (
+            info, 
+            data
+        ) = _getAndVerifyContractInfo(distribution, DISTRIBUTION(), owner);
+
+        info.nftId = _registry.register(info); 
+        distribution.linkToRegisteredNftId();
+
+        return (info, data);  
+    }
+
+    function registerPolicy(IRegistry.ObjectInfo memory info)
+        external
+        restricted 
+        returns(NftId nftId) 
+    {
+        _verifyObjectInfo(info, POLICY());
+
+        nftId = _registry.register(info);
+    }
+
+    function registerBundle(IRegistry.ObjectInfo memory info)
+        external
+        restricted 
+        returns(NftId nftId) 
+    {
+        _verifyObjectInfo(info, BUNDLE());
+
+        nftId = _registry.register(info);
+    }
+
+    function registerStake(IRegistry.ObjectInfo memory info)
+        external
+        restricted 
+        returns(NftId nftId) 
+    {
+        _verifyObjectInfo(info, STAKE());
+
+        nftId = _registry.register(info);
+    }
+
+    // From IService
+    function getName() public pure override(IService, Service) returns(string memory) {
+        return NAME;
+    }
+    //function getType() public pure override(IService, ServiceBase) returns(ObjectType serviceType) {
+    //    return SERVICE_TYPE;
+    //}
+
+
+    // from Versionable
+
+    /// @dev top level initializer
+    // 1) registry is non upgradeable -> don't need a proxy and uses constructor !
+    // 2) deploy registry service first -> from its initialization func it is easier to deploy registry then vice versa
+    // 3) deploy registry -> pass registry service address as constructor argument
+    // registry is getting instantiated and locked to registry service address forever
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        initializer
+        virtual override
+    {
+        (
+            address initialAuthority,
+            bytes memory registryByteCodeWithInitCode
+        ) = abi.decode(data, (address, bytes));
+
+        __AccessManaged_init(initialAuthority);
+
+        bytes memory encodedConstructorArguments = abi.encode(
+            owner,
+            getMajorVersion());
+
+        bytes memory registryCreationCode = ContractDeployerLib.getCreationCode(
+            registryByteCodeWithInitCode,
+            encodedConstructorArguments);
+
+        IRegistry registry = IRegistry(ContractDeployerLib.deploy(
+            registryCreationCode,
+            REGISTRY_CREATION_CODE_HASH));
+
+        NftId registryNftId = registry.getNftId(address(registry));
+
+        _initializeService(address(registry), owner);
+
+        // TODO why do registry service proxy need to keep its nftId??? -> no registryServiceNftId checks in implementation
+        // if they are -> use registry address to obtain owner of registry service nft (works the same with any registerable and(or) implementation)
+        linkToRegisteredNftId(); 
+        _registerInterface(type(IRegistryService).interfaceId);
+    }
+
+    function _getAndVerifyContractInfo(
+        IRegisterable registerable,
+        ObjectType expectedType, // assume can be valid only
+        address expectedOwner // assume can be 0
+    )
+        internal
+        view
+        returns(
+            IRegistry.ObjectInfo memory info, 
+            bytes memory data
+        )
+    {
+        (
+            info, 
+            data
+        ) = registerable.getInitialInfo();
+        info.objectAddress = address(registerable);
+
+        if(info.objectType != expectedType) {// type is checked in registry anyway...but service logic may depend on expected value
+            revert UnexpectedRegisterableType(expectedType, info.objectType);
+        }
+
+        address owner = info.initialOwner;
+
+        // solhint-disable-next-line 
+        if(expectedType == INSTANCE()) { 
+            // any address may create a new instance via instance service
+        } else {
+            if(owner != expectedOwner) { // registerable owner protection
+                revert NotRegisterableOwner(expectedOwner);
+            }
+        }
+
+        if(owner == address(registerable)) {
+            revert SelfRegistration();
+        }
+
+        if(owner == address(0)) {
+            revert RegisterableOwnerIsZero();
+        }
+        
+        if(getRegistry().isRegistered(owner)) { 
+            revert RegisterableOwnerIsRegistered();
+        }
+
+        /*NftId parentNftId = info.parentNftId;
+        IRegistry.ObjectInfo memory parentInfo = getRegistry().getObjectInfo(parentNftId);
+
+        if(parentInfo.objectType != parentType) { // parent registration + type
+            revert InvalidParent(parentNftId);
+        }*/
+
+        return(
+            info,
+            data
+        );
+    }
+
+    function _verifyObjectInfo(
+        IRegistry.ObjectInfo memory info,
+        ObjectType expectedType
+    )
+        internal
+        view
+    {
+        // enforce instead of check
+        info.objectAddress = address(0);
+
+        if(info.objectType != expectedType) {// type is checked in registry anyway...but service logic may depend on expected value
+            revert UnexpectedRegisterableType(expectedType, info.objectType);
+        }
+
+        address owner = info.initialOwner;
+
+        if(owner == address(0)) {
+            revert RegisterableOwnerIsZero();
+        }
+
+        if(getRegistry().isRegistered(owner)) { 
+            revert RegisterableOwnerIsRegistered();
+        }
+
+        // can catch all 3 if check that initialOwner is not registered
+        /*if(info.initialOwner == msg.sender) {
+            revert InitialOwnerIsParent();
+        }
+
+        if(info.initialOwner == address(this)) {
+            revert InitialOwnerIsService();
+        }
+
+        if(info.initialOwner == address(getRegistry())) {
+            revert InitialOwnerIsRegistry();
+        }*/
+
+        /*NftId parentNftId = info.parentNftId;
+        IRegistry.ObjectInfo memory parentInfo = getRegistry().getObjectInfo(parentNftId);
+
+        if(parentInfo.objectType != parentType) { // parent registration + type
+            revert InvalidParent(parentNftId);
+        }*/        
+    }
+}

package/contracts/registry/RegistryServiceManager.sol

@@ -0,0 +1,80 @@
+// SPDX-License-Identifier: UNLICENSED
+pragma solidity ^0.8.20;
+
+import {AccessManager} from "@openzeppelin/contracts/access/manager/AccessManager.sol";
+
+import {ContractDeployerLib} from "../shared/ContractDeployerLib.sol";
+
+import {Registry} from "./Registry.sol";
+import {IVersionable} from "../shared/IVersionable.sol";
+import {ProxyManager} from "../shared/ProxyManager.sol";
+import {RegistryService} from "./RegistryService.sol";
+import {TokenRegistry} from "./TokenRegistry.sol";
+
+
+contract RegistryServiceManager is
+    ProxyManager
+{
+    bytes32 constant public ACCESS_MANAGER_CREATION_CODE_HASH = 0x0;
+
+    AccessManager private _accessManager;
+    RegistryService private _registryService; 
+    TokenRegistry private _tokenRegistry;
+
+    /// @dev initializes proxy manager with registry service implementation and deploys registry
+    constructor(
+        address accessManager
+    )
+        ProxyManager()
+    {
+        _accessManager = AccessManager(accessManager);
+
+        bytes memory initializationData = abi.encode(accessManager, type(Registry).creationCode);
+
+        IVersionable versionable = deploy(
+            address(new RegistryService()), 
+            initializationData);
+
+        _registryService = RegistryService(address(versionable));
+
+        // link ownership of registry service manager ot nft owner of registry service
+        _linkToNftOwnable(
+            address(_registryService.getRegistry()),
+            address(_registryService));
+
+        // deploy token registry
+
+        // _tokenRegistry = new TokenRegistry(
+        //     address(_registryService.getRegistry()),
+        //     address(_registryService));
+
+        // implies that after this constructor call only upgrade functionality is available
+        _isDeployed = true;
+    }
+
+    //--- view functions ----------------------------------------------------//
+
+    function getAccessManager()
+        external
+        view
+        returns (AccessManager)
+    {
+        return _accessManager;
+    }
+
+    function getRegistryService()
+        external
+        view
+        returns (RegistryService registryService)
+    {
+        return _registryService;
+    }
+
+    function getTokenRegistry()
+        external
+        view
+        returns (TokenRegistry)
+    {
+        return _tokenRegistry;
+    }
+}

package/contracts/registry/TokenRegistry.sol

@@ -0,0 +1,111 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+import {ERC165Checker} from "@openzeppelin/contracts/utils/introspection/ERC165Checker.sol";
+
+import {IRegisterable} from "../shared/IRegisterable.sol";
+import {IRegistry} from "./IRegistry.sol";
+import {Version, VersionPart, VersionLib, VersionPartLib} from "../types/Version.sol";
+import {NftOwnable} from "../shared/NftOwnable.sol";
+
+/// @title contract to register token per GIF major release.
+contract TokenRegistry is
+    NftOwnable
+{
+
+    string public constant REGISTRY_SERVICE_NAME = "RegistryService";
+
+    event LogRegistered(address token, string symbol, uint256 decimals);
+    event LogTokenStateSet(address token, VersionPart majorVersion, bool active);
+
+    error NotContract(address account);
+    error NotToken(address account);
+    error TokenDecimalsZero();
+    error TokenMajorVersionInvalid(VersionPart majorVersion);
+
+    address [] internal _token;
+    mapping(address token => bool registered) internal _registered;
+    mapping(address token => mapping(VersionPart majorVersion => bool isActive)) internal _active;
+
+    constructor()
+        NftOwnable()
+    { }
+
+
+    /// @dev link ownership of token registry to nft owner of registry service
+    function linkToNftOwnable(address registryAddress) 
+        external
+        onlyOwner
+    {
+        IRegistry registry = IRegistry(registryAddress);
+        address registryServiceAddress = registry.getServiceAddress(REGISTRY_SERVICE_NAME, registry.getMajorVersion());
+
+        _linkToNftOwnable(registryAddress, registryServiceAddress);
+    }
+
+    /// @dev token state is informative, registry have no clue about used tokens
+    // component owner is responsible for token selection and operations
+    // service MUST deny registration of component with inactive token 
+    function setActive(address token, VersionPart majorVersion, bool active)
+        external
+        onlyOwner
+    {
+        // verify that token is registered
+        if (!_registered[token]) {
+            _registerToken(token);
+        }
+
+        // verify valid major version
+        // ensure major version increments is one
+        uint256 version = majorVersion.toInt();
+        if (version < _registry.getMajorVersionMin().toInt() || version > _registry.getMajorVersionMax().toInt()) {
+            revert TokenMajorVersionInvalid(majorVersion);
+        }
+
+        _active[token][majorVersion] = active;
+
+        emit LogTokenStateSet(token, majorVersion, active);
+    }
+
+    function tokens() external view returns (uint256) {
+        return _token.length;
+    }
+
+    function getToken(uint256 idx) external view returns (IERC20Metadata token) {
+        return IERC20Metadata(_token[idx]);
+    }
+
+    function isRegistered(address token) external view returns (bool) {
+        return _registered[token];
+    }
+
+     function isActive(address token, VersionPart majorVersion) external view returns (bool) {
+        return _active[token][majorVersion];
+    }
+
+    /// @dev some sanity checks to prevent unintended registration
+    function _registerToken(address token) internal {
+
+        // MUST be contract
+        if(token.code.length == 0) {
+            revert NotContract(token);
+        }
+
+        // MUST not be GIF registerable
+        if(ERC165Checker.supportsInterface(token, type(IRegisterable).interfaceId)) {
+            revert NotToken(token);
+        }
+
+        // MUST have decimals > 0
+        IERC20Metadata erc20 = IERC20Metadata(token);
+        if(erc20.decimals() == 0) {
+            revert TokenDecimalsZero();
+        }
+
+        _registered[token] = true;
+        _token.push(token);
+
+        emit LogRegistered(token, erc20.symbol(), erc20.decimals());
+    }
+}

package/contracts/shared/ContractDeployerLib.sol

@@ -0,0 +1,72 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+library ContractDeployerLib {
+
+    event LogContractDeployed(address contractAddress);
+
+    error ErrorCreationCodeHashMismatch(bytes32 expectedHash, bytes32 actualHash);
+
+    /// @dev deploys a new contract using the provided creation code
+    function deploy(
+        bytes memory creationCode,
+        bytes32 expectedCreationCodeHash
+    ) 
+        public
+        returns (address contractAdress)
+    {
+        // check against expected hash, if provided
+        if (expectedCreationCodeHash != bytes32(0)) {
+            bytes32 creationCodeHash = getHash(creationCode);
+            if (creationCodeHash != expectedCreationCodeHash) {
+                revert ErrorCreationCodeHashMismatch(expectedCreationCodeHash, creationCodeHash);
+            }
+        }
+
+        // solhint-disable no-inline-assembly
+        assembly {
+            contractAdress := create(0, add(creationCode, 0x20), mload(creationCode))  
+
+            if iszero(extcodesize(contractAdress)) {
+                revert(0, 0)
+            }
+        }
+        // solhint enable
+
+        emit LogContractDeployed(contractAdress);
+    }
+
+    /// @dev gets the creation code for the new contract
+    // for terminology see eg https://www.rareskills.io/post/ethereum-contract-creation-code
+    function getCreationCode(
+        bytes memory byteCodeWithInitCode, // what you get with type(<Contract>).creationCode
+        bytes memory encodedConstructorArguments // what you get with 
+    )
+        public
+        pure
+        returns (bytes memory creationCode)
+    {
+        return abi.encodePacked(byteCodeWithInitCode, encodedConstructorArguments);
+    }
+
+
+    function matchesWithHash(
+        bytes memory creationCode,
+        bytes32 expectedHash
+    )
+        public
+        pure
+        returns (bool isMatching)
+    {
+        return getHash(creationCode) == expectedHash;
+    }
+
+
+    function getHash(bytes memory creationCode)
+        public
+        pure
+        returns (bytes32 hash)
+    {
+        return keccak256(creationCode);
+    }
+}

package/contracts/shared/ERC165.sol

@@ -7,14 +7,18 @@ contract ERC165 is IERC165 {
     mapping(bytes4 => bool) private _isSupported;
 
     constructor() {
-        // register support for ERC165
-        _registerInterface(type(IERC165).interfaceId);
+        _initializeERC165();
     }
 
     function supportsInterface(bytes4 interfaceId) external view override returns (bool) {
         return _isSupported[interfaceId];
     }
 
+    // @dev register support for ERC165 itself
+    function _initializeERC165() internal {
+        _isSupported[type(IERC165).interfaceId] = true;
+    }
+
     function _registerInterface(bytes4 interfaceId) internal {
         _isSupported[interfaceId] = true;
     }

package/contracts/shared/INftOwnable.sol

@@ -0,0 +1,22 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {NftId} from "../types/NftId.sol";
+
+interface INftOwnable {
+    error ErrorNotOwner(address account);
+
+    error ErrorAlreadyLinked(address registry, NftId nftId);
+    error ErrorRegistryAlreadyInitialized(address registry);
+    error ErrorRegistryNotInitialized();
+    error ErrorRegistryAddressZero();
+    error ErrorNotRegistry(address registryAddress);
+    error ErrorContractNotRegistered(address contractAddress);
+
+    function linkToRegisteredNftId() external;
+
+    function getRegistry() external view returns (IRegistry);
+    function getNftId() external view returns (NftId);
+    function getOwner() external view returns (address);
+}

package/contracts/shared/IRegisterable.sol

@@ -1,24 +1,17 @@
 // SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
+pragma solidity ^0.8.20;
 
 import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
 
+import {INftOwnable} from "./INftOwnable.sol";
 import {IRegistry} from "../registry/IRegistry.sol";
 import {NftId} from "../types/NftId.sol";
 import {ObjectType} from "../types/ObjectType.sol";
 
-import {IOwnable} from "./IOwnable.sol";
+interface IRegisterable is IERC165, INftOwnable {
 
-interface IRegisterable is IERC165, IOwnable {
-    function getRegistry() external view returns (IRegistry registry);
-
-    function register() external returns (NftId nftId);
-
-    function getType() external pure returns (ObjectType objectType);
-
-    function getNftId() external view returns (NftId nftId);
-
-    function getParentNftId() external view returns (NftId nftId);
-
-    function getData() external view returns (bytes memory data);
-}
+    function getInitialInfo() 
+        external 
+        view
+        returns (IRegistry.ObjectInfo memory, bytes memory data);
+}