@etherisc/gif-next 0.0.2-e6a90b9 → 0.0.2-e875d61-189

package/contracts/instance/base/IInstanceBase.sol

@@ -0,0 +1,19 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Key32} from "../../types/Key32.sol";
+import {StateId} from "../../types/StateId.sol";
+
+import {IKeyValueStore} from "./IKeyValueStore.sol";
+import {IComponentOwnerService} from "../service/IComponentOwnerService.sol";
+import {IProductService} from "../service/IProductService.sol";
+import {IPoolService} from "../service/IPoolService.sol";
+
+interface IInstanceBase {
+    function getKeyValueStore() external view returns (IKeyValueStore keyValueStore);
+    function updateState(Key32 key, StateId state) external;
+
+    function getComponentOwnerService() external view returns(IComponentOwnerService service);
+    function getProductService() external view returns(IProductService service);
+    function getPoolService() external view returns(IPoolService service);
+}

package/contracts/instance/base/IKeyValueStore.sol

@@ -0,0 +1,50 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Blocknumber, blockBlocknumber, zeroBlocknumber} from "../../types/Blocknumber.sol";
+import {Key32, KeyId} from "../../types/Key32.sol";
+import {NftId} from "../../types/NftId.sol";
+import {ObjectType} from "../../types/ObjectType.sol";
+import {StateId} from "../../types/StateId.sol";
+
+import {ILifecycle} from "./ILifecycle.sol";
+
+interface IKeyValueStore is ILifecycle {
+
+    struct Key {
+        ObjectType objectType;
+        KeyId id;
+    }
+
+    struct Value {
+        Metadata metadata;
+        bytes data;
+    }
+
+    struct Metadata {
+        ObjectType objectType;
+        StateId state;
+        address updatedBy;
+        Blocknumber updatedIn;
+        Blocknumber createdIn;
+    }
+
+    event LogInfoCreated(Key key, StateId state, address createdBy, address txOrigin);
+    event LogInfoUpdated(Key key, StateId state, address updatedBy, address txOrigin, Blocknumber lastUpdatedIn);
+    event LogStateUpdated(Key key, StateId stateOld, StateId stateNew, address updatedBy, address txOrigin, Blocknumber lastUpdatedIn);
+
+    // generic state changing functions
+    function create(Key32 key, ObjectType objectType, bytes memory data) external;
+    function update(Key32 key, StateId state, bytes memory data) external;
+    function updateData(Key32 key, bytes memory data) external;
+    function updateState(Key32 key, StateId state) external;
+
+    function exists(Key32 key) external view returns (bool);
+    function get(Key32 key) external view returns (Value memory value);
+    function getData(Key32 key) external view returns (bytes memory data);
+    function getMetadata(Key32 key) external view returns (Metadata memory metadata);
+    function getState(Key32 key) external view returns (StateId state);
+
+    function toKey32(ObjectType objectType, KeyId id) external pure returns(Key32);
+    function toKey(Key32 key32) external pure returns(Key memory key);
+}

package/contracts/instance/base/ILifecycle.sol

@@ -0,0 +1,30 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {ObjectType} from "../../types/ObjectType.sol";
+import {StateId, toStateId, zeroStateId} from "../../types/StateId.sol";
+import {NftId} from "../../types/NftId.sol";
+
+interface ILifecycle {
+
+    error ErrorNoLifecycle(NftId nftId, ObjectType objectType);
+    error ErrorInvalidStateTransition(
+        ObjectType objectType,
+        StateId fromStateId,
+        StateId toStateId
+    );
+
+    function hasLifecycle(
+        ObjectType objectType
+    ) external view returns (bool);
+
+    function getInitialState(
+        ObjectType objectType
+    ) external view returns (StateId);
+
+    function isValidTransition(
+        ObjectType objectType,
+        StateId fromId,
+        StateId toId
+    ) external view returns (bool);
+}

package/contracts/instance/base/IService.sol

