@etherisc/gif-next 0.0.2-e59218b-293 → 0.0.2-e5a6af8-639

package/contracts/shared/ERC165.sol

@@ -1,25 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
-
-contract ERC165 is IERC165 {
-    mapping(bytes4 => bool) private _isSupported;
-
-    constructor() {
-        _initializeERC165();
-    }
-
-    function supportsInterface(bytes4 interfaceId) external view override returns (bool) {
-        return _isSupported[interfaceId];
-    }
-
-    // @dev register support for ERC165 itself
-    function _initializeERC165() internal {
-        _isSupported[type(IERC165).interfaceId] = true;
-    }
-
-    function _registerInterface(bytes4 interfaceId) internal {
-        _isSupported[interfaceId] = true;
-    }
-}

package/contracts/shared/ProxyManager.sol

@@ -1,94 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.20;
-
-import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
-import {ProxyAdmin} from "@openzeppelin/contracts/proxy/transparent/ProxyAdmin.sol";
-import {ITransparentUpgradeableProxy} from "@openzeppelin/contracts/proxy/transparent/TransparentUpgradeableProxy.sol";
-
-import {IVersionable} from "./IVersionable.sol";
-import {NftOwnable} from "./NftOwnable.sol";
-import {UpgradableProxyWithAdmin} from "./UpgradableProxyWithAdmin.sol";
-
-/// @dev manages proxy deployments for upgradable contracs of type IVersionable
-contract ProxyManager is
-    NftOwnable
-{
-
-    event LogProxyDeployed(address indexed proxy, address initialImplementation);
-    event LogProxyDeployedWithSalt(address indexed proxy, address initialImplementation);
-    event LogProxyUpgraded(address indexed proxy, address upgradedImplementation);
-
-    error ErrorAlreadyDeployed();
-    error ErrorAlreadyDeployedWithSalt();
-    error ErrorNotYetDeployed();
-
-    UpgradableProxyWithAdmin internal _proxy;
-    bool internal _isDeployed;
-
-    /// @dev only used to capture proxy owner
-    constructor()
-        NftOwnable()
-    { }
-
-    /// @dev deploy initial contract
-    function deploy(address initialImplementation, bytes memory initializationData)
-        public
-        virtual
-        onlyOwner()
-        returns (IVersionable versionable)
-    {
-        if (_isDeployed) { revert ErrorAlreadyDeployed(); }
-
-        address currentProxyOwner = getOwner(); // used by implementation
-        address initialProxyAdminOwner = address(this); // used by proxy
-        bytes memory data = getDeployData(initialImplementation, currentProxyOwner, initializationData);
-        
-        _proxy = new UpgradableProxyWithAdmin(
-            initialImplementation,
-            initialProxyAdminOwner,
-            data
-        );
-
-        _isDeployed = true;
-        versionable = IVersionable(address(_proxy));
-
-        emit LogProxyDeployed(address(_proxy), initialImplementation);
-    }
-
-    /// @dev upgrade existing contract
-    function upgrade(address newImplementation, bytes memory upgradeData)
-        public
-        virtual
-        onlyOwner()
-        returns (IVersionable versionable)
-    {
-        if (!_isDeployed) { revert ErrorNotYetDeployed(); }
-
-        address currentProxyOwner = getOwner();
-        ProxyAdmin proxyAdmin = getProxy().getProxyAdmin();
-        ITransparentUpgradeableProxy proxy = ITransparentUpgradeableProxy(address(_proxy));
-        bytes memory data = getUpgradeData(newImplementation, currentProxyOwner, upgradeData);
-
-        proxyAdmin.upgradeAndCall(
-            proxy,
-            newImplementation, 
-            data);
-
-        versionable = IVersionable(address(_proxy));
-
-        emit LogProxyUpgraded(address(_proxy), newImplementation);
-
-    }
-
-    function getDeployData(address implementation, address proxyOwner, bytes memory deployData) public pure returns (bytes memory data) {
-        return abi.encodeWithSelector(IVersionable.initialize.selector, implementation, proxyOwner, deployData);
-    }
-
-    function getUpgradeData(address implementation, address proxyOwner, bytes memory upgradeData) public pure returns (bytes memory data) {
-        return abi.encodeWithSelector(IVersionable.upgrade.selector, implementation, proxyOwner, upgradeData);
-    }
-
-    function getProxy() public returns (UpgradableProxyWithAdmin) {
-        return _proxy;
-    }
-}

