@etherisc/gif-next 0.0.2-def25d4-556 → 0.0.2-e0ff180-567

package/contracts/components/Component.sol

@@ -0,0 +1,253 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
+import {IAccessManaged} from "@openzeppelin/contracts/access/manager/IAccessManaged.sol";
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
+
+import {IComponent} from "./IComponent.sol";
+import {IComponents} from "../instance/module/IComponents.sol";
+import {IProductService} from "../instance/service/IProductService.sol";
+import {IInstanceService} from "../instance/IInstanceService.sol";
+import {IInstance} from "../instance/IInstance.sol";
+import {InstanceAccessManager} from "../instance/InstanceAccessManager.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {NftId} from "../types/NftId.sol";
+import {ObjectType, INSTANCE, PRODUCT} from "../types/ObjectType.sol";
+import {VersionPart} from "../types/Version.sol";
+import {Registerable} from "../shared/Registerable.sol";
+import {RoleId, RoleIdLib} from "../types/RoleId.sol";
+import {IAccess} from "../instance/module/IAccess.sol";
+import {VersionPart} from "../types/Version.sol";
+
+// TODO discuss to inherit from oz accessmanaged
+// then add (Distribution|Pool|Product)Upradeable that also intherit from Versionable
+// same pattern as for Service which is also upgradeable
+abstract contract Component is
+    Registerable,
+    IComponent,
+    AccessManagedUpgradeable
+{
+    // keccak256(abi.encode(uint256(keccak256("gif-next.contracts.component.Component.sol")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant COMPONENT_LOCATION_V1 = 0xffe8d4462baed26a47154f4b8f6db497d2f772496965791d25bd456e342b7f00;
+
+    struct ComponentStorage {
+        string _name; // unique (per instance) component name
+        IERC20Metadata _token; // token for this component
+        IInstance _instance; // instance for this component
+        address _wallet; // wallet for this component (default = component contract itself)
+        InstanceReader _instanceReader; // instance reader for this component
+        bool _isNftInterceptor; // declares if component is involved in nft transfers
+        NftId _productNftId; // only relevant for components that are linked to a aproduct
+    }
+
+    function _getComponentStorage() private pure returns (ComponentStorage storage $) {
+        assembly {
+            $.slot := COMPONENT_LOCATION_V1
+        }
+    }
+
+    modifier onlyChainNft() {
+        if(msg.sender != getRegistry().getChainNftAddress()) {
+            revert ErrorComponentNotChainNft(msg.sender);
+        }
+        _;
+    }
+
+    function initializeComponent(
+        address registry,
+        NftId instanceNftId,
+        string memory name,
+        address token,
+        ObjectType componentType,
+        bool isInterceptor,
+        address initialOwner,
+        bytes memory registryData // writeonly data that will saved in the object info record of the registry
+    )
+        public
+        virtual
+        onlyInitializing()
+    {
+        initializeRegisterable(registry, instanceNftId, componentType, isInterceptor, initialOwner, registryData);
+
+        // set and check linked instance
+        ComponentStorage storage $ = _getComponentStorage();
+        $._instance = IInstance(
+            getRegistry().getObjectInfo(instanceNftId).objectAddress);
+
+        if(!$._instance.supportsInterface(type(IInstance).interfaceId)) {
+            revert ErrorComponentNotInstance(instanceNftId);
+        }
+
+        // initialize AccessManagedUpgradeable
+        __AccessManaged_init($._instance.authority());
+
+        // set component state
+        $._name = name;
+        $._isNftInterceptor = isInterceptor;
+        $._instanceReader = $._instance.getInstanceReader();
+        $._wallet = address(this);
+        $._token = IERC20Metadata(token);
+
+        registerInterface(type(IAccessManaged).interfaceId);
+        registerInterface(type(IComponent).interfaceId);
+    }
+
+    function lock() external onlyOwner override {
+        IInstanceService(_getServiceAddress(INSTANCE())).setComponentLocked(true);
+    }
+    
+    function unlock() external onlyOwner override {
+        IInstanceService(_getServiceAddress(INSTANCE())).setComponentLocked(false);
+    }
+
+    function setWallet(address newWallet)
+        external
+        override
+        onlyOwner
+    {
+        ComponentStorage storage $ = _getComponentStorage();
+
+        address currentWallet = $._wallet;
+        uint256 currentBalance = $._token.balanceOf(currentWallet);
+
+        // checks
+        if (newWallet == address(0)) {
+            revert ErrorComponentWalletAddressZero();
+        }
+
+        if (newWallet == currentWallet) {
+            revert ErrorComponentWalletAddressIsSameAsCurrent();
+        }
+
+        if (currentBalance > 0) {
+            if (currentWallet == address(this)) {
+                // move tokens from component smart contract to external wallet
+            } else {
+                // move tokens from external wallet to component smart contract or another external wallet
+                uint256 allowance = $._token.allowance(currentWallet, address(this));
+                if (allowance < currentBalance) {
+                    revert ErrorComponentWalletAllowanceTooSmall(currentWallet, newWallet, allowance, currentBalance);
+                }
+            }
+        }
+
+        // effects
+        $._wallet = newWallet;
+        emit LogComponentWalletAddressChanged(currentWallet, newWallet);
+
+        // interactions
+        if (currentBalance > 0) {
+            // transfer tokens from current wallet to new wallet
+            if (currentWallet == address(this)) {
+                // transferFrom requires self allowance too
+                $._token.approve(address(this), currentBalance);
+            }
+            
+            SafeERC20.safeTransferFrom($._token, currentWallet, newWallet, currentBalance);
+            emit LogComponentWalletTokensTransferred(currentWallet, newWallet, currentBalance);
+        }
+    }
+
+    function setProductNftId(NftId productNftId)
+        external
+        override
+    {
+        ComponentStorage storage $ = _getComponentStorage();
+
+        // verify caller is product service
+        if(msg.sender != _getServiceAddress(PRODUCT())) {
+            revert ErrorComponentNotProductService(msg.sender);
+        }
+
+        // verify component is not yet linked to a product
+        if($._productNftId.gtz()) {
+            revert ErrorComponentProductNftAlreadySet();
+        }
+
+        $._productNftId = productNftId;
+    }
+
+    function nftMint(address to, uint256 tokenId) 
+        external 
+        virtual
+        onlyChainNft
+    {}
+
+    /// @dev callback function for nft transfers
+    /// may only be called by chain nft contract.
+    /// do not override this function to implement business logic for handling transfers
+    /// override internal function _nftTransferFrom instead
+    function nftTransferFrom(address from, address to, uint256 tokenId)
+        external
+        virtual
+        onlyChainNft
+    {
+        _nftTransferFrom(from, to, tokenId);
+    }
+
+    function getWallet() public view override returns (address walletAddress)
+    {
+        return _getComponentStorage()._wallet;
+    }
+
+    function getToken() public view override returns (IERC20Metadata token) {
+        return _getComponentStorage()._token;
+    }
+
+    function isNftInterceptor() public view override returns(bool isInterceptor) {
+        return _getComponentStorage()._isNftInterceptor;
+    }
+
+    function getInstance() public view override returns (IInstance instance) {
+        return _getComponentStorage()._instance;
+    }
+
+    function getName() public view override returns(string memory name) {
+        return _getComponentStorage()._name;
+    }
+
+    function getProductNftId() public view override returns (NftId productNftId) {
+        return _getComponentStorage()._productNftId;
+    }
+
+    function getComponentInfo() public view returns (IComponents.ComponentInfo memory info) {
+        info = _getInstanceReader().getComponentInfo(getNftId());
+
+        // fallback to initial info (wallet is always != address(0))
+        if(info.wallet == address(0)) {
+            info = _getInitialInfo();
+        }
+    }
+
+    /// @dev defines initial component specification
+    /// overwrite this function according to your use case
+    function _getInitialInfo()
+        internal
+        view 
+        virtual
+        returns (IComponents.ComponentInfo memory info)
+    { }
+
+
+    /// @dev internal function for nft transfers.
+    /// handling logic that deals with nft transfers need to overwrite this function
+    function _nftTransferFrom(address from, address to, uint256 tokenId)
+        internal
+        virtual
+    { }
+
+    /// @dev returns reader for linked instance
+    function _getInstanceReader() internal view returns (InstanceReader reader) {
+        return _getComponentStorage()._instanceReader;
+    }
+
+    /// @dev returns the service address for the specified domain
+    /// gets address via lookup from registry using the major version form the linked instance
+    function _getServiceAddress(ObjectType domain) internal view returns (address service) {
+        VersionPart majorVersion = _getComponentStorage()._instance.getMajorVersion();
+        return getRegistry().getServiceAddress(domain, majorVersion);
+    }
+}

