@etherisc/gif-next 0.0.2-e37834a-021 → 0.0.2-e38b7e6-931

package/contracts/instance/InstanceAccessManager.sol

@@ -0,0 +1,303 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {EnumerableSet} from "@openzeppelin/contracts/utils/structs/EnumerableSet.sol";
+import {ShortString, ShortStrings} from "@openzeppelin/contracts/utils/ShortStrings.sol";
+import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
+
+import {AccessManagerUpgradeableInitializeable} from "../../contracts/instance/AccessManagerUpgradeableInitializeable.sol";
+import {RoleId, RoleIdLib } from "../types/RoleId.sol";
+import {TimestampLib} from "../types/Timestamp.sol";
+import {IAccess} from "./module/IAccess.sol";
+
+contract InstanceAccessManager is
+    AccessManagedUpgradeable
+{
+    using RoleIdLib for RoleId;
+
+    string public constant ADMIN_ROLE_NAME = "AdminRole";
+    string public constant PUBLIC_ROLE_NAME = "PublicRole";
+
+    uint64 public constant CUSTOM_ROLE_ID_MIN = 10000;
+    uint32 public constant EXECUTION_DELAY = 0;
+
+    // role specific state
+    mapping(RoleId roleId => IAccess.RoleInfo info) internal _role;
+    mapping(RoleId roleId => EnumerableSet.AddressSet roleMembers) internal _roleMembers; 
+    mapping(ShortString name => RoleId roleId) internal _roleForName;
+    RoleId [] internal _roles;
+
+    // target specific state
+    mapping(address target => IAccess.TargetInfo info) internal _target;
+    mapping(ShortString name => address target) internal _targetForName;
+    address [] internal _targets;
+
+    AccessManagerUpgradeableInitializeable internal _accessManager;
+
+    function __InstanceAccessManager_initialize(address initialAdmin) external initializer
+    {
+        // if size of the contract gets too large, this can be externalized which will reduce the contract size considerably
+        _accessManager = new AccessManagerUpgradeableInitializeable();
+        // this service required adin rights to access manager to be able to grant/revoke roles
+        _accessManager.__AccessManagerUpgradeableInitializeable_init(address(this));
+        _accessManager.grantRole(_accessManager.ADMIN_ROLE(), initialAdmin, 0);
+
+        __AccessManaged_init(address(_accessManager));
+
+        _createRole(RoleIdLib.toRoleId(_accessManager.ADMIN_ROLE()), ADMIN_ROLE_NAME, false, false);
+        _createRole(RoleIdLib.toRoleId(_accessManager.PUBLIC_ROLE()), PUBLIC_ROLE_NAME, false, false);
+    }
+
+    //--- Role ------------------------------------------------------//
+    function createGifRole(RoleId roleId, string memory name) external restricted() {
+        _createRole(roleId, name, false, true);
+    }
+
+    function createRole(RoleId roleId, string memory name) external restricted() {
+        _createRole(roleId, name, true, true);
+    }
+
+    function setRoleLocked(RoleId roleId, bool locked) external restricted() {
+        if (!roleExists(roleId)) {
+            revert IAccess.ErrorIAccessSetLockedForNonexstentRole(roleId);
+        }
+
+        _role[roleId].isLocked = locked;
+        _role[roleId].updatedAt = TimestampLib.blockTimestamp();
+    }
+
+    function roleExists(RoleId roleId) public view returns (bool exists) {
+        return _role[roleId].createdAt.gtz();
+    }
+
+    function grantRole(RoleId roleId, address member) external restricted() returns (bool granted) {
+        if (!roleExists(roleId)) {
+            revert IAccess.ErrorIAccessGrantNonexstentRole(roleId);
+        }
+
+        if (_role[roleId].isLocked) {
+            revert IAccess.ErrorIAccessRoleIdNotActive(roleId);
+        }
+
+        if (!EnumerableSet.contains(_roleMembers[roleId], member)) {
+            _accessManager.grantRole(roleId.toInt(), member, EXECUTION_DELAY);
+            EnumerableSet.add(_roleMembers[roleId], member);
+            return true;
+        }
+
+        return false;
+    }
+
+    function revokeRole(RoleId roleId, address member) external restricted() returns (bool revoked) {
+        if (!roleExists(roleId)) {
+            revert IAccess.ErrorIAccessRevokeNonexstentRole(roleId);
+        }
+
+        if (EnumerableSet.contains(_roleMembers[roleId], member)) {
+            _accessManager.revokeRole(roleId.toInt(), member);
+            EnumerableSet.remove(_roleMembers[roleId], member);
+            return true;
+        }
+
+        return false;
+    }
+
+    /// @dev not restricted function by intention
+    /// the restriction to role members is already enforced by the call to the access manger
+    function renounceRole(RoleId roleId) external returns (bool revoked) {
+        address member = msg.sender;
+
+        if (!roleExists(roleId)) {
+            revert IAccess.ErrorIAccessRenounceNonexstentRole(roleId);
+        }
+
+        if (EnumerableSet.contains(_roleMembers[roleId], member)) {
+            // cannot use accessManger.renounce as it directly checks against msg.sender
+            _accessManager.revokeRole(roleId.toInt(), member);
+            EnumerableSet.remove(_roleMembers[roleId], member);
+            return true;
+        }
+
+        return false;
+    }
+
+    function roles() external view returns (uint256 numberOfRoles) {
+        return _roles.length;
+    }
+
+    function getRoleId(uint256 idx) external view returns (RoleId roleId) {
+        return _roles[idx];
+    }
+
+    function getRoleIdForName(string memory name) external view returns (RoleId roleId) {
+        return _roleForName[ShortStrings.toShortString(name)];
+    }
+
+    function getRole(RoleId roleId) external view returns (IAccess.RoleInfo memory role) {
+        return _role[roleId];
+    }
+
+    function hasRole(RoleId roleId, address account) external view returns (bool accountHasRole) {
+        (accountHasRole, ) = _accessManager.hasRole(roleId.toInt(), account);
+    }
+
+    function roleMembers(RoleId roleId) external view returns (uint256 numberOfMembers) {
+        return EnumerableSet.length(_roleMembers[roleId]);
+    }
+
+    function getRoleMember(RoleId roleId, uint256 idx) external view returns (address roleMember) {
+        return EnumerableSet.at(_roleMembers[roleId], idx);
+    }
+
+    //--- Target ------------------------------------------------------//
+    function createGifTarget(address target, string memory name) external restricted() {
+        _createTarget(target, name, false, true);
+    }
+
+    function createTarget(address target, string memory name) external restricted() {
+        _createTarget(target, name, true, true);
+    }
+
+    function setTargetLocked(string memory targetName, bool locked) external restricted() {
+        address target = _targetForName[ShortStrings.toShortString(targetName)];
+        
+        if (target == address(0)) {
+            revert IAccess.ErrorIAccessSetLockedForNonexstentTarget(target);
+        }
+
+        _target[target].isLocked = locked;
+        _accessManager.setTargetClosed(target, locked);
+    }
+
+    function targetExists(address target) public view returns (bool exists) {
+        return _target[target].createdAt.gtz();
+    }
+
+    //--- internal view/pure functions --------------------------------------//
+
+    function _createRole(RoleId roleId, string memory name, bool isCustom, bool validateParameters) internal {
+        if (validateParameters) {
+            _validateRoleParameters(roleId, name, isCustom);
+        }
+
+        IAccess.RoleInfo memory role = IAccess.RoleInfo(
+            ShortStrings.toShortString(name), 
+            isCustom,
+            false, // role un-locked,
+            TimestampLib.blockTimestamp(),
+            TimestampLib.blockTimestamp());
+
+        _role[roleId] = role;
+        _roleForName[role.name] = roleId;
+        _roles.push(roleId);
+    }
+
+    function _validateRoleParameters(
+        RoleId roleId, 
+        string memory name, 
+        bool isCustom
+    )
+        internal
+        view 
+        returns (IAccess.RoleInfo memory existingRole)
+    {
+        // check role id
+        uint64 roleIdInt = RoleId.unwrap(roleId);
+        if(roleIdInt == _accessManager.ADMIN_ROLE() || roleIdInt == _accessManager.PUBLIC_ROLE()) {
+            revert IAccess.ErrorIAccessRoleIdInvalid(roleId); 
+        }
+
+        // prevent changing isCustom for existing roles
+        existingRole = _role[roleId];
+
+        if (existingRole.createdAt.gtz() && isCustom != existingRole.isCustom) {
+            revert IAccess.ErrorIAccessRoleIsCustomIsImmutable(roleId, isCustom, existingRole.isCustom); 
+        }
+
+        if (isCustom && roleIdInt < CUSTOM_ROLE_ID_MIN) {
+            revert IAccess.ErrorIAccessRoleIdTooSmall(roleId); 
+        } else if (!isCustom && roleIdInt >= CUSTOM_ROLE_ID_MIN) {
+            revert IAccess.ErrorIAccessRoleIdTooBig(roleId); 
+        }
+
+        // role name checks
+        ShortString nameShort = ShortStrings.toShortString(name);
+        if (ShortStrings.byteLength(nameShort) == 0) {
+            revert IAccess.ErrorIAccessRoleNameEmpty(roleId);
+        }
+
+        if (_roleForName[nameShort] != RoleIdLib.zero() && _roleForName[nameShort] != roleId) {
+            revert IAccess.ErrorIAccessRoleNameNotUnique(_roleForName[nameShort], nameShort);
+        }
+    }
+
+    function _createTarget(address target, string memory name, bool isCustom, bool validateParameters) internal {
+        if (validateParameters) {
+            _validateTargetParameters(target, name, isCustom);
+        }
+
+        if (_target[target].createdAt.gtz()) {
+            revert IAccess.ErrorIAccessTargetAlreadyExists(target, _target[target].name);
+        }
+        if (_targetForName[ShortStrings.toShortString(name)] != address(0)) {
+            revert IAccess.ErrorIAccessTargetNameExists(target, _targetForName[ShortStrings.toShortString(name)], ShortStrings.toShortString(name));
+        }
+
+        IAccess.TargetInfo memory info = IAccess.TargetInfo(
+            ShortStrings.toShortString(name), 
+            isCustom,
+            _accessManager.isTargetClosed(target), // sync with state in access manager
+            TimestampLib.blockTimestamp(),
+            TimestampLib.blockTimestamp());
+
+        _target[target] = info;
+        _targetForName[info.name] = target;
+        _targets.push(target);
+    }
+
+    function _validateTargetParameters(address target, string memory name, bool isCustom) internal view {
+        // TODO: implement
+    }
+
+    function setTargetFunctionRole(
+        address target,
+        bytes4[] calldata selectors,
+        uint64 roleId
+    ) public virtual restricted() {
+        _accessManager.setTargetFunctionRole(target, selectors, roleId);
+    }
+
+    function setTargetFunctionRole(
+        string memory targetName,
+        bytes4[] calldata selectors,
+        RoleId roleId
+    ) public virtual restricted() {
+        address target = _targetForName[ShortStrings.toShortString(targetName)];
+        uint64 roleIdInt = RoleId.unwrap(roleId);
+        _accessManager.setTargetFunctionRole(target, selectors, roleIdInt);
+    }
+
+    function getAccessManager() public restricted() returns (AccessManagerUpgradeableInitializeable) {
+        return _accessManager;
+    }
+
+    function setTargetClosed(string memory targetName, bool closed) public restricted() {
+        address target = _targetForName[ShortStrings.toShortString(targetName)];
+        if (target == address(0)) {
+            revert IAccess.ErrorIAccessTargetAddressZero();
+        }
+        _accessManager.setTargetClosed(target, closed);
+    }
+
+    function isTargetLocked(address target) public view returns (bool locked) {
+        return _accessManager.isTargetClosed(target);
+    }
+
+    function canCall(
+        address caller,
+        address target,
+        bytes4 selector
+    ) public view virtual returns (bool immediate, uint32 delay) {
+        return _accessManager.canCall(caller, target, selector);
+    }
+}