package/contracts/shared/RegisterableUpgradable.sol

@@ -1,16 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {Registerable} from "./Registerable.sol";
-import {Versionable} from "./Versionable.sol";
-
-/// @dev base contract for upgradable objects like services and upgradable components
-/// deriving contracs need to call _initializeRegisterable
-/// TODO internalizes versionable here, a non-registerable versionalbe might itself have some value but is outside the scope of the gif
-/// after this merge versionable will no longer exist on its own in gif
-/// only registerable and upgradable (which is a registerable too) will remain
-abstract contract RegisterableUpgradable is 
-    Registerable,
-    Versionable
-{
-}

package/contracts/shared/Versionable.sol

@@ -1,147 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.20;
-
-import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol";
-
-import {Blocknumber, blockNumber} from "../types/Blocknumber.sol";
-import {Timestamp, TimestampLib} from "../types/Timestamp.sol";
-import {Version, VersionPart, VersionLib} from "../types/Version.sol";
-
-import {IVersionable} from "./IVersionable.sol";
-
-
-
-abstract contract Versionable is 
-    Initializable,
-    IVersionable 
-{
-    // keccak256(abi.encode(uint256(keccak256("gif-next.contracts.shared.Versionable.sol")) - 1)) & ~bytes32(uint256(0xff))
-    bytes32 private constant VERSIONABLE_LOCATION_V1 = 0x4f61291a8ac3d020d0a7d919a76b8592aa88385744dee3f8b4f3873b969ed900;
-
-
-    /// @custom:storage-location erc7201:gif-next.contracts.shared.Versionable.sol
-    struct VersionableStorage {
-        mapping(Version version => VersionInfo info) _versionHistory;
-        Version [] _versions;
-        Version _v1;
-    }
-
-
-    constructor() {
-        _disableInitializers();
-    }
-    // TODO write test where new version of private _updateVersionHistory is added and used... 
-    function initialize(
-        address implementation,
-        address activatedBy,
-        bytes memory data
-    )
-        public
-        initializer
-    {
-        _updateVersionHistory(implementation, activatedBy);
-        _initialize(activatedBy, data);
-    }
-
-    // TODO activatedBy MUST ALWAYS be an owner?
-    function upgrade(
-        address implementation,
-        address activatedBy,
-        bytes memory data
-    )
-        external
-        reinitializer(VersionLib.toUint64(getVersion()))
-    {
-        _updateVersionHistory(implementation, activatedBy);
-        _upgrade(data);
-    }
-
-    function isInitialized(Version _version) public override view returns(bool) {
-        return _getVersionableStorage()._versionHistory[_version].activatedIn.toInt() > 0;
-    }
-
-    function getVersion() public pure virtual returns(Version);
-
-    function getVersionCount() public view override returns(uint256) {
-        return _getVersionableStorage()._versions.length;
-    }
-
-    function getVersion(uint256 idx) public view override returns(Version) {
-        return _getVersionableStorage()._versions[idx];
-    }
-
-    function getVersionInfo(Version _version) public override view returns(VersionInfo memory) {
-        return _getVersionableStorage()._versionHistory[_version];
-    }
-
-    function getInitializedVersion() public view returns(uint64) {
-        return _getInitializedVersion();
-    }
-
-
-
-    // IMPORTANT each version must implement this function 
-    // each implementation MUST use onlyInitialising modifier
-    // each implementation MUST call intializers of all base contracts...
-    function _initialize(address owner, bytes memory data) 
-        internal
-        onlyInitializing
-        virtual 
-    {
-        revert();
-    }
-
-
-    // IMPORTANT each version except version "1" must implement this function 
-    // each implementation MUST use onlyInitialising modifier
-    function _upgrade(bytes memory data)
-        internal
-        onlyInitializing
-        virtual
-    {
-        revert();
-    }
-
-    function _getVersionableStorage() private pure returns (VersionableStorage storage $) {
-        assembly {
-            $.slot := VERSIONABLE_LOCATION_V1
-        }
-    }
-
-    // can only be called once per contract
-    // needs to be called inside the proxy upgrade tx
-    // TODO run reinitializer(version().toUint64()) modifier after "version()" is checked, 
-    function _updateVersionHistory(
-        address implementation,
-        address activatedBy
-    )
-        private
-        onlyInitializing
-    {
-        VersionableStorage storage $ = _getVersionableStorage();
-
-        uint64 version = _getInitializedVersion();
-
-        Version thisVersion = getVersion();
-
-        if(version == 1) {
-            // thisVersion is alias to version "1"
-            $._v1 = thisVersion;
-        }
-        else {
-            require(thisVersion > $._v1, "INVALID VERSION");
-        }
-
-        // update version history
-        $._versions.push(thisVersion);
-        $._versionHistory[thisVersion] = VersionInfo(
-            thisVersion,
-            implementation,
-            activatedBy,
-            TimestampLib.blockTimestamp(),
-            blockNumber()
-        );
-
-        emit LogVersionableInitialized(thisVersion, implementation, activatedBy);
-    }
-}

