@etherisc/gif-next 0.0.2-e875d61-189 → 0.0.2-e8a628e-326

package/contracts/{types → type}/UFixed.sol

@@ -1,10 +1,10 @@
 // SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
+pragma solidity ^0.8.20;
 
 import {Math} from "@openzeppelin/contracts/utils/math/Math.sol";
 
-/// @dev UFixed is a fixed point number with 18 decimals precision.
-type UFixed is uint256;
+/// @dev UFixed is a 160-bit fixed point number with 15 decimals precision.
+type UFixed is uint160; 
 
 using {
     addUFixed as +,
@@ -16,28 +16,42 @@ using {
     ltUFixed as <,
     lteUFixed as <=,
     eqUFixed as ==,
-    UFixedMathLib.toInt
+    neUFixed as !=,
+    UFixedLib.gt,
+    UFixedLib.eqz,
+    UFixedLib.gtz,
+    UFixedLib.toInt,
+    UFixedLib.toInt1000
 } for UFixed global;
 
+// TODO move to UFixedLib and rename to zero()
+function zeroUFixed() pure returns (UFixed zero) {
+    return UFixed.wrap(0);
+}
+
 function addUFixed(UFixed a, UFixed b) pure returns (UFixed) {
     return UFixed.wrap(UFixed.unwrap(a) + UFixed.unwrap(b));
 }
 
 function subUFixed(UFixed a, UFixed b) pure returns (UFixed) {
-    require(a >= b, "ERROR:UFM-010:NEGATIVE_RESULT");
+    if (a < b) {
+        revert UFixedLib.UFixedLibNegativeResult();
+    }
     return UFixed.wrap(UFixed.unwrap(a) - UFixed.unwrap(b));
 }
 
 function mulUFixed(UFixed a, UFixed b) pure returns (UFixed) {
     return
-        UFixed.wrap(Math.mulDiv(UFixed.unwrap(a), UFixed.unwrap(b), 10 ** 18));
+        UFixed.wrap(uint160(Math.mulDiv(UFixed.unwrap(a), UFixed.unwrap(b), 10 ** 15)));
 }
 
 function divUFixed(UFixed a, UFixed b) pure returns (UFixed) {
-    require(UFixed.unwrap(b) > 0, "ERROR:UFM-020:DIVISOR_ZERO");
-
+    if (UFixed.unwrap(b) == 0) {
+        revert UFixedLib.UFixedLibDivisionByZero();
+    }
+    
     return
-        UFixed.wrap(Math.mulDiv(UFixed.unwrap(a), 10 ** 18, UFixed.unwrap(b)));
+        UFixed.wrap(uint160(Math.mulDiv(UFixed.unwrap(a), 10 ** 15, UFixed.unwrap(b))));
 }
 
 function gtUFixed(UFixed a, UFixed b) pure returns (bool isGreaterThan) {
@@ -60,6 +74,10 @@ function eqUFixed(UFixed a, UFixed b) pure returns (bool isEqual) {
     return UFixed.unwrap(a) == UFixed.unwrap(b);
 }
 
+function neUFixed(UFixed a, UFixed b) pure returns (bool isEqual) {
+    return UFixed.unwrap(a) != UFixed.unwrap(b);
+}
+
 function gtzUFixed(UFixed a) pure returns (bool isZero) {
     return UFixed.unwrap(a) > 0;
 }
@@ -76,8 +94,16 @@ function deltaUFixed(UFixed a, UFixed b) pure returns (UFixed) {
     return b - a;
 }
 
-library UFixedMathLib {
-    int8 public constant EXP = 18;
+library UFixedLib {
+    error UFixedLibNegativeResult();
+    error UFixedLibDivisionByZero();
+
+    error UFixedLibExponentTooSmall(int8 exp);
+    error UFixedLibExponentTooLarge(int8 exp);
+
+    error UFixedLibNumberTooLarge(uint256 number);
+
+    int8 public constant EXP = 15;
     uint256 public constant MULTIPLIER = 10 ** uint256(int256(EXP));
     uint256 public constant MULTIPLIER_HALF = MULTIPLIER / 2;
 
@@ -96,17 +122,32 @@ library UFixedMathLib {
         return uint8(2);
     }
 
-    /// @dev Converts the uint256 to a UFixed.
+    /// @dev Converts the uint256 to a uint160 based UFixed. 
+    /// This method reverts if the number is too large to fit in a uint160.
     function toUFixed(uint256 a) public pure returns (UFixed) {
-        return UFixed.wrap(a * MULTIPLIER);
+        uint256 n = a * MULTIPLIER;
+        if (n > type(uint160).max) {
+            revert UFixedLibNumberTooLarge(a);
+        }
+        return UFixed.wrap(uint160(n));
     }
 
     /// @dev Converts the uint256 to a UFixed with given exponent.
     function toUFixed(uint256 a, int8 exp) public pure returns (UFixed) {
-        require(EXP + exp >= 0, "ERROR:FM-010:EXPONENT_TOO_SMALL");
-        require(EXP + exp <= 64, "ERROR:FM-011:EXPONENT_TOO_LARGE");
+        if (EXP + exp < 0) {
+            revert UFixedLibExponentTooSmall(exp);
+        }
+        if (EXP + exp > 48) {
+            revert UFixedLibExponentTooLarge(exp);
+        }
+        
+        uint256 n = a * 10 ** uint8(EXP + exp);
+
+        if (n > type(uint160).max) {
+            revert UFixedLibNumberTooLarge(n);
+        }
 
-        return UFixed.wrap(a * 10 ** uint8(EXP + exp));
+        return UFixed.wrap(uint160(n));
     }
 
     /// @dev returns the decimals precision of the UFixed type
@@ -119,6 +160,11 @@ library UFixedMathLib {
         return toIntWithRounding(a, ROUNDING_HALF_UP());
     }
 
+    /// @dev Converts a UFixed to a uint256.
+    function toInt1000(UFixed a) public pure returns (uint256) {
+        return toIntWithRounding(toUFixed(1000) * a, ROUNDING_HALF_UP());
+    }
+
     /// @dev Converts a UFixed to a uint256 with given rounding mode.
     function toIntWithRounding(UFixed a, uint8 rounding) public pure returns (uint256) {
         if (rounding == ROUNDING_HALF_UP()) {
@@ -127,7 +173,7 @@ library UFixedMathLib {
                     UFixed.unwrap(a) + MULTIPLIER_HALF,
                     1,
                     MULTIPLIER,
-                    Math.Rounding.Down
+                    Math.Rounding.Floor
                 );
         } else if (rounding == ROUNDING_DOWN()) {
             return
@@ -135,11 +181,11 @@ library UFixedMathLib {
                     UFixed.unwrap(a),
                     1,
                     MULTIPLIER,
-                    Math.Rounding.Down
+                    Math.Rounding.Floor
                 );
         } else {
             return
-                Math.mulDiv(UFixed.unwrap(a), 1, MULTIPLIER, Math.Rounding.Up);
+                Math.mulDiv(UFixed.unwrap(a), 1, MULTIPLIER, Math.Rounding.Ceil);
         }
     }
 
@@ -202,6 +248,14 @@ library UFixedMathLib {
         return UFixed.wrap(0);
     }
 
+    function one() public pure returns (UFixed) {
+        return UFixed.wrap(uint160(MULTIPLIER));
+    }
+
+    function max() public pure returns (UFixed) {
+        return UFixed.wrap(type(uint160).max);
+    }
+
     /// @dev return the absolute delta between two UFixed numbers
     function delta(UFixed a, UFixed b) public pure returns (UFixed) {
         return deltaUFixed(a, b);

package/contracts/type/Version.sol

@@ -0,0 +1,159 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+type VersionPart is uint8;
+
+using {
+    versionPartGt as >,
+    versionPartEq as ==,
+    versionPartNe as !=,
+    VersionPartLib.eqz,
+    VersionPartLib.gtz,
+    VersionPartLib.toInt,
+    VersionPartLib.toString,
+    VersionPartLib.isValidRelease
+}
+    for VersionPart global;
+
+function versionPartGt(VersionPart a, VersionPart b) pure returns(bool isGreaterThan) { return VersionPart.unwrap(a) > VersionPart.unwrap(b); }
+function versionPartEq(VersionPart a, VersionPart b) pure returns(bool isSame) { return VersionPart.unwrap(a) == VersionPart.unwrap(b); }
+function versionPartNe(VersionPart a, VersionPart b) pure returns(bool isSame) { return VersionPart.unwrap(a) != VersionPart.unwrap(b); }
+
+library VersionPartLib {
+
+    error ErrorReleaseTooBig(VersionPart releaseMax, VersionPart release);
+
+    function releaseMin() public pure returns (VersionPart) { return toVersionPart(3); }
+    function releaseMax() public pure returns (VersionPart) { return toVersionPart(99); }
+
+    function isValidRelease(VersionPart release) external pure returns(bool) { 
+        uint256 releaseInt = VersionPart.unwrap(release);
+        return 3 <= releaseInt && releaseInt <= 99; 
+    } 
+
+    function toString(VersionPart a) external pure returns (string memory) {
+        if (a > releaseMax()) {
+            revert ErrorReleaseTooBig(releaseMax(), a);
+        }
+
+        uint256 value = VersionPart.unwrap(a);
+        if (value == 0) {
+            return "0";
+        }
+
+        uint256 temp = value;
+        uint256 digits = 0;
+        while (temp != 0) {
+            digits++;
+            temp /= 10;
+        }
+
+        bytes memory buffer = new bytes(digits);
+        uint index = digits - 1;
+
+        temp = value;
+        while (temp != 0) {
+            buffer[index] = bytes1(uint8(48 + temp % 10));
+            temp /= 10;
+
+            if (index > 0) {
+                index--;
+            }
+        }
+
+        return string(buffer);
+    }
+
+    function eqz(VersionPart a) external pure returns(bool) { return VersionPart.unwrap(a) == 0; }
+    function gtz(VersionPart a) external pure returns(bool) { return VersionPart.unwrap(a) > 0; }
+    function toInt(VersionPart a) external pure returns(uint256) { return VersionPart.unwrap(a); }
+    function toVersionPart(uint256 a) public pure returns(VersionPart) { return VersionPart.wrap(uint8(a)); }
+}
+
+type Version is uint24; // contains major,minor,patch version parts
+
+using {
+    versionGt as >,
+    versionEq as ==,
+    VersionLib.toInt,
+    VersionLib.toUint64,
+    VersionLib.toMajorPart,
+    VersionLib.toVersionParts
+}
+    for Version global;
+
+function versionGt(Version a, Version b) pure returns(bool isGreaterThan) { return Version.unwrap(a) > Version.unwrap(b); }
+function versionEq(Version a, Version b) pure returns(bool isSame) { return Version.unwrap(a) == Version.unwrap(b); }
+
+library VersionLib {
+
+    function toInt(Version version) external pure returns(uint) { return Version.unwrap(version); }
+
+    function toUint64(Version version) external pure returns(uint64) { return Version.unwrap(version); }
+
+    function toMajorPart(Version version)
+        external    
+        pure 
+        returns(VersionPart major)
+    { 
+        uint24 versionInt = Version.unwrap(version);
+        uint8 majorInt = uint8(versionInt >> 16);
+        return VersionPart.wrap(majorInt);
+    }
+
+    function toVersionParts(Version version)
+        external
+        pure
+        returns(
+            VersionPart major,
+            VersionPart minor,
+            VersionPart patch
+        )
+    {
+        uint24 versionInt = Version.unwrap(version);
+        uint8 majorInt = uint8(versionInt >> 16);
+
+        versionInt -= majorInt << 16;
+        uint8 minorInt = uint8(versionInt >> 8);
+        uint8 patchInt = uint8(versionInt - (minorInt << 8));
+
+        return (
+            VersionPart.wrap(majorInt),
+            VersionPart.wrap(minorInt),
+            VersionPart.wrap(patchInt)
+        );
+    }
+
+    // function toVersionPart(uint256 versionPart) public pure returns(VersionPart) { 
+    //     return VersionPart.wrap(uint8(versionPart)); 
+    // }
+
+    function toVersion(
+        uint256 major,
+        uint256 minor,
+        uint256 patch
+    )
+        external
+        pure
+        returns(Version)
+    {
+        require(
+            major < 256 && minor < 256 && patch < 256,
+            "ERROR:VRS-010:VERSION_PART_TOO_BIG");
+
+        return Version.wrap(
+            uint24(
+                (major << 16) + (minor << 8) + patch));
+    }
+
+    // TODO check for overflow?
+    function toVersion(uint64 versionNumber) external pure returns(Version) {
+        //assert(versionNumber <= type(Version).max);
+        return Version.wrap(uint24(versionNumber));
+    }
+
+    // TODO rename to zero()
+    function zeroVersion() external pure returns(Version) {
+        return Version.wrap(0);
+    }
+}

package/contracts/upgradeability/IVersionable.sol

@@ -0,0 +1,56 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Version} from "../type/Version.sol";
+
+/// IMPORTANT
+// Upgradeable contract MUST:
+// 1) inherit from Versionable
+// 2) implement version() function
+// 3) implement internal _initialize() function with onlyInitializing modifier 
+// 4) implement internal _upgrade() function with onlyInitializing modifier (1st version MUST revert)
+// 5) have onlyInitialising modifier for each function callable inside _initialize()/_upgrade() (MUST use different functions for initialization/upgrade and normal operations)
+// 6) use default empty constructor -> _disableInitializer() is called from Versionable contructor
+// 7) use namespace storage (should this be needed)
+// 8) since now inheritance is used for upgradability, contract MUST BE inherited ONLY by the next version 
+// Upgradeable contract SHOULD:
+// 9) define all non private methods as virtual (in order to be able to upgrade them latter)
+//    otherwise, it is still possible to upgrade contract, but everyone who is using it will have to switch to a new fucntions
+//    in some cases this ok but not in the others...
+//
+// IMPORTANT
+// If introducting/amending storage related to Versionable version MUST:
+// 1) define namespace storage struct if accessing storage
+//      - DO NOT use structs inside, except
+//      - CAN use structs ONLY inside mappings
+// 2) ALWAYS define private getter if accessing storage
+//      - MUST use default implementation, CAN change ONLY return type
+
+interface IVersionable {
+
+    error ErrorVersionableInitializeNotImplemented();
+    error ErrorVersionableUpgradeNotImplemented();
+
+    /**
+     * @dev IMPORTANT
+     * implementation MUST be guarded by initializer modifier
+     * new version MUST inherit from previous version
+     */
+    function initializeVersionable(address activatedBy, bytes memory activationData) external;
+
+    /**
+     * @dev
+     * implementation MUST be guarded by reinitializer(version().toUint64()) modifier
+     * new version MUST inherit from previous version
+     * the first verion MUST revert 
+     */
+    function upgradeVersionable(bytes memory upgradeData) external;
+
+    /**
+     * @dev returns version of this contract
+     * each new implementation MUST implement this function
+     * version number MUST increase 
+     */
+    function getVersion() external pure returns(Version);
+
+}

package/contracts/upgradeability/ProxyManager.sol

@@ -0,0 +1,246 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ProxyAdmin} from "@openzeppelin/contracts/proxy/transparent/ProxyAdmin.sol";
+import {ITransparentUpgradeableProxy} from "@openzeppelin/contracts/proxy/transparent/TransparentUpgradeableProxy.sol";
+
+import {Blocknumber, blockNumber} from "../type/Blocknumber.sol";
+import {IVersionable} from "./IVersionable.sol";
+import {NftId} from "../type/NftId.sol";
+import {NftOwnable} from "../shared/NftOwnable.sol";
+import {Timestamp, TimestampLib} from "../type/Timestamp.sol";
+import {UpgradableProxyWithAdmin} from "./UpgradableProxyWithAdmin.sol";
+import {Version, VersionLib} from "../type/Version.sol";
+
+/// @dev manages proxy deployments for upgradable contracs of type IVersionable
+contract ProxyManager is
+    NftOwnable
+{
+
+    struct VersionInfo {
+        // slot 0
+        address implementation;
+        Timestamp activatedAt;
+        Blocknumber activatedIn;
+        Version version;
+        // slot 1
+        address activatedBy;
+    }
+
+    event LogProxyManagerVersionableDeployed(address indexed proxy, address initialImplementation);
+    event LogProxyManagerVersionableUpgraded(address indexed proxy, address upgradedImplementation);
+
+    error ErrorProxyManagerAlreadyDeployed();
+    error ErrorProxyManagerNotYetDeployed();
+
+    error ErrorProxyManagerZeroVersion();
+    error ErrorProxyManagerNextVersionNotIncreasing(Version nextVersion);
+
+    UpgradableProxyWithAdmin internal _proxy;
+
+    // state to keep version history
+    mapping(Version version => VersionInfo info) internal _versionHistory;
+    Version [] internal _versions;
+
+    /// @dev convencience initializer
+    function initialize(
+        address registry,
+        address implementation,
+        bytes memory data,
+        bytes32 salt
+    )
+        public
+        initializer()
+        returns (IVersionable versionable)
+    {
+        versionable = deployDetermenistic(
+            registry,
+            implementation, 
+            data,
+            salt);
+    }
+
+    /// @dev deploy initial contract
+    function deploy(
+        address registry, 
+        address initialImplementation, 
+        bytes memory initializationData
+    )
+        public
+        virtual
+        onlyInitializing()
+        returns (IVersionable versionable)
+    {
+        (
+            address currentProxyOwner, 
+            address initialProxyAdminOwner
+        ) = _preDeployChecksAndSetup(registry);
+
+        _proxy = new UpgradableProxyWithAdmin(
+            initialImplementation,
+            initialProxyAdminOwner,
+            getDeployData(currentProxyOwner, initializationData)
+        );
+
+        versionable = _updateVersionHistory(
+            initialImplementation, 
+            currentProxyOwner);
+
+        emit LogProxyManagerVersionableDeployed(address(versionable), initialImplementation);
+    }
+
+    function deployDetermenistic(
+        address registry, 
+        address initialImplementation, 
+        bytes memory initializationData, 
+        bytes32 salt
+    )
+        public
+        virtual
+        onlyInitializing()
+        returns (IVersionable versionable)
+    {
+        (
+            address currentProxyOwner, 
+            address initialProxyAdminOwner
+        ) = _preDeployChecksAndSetup(registry);
+
+        _proxy = new UpgradableProxyWithAdmin{salt: salt}(
+            initialImplementation,
+            initialProxyAdminOwner,
+            getDeployData(currentProxyOwner, initializationData)
+        );
+
+        versionable = _updateVersionHistory(
+            initialImplementation, 
+            currentProxyOwner);
+
+        emit LogProxyManagerVersionableDeployed(address(versionable), initialImplementation);
+    }
+
+    /// @dev upgrade existing contract.
+    /// convenience method using empty data
+    function upgrade(address newImplementation) 
+        public
+        virtual
+        onlyOwner()
+        returns (IVersionable versionable)
+    {
+        bytes memory emptyUpgradeData;
+        return upgrade(newImplementation, emptyUpgradeData);
+    }
+
+    /// @dev upgrade existing contract
+    function upgrade(address newImplementation, bytes memory upgradeData)
+        public
+        virtual
+        onlyOwner()
+        returns (IVersionable versionable)
+    {
+        if (_versions.length == 0) { 
+            revert ErrorProxyManagerNotYetDeployed();
+        }
+
+        address currentProxyOwner = getOwner();
+        ProxyAdmin proxyAdmin = getProxy().getProxyAdmin();
+        ITransparentUpgradeableProxy proxy = ITransparentUpgradeableProxy(address(_proxy));
+
+        proxyAdmin.upgradeAndCall(
+            proxy,
+            newImplementation, 
+            getUpgradeData(upgradeData));
+
+        versionable = _updateVersionHistory(
+            newImplementation, 
+            currentProxyOwner);
+
+        emit LogProxyManagerVersionableUpgraded(address(versionable), newImplementation);
+
+    }
+
+    function linkToProxy() public returns (NftId) {
+        return _linkToNftOwnable(address(_proxy));
+    }
+
+    function getDeployData(address proxyOwner, bytes memory deployData) public pure returns (bytes memory data) {
+        return abi.encodeWithSelector(
+            IVersionable.initializeVersionable.selector, 
+            proxyOwner, 
+            deployData);
+    }
+
+    function getUpgradeData(bytes memory upgradeData) public pure returns (bytes memory data) {
+        return abi.encodeWithSelector(
+            IVersionable.upgradeVersionable.selector, 
+            upgradeData);
+    }
+
+    function getProxy() public view returns (UpgradableProxyWithAdmin) {
+        return _proxy;
+    }
+
+    function getVersion() external view virtual returns(Version) {
+        return IVersionable(address(_proxy)).getVersion();
+    }
+
+    function getVersionCount() external view returns(uint256) {
+        return _versions.length;
+    }
+
+    function getVersion(uint256 idx) external view returns(Version) {
+        return _versions[idx];
+    }
+
+    function getVersionInfo(Version _version) external view returns(VersionInfo memory) {
+        return _versionHistory[_version];
+    }
+
+    function _preDeployChecksAndSetup(address registry)
+        private
+        returns (
+            address currentProxyOwner,
+            address initialProxyAdminOwner
+        )
+    {
+        if (_versions.length > 0) {
+            revert ErrorProxyManagerAlreadyDeployed();
+        }
+
+        address initialOwner = msg.sender;
+        __NftOwnable_init(registry, initialOwner);
+
+        currentProxyOwner = getOwner(); // used by implementation
+        initialProxyAdminOwner = address(this); // used by proxy
+    }
+
+    function _updateVersionHistory(
+        address implementation,
+        address activatedBy
+    )
+        private
+        returns (IVersionable versionable)
+    {
+        versionable = IVersionable(address(_proxy));
+        Version newVersion = versionable.getVersion();
+
+        if(newVersion == VersionLib.zeroVersion()) {
+            revert ErrorProxyManagerZeroVersion();
+        }
+
+        if(_versions.length > 0) {
+            if(newVersion.toInt() <= _versions[_versions.length-1].toInt()) {
+                revert ErrorProxyManagerNextVersionNotIncreasing(newVersion);
+            }
+        }
+
+        // update version history
+        _versions.push(newVersion);
+        _versionHistory[newVersion] = VersionInfo({
+            version: newVersion,
+            implementation: implementation,
+            activatedBy: activatedBy,
+            activatedAt: TimestampLib.current(),
+            activatedIn: blockNumber()
+        });
+    }
+}

package/contracts/upgradeability/UpgradableProxyWithAdmin.sol

@@ -0,0 +1,24 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ProxyAdmin} from "@openzeppelin/contracts/proxy/transparent/ProxyAdmin.sol";
+import {TransparentUpgradeableProxy} from "@openzeppelin/contracts/proxy/transparent/TransparentUpgradeableProxy.sol";
+
+contract UpgradableProxyWithAdmin is TransparentUpgradeableProxy {
+
+    bytes internal _initializationData;
+    
+    constructor(address implementation, address initialProxyAdminOwner, bytes memory data)
+        TransparentUpgradeableProxy(implementation, initialProxyAdminOwner, data)
+    {
+        _initializationData = data;
+    }
+
+    function getProxyAdmin() external returns (ProxyAdmin) { 
+        return ProxyAdmin(_proxyAdmin()); 
+    }
+
+    function getInitializationData() external view returns (bytes memory) { 
+        return _initializationData; 
+    }
+}