@etherisc/gif-next 0.0.2-e6a90b9 → 0.0.2-e769e2e-077

package/contracts/registry/RegistryAccessManager.sol

@@ -0,0 +1,213 @@
+// SPDX-License-Identifier: UNLICENSED
+pragma solidity ^0.8.20;
+
+import {AccessManager} from "@openzeppelin/contracts/access/manager/AccessManager.sol";
+import {AccessManaged} from "@openzeppelin/contracts/access/manager/AccessManaged.sol";
+
+import {RoleId, RoleIdLib,
+        GIF_MANAGER_ROLE,
+        GIF_ADMIN_ROLE,
+        RELEASE_MANAGER_ROLE} from "../type/RoleId.sol";
+
+import {TokenRegistry} from "./TokenRegistry.sol";
+import {ReleaseManager} from "./ReleaseManager.sol";
+
+/*
+    4 types of roles:
+    1) RELEASE_MANAGER_ROLE
+        - has only ReleaseManager as member
+        - responsible for setting and granting of REGISTRAR roles
+    1) REGISTRAR roles
+        - set and granted by RELEASE_MANAGER_ROLE
+        - for each service and major version X there is 1 unique member (the service with version X itself) (subject to change)
+        - each set to 1 target (registry service ver.X) and 1 selector (function of registry service ver.X) (subject to change)
+    2) GIF_MANAGER_ROLE
+        - can have arbitrary number of members
+        - responsible for services registrations
+        - responsible for token registration and activation
+    3) GIF_ADMIN_ROLE
+        - admin of GIF_MANAGER_ROLE
+        - MUST have 1 member at any time
+        - granted/revoked ONLY in transferAdminRole() -> consider lock out situations!!!
+        - responsible for creation and activation of releases
+
+*/
+
+contract RegistryAccessManager is AccessManaged
+{
+    error NotInitialized();
+    error AlreadyInitialized();
+
+    uint64 public constant UNIQUE_ROLE_ID_MIN = 1000000;
+    
+    AccessManager private immutable _accessManager;
+    address private _releaseManager;
+    address private _tokenRegistry;
+
+    uint64 private _idNext; // role id
+    bool private _isInitialized;
+
+    modifier onlyOnce() {
+        if(_isInitialized) {
+            revert AlreadyInitialized();
+        } 
+        _;
+        _isInitialized = true;
+    }
+
+    modifier onlyInitialized() {
+        if(!_isInitialized) {
+            revert NotInitialized();
+        }
+        _;
+    }
+
+    constructor(address manager)
+        AccessManaged(msg.sender)
+    {
+        _accessManager = new AccessManager(address(this));
+        setAuthority(address(_accessManager));
+
+        _idNext = UNIQUE_ROLE_ID_MIN;
+
+        _configureAdminRoleInitial();
+
+        address admin = msg.sender;
+        _grantRole(GIF_ADMIN_ROLE(), admin, 0);
+        _grantRole(GIF_MANAGER_ROLE(), manager, 0);
+    }
+
+    function initialize(address releaseManager, address tokenRegistry)
+        external 
+        restricted // GIF_ADMIN_ROLE
+        onlyOnce
+    {
+        require(
+            ReleaseManager(releaseManager).authority() == address(_accessManager),
+            "RegistryAccessManager: release manager authority is invalid");
+        require(tokenRegistry > address(0), "RegistryAccessManager: token registry is 0");
+        //require(tokenRegistry.authority() == address(_accessManager));
+
+        _releaseManager = releaseManager;
+        _tokenRegistry = tokenRegistry;
+
+        _configureAdminRole();
+        _configureManagerRole();
+        _configureReleaseManagerRole();
+
+        _grantRole(RELEASE_MANAGER_ROLE(), releaseManager, 0);
+    }
+
+    // set unique role for target, role forever have 1 member and never revoked
+    function setAndGrantUniqueRole(
+        address account, 
+        address target, 
+        bytes4[] memory selector
+    )
+        external
+        restricted // RELEASE_MANAGER_ROLE
+        onlyInitialized
+        returns(RoleId)
+    {
+        // TODO define and add checks
+        RoleId roleId = _getNextRoleId();
+
+        _setTargetFunctionRole(target, selector, roleId);
+        _grantRole(roleId, account, 0);
+    }
+
+    function setTargetFunctionRole(
+        address target, 
+        bytes4[] memory selector,
+        RoleId roleId
+    )
+        external
+        restricted // RELEASE_MANAGER_ROLE
+        onlyInitialized
+    {
+        _setTargetFunctionRole(target, selector, roleId);
+    }
+
+    /*function transferAdmin(address to)
+        external
+        restricted // only with GIF_ADMIN_ROLE or nft owner
+    {
+        _accessManager.revoke(GIF_ADMIN_ROLE, );
+        _accesssManager.grant(GIF_ADMIN_ROLE, to, 0);
+    }*/
+
+    //--- view functions ----------------------------------------------------//
+
+    function getAccessManager()
+        external
+        view
+        returns (AccessManager)
+    {
+        return _accessManager;
+    }
+
+    //--- private functions -------------------------------------------------//
+
+    function _configureAdminRoleInitial() private
+    {
+        bytes4[] memory functionSelector = new bytes4[](1);
+
+        functionSelector[0] = RegistryAccessManager.initialize.selector;
+        _setTargetFunctionRole(address(this), functionSelector, GIF_ADMIN_ROLE());
+    }
+
+    function _configureAdminRole() private
+    {
+        // for ReleaseManager
+        bytes4[] memory functionSelector = new bytes4[](3);
+        functionSelector[0] = ReleaseManager.registerStaking.selector;
+        functionSelector[1] = ReleaseManager.createNextRelease.selector;
+        functionSelector[2] = ReleaseManager.activateNextRelease.selector;
+        _setTargetFunctionRole(_releaseManager, functionSelector, GIF_ADMIN_ROLE());
+    }
+    
+    function _configureManagerRole() private 
+    {
+        bytes4[] memory functionSelector = new bytes4[](1);
+
+        // for TokenRegistry
+        functionSelector[0] = TokenRegistry.setActive.selector;
+        _setTargetFunctionRole(address(_tokenRegistry), functionSelector, GIF_MANAGER_ROLE());
+
+        // for ReleaseManager
+        functionSelector[0] = ReleaseManager.registerService.selector;
+        _setTargetFunctionRole(_releaseManager, functionSelector, GIF_MANAGER_ROLE());
+
+        functionSelector[0] = ReleaseManager.registerRegistryService.selector;
+        _setTargetFunctionRole(_releaseManager, functionSelector, GIF_MANAGER_ROLE());
+
+        // set admin
+        _setRoleAdmin(GIF_MANAGER_ROLE(), GIF_ADMIN_ROLE());
+    }
+
+    function _configureReleaseManagerRole() private
+    {
+        bytes4[] memory functionSelector = new bytes4[](2);
+
+        functionSelector[0] = RegistryAccessManager.setAndGrantUniqueRole.selector;
+        functionSelector[1] = RegistryAccessManager.setTargetFunctionRole.selector;
+
+        _setTargetFunctionRole(address(this), functionSelector, RELEASE_MANAGER_ROLE());
+    }
+
+    function _setTargetFunctionRole(address target, bytes4[] memory selectors, RoleId roleId) private {
+        _accessManager.setTargetFunctionRole(target, selectors, roleId.toInt());        
+    }
+
+    function _setRoleAdmin(RoleId roleId, RoleId adminRoleId) private {
+        _accessManager.setRoleAdmin(roleId.toInt(), adminRoleId.toInt());
+    }
+
+    function _grantRole(RoleId roleId, address account, uint32 executionDelay) private {
+            _accessManager.grantRole(roleId.toInt(), account, executionDelay);
+    }
+
+    function _getNextRoleId() private returns(RoleId roleId) {
+        roleId = RoleIdLib.toRoleId(_idNext++);
+    }
+}