package/contracts/test/TestFee.sol

@@ -1,25 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {UFixed, UFixedLib} from "../types/UFixed.sol";
-import {Fee, FeeLib} from "../types/Fee.sol";
-
-contract TestFee {
-
-    function createFee(
-        uint256 fractionalValue,
-        int8 exponent,
-        uint256 fixedValue
-    )
-        external 
-        pure 
-        returns(Fee memory fee)
-    {
-        return FeeLib.toFee(UFixedLib.toUFixed(fractionalValue, exponent), fixedValue);
-    }
-
-    function getZeroFee() external pure returns(Fee memory fee) {
-        return FeeLib.zeroFee();
-    }
-
-}

package/contracts/test/TestRegisterable.sol

@@ -1,18 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {NftId} from "../../contracts/types/NftId.sol";
-import {ObjectType, TOKEN} from "../../contracts/types/ObjectType.sol";
-import {IRegistry} from "../../contracts/registry/IRegistry.sol";
-import {Registerable} from "../../contracts/shared/Registerable.sol";
-
-contract TestRegisterable is Registerable {
-
-    constructor(address registry, NftId registryNftId, ObjectType objectType, bool isInterceptor, address initialOwner)
-        //Registerable(registry, registryNftId)
-    // solhint-disable-next-line no-empty-blocks
-    {
-        bytes memory data = "";
-        _initializeRegisterable(registry, registryNftId, objectType, isInterceptor, initialOwner, data);
-    }
-}

package/contracts/test/TestRoleId.sol

@@ -1,14 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {RoleId, RoleIdLib, PRODUCT_OWNER_ROLE_NAME, PRODUCT_OWNER_ROLE, POOL_OWNER_ROLE_NAME, POOL_OWNER_ROLE} from "../../contracts/types/RoleId.sol";
-
-contract TestRoleId {
-    function getRole(uint256 roleNum) external pure returns (RoleId) { return RoleIdLib.toRoleId(roleNum); }
-
-    function getProductOwnerRoleName() external pure returns (string memory) { return PRODUCT_OWNER_ROLE_NAME(); }
-    function getProductOwnerRole() external pure returns (RoleId) { return PRODUCT_OWNER_ROLE(); } 
-
-    function getPoolOwnerRoleName() external pure returns (string memory) { return POOL_OWNER_ROLE_NAME(); }
-    function getPoolOwnerRole() external pure returns (RoleId) { return POOL_OWNER_ROLE(); } 
-}

package/contracts/test/TestService.sol