@@ -0,0 +1,15 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {VersionPart} from "../../types/Version.sol";
+
+import {IRegisterable} from "../../shared/IRegisterable.sol";
+import {IVersionable} from "../../shared/IVersionable.sol";
+
+interface IService is 
+    IRegisterable,
+    IVersionable
+{
+    function getName() external pure returns(string memory name);
+    function getMajorVersion() external view returns(VersionPart majorVersion);
+}

package/contracts/instance/base/InstanceBase.sol

@@ -0,0 +1,84 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Versionable} from "../../shared/Versionable.sol";
+import {Registerable} from "../../shared/Registerable.sol";
+
+import {ObjectType, INSTANCE} from "../../types/ObjectType.sol";
+import {Key32} from "../../types/Key32.sol";
+import {NftId} from "../../types/NftId.sol";
+import {StateId} from "../../types/StateId.sol";
+import {Version, VersionPart, VersionLib} from "../../types/Version.sol";
+
+import {IComponentOwnerService} from "../service/IComponentOwnerService.sol";
+import {IProductService} from "../service/IProductService.sol";
+import {IPoolService} from "../service/IPoolService.sol";
+
+import {IKeyValueStore} from "./IKeyValueStore.sol";
+import {IInstance} from "../IInstance.sol";
+import {IInstanceBase} from "./IInstanceBase.sol";
+
+import {KeyValueStore} from "./KeyValueStore.sol";
+
+abstract contract InstanceBase is
+    Versionable,
+    Registerable,
+    IInstanceBase
+{
+    IKeyValueStore internal _keyValueStore;
+
+    IComponentOwnerService internal _componentOwnerService;
+    IProductService internal _productService;
+    IPoolService internal _poolService;
+
+    constructor(
+        address registry,
+        NftId registryNftId
+    )
+        Registerable(registry, registryNftId)
+        Versionable()
+    {
+        _keyValueStore = new KeyValueStore();
+
+        _registerInterface(type(IInstance).interfaceId);
+        _linkToServicesInRegistry();
+    }
+
+    function getKeyValueStore() public view virtual override returns (IKeyValueStore keyValueStore) { return _keyValueStore; }
+
+    function updateState(Key32 key, StateId state) external override {
+        _keyValueStore.updateState(key, state);
+    }
+
+    // from versionable
+    function getVersion()
+        public 
+        pure 
+        virtual override
+        returns(Version)
+    {
+        return VersionLib.toVersion(3,0,0);
+    }
+
+    // from registerable
+    function getType() external pure override returns (ObjectType objectType) {
+        return INSTANCE();
+    }
+
+
+    // internal / private functions
+    function _linkToServicesInRegistry() internal {
+        VersionPart majorVersion = getVersion().toMajorPart();
+        _componentOwnerService = IComponentOwnerService(_getAndCheck("ComponentOwnerService", majorVersion));
+        _productService = IProductService(_getAndCheck("ProductService", majorVersion));
+        _poolService = IPoolService(_getAndCheck("PoolService", majorVersion));
+    }
+
+    function _getAndCheck(string memory serviceName, VersionPart majorVersion) internal view returns (address serviceAddress) {
+        serviceAddress = _registry.getServiceAddress(serviceName, majorVersion);
+        require(
+            serviceAddress != address(0),
+            "ERROR:INS-001:NOT_REGISTERED"
+        );
+    }
+}

package/contracts/instance/base/KeyValueStore.sol