package/contracts/instance/InstanceBase.sol

@@ -0,0 +1,39 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {EnumerableSet} from "@openzeppelin/contracts/utils/structs/EnumerableSet.sol";
+import {ShortString, ShortStrings} from "@openzeppelin/contracts/utils/ShortStrings.sol";
+
+import {IAccess} from "./module/IAccess.sol";
+import {IBundle} from "./module/IBundle.sol";
+import {IPolicy} from "./module/IPolicy.sol";
+import {IRisk} from "./module/IRisk.sol";
+import {ISetup} from "./module/ISetup.sol";
+import {Key32, KeyId, Key32Lib} from "../types/Key32.sol";
+import {KeyValueStore} from "./base/KeyValueStore.sol";
+import {IInstance} from "./IInstance.sol";
+import {InstanceReader} from "./InstanceReader.sol";
+import {BundleManager} from "./BundleManager.sol";
+import {NftId} from "../types/NftId.sol";
+import {NumberId} from "../types/NumberId.sol";
+import {ObjectType, BUNDLE, DISTRIBUTION, INSTANCE, POLICY, POOL, ROLE, PRODUCT, TARGET} from "../types/ObjectType.sol";
+import {RiskId, RiskIdLib} from "../types/RiskId.sol";
+import {RoleId, RoleIdLib} from "../types/RoleId.sol";
+import {StateId, ACTIVE} from "../types/StateId.sol";
+import {ERC165} from "../shared/ERC165.sol";
+import {Registerable} from "../shared/Registerable.sol";
+import {IDistributionService} from "./service/IDistributionService.sol";
+import {IPoolService} from "./service/IPoolService.sol";
+import {IProductService} from "./service/IProductService.sol";
+import {VersionPart} from "../types/Version.sol";
+import {IInstanceBase} from "./IInstanceBase.sol";
+
+contract InstanceBase is
+    IInstanceBase,
+    KeyValueStore,
+    ERC165,
+    Registerable
+{
+
+
+}

package/contracts/instance/InstanceReader.sol

@@ -0,0 +1,315 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {DistributorType} from "../types/DistributorType.sol";
+import {Fee, FeeLib} from "../types/Fee.sol";
+import {Key32} from "../types/Key32.sol";
+import {NftId} from "../types/NftId.sol";
+import {ObjectType, DISTRIBUTOR, DISTRIBUTION, INSTANCE, PRODUCT, POLICY, POOL, TREASURY, BUNDLE} from "../types/ObjectType.sol";
+import {ReferralId, ReferralStatus, ReferralLib, REFERRAL_OK, REFERRAL_ERROR_UNKNOWN, REFERRAL_ERROR_EXPIRED, REFERRAL_ERROR_EXHAUSTED} from "../types/Referral.sol";
+import {Registerable} from "../shared/Registerable.sol";
+import {RiskId} from "../types/RiskId.sol";
+import {UFixed, MathLib, UFixedLib} from "../types/UFixed.sol";
+import {Version} from "../types/Version.sol";
+import {StateId} from "../types/StateId.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IBundle} from "../instance/module/IBundle.sol";
+import {IDistribution} from "../instance/module/IDistribution.sol";
+import {IInstance} from "./IInstance.sol";
+import {IKeyValueStore} from "../instance/base/IKeyValueStore.sol";
+import {IPolicy} from "../instance/module/IPolicy.sol";
+import {IRisk} from "../instance/module/IRisk.sol";
+import {ISetup} from "../instance/module/ISetup.sol";
+import {ITreasury} from "../instance/module/ITreasury.sol";
+import {TimestampLib} from "../types/Timestamp.sol";
+
+
+contract InstanceReader {
+    bool private _initialized;
+
+    IRegistry internal _registry;
+    NftId internal _instanceNftId;
+    IInstance internal _instance;
+    IKeyValueStore internal _store;
+
+    constructor(
+        address registry, 
+        NftId instanceNftId
+    )
+    {
+        initialize(registry, instanceNftId);
+    }
+
+    function initialize(address registry, NftId instanceNftId) public {
+        require(!_initialized, "ERROR:CRD-000:ALREADY_INITIALIZED");
+
+        require(
+            address(registry) != address(0),
+            "ERROR:CRD-001:REGISTRY_ZERO");
+
+        require(
+            instanceNftId.gtz(),
+            "ERROR:CRD-002:NFT_ID_ZERO");
+
+        _registry = IRegistry(registry);
+        _instanceNftId = instanceNftId;
+        IRegistry.ObjectInfo memory instanceInfo = _registry.getObjectInfo(_instanceNftId);
+
+        require(
+            instanceInfo.objectType == INSTANCE(), 
+            "ERROR:CRD-003:PARENT_NOT_INSTANCE");
+
+        _instance = IInstance(instanceInfo.objectAddress);
+        _store = IKeyValueStore(instanceInfo.objectAddress);
+
+        _initialized = true;
+    }
+
+
+    // module specific functions
+
+    function getPolicyInfo(NftId policyNftId)
+        public
+        view
+        returns (IPolicy.PolicyInfo memory info)
+    {
+        bytes memory data = _store.getData(toPolicyKey(policyNftId));
+        if (data.length > 0) {
+            return abi.decode(data, (IPolicy.PolicyInfo));
+        }
+    }
+
+    function getPolicyState(NftId policyNftId)
+        public
+        view
+        returns (StateId state)
+    {
+        return _instance.getState(toPolicyKey(policyNftId));
+    }
+
+    function getRiskInfo(RiskId riskId)
+        public 
+        view 
+        returns (IRisk.RiskInfo memory info)
+    {
+        bytes memory data = _store.getData(riskId.toKey32());
+        if (data.length > 0) {
+            return abi.decode(data, (IRisk.RiskInfo));
+        }
+    }
+
+    function getTokenHandler(NftId productNftId)
+        public
+        view
+        returns (address tokenHandler)
+    {
+        bytes memory data = _store.getData(toTreasuryKey(productNftId));
+
+        if (data.length > 0) {
+            ITreasury.TreasuryInfo memory info = abi.decode(data, (ITreasury.TreasuryInfo));
+            return address(info.tokenHandler);
+        }
+    }
+
+    function getTreasuryInfo(NftId productNftId)
+        public 
+        view 
+        returns (ITreasury.TreasuryInfo memory info)
+    {
+        bytes memory data = _store.getData(toTreasuryKey(productNftId));
+        if (data.length > 0) {
+            return abi.decode(data, (ITreasury.TreasuryInfo));
+        }
+    }
+    
+    function getBundleInfo(NftId bundleNftId)
+        public 
+        view 
+        returns (IBundle.BundleInfo memory info)
+    {
+        bytes memory data = _store.getData(toBundleKey(bundleNftId));
+        if (data.length > 0) {
+            return abi.decode(data, (IBundle.BundleInfo));
+        }
+    }
+
+    function getDistributorTypeInfo(DistributorType distributorType)
+        public 
+        view 
+        returns (IDistribution.DistributorTypeInfo memory info)
+    {
+        bytes memory data = _store.getData(distributorType.toKey32());
+        if (data.length > 0) {
+            return abi.decode(data, (IDistribution.DistributorTypeInfo));
+        }
+    }
+
+    function getDistributorInfo(NftId distributorNftId)
+        public
+        view
+        returns (IDistribution.DistributorInfo memory info)
+    {
+        bytes memory data = _store.getData(toDistributorKey(distributorNftId));
+        if (data.length > 0) {
+            return abi.decode(data, (IDistribution.DistributorInfo));
+        }
+    }
+
+    function getDistributionSetupInfo(NftId distributionNftId)
+        public
+        view
+        returns (ISetup.DistributionSetupInfo memory info)
+    {
+        bytes memory data = _store.getData(toDistributionKey(distributionNftId));
+        if (data.length > 0) {
+            return abi.decode(data, (ISetup.DistributionSetupInfo));
+        }
+    }
+
+    function getPoolSetupInfo(NftId poolNftId)
+        public
+        view
+        returns (ISetup.PoolSetupInfo memory info)
+    {
+        bytes memory data = _store.getData(toPoolKey(poolNftId));
+        if (data.length > 0) {
+            return abi.decode(data, (ISetup.PoolSetupInfo));
+        }
+    }
+
+    function getProductSetupInfo(NftId productNftId)
+        public
+        view
+        returns (ISetup.ProductSetupInfo memory info)
+    {
+        bytes memory data = _store.getData(toProductKey(productNftId));
+        if (data.length > 0) {
+            return abi.decode(data, (ISetup.ProductSetupInfo));
+        }
+    }
+
+    function getReferralInfo(ReferralId referralId)
+        public 
+        view 
+        returns (IDistribution.ReferralInfo memory info)
+    {
+        bytes memory data = _store.getData(referralId.toKey32());
+        if (data.length > 0) {
+            return abi.decode(data, (IDistribution.ReferralInfo));
+        }
+    }
+
+
+    function getMetadata(Key32 key)
+        public 
+        view 
+        returns (IKeyValueStore.Metadata memory metadata)
+    {
+        return _store.getMetadata(key);
+    }
+
+
+    function toReferralId(
+        NftId distributionNftId,
+        string memory referralCode
+    )
+        public
+        pure 
+        returns (ReferralId referralId)
+    {
+        return ReferralLib.toReferralId(
+            distributionNftId, 
+            referralCode);      
+    }
+
+
+    function getDiscountPercentage(ReferralId referralId)
+        public
+        view
+        returns (
+            UFixed discountPercentage, 
+            ReferralStatus status
+        )
+    {
+        IDistribution.ReferralInfo memory info = getReferralInfo(
+            referralId);        
+
+        if (info.expiryAt.eqz()) {
+            return (
+                UFixedLib.zero(),
+                REFERRAL_ERROR_UNKNOWN());
+        }
+
+        if (info.expiryAt < TimestampLib.blockTimestamp()) {
+            return (
+                UFixedLib.zero(),
+                REFERRAL_ERROR_EXPIRED());
+        }
+
+        if (info.usedReferrals >= info.maxReferrals) {
+            return (
+                UFixedLib.zero(),
+                REFERRAL_ERROR_EXHAUSTED());
+        }
+
+        return (
+            info.discountPercentage,
+            REFERRAL_OK()
+        );
+    }
+
+
+    function toTreasuryKey(NftId productNftId) public pure returns (Key32) { 
+        return productNftId.toKey32(TREASURY());
+    }
+
+
+    function toPolicyKey(NftId policyNftId) public pure returns (Key32) { 
+        return policyNftId.toKey32(POLICY());
+    }
+
+
+    function toDistributorKey(NftId distributorNftId) public pure returns (Key32) { 
+        return distributorNftId.toKey32(DISTRIBUTOR());
+    }
+
+    function toDistributionKey(NftId distributionNftId) public pure returns (Key32) { 
+        return distributionNftId.toKey32(DISTRIBUTION());
+    }
+
+    function toBundleKey(NftId poolNftId) public pure returns (Key32) { 
+        return poolNftId.toKey32(BUNDLE());
+    }
+
+    function toPoolKey(NftId poolNftId) public pure returns (Key32) { 
+        return poolNftId.toKey32(POOL());
+    }
+
+    function toProductKey(NftId productNftId) public pure returns (Key32) { 
+        return productNftId.toKey32(PRODUCT());
+    }
+
+    // low level function
+    function getInstance() external view returns (IInstance instance) {
+        return _instance;
+    }
+
+    function getInstanceStore() external view returns (IKeyValueStore store) {
+        return _store;
+    }
+
+    function getInstanceNftId() external view returns (NftId nftId) {
+        return _instanceNftId;
+    }
+
+    function toUFixed(uint256 value, int8 exp) public pure returns (UFixed) {
+        return UFixedLib.toUFixed(value, exp);
+    }
+
+    function toInt(UFixed value) public pure returns (uint256) {
+        return UFixedLib.toInt(value);
+    }
+}