@@ -1,24 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {NftId} from "../../contracts/types/NftId.sol";
-import {Version, VersionLib} from "../../contracts/types/Version.sol";
-import {Service} from "../../contracts/shared/Service.sol";
-
-import {IVersionable} from "../../contracts/shared/IVersionable.sol";
-import {Versionable} from "../../contracts/shared/Versionable.sol";
-
-contract TestService is Service {
-
-    string public constant NAME = "TestService";
-
-    constructor(address registry, NftId registryNftId, address initialOwner)
-    // solhint-disable-next-line no-empty-blocks
-    {
-        _initializeService(registry, initialOwner);
-    }
-
-    function getName() public pure override returns(string memory name) {
-        return NAME;
-    }
-}

package/contracts/test/TestToken.sol

@@ -1,26 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
-
-contract TestUsdc is ERC20 {
-
-    // https://etherscan.io/token/0xc719d010b63e5bbf2c0551872cd5316ed26acd83#readContract
-    string public constant NAME = "USDC - Test";
-    string public constant SYMBOL = "USDC";
-    uint8 public constant DECIMALS = 6;
-    uint256 public constant INITIAL_SUPPLY = 10**9 * 10**DECIMALS; // 1 Billion 1'000'000'000
-    // decimals == 18 (openzeppelin erc20 default)
-    constructor()
-        ERC20(NAME, SYMBOL)
-    {
-        _mint(
-            _msgSender(),
-            INITIAL_SUPPLY
-        );   
-    }
-
-    function decimals() public pure override returns(uint8) {
-        return DECIMALS;
-    }
-}

package/contracts/test/TestVersion.sol

@@ -1,44 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {Version, VersionPart, VersionLib} from "../types/Version.sol";
-
-contract TestVersion {
-
-    function createVersion(uint major, uint minor, uint patch) external pure returns(Version) {
-        return VersionLib.toVersion(major, minor, patch);
-    }
-
-    function createVersionPart(uint versionPart) external pure returns(VersionPart) {
-        return VersionLib.toVersionPart(uint8(versionPart));
-    }
-
-    function getVersionParts(Version version)
-        external
-        pure
-        returns(
-            VersionPart major,
-            VersionPart minor,
-            VersionPart patch
-        )
-    {
-        return version.toVersionParts();
-    }
-
-    function getMajorPart(Version version) external pure returns(VersionPart major) {
-        return version.toMajorPart();
-    }
-
-    function getZeroVersion() external pure returns(Version) {
-        return VersionLib.zeroVersion();
-    }
-
-    function isSameVersion(Version a, Version b) external pure returns(bool) {
-        return a == b;
-    }
-
-    function isLargerVersion(Version a, Version b) external pure returns(bool) {
-        return a > b;
-    }
-
-}

package/contracts/test/TestVersionable.sol

@@ -1,17 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {Version, VersionLib} from "../../contracts/types/Version.sol";
-import {Versionable} from "../../contracts/shared/Versionable.sol";
-
-contract TestVersionable is Versionable {
-
-    function getVersion()
-        public 
-        pure 
-        virtual override
-        returns(Version)
-    {
-        return VersionLib.toVersion(3,0,0);
-    }
-}

package/contracts/types/ChainId.sol

@@ -1,38 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-/// @dev bytes5 (uint40) allows for chain ids up to 13 digits
-type ChainId is bytes5;
-
-// type bindings
-using {eqChainId as ==, neChainId as !=, ChainIdLib.toInt} for ChainId global;
-
-// general pure free functions
-/// @dev Converts the uint256 to a ChainId.
-function toChainId(uint256 chainId) pure returns (ChainId) {
-    return ChainId.wrap(bytes5(uint40(chainId)));
-}
-
-/// @dev Return the ChainId for the chain the contract is deployed to
-function thisChainId() view returns (ChainId) {
-    return toChainId(block.chainid);
-}
-
-// pure free functions for operators
-/// @dev Returns true if the values are equal (==).
-function eqChainId(ChainId a, ChainId b) pure returns (bool isSame) {
-    return ChainId.unwrap(a) == ChainId.unwrap(b);
-}
-
-/// @dev Returns true if the values are not equal (!=).
-function neChainId(ChainId a, ChainId b) pure returns (bool isDifferent) {
-    return ChainId.unwrap(a) != ChainId.unwrap(b);
-}
-
-// library functions that operate on user defined type
-library ChainIdLib {
-    /// @dev Converts the ChainId to a uint256.
-    function toInt(ChainId chainId) internal pure returns (uint256) {
-        return uint256(uint40(ChainId.unwrap(chainId)));
-    }
-}