@@ -0,0 +1,161 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Blocknumber, blockBlocknumber, zeroBlocknumber} from "../../types/Blocknumber.sol";
+import {Key32, KeyId, Key32Lib} from "../../types/Key32.sol";
+import {NftId} from "../../types/NftId.sol";
+import {ObjectType} from "../../types/ObjectType.sol";
+import {StateId, ACTIVE} from "../../types/StateId.sol";
+import {Timestamp, blockTimestamp, zeroTimestamp} from "../../types/Timestamp.sol";
+
+import {Lifecycle} from "./Lifecycle.sol";
+import {IKeyValueStore} from "./IKeyValueStore.sol";
+
+contract KeyValueStore is Lifecycle, IKeyValueStore {
+
+    mapping(Key32 key32 => Value value) private _value;
+    address private _owner;
+
+    modifier onlyOwner() {
+        require(
+            msg.sender == _owner,
+            "ERROR:KVS-001:NOT_OWNER");
+        _;
+    }
+
+    constructor() {
+        _owner = msg.sender;
+    }
+
+    function create(
+        Key32 key32, 
+        ObjectType objectType, 
+        bytes memory data
+    )
+        public
+        onlyOwner
+    {
+        require(objectType.gtz(), "ERROR:KVS-010:TYPE_UNDEFINED");
+
+        Metadata storage metadata = _value[key32].metadata;
+        require(metadata.state.eqz(), "ERROR:KVS-012:ALREADY_CREATED");
+
+        address createdBy = msg.sender;
+        Blocknumber blocknumber = blockBlocknumber();
+        StateId initialState = hasLifecycle(objectType) ? getInitialState(objectType) : ACTIVE();
+
+        // set metadata
+        metadata.objectType = objectType;
+        metadata.state = initialState;
+        metadata.updatedBy = createdBy;
+        metadata.updatedIn = blocknumber;
+        metadata.createdIn = blocknumber;
+
+        // set data
+        _value[key32].data = data;
+
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogInfoCreated(toKey(key32), initialState, createdBy, tx.origin);
+    }
+
+    function update(Key32 key32, StateId state, bytes memory data) 
+        public
+        onlyOwner
+    {
+        require(state.gtz(), "ERROR:KVS-020:STATE_UNDEFINED");
+        Metadata storage metadata = _value[key32].metadata;
+        StateId stateOld = metadata.state;
+        require(stateOld.gtz(), "ERROR:KVS-021:NOT_EXISTING");
+
+        // update data
+        _value[key32].data = data;
+
+        // update metadata (and state)
+        address updatedBy = msg.sender;
+        Blocknumber lastUpdatedIn = metadata.updatedIn;
+        metadata.state = state;
+        metadata.updatedBy = updatedBy;
+        metadata.updatedIn = blockBlocknumber();
+
+        // create log entries
+        Key memory key = toKey(key32);
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogStateUpdated(key, state, stateOld, updatedBy, tx.origin, lastUpdatedIn);
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogInfoUpdated(key, state, updatedBy, tx.origin, lastUpdatedIn);
+    }
+
+    function updateData(Key32 key32, bytes memory data) 
+        public
+        onlyOwner
+    {
+        Metadata storage metadata = _value[key32].metadata;
+        StateId state = metadata.state;
+        require(state.gtz(), "ERROR:KVS-030:NOT_EXISTING");
+
+        // update data
+        _value[key32].data = data;
+
+        // update metadata
+        address updatedBy = msg.sender;
+        Blocknumber lastUpdatedIn = metadata.updatedIn;
+        metadata.updatedBy = updatedBy;
+        metadata.updatedIn = blockBlocknumber();
+
+        // create log entry
+        Key memory key = toKey(key32);
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogInfoUpdated(key, state, updatedBy, tx.origin, lastUpdatedIn);
+    }
+
+    function updateState(Key32 key32, StateId state)
+        public
+        onlyOwner
+    {
+        require(state.gtz(), "ERROR:KVS-040:STATE_UNDEFINED");
+        Metadata storage metadata = _value[key32].metadata;
+        StateId stateOld = metadata.state;
+        require(stateOld.gtz(), "ERROR:KVS-041:NOT_EXISTING");
+
+        // update metadata (and state)
+        address updatedBy = msg.sender;
+        Blocknumber lastUpdatedIn = metadata.updatedIn;
+        metadata.state = state;
+        metadata.updatedBy = updatedBy;
+        metadata.updatedIn = blockBlocknumber();
+
+        // create log entry
+        Key memory key = toKey(key32);
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogStateUpdated(key, state, stateOld, updatedBy, tx.origin, lastUpdatedIn);
+    }
+
+    function exists(Key32 key32) public view returns (bool) {
+        return _value[key32].metadata.state.gtz();
+    }
+
+    function get(Key32 key32) public view returns (Value memory value) {
+        return _value[key32];
+    }
+
+    function getMetadata(Key32 key32) public view returns (Metadata memory metadata) {
+        return _value[key32].metadata;
+    }
+
+    function getData(Key32 key32) public view returns (bytes memory data) {
+        return _value[key32].data;
+    }
+
+    function getState(Key32 key32) public view returns (StateId state) {
+        return _value[key32].metadata.state;
+    }
+
+    function toKey32(ObjectType objectType, KeyId id) external pure override returns(Key32) {
+        return Key32Lib.toKey32(objectType, id);
+    }
+
+    function toKey(Key32 key32) public pure override returns (Key memory key) {
+        (ObjectType objectType, KeyId id) = key32.toKey();
+        return Key(objectType, id);
+    }
+}