package/contracts/components/Distribution.sol

@@ -4,10 +4,11 @@ pragma solidity ^0.8.19;
 import {DISTRIBUTION} from "../types/ObjectType.sol";
 import {IDistributionService} from "../instance/service/IDistributionService.sol";
 import {IProductService} from "../instance/service/IProductService.sol";
-import {NftId, zeroNftId, NftIdLib} from "../types/NftId.sol";
-import {ReferralId} from "../types/Referral.sol";
+import {NftId, zeroNftId, NftIdLib, toNftId} from "../types/NftId.sol";
+import {ReferralId, ReferralStatus, ReferralLib} from "../types/Referral.sol";
 import {Fee, FeeLib} from "../types/Fee.sol";
-import {BaseComponent} from "./BaseComponent.sol";
+import {Component} from "./Component.sol";
+import {IDistribution} from "../instance/module/IDistribution.sol";
 import {IDistributionComponent} from "./IDistributionComponent.sol";
 import {IRegistry} from "../registry/IRegistry.sol";
 import {IRegisterable} from "../shared/IRegisterable.sol";
@@ -15,72 +16,200 @@ import {ISetup} from "../instance/module/ISetup.sol";
 import {Registerable} from "../shared/Registerable.sol";
 import {TokenHandler} from "../shared/TokenHandler.sol";
 import {InstanceReader} from "../instance/InstanceReader.sol";