package/contracts/types/NftIdSet.sol

@@ -1,60 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {NftId} from "../types/NftId.sol";
-
-// based on https://github.com/OpenZeppelin/openzeppelin-contracts/blob/master/contracts/utils/structs/EnumerableSet.sol
-library LibNftIdSet {
-
-    struct Set {
-        NftId[] ids;
-        mapping(NftId nftid => uint256 index) at;
-    }
-
-    function add(Set storage set, NftId nftId) external returns(bool added) {
-        if (set.at[nftId] == 0) {
-            set.ids.push(nftId);
-            set.at[nftId] = set.ids.length;
-            return true;
-        } else {
-            return false;
-        }
-    }
-
-    function remove(Set storage set, NftId nftId) external returns(bool removed) {
-        uint256 nftIdIndex = set.at[nftId];
-
-        if (nftIdIndex > 0) {
-            uint256 toDeleteIndex = nftIdIndex - 1;
-            uint256 lastIndex = set.ids.length - 1;
-
-            if (lastIndex != toDeleteIndex) {
-                NftId lastId = set.ids[lastIndex];
-                set.ids[toDeleteIndex] = lastId;
-                set.at[lastId] = nftIdIndex; // Replace lastValue's index to valueIndex
-            }
-
-            set.ids.pop();
-            delete set.at[nftId];
-            return true;
-        } else {
-            return false;
-        }
-    }
-
-    function isEmpty(Set storage set) external view returns(bool empty) {
-        return set.ids.length == 0;
-    }
-
-    function contains(Set storage set, NftId nftId) external view returns(bool inSet) {
-        return set.at[nftId] > 0;
-    }
-
-    function getLength(Set storage set) external view returns(uint256 length) {
-        return set.ids.length;
-    }
-
-    function getElementAt(Set storage set, uint256 index) external view returns(NftId nftId) {
-        return set.ids[index];
-    }
-}

package/contracts/types/NumberId.sol

@@ -1,52 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.20;
-
-// uint32 allows for 4'294'967'296 individual items
-type NumberId is uint32;
-
-// type bindings
-using {
-    eqNumberId as ==, 
-    neNumberId as !=, 
-    NumberIdLib.eqz,
-    NumberIdLib.gtz,
-    NumberIdLib.toInt
-} for NumberId global;
-
-
-// pure free functions for operators
-function eqNumberId(NumberId a, NumberId b) pure returns (bool isSame) {
-    return NumberId.unwrap(a) == NumberId.unwrap(b);
-}
-
-function neNumberId(NumberId a, NumberId b) pure returns (bool isDifferent) {
-    return NumberId.unwrap(a) != NumberId.unwrap(b);
-}
-
-// library functions that operate on user defined type
-library NumberIdLib {
-    /// @dev Converts the NumberId to a uint.
-    function zero() public pure returns (NumberId) {
-        return NumberId.wrap(0);
-    }
-
-    /// @dev Converts an uint into a NumberId.
-    function toNumberId(uint256 a) public pure returns (NumberId) {
-        return NumberId.wrap(uint32(a));
-    }
-
-    /// @dev Converts the NumberId to a uint.
-    function toInt(NumberId a) public pure returns (uint32) {
-        return uint32(NumberId.unwrap(a));
-    }
-
-    /// @dev Returns true if the value is non-zero (> 0).
-    function gtz(NumberId a) public pure returns (bool) {
-        return NumberId.unwrap(a) > 0;
-    }
-
-    /// @dev Returns true if the value is zero (== 0).
-    function eqz(NumberId a) public pure returns (bool) {
-        return NumberId.unwrap(a) == 0;
-    }
-}