package/contracts/registry/RegistryService.sol

@@ -0,0 +1,327 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ERC165Checker} from "@openzeppelin/contracts/utils/introspection/ERC165Checker.sol";
+// import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
+
+import {IRegistry} from "./IRegistry.sol";
+import {IInstance} from "../instance/IInstance.sol";
+
+import {IComponent} from "../../contracts/shared/IComponent.sol";
+import {IPoolComponent} from "../../contracts/pool/IPoolComponent.sol";
+import {IProductComponent} from "../../contracts/product/IProductComponent.sol";
+import {IDistributionComponent} from "../../contracts/distribution/IDistributionComponent.sol";
+
+import {IVersionable} from "../../contracts/shared/IVersionable.sol";
+import {Versionable} from "../../contracts/shared/Versionable.sol";
+import {IRegisterable} from "../../contracts/shared/IRegisterable.sol";
+import {Registerable} from "../../contracts/shared/Registerable.sol";
+
+import {RoleId, PRODUCT_OWNER_ROLE, POOL_OWNER_ROLE, ORACLE_OWNER_ROLE} from "../../contracts/type/RoleId.sol";
+import {ObjectType, REGISTRY, SERVICE, PRODUCT, ORACLE, POOL, INSTANCE, COMPONENT, DISTRIBUTION, DISTRIBUTOR, APPLICATION, POLICY, CLAIM, BUNDLE, STAKE, STAKING, PRICE} from "../../contracts/type/ObjectType.sol";
+import {StateId, ACTIVE, PAUSED} from "../../contracts/type/StateId.sol";
+import {NftId, NftIdLib} from "../../contracts/type/NftId.sol";
+import {Fee, FeeLib} from "../../contracts/type/Fee.sol";
+import {Version, VersionPart, VersionLib} from "../../contracts/type/Version.sol";
+
+import {Service} from "../shared/Service.sol";
+import {IService} from "../shared/IService.sol";
+import {IRegistryService} from "./IRegistryService.sol";
+import {Registry} from "./Registry.sol";
+
+contract RegistryService is
+    Service,
+    IRegistryService
+{
+    using NftIdLib for NftId;
+
+    // TODO update to real hash when registry is stable
+    bytes32 public constant REGISTRY_CREATION_CODE_HASH = bytes32(0);
+
+    // From IService
+    function getDomain() public pure override returns(ObjectType serviceDomain) {
+        return REGISTRY(); 
+    }
+
+    // from Versionable
+
+    /// @dev top level initializer
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        virtual override
+        initializer()
+    {
+        (
+            address registryAddress,
+            address initialAuthority
+        ) = abi.decode(data, (address, address));
+
+        initializeService(registryAddress, initialAuthority, owner);
+        registerInterface(type(IRegistryService).interfaceId);
+    }
+
+
+    function registerStaking(IRegisterable staking, address owner)
+        external
+        virtual
+        restricted
+        returns(
+            IRegistry.ObjectInfo memory info
+        )
+    {
+        info = _getAndVerifyContractInfo(staking, STAKING(), owner);
+        info.nftId = getRegistry().register(info);
+    }
+
+
+    function registerInstance(IRegisterable instance, address owner)
+        external
+        virtual
+        restricted
+        returns(
+            IRegistry.ObjectInfo memory info
+        ) 
+    {
+        if(!instance.supportsInterface(type(IInstance).interfaceId)) {
+            revert NotInstance();
+        }
+
+        info = _getAndVerifyContractInfo(instance, INSTANCE(), owner);
+        info.nftId = getRegistry().register(info);
+
+        instance.linkToRegisteredNftId(); // asume safe
+    }
+
+    function registerProduct(IComponent product, address owner)
+        external
+        restricted
+        returns(
+            IRegistry.ObjectInfo memory info
+        ) 
+    {
+        // CAN revert if no ERC165 support -> will revert with empty message 
+        if(!product.supportsInterface(type(IProductComponent).interfaceId)) {
+            revert NotProduct();
+        }
+
+        info = _getAndVerifyContractInfo(product, PRODUCT(), owner);
+        info.nftId = getRegistry().register(info);
+    }
+
+    function registerComponent(
+        IComponent component, 
+        ObjectType objectType,
+        address initialOwner
+    )
+        external
+        restricted
+        returns(
+            IRegistry.ObjectInfo memory info
+        ) 
+    {
+        // CAN revert if no ERC165 support -> will revert with empty message 
+        if(!component.supportsInterface(type(IComponent).interfaceId)) {
+            revert NotComponent();
+        }
+
+        info = _getAndVerifyContractInfo(component, objectType, initialOwner);
+        info.nftId = getRegistry().register(info);
+    }
+
+    function registerPool(IComponent pool, address owner)
+        external
+        restricted
+        returns(
+            IRegistry.ObjectInfo memory info
+        ) 
+    {
+        if(!pool.supportsInterface(type(IPoolComponent).interfaceId)) {
+            revert NotPool();
+        }
+
+        info = _getAndVerifyContractInfo(pool, POOL(), owner);
+        info.nftId = getRegistry().register(info);
+    }
+
+    function registerDistribution(IComponent distribution, address owner)
+        external
+        restricted
+        returns(
+            IRegistry.ObjectInfo memory info
+        ) 
+    {
+        if(!distribution.supportsInterface(type(IDistributionComponent).interfaceId)) {
+            revert NotDistribution();
+        }
+
+        info = _getAndVerifyContractInfo(distribution, DISTRIBUTION(), owner);
+        info.nftId = getRegistry().register(info);
+    }
+
+    function registerDistributor(IRegistry.ObjectInfo memory info)
+        external
+        restricted 
+        returns(NftId nftId) 
+    {
+        _verifyObjectInfo(info, DISTRIBUTOR());
+        nftId = getRegistry().register(info);
+    }
+
+    function registerPolicy(IRegistry.ObjectInfo memory info)
+        external
+        restricted 
+        returns(NftId nftId) 
+    {
+        _verifyObjectInfo(info, POLICY());
+
+        nftId = getRegistry().register(info);
+    }
+
+    function registerBundle(IRegistry.ObjectInfo memory info)
+        external
+        restricted 
+        returns(NftId nftId) 
+    {
+        _verifyObjectInfo(info, BUNDLE());
+
+        nftId = getRegistry().register(info);
+    }
+
+    function registerStake(IRegistry.ObjectInfo memory info)
+        external
+        restricted 
+        returns(NftId nftId) 
+    {
+        _verifyObjectInfo(info, STAKE());
+
+        nftId = getRegistry().register(info);
+    }
+
+    // from IRegisterable
+
+    function getFunctionConfigs()
+        external
+        pure
+        returns(
+            FunctionConfig[] memory config
+        )
+    {
+        config = new FunctionConfig[](11);
+
+        // order of service registrations MUST be reverse to this array 
+        /*config[-1].serviceDomain = STAKE();
+        config[-1].selector = RegistryService.registerStake.selector;*/
+
+        config[0].serviceDomain = POLICY();
+        config[0].authorizedSelectors = new bytes4[](0);
+
+        config[1].serviceDomain = APPLICATION();
+        config[1].authorizedSelectors = new bytes4[](1);
+        config[1].authorizedSelectors[0] = RegistryService.registerPolicy.selector;
+
+        config[2].serviceDomain = CLAIM();
+        config[2].authorizedSelectors = new bytes4[](0);
+
+        config[3].serviceDomain = PRODUCT();
+        config[3].authorizedSelectors = new bytes4[](1);
+        config[3].authorizedSelectors[0] = RegistryService.registerProduct.selector;
+
+        config[4].serviceDomain = POOL();
+        config[4].authorizedSelectors = new bytes4[](1);
+        config[4].authorizedSelectors[0] = RegistryService.registerPool.selector;
+
+        // registration of bundle service must preceed registration of pool service
+        config[5].serviceDomain = BUNDLE();
+        config[5].authorizedSelectors = new bytes4[](1);
+        config[5].authorizedSelectors[0] = RegistryService.registerBundle.selector;
+
+        // registration of pricing service must preceed registration of application service
+        config[6].serviceDomain = PRICE();
+        config[6].authorizedSelectors = new bytes4[](0);
+
+        // registration of distribution service must preceed registration of pricing service
+        config[7].serviceDomain = DISTRIBUTION();
+        config[7].authorizedSelectors = new bytes4[](2);
+        config[7].authorizedSelectors[0] = RegistryService.registerDistribution.selector;
+        config[7].authorizedSelectors[1] = RegistryService.registerDistributor.selector;
+
+        config[8].serviceDomain = COMPONENT();
+        config[8].authorizedSelectors = new bytes4[](1);
+        config[8].authorizedSelectors[0] = RegistryService.registerComponent.selector;
+
+        config[9].serviceDomain = INSTANCE();
+        config[9].authorizedSelectors = new bytes4[](1);
+        config[9].authorizedSelectors[0] = RegistryService.registerInstance.selector;
+
+        config[10].serviceDomain = STAKING();
+        config[10].authorizedSelectors = new bytes4[](1);
+        config[10].authorizedSelectors[0] = RegistryService.registerStaking.selector;
+    }
+
+    // Internal
+
+    function _getAndVerifyContractInfo(
+        IRegisterable registerable,
+        ObjectType expectedType, // assume can be valid only
+        address expectedOwner // assume can be 0 when given by other service
+    )
+        internal
+        // view
+        returns(
+            IRegistry.ObjectInfo memory info 
+        )
+    {
+        info = registerable.getInitialInfo();
+        info.objectAddress = address(registerable);
+
+        if(info.objectType != expectedType) {// type is checked in registry anyway...but service logic may depend on expected value
+            revert UnexpectedRegisterableType(expectedType, info.objectType);
+        }
+
+        address owner = info.initialOwner;
+
+        if(owner != expectedOwner) { // registerable owner protection
+            revert NotRegisterableOwner(expectedOwner);
+        }
+
+        if(owner == address(registerable)) {
+            revert SelfRegistration();
+        }
+
+        if(owner == address(0)) {
+            revert RegisterableOwnerIsZero();
+        }
+        
+        if(getRegistry().isRegistered(owner)) { 
+            revert RegisterableOwnerIsRegistered();
+        }
+    }
+
+    function _verifyObjectInfo(
+        IRegistry.ObjectInfo memory info,
+        ObjectType expectedType
+    )
+        internal
+        view
+    {
+        // enforce instead of check
+        info.objectAddress = address(0);
+
+        if(info.objectType != expectedType) {// type is checked in registry anyway...but service logic may depend on expected value
+            revert UnexpectedRegisterableType(expectedType, info.objectType);
+        }
+
+        address owner = info.initialOwner;
+
+        if(owner == address(0)) {
+            revert RegisterableOwnerIsZero();
+        }
+
+        if(getRegistry().isRegistered(owner)) { 
+            revert RegisterableOwnerIsRegistered();
+        }
+    }
+}