package/contracts/instance/base/Lifecycle.sol

@@ -0,0 +1,92 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {NftId} from "../../types/NftId.sol";
+import {ObjectType, COMPONENT, BUNDLE, POLICY} from "../../types/ObjectType.sol";
+import {StateId, ACTIVE, PAUSED, ARCHIVED, CLOSED, APPLIED, UNDERWRITTEN, REVOKED, DECLINED} from "../../types/StateId.sol";
+import {ILifecycle} from "./ILifecycle.sol";
+
+contract Lifecycle is ILifecycle {
+    mapping(ObjectType objectType => StateId initialState)
+        private _initialState;
+
+    mapping(ObjectType objectType => mapping(StateId stateFrom => mapping(StateId stateTo => bool isValid)))
+        private _isValidTransition;
+
+    constructor() {
+        _setupComponentLifecycle();
+        _setupBundleLifecycle();
+        _setupPolicyLifecycle();
+    }
+
+    function hasLifecycle(
+        ObjectType objectType
+    )
+        public
+        view
+        override
+        returns (bool)
+    {
+        return _initialState[objectType].gtz();
+    }
+
+    function getInitialState(
+        ObjectType objectType
+    )
+        public
+        view
+        returns (StateId)
+    {
+        return _initialState[objectType];
+    }
+
+    function checkTransition(
+        ObjectType objectType,
+        StateId fromId,
+        StateId toId
+    )
+        public
+        view
+    {
+        // return if no life cycle support
+        if (_initialState[objectType].eqz()) {
+            return;
+        }
+
+        // enforce valid state transition
+        if (!_isValidTransition[objectType][fromId][toId]) {
+            revert ErrorInvalidStateTransition(objectType, fromId, toId);
+        }
+    }
+
+    function isValidTransition(
+        ObjectType objectType,
+        StateId fromId,
+        StateId toId
+    ) public view returns (bool) {
+        return _isValidTransition[objectType][fromId][toId];
+    }
+
+    function _setupComponentLifecycle() internal {
+        _initialState[COMPONENT()] = ACTIVE();
+        _isValidTransition[COMPONENT()][ACTIVE()][PAUSED()] = true;
+        _isValidTransition[COMPONENT()][PAUSED()][ACTIVE()] = true;
+        _isValidTransition[COMPONENT()][PAUSED()][ARCHIVED()] = true;
+    }
+
+    function _setupBundleLifecycle() internal {
+        _initialState[BUNDLE()] = ACTIVE();
+        _isValidTransition[BUNDLE()][ACTIVE()][PAUSED()] = true;
+        _isValidTransition[BUNDLE()][PAUSED()][ACTIVE()] = true;
+        _isValidTransition[BUNDLE()][PAUSED()][CLOSED()] = true;
+    }
+
+    function _setupPolicyLifecycle() internal {
+        _initialState[POLICY()] = APPLIED();
+        _isValidTransition[POLICY()][APPLIED()][REVOKED()] = true;
+        _isValidTransition[POLICY()][APPLIED()][DECLINED()] = true;
+        _isValidTransition[POLICY()][APPLIED()][UNDERWRITTEN()] = true;
+        _isValidTransition[POLICY()][UNDERWRITTEN()][ACTIVE()] = true;
+        _isValidTransition[POLICY()][ACTIVE()][CLOSED()] = true;
+    }
+}

package/contracts/instance/base/ModuleBase.sol

@@ -0,0 +1,46 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../registry/IRegistry.sol";
+
+import {Blocknumber, blockNumber} from "../../types/Blocknumber.sol";
+import {Key32, KeyId} from "../../types/Key32.sol";
+import {LibNftIdSet} from "../../types/NftIdSet.sol";
+import {NftId} from "../../types/NftId.sol";
+import {ObjectType, PRODUCT, ORACLE, POOL, BUNDLE, POLICY} from "../../types/ObjectType.sol";
+import {StateId, ACTIVE, PAUSED, ARCHIVED, CLOSED, APPLIED, REVOKED, DECLINED} from "../../types/StateId.sol";
+import {Timestamp, blockTimestamp, zeroTimestamp} from "../../types/Timestamp.sol";
+
+import {IKeyValueStore} from "./IKeyValueStore.sol";
+
+abstract contract ModuleBase {
+
+    IKeyValueStore private _store;
+
+    function _initialize(IKeyValueStore keyValueStore) internal {
+        _store = keyValueStore;
+    }
+
+    function _create(ObjectType objectType, NftId nftId, bytes memory data) internal {
+        _store.create(
+            nftId.toKey32(objectType), 
+            objectType,
+            data);
+    }
+
+    function _updateData(ObjectType objectType, NftId nftId, bytes memory data) internal {
+        _store.updateData(nftId.toKey32(objectType), data);
+    }
+
+    function _updateState(ObjectType objectType, NftId nftId, StateId state) internal {
+        _store.updateState(nftId.toKey32(objectType), state);
+    }
+
+    function _getData(ObjectType objectType, NftId nftId) internal view returns(bytes memory data) {
+        return _store.getData(nftId.toKey32(objectType));
+    }
+
+    function _getState(ObjectType objectType, NftId nftId) internal view returns(StateId) {
+        return _store.getState(nftId.toKey32(objectType));
+    }
+}

package/contracts/instance/base/ServiceBase.sol

@@ -0,0 +1,37 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {NftId, zeroNftId} from "../../types/NftId.sol";
+import {ObjectType, SERVICE} from "../../types/ObjectType.sol";
+import {Version, VersionPart} from "../../types/Version.sol";
+
+import {Registerable} from "../../shared/Registerable.sol";
+import {IVersionable} from "../../shared/IVersionable.sol";
+import {Versionable} from "../../shared/Versionable.sol";
+
+import {IService} from "./IService.sol";
+
+abstract contract ServiceBase is 
+    Registerable,
+    Versionable,
+    IService
+{
+
+    constructor(
+        address registry,
+        NftId registryNftId
+    )
+        Registerable(registry, registryNftId)
+        Versionable()
+    {
+        _registerInterface(type(IService).interfaceId);
+    }
+
+    function getMajorVersion() external view override returns(VersionPart majorVersion) {
+        return this.getVersion().toMajorPart();
+    }
+
+    function getType() external pure override returns (ObjectType) {
+        return SERVICE();
+    }
+}

package/contracts/instance/module/access/Access.sol

@@ -0,0 +1,149 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+// role admin handling of oz doesn't fit nft ownability
+// import {AccessControlEnumerable} from "@openzeppelin/contracts/access/AccessControlEnumerable.sol";
+import "@openzeppelin/contracts/utils/structs/EnumerableSet.sol";
+
+import {RoleId, RoleIdLib} from "../../../types/RoleId.sol";
+import {DISTRIBUTOR_OWNER_ROLE, ORACLE_OWNER_ROLE, POOL_OWNER_ROLE, PRODUCT_OWNER_ROLE} from "../../../types/RoleId.sol";
+import {DISTRIBUTOR_OWNER_ROLE_NAME, ORACLE_OWNER_ROLE_NAME, POOL_OWNER_ROLE_NAME, PRODUCT_OWNER_ROLE_NAME} from "../../../types/RoleId.sol";
+import {IAccessModule} from "./IAccess.sol";
+
+abstract contract AccessModule is IAccessModule {
+
+    using EnumerableSet for EnumerableSet.AddressSet;
+
+    mapping(RoleId role => RoleInfo info) private _info;
+    RoleId[] private _roles;
+
+    mapping(RoleId role => mapping(address member => bool isMember))
+        private _isRoleMember;
+    mapping(RoleId role => EnumerableSet.AddressSet members) private _roleMembers;
+
+    modifier onlyAccessOwner() {
+        require(
+            msg.sender == this.getOwner(),
+            "ERROR:ACS-001:NOT_OWNER");
+        _;
+    }
+
+    modifier onlyExistingRole(RoleId role) {
+        require(
+            _info[role].id == role,
+            "ERROR:ACS-002:ROLE_NOT_EXISTING");
+        _;
+    }
+
+    constructor() {
+        _createRole(DISTRIBUTOR_OWNER_ROLE(), DISTRIBUTOR_OWNER_ROLE_NAME());
+        _createRole(ORACLE_OWNER_ROLE(), ORACLE_OWNER_ROLE_NAME());
+        _createRole(POOL_OWNER_ROLE(), POOL_OWNER_ROLE_NAME());
+        _createRole(PRODUCT_OWNER_ROLE(), PRODUCT_OWNER_ROLE_NAME());
+    }
+
+    function createRole(
+        string memory roleName
+    ) public override onlyAccessOwner returns (RoleId role) {
+        role = RoleIdLib.toRoleId(roleName);
+        require(
+            !roleExists(role),
+            "ERROR:ACS-010:ROLE_ALREADY_EXISTS");
+        
+        _createRole(role, roleName);
+    }
+
+    function setRoleState(RoleId role, bool active) external override onlyExistingRole(role) onlyAccessOwner {
+        RoleInfo memory info = _info[role];
+        info.isActive = active;
+        _setRoleInfo(info);
+
+        emit LogAccessRoleStateSet(role, active);
+    }
+
+    function grantRole(
+        RoleId role,
+        address member
+    ) external override onlyExistingRole(role) onlyAccessOwner {
+        require(_info[role].isActive, "ERROR:ACS-040:ROLE_NOT_ACTIVE");
+
+        _isRoleMember[role][member] = true;
+        _roleMembers[role].add(member);
+
+        emit LogAccessRoleGranted(role, member, _isRoleMember[role][member]);
+    }
+
+    function revokeRole(
+        RoleId role,
+        address member
+    ) external override onlyExistingRole(role) onlyAccessOwner {
+        delete _isRoleMember[role][member];
+        _roleMembers[role].remove(member);
+
+        emit LogAccessRoleGranted(role, member, false);
+    }
+
+    function roleExists(RoleId role) public view virtual override returns (bool) {
+        return _info[role].id == role;
+    }
+
+    function hasRole(
+        RoleId role,
+        address member
+    ) public view virtual override returns (bool) {
+        return _isRoleMember[role][member];
+    }
+
+    function getRoleId(string memory roleName) external pure override returns (RoleId role) {
+        return RoleIdLib.toRoleId(roleName);
+    }
+
+    function getRoleInfo(
+        RoleId role
+    ) external view override returns (RoleInfo memory info) {
+        return _info[role];
+    }
+
+    function getRole(
+        uint256 idx
+    ) external view override returns (RoleId role) {
+        return _roles[idx];
+    }
+
+    function getRoleCount() external view override returns (uint256 roles) {
+        return _roles.length;
+    }
+
+    function getRoleMemberCount(
+        RoleId role
+    ) public view override returns (uint256 roleMembers) {
+        return _roleMembers[role].length();
+    }
+
+    function getRoleMember(
+        RoleId role,
+        uint256 idx
+    ) public view override returns (address roleMembers) {
+        return _roleMembers[role].at(idx);
+    }
+
+    function _createRole(
+        RoleId role,
+        string memory roleName
+    ) internal {
+        RoleInfo memory info = RoleInfo(role, roleName, true);
+        _setRoleInfo(info);
+
+        emit LogAccessRoleCreated(role, roleName);
+    }
+
+    function _setRoleInfo(
+        RoleInfo memory info
+    ) internal {
+        RoleId role = info.id;
+        _info[role] = info;
+        if(!roleExists(role)) {
+            _roles.push(role);
+        }
+    }
+}