+import {UFixed} from "../types/UFixed.sol";
+import {DistributorType} from "../types/DistributorType.sol";
+import {Timestamp, TimestampLib} from "../types/Timestamp.sol";
+import {ITransferInterceptor} from "../registry/ITransferInterceptor.sol";
 
-contract Distribution is
-    BaseComponent,
+
+abstract contract Distribution is
+    Component,
     IDistributionComponent
 {
-    using NftIdLib for NftId;
-
-    Fee internal _initialDistributionFee;
-    bool internal _isVerifying;
+    // keccak256(abi.encode(uint256(keccak256("etherisc.storage.Distribution")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant DISTRIBUTION_STORAGE_LOCATION_V1 = 0xaab7c5ea03d290056d6c060e0833d3ebcbe647f7694616a2ec52738a64b2f900;
 
-    IDistributionService private _distributionService;
-    IProductService private _productService;
-
-    modifier onlyProductService() {
-        require(
-            msg.sender == address(_productService), 
-            "ERROR:POL-002:NOT_PRODUCT_SERVICE");
-        _;
+    struct DistributionStorage {
+        Fee _minDistributionOwnerFee;
+        Fee _distributionFee;
+        TokenHandler _tokenHandler;
+        IDistributionService _distributionService;
+        mapping(address distributor => NftId distributorNftId) _distributorNftId;
     }
 
-    constructor(
+    function initializeDistribution(
         address registry,
         NftId instanceNftId,
-        // TODO refactor into tokenNftId
+        string memory name,
         address token,
-        bool verifying,
+        Fee memory minDistributionOwnerFee,
         Fee memory distributionFee,
-        address initialOwner
+        address initialOwner,
+        bytes memory registryData // writeonly data that will saved in the object info record of the registry
     )
-        BaseComponent(registry, instanceNftId, token, DISTRIBUTION(), true, initialOwner)
+        public
+        virtual
+        onlyInitializing()
     {
-        _isVerifying = verifying;
-        _initialDistributionFee = distributionFee;
+        initializeComponent(registry, instanceNftId, name, token, DISTRIBUTION(), true, initialOwner, registryData);
 
-        _distributionService = _instance.getDistributionService();
-        // TODO: reactivate when services are available again
-        // _productService = _instance.getProductService();
+        DistributionStorage storage $ = _getDistributionStorage();
+        // TODO add validation
+        $._minDistributionOwnerFee = minDistributionOwnerFee;
+        $._distributionFee = distributionFee;
+        $._tokenHandler = new TokenHandler(token);
+        $._distributionService = getInstance().getDistributionService();
 
-        _registerInterface(type(IDistributionComponent).interfaceId);
+        registerInterface(type(IDistributionComponent).interfaceId);
     }
 
-
     function setFees(
+        Fee memory minDistributionOwnerFee,
         Fee memory distributionFee
     )
         external
         override
+        onlyOwner
+        restricted()
     {
-        _distributionService.setFees(distributionFee);
+        _getDistributionStorage()._distributionService.setFees(minDistributionOwnerFee, distributionFee);
     }
 
-    function calculateFeeAmount(
-        ReferralId referralId,
-        uint256 netPremiumAmount
+    function getDistributionFee() external view returns (Fee memory distributionFee) {
+        DistributionStorage storage $ = _getDistributionStorage();
+        return $._distributionFee;
+    }
+
+    function createDistributorType(
+        string memory name,
+        UFixed minDiscountPercentage,
+        UFixed maxDiscountPercentage,
+        UFixed commissionPercentage,
+        uint32 maxReferralCount,
+        uint32 maxReferralLifetime,
+        bool allowSelfReferrals,
+        bool allowRenewals,
+        bytes memory data
+    )
+        public
+        returns (DistributorType distributorType)
+    {
+        DistributionStorage storage $ = _getDistributionStorage();
+        distributorType = $._distributionService.createDistributorType(
+            name,
+            minDiscountPercentage,
+            maxDiscountPercentage,
+            commissionPercentage,
+            maxReferralCount,
+            maxReferralLifetime,
+            allowSelfReferrals,
+            allowRenewals,
+            data);
+    }
+
+    function createDistributor(
+        address distributor,
+        DistributorType distributorType,
+        bytes memory data
+    )
+        public
+        returns(NftId distributorNftId)
+    {
+        DistributionStorage storage $ = _getDistributionStorage();
+        require($._distributorNftId[distributor].eqz(), "ERROR:DST-030:ALREADY_DISTRIBUTOR");
+
+        distributorNftId = $._distributionService.createDistributor(
+            distributor,
+            distributorType,
+            data);
+
+        $._distributorNftId[distributor] = distributorNftId;
+    }
+
+    function updateDistributorType(
+        NftId distributorNftId,
+        DistributorType distributorType,
+        bytes memory data
+    )
+        public
+        // TODO figure out what we need for authz
+        // and add it
+    {
+        DistributionStorage storage $ = _getDistributionStorage();
+        $._distributionService.updateDistributorType(
+            distributorNftId,
+            distributorType,
+            data);
+    }
+
+    /**
+     * @dev lets distributors create referral codes.
+     * referral codes need to be unique
+     */
+    function _createReferral(
+        NftId distributorNftId,
+        string memory code,
+        UFixed discountPercentage,
+        uint32 maxReferrals,
+        Timestamp expiryAt,
+        bytes memory data
     )
+        internal
+        returns (ReferralId referralId)
+    {
+        DistributionStorage storage $ = _getDistributionStorage();
+        referralId = $._distributionService.createReferral(
+            distributorNftId,
+            code,
+            discountPercentage,
+            maxReferrals,
+            expiryAt,
+            data);
+    }
+
+    function isDistributor(address candidate)
+        public
+        view
+        returns (bool)
+    {
+        DistributionStorage storage $ = _getDistributionStorage();
+        return $._distributorNftId[candidate].gtz();
+    }
+
+    function getDistributorNftId(address distributor)
+        public
+        view
+        returns (NftId distributorNftId)
+    {
+        DistributionStorage storage $ = _getDistributionStorage();
+        return $._distributorNftId[distributor];
+    }
+
+    function getDiscountPercentage(string memory referralCode)
         external
         view
-        virtual override
-        returns (uint256 feeAmount)
+        returns (
+            UFixed discountPercentage, 
+            ReferralStatus status
+        )
     {
-        ISetup.DistributionSetupInfo memory setupInfo = getSetupInfo();
-        Fee memory fee = setupInfo.distributionFee;
-        (feeAmount,) = FeeLib.calculateFee(fee, netPremiumAmount);
+        ReferralId referralId = getReferralId(referralCode);
+        return _getInstanceReader().getDiscountPercentage(referralId);
     }
 
 
+    function getReferralId(
+        string memory referralCode
+    )
+        public
+        view 
+        returns (ReferralId referralId)
+    {
+        return ReferralLib.toReferralId(
+            getNftId(), 
+            referralCode);      
+    }
+
     function calculateRenewalFeeAmount(
         ReferralId referralId,
         uint256 netPremiumAmount
@@ -94,73 +223,58 @@ contract Distribution is
         return 0 * netPremiumAmount;
     }
 
-    function processSale(
-        ReferralId referralId,
-        uint256 feeAmount
-    )
-        external
-        onlyProductService
-        virtual override
-    {
-        // default is no action
-    }
-
     function processRenewal(
         ReferralId referralId,
         uint256 feeAmount
     )
         external
-        onlyProductService
+        onlyOwner
+        restricted()
         virtual override
     {
         // default is no action
     }
 
-    function referralIsValid(ReferralId referralId) external view returns (bool isValid) {
-        // default is invalid
-        return false;
+    function getSetupInfo() public view returns (ISetup.DistributionSetupInfo memory setupInfo) {
+        InstanceReader reader = getInstance().getInstanceReader();
+        setupInfo = reader.getDistributionSetupInfo(getNftId());
+
+        // fallback to initial setup info (wallet is always != address(0))
+        if(setupInfo.wallet == address(0)) {
+            setupInfo = _getInitialSetupInfo();
+        }
     }
 
-    function getInitialSetupInfo() public view returns (ISetup.DistributionSetupInfo memory setupInfo) {
+    function _getInitialSetupInfo() internal view returns (ISetup.DistributionSetupInfo memory setupInfo) {
+        DistributionStorage storage $ = _getDistributionStorage();
         return ISetup.DistributionSetupInfo(
-            _productNftId,
-            TokenHandler(address(_token)),
-            _initialDistributionFee,
-            _isVerifying,
-            address(this)
+            zeroNftId(),
+            $._tokenHandler,
+            $._minDistributionOwnerFee,
+            $._distributionFee,
+            address(this),
+            0
         );
     }
 
-    function getSetupInfo() public view returns (ISetup.DistributionSetupInfo memory setupInfo) {
-        InstanceReader reader = _instance.getInstanceReader();
-        return reader.getDistributionSetupInfo(getNftId());
+
+    function _nftTransferFrom(address from, address to, uint256 tokenId) internal virtual override {
+        // keep track of distributor nft owner
+        emit LogDistributorUpdated(to, msg.sender);
+        DistributionStorage storage $ = _getDistributionStorage();
+        $._distributorNftId[from] = zeroNftId();
+        $._distributorNftId[to] = toNftId(tokenId);
     }
     
 
     /// @dev returns true iff the component needs to be called when selling/renewing policis
     function isVerifying() external view returns (bool verifying) {
-        return _isVerifying;
+        return true;
     }
 
-    // from IRegisterable
-
-    function getInitialInfo() 
-        public 
-        view
-        override (IRegisterable, Registerable)
-        returns(IRegistry.ObjectInfo memory, bytes memory)
-    {
-        (
-            IRegistry.ObjectInfo memory info, 
-            bytes memory data
-        ) = super.getInitialInfo();
-
-        return (
-            info,
-            abi.encode(
-                _initialDistributionFee,
-                _isVerifying
-            )
-        );
+    function _getDistributionStorage() private pure returns (DistributionStorage storage $) {
+        assembly {
+            $.slot := DISTRIBUTION_STORAGE_LOCATION_V1
+        }
     }
 }

package/contracts/components/IComponent.sol

@@ -0,0 +1,76 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IAccessManaged} from "@openzeppelin/contracts/access/manager/IAccessManaged.sol";
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {IComponents} from "../instance/module/IComponents.sol";
+import {IInstance} from "../instance/IInstance.sol";
+import {IInstanceService} from "../instance/IInstanceService.sol";
+import {IProductService} from "../instance/service/IProductService.sol";
+import {IRegisterable} from "../shared/IRegisterable.sol";
+import {ITransferInterceptor} from "../registry/ITransferInterceptor.sol";
+import {NftId} from "../types/NftId.sol";
+import {ObjectType} from "../types/ObjectType.sol";
+
+/// @dev component base class
+/// component examples are product, distribution, pool and oracle
+interface IComponent is 
+    IRegisterable,
+    ITransferInterceptor,
+    IAccessManaged
+{
+    error ErrorComponentNotChainNft(address caller);
+    error ErrorComponentNotProductService(address caller);
+    error ErrorComponentNotInstance(NftId instanceNftId);
+    error ErrorComponentProductNftAlreadySet();
+
+    error ErrorComponentWalletAddressZero();
+    error ErrorComponentWalletAddressIsSameAsCurrent();
+    error ErrorComponentWalletAllowanceTooSmall(address oldWallet, address newWallet, uint256 allowance, uint256 balance);
+
+    event LogComponentWalletAddressChanged(address oldWallet, address newWallet);
+    event LogComponentWalletTokensTransferred(address from, address to, uint256 amount);
+
+    /// @dev locks component to disable functions that may change state related to this component, the only exception is function "unlock"
+    /// only component owner (nft holder) is authorizes to call this function
+    function lock() external;
+
+    /// @dev unlocks component to (re-)enable functions that may change state related to this component
+    /// only component owner (nft holder) is authorizes to call this function
+    function unlock() external;
+
+    /// @dev sets the wallet address for the component
+    /// if the current wallet has tokens, these will be transferred
+    /// if the new wallet address is externally owned, an approval from the 
+    /// owner of the external wallet for the component to move all tokens must exist
+    function setWallet(address walletAddress) external;
+
+    /// @dev only product service may set product nft id during registration of product setup
+    function setProductNftId(NftId productNftId) external;
+
+    /// @dev returns the name of this component
+    /// to successfully register the component with an instance the name MUST be unique in the linked instance
+    function getName() external view returns (string memory name);
+
+    /// @dev defines which ERC20 token is used by this component
+    function getToken() external view returns (IERC20Metadata token);
+
+    /// @dev defines the instance to which this component is linked to
+    function getInstance() external view returns (IInstance instance);
+
+    /// @dev defines the wallet address used to hold the ERC20 tokens related to this component
+    /// the default address is the component token address
+    function getWallet() external view returns (address walletAddress);
+
+    /// @dev defines the product to which this component is linked to
+    /// this is only relevant for pool and distribution components
+    function getProductNftId() external view returns (NftId productNftId);
+
+    function isNftInterceptor() external view returns(bool isInterceptor);
+
+    /// @dev returns component infos for this pool
+    /// when registered with an instance the info is obtained from the data stored in the instance
+    /// when not registered the function returns the info from the component contract
+    function getComponentInfo() external view returns (IComponents.ComponentInfo memory info);
+}