package/contracts/registry/RegistryServiceManager.sol

@@ -0,0 +1,60 @@
+// SPDX-License-Identifier: UNLICENSED
+pragma solidity ^0.8.20;
+
+import {AccessManager} from "@openzeppelin/contracts/access/manager/AccessManager.sol";
+
+import {Registry} from "./Registry.sol";
+import {IVersionable} from "../shared/IVersionable.sol";
+import {ProxyManager} from "../shared/ProxyManager.sol";
+import {RegistryService} from "./RegistryService.sol";
+import {TokenRegistry} from "./TokenRegistry.sol";
+
+
+contract RegistryServiceManager is
+    ProxyManager
+{
+    bytes32 constant public ACCESS_MANAGER_CREATION_CODE_HASH = 0x0;
+
+    RegistryService private immutable _registryService;
+
+    /// @dev initializes proxy manager with registry service implementation and deploys registry
+    constructor(
+        address initialAuthority, // used by implementation 
+        address registryAddress) // used by implementation 
+        ProxyManager(registryAddress)
+    {
+        require(initialAuthority > address(0), "RegistryServiceManager: initial authority is 0");
+        require(registryAddress > address(0), "RegistryServiceManager: registry is 0");
+        
+        // implementation's initializer func `data` argument
+        RegistryService srv = new RegistryService();
+        bytes memory data = abi.encode(registryAddress, initialAuthority);
+        IVersionable versionable = deploy(
+            address(srv), 
+            data);
+
+        _registryService = RegistryService(address(versionable));
+
+//        _linkToNftOwnable(address(_registryService));
+    }
+
+    // // from IRegisterable
+
+    // // IMPORTANT: registry here and in constructor MUST be the same
+    function linkOwnershipToServiceNft()
+        public
+        onlyOwner
+    {
+        _linkToNftOwnable(address(_registryService));
+    }
+
+    //--- view functions ----------------------------------------------------//
+
+    function getRegistryService()
+        external
+        view
+        returns (RegistryService registryService)
+    {
+        return _registryService;
+    }
+}