@etherisc/gif-next 0.0.2-da77c50-824 → 0.0.2-db12733-152

package/contracts/shared/Lifecycle.sol

@@ -0,0 +1,88 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ObjectType} from "../type/ObjectType.sol";
+import {StateId, zeroStateId} from "../type/StateId.sol";
+import {ILifecycle} from "./ILifecycle.sol";
+
+abstract contract Lifecycle is
+    ILifecycle
+{
+    mapping(ObjectType objectType => StateId initialState)
+        private _initialState;
+
+    mapping(ObjectType objectType => mapping(StateId stateFrom => mapping(StateId stateTo => bool isValid)))
+        private _isValidTransition;
+
+    /// @dev child class must implement and CALL setup func at deployment/initializaton time
+    function _setupLifecycle() internal virtual;
+
+    function setInitialState(ObjectType ttype, StateId state) internal virtual {
+        assert(_initialState[ttype] == zeroStateId());
+        _initialState[ttype] = state;
+    }
+
+    function setStateTransition(ObjectType ttype, StateId oldState, StateId newState) internal virtual {
+        assert(_isValidTransition[ttype][oldState][newState] == false);
+        _isValidTransition[ttype][oldState][newState] = true;
+    }
+
+    function hasLifecycle(
+        ObjectType objectType
+    )
+        public
+        view
+        override
+        returns (bool)
+    {
+        return _initialState[objectType].gtz();
+    }
+
+    function getInitialState(
+        ObjectType objectType
+    )
+        public
+        view
+        returns (StateId)
+    {
+        return _initialState[objectType];
+    }
+
+    function checkTransition(
+        StateId stateId,
+        ObjectType objectType,
+        StateId expectedFromId,
+        StateId toId
+    )
+        public
+        view
+    {
+        // revert if no life cycle support
+        if (_initialState[objectType].eqz()) {
+            revert ErrorNoLifecycle(address(this), objectType);
+        }
+
+        // revert if current state is not expected `from` state
+        if(stateId != expectedFromId) {
+            revert ErrorFromStateMissmatch(address(this), objectType, stateId, expectedFromId);
+        }
+
+        // enforce valid state transition
+        if (!_isValidTransition[objectType][stateId][toId]) {
+            revert ErrorInvalidStateTransition(
+                address(this),
+                objectType, 
+                stateId, 
+                toId
+            );
+        }
+    }
+
+    function isValidTransition(
+        ObjectType objectType,
+        StateId fromId,
+        StateId toId
+    ) public view returns (bool) {
+        return _isValidTransition[objectType][fromId][toId];
+    }
+}

package/contracts/shared/NftIdSet.sol

@@ -0,0 +1,65 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {LibNftIdSet} from "../type/NftIdSet.sol";
+import {NftId} from "../type/NftId.sol";
+
+contract NftIdSet {
+
+    error ErrorNftIdSetManagerNotOwner(address owner, address sender);
+    error ErrorNftIdSetManagerOwnerAlreadySet(address owner);
+    error ErrorNftIdSetManagerNftIdInvalid(NftId objectNftId);
+    error ErrorNftIdSetManagerAlreadyAdded(NftId objectNftId);
+
+    LibNftIdSet.Set private _allObjects;
+    LibNftIdSet.Set private _activeObjects;
+    address private _owner;
+
+    modifier onlyOwner() {
+        if(msg.sender != _owner) {
+            revert ErrorNftIdSetManagerNotOwner(_owner, msg.sender);
+        }
+        _;
+    }
+
+    constructor() {
+        _owner = msg.sender;
+    }
+
+    function add(NftId objectNftId) external onlyOwner {
+        LibNftIdSet.add(_allObjects, objectNftId);
+        LibNftIdSet.add(_activeObjects, objectNftId);
+    }
+
+    function activate(NftId componentNftId, NftId objectNftId) external onlyOwner {
+        LibNftIdSet.add(_activeObjects, objectNftId);
+    }
+
+    function deactivate(NftId componentNftId, NftId objectNftId) external onlyOwner {
+        LibNftIdSet.remove(_activeObjects, objectNftId);
+    }
+
+    function nftIds() external view returns (uint256 ids) {
+        return LibNftIdSet.size(_allObjects);
+    }
+
+    function getNftId(uint256 idx) external view returns (NftId) {
+        return LibNftIdSet.getElementAt(_allObjects, idx);
+    }
+
+    function exists(NftId objectNftId) external view returns (bool) {
+        return LibNftIdSet.contains(_allObjects, objectNftId);
+    }
+
+    function activeNftIds() external view returns (uint256 ids) {
+        return LibNftIdSet.size(_activeObjects);
+    }
+
+    function getActiveNftId(uint256 idx) external view returns (NftId) {
+        return LibNftIdSet.getElementAt(_activeObjects, idx);
+    }
+
+    function isActive(NftId objectNftId) external view returns (bool) {
+        return LibNftIdSet.contains(_activeObjects, objectNftId);
+    }
+}

package/contracts/shared/NftOwnable.sol

@@ -0,0 +1,127 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {InitializableERC165} from "./InitializableERC165.sol";
+import {INftOwnable} from "./INftOwnable.sol";
+import {NftId} from "../type/NftId.sol";
+import {ObjectType} from "../type/ObjectType.sol";
+import {RegistryLinked} from "./RegistryLinked.sol";
+
+contract NftOwnable is
+    InitializableERC165,
+    RegistryLinked,
+    INftOwnable
+{
+    // keccak256(abi.encode(uint256(keccak256("etherisc.storage.NftOwnable")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant NFT_OWNABLE_STORAGE_LOCATION_V1 = 0x07ebcf49758b6ed3af50fa146bec0abe157c0218fe65dc0874c286e9d5da4f00;
+
+    struct NftOwnableStorage {
+        NftId _nftId;
+        address _initialOwner; 
+    }
+
+    /// @dev enforces msg.sender is owner of nft (or initial owner of nft ownable)
+    modifier onlyOwner() {
+        if (msg.sender != getOwner()) {
+            revert ErrorNftOwnableNotOwner(msg.sender);
+        }
+        _;
+    }
+
+    modifier onlyNftOwner(NftId nftId) {
+        if(!getRegistry().isOwnerOf(nftId, msg.sender)) {
+            revert ErrorNftOwnableNotOwner(msg.sender);
+        }
+        _;
+    }
+
+    modifier onlyNftOfType(NftId nftId, ObjectType expectedObjectType) {
+        _checkNftType(nftId, expectedObjectType);
+        _;
+    }
+
+    function _checkNftType(NftId nftId, ObjectType expectedObjectType) internal view {
+        if(!getRegistry().isObjectType(nftId, expectedObjectType)) {
+            revert ErrorNftOwnableInvalidType(nftId, expectedObjectType);
+        }
+    }
+
+
+    /// @dev Initialization for upgradable contracts.
+    // used in __Registerable_init, ProxyManager._preDeployChecksAndSetup
+    function __NftOwnable_init(
+        address registry,
+        address initialOwner
+    )
+        internal
+        virtual
+        onlyInitializing()
+    {
+        __ERC165_init();
+        __RegistryLinked_init(registry);
+
+        if(initialOwner == address(0)) {
+            revert ErrorNftOwnableInitialOwnerZero();
+        }
+
+        _getNftOwnableStorage()._initialOwner = initialOwner;
+    }
+
+
+    /// @dev links this contract to nft after registration
+    // needs to be done once per registered contract and 
+    // reduces registry calls to check ownership
+    // does not need any protection as function can only do the "right thing"
+    function linkToRegisteredNftId()
+        public
+        virtual
+        returns (NftId nftId)
+    {
+        return _linkToNftOwnable(address(this));
+    }
+
+    function getNftId() public view virtual override returns (NftId) {
+        return _getNftOwnableStorage()._nftId;
+    }
+
+    function getOwner() public view virtual override returns (address) {
+        NftOwnableStorage storage $ = _getNftOwnableStorage();
+
+        if ($._nftId.gtz()) {
+            return getRegistry().ownerOf($._nftId);
+        }
+
+        return $._initialOwner;
+    }
+
+    /// @dev used in constructor of registry service manager
+    // links ownership of registry service manager ot nft owner of registry service
+    function _linkToNftOwnable(
+        address nftOwnableAddress
+    )
+        internal
+        returns (NftId)
+    {
+        NftOwnableStorage storage $ = _getNftOwnableStorage();
+
+        if ($._nftId.gtz()) {
+            revert ErrorNftOwnableAlreadyLinked($._nftId);
+        }
+
+        if (!getRegistry().isRegistered(nftOwnableAddress)) {
+            revert ErrorNftOwnableContractNotRegistered(nftOwnableAddress);
+        }
+
+        $._nftId = getRegistry().getNftIdForAddress(nftOwnableAddress);
+
+        return $._nftId;
+    }
+
+
+    function _getNftOwnableStorage() private pure returns (NftOwnableStorage storage $) {
+        // solhint-disable-next-line no-inline-assembly
+        assembly {
+            $.slot := NFT_OWNABLE_STORAGE_LOCATION_V1
+        }
+    }
+}

package/contracts/shared/PolicyHolder.sol

@@ -0,0 +1,62 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC721Receiver} from "@openzeppelin/contracts/token/ERC721/IERC721Receiver.sol";
+
+import {Amount} from "../type/Amount.sol";
+import {ClaimId} from "../type/ClaimId.sol";
+import {InitializableERC165} from "./InitializableERC165.sol";
+import {IPolicyHolder} from "./IPolicyHolder.sol";
+import {NftId} from "../type/NftId.sol";
+import {PayoutId, PayoutIdLib} from "../type/PayoutId.sol";
+import {RegistryLinked} from "./RegistryLinked.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+
+/// @dev template implementation for IPolicyHolder
+contract PolicyHolder is
+    InitializableERC165,
+    RegistryLinked,
+    IPolicyHolder
+{
+    // TODO add modifier to protect callback functions from unauthorized access
+    // callbacks must only be allowed from the policy and claim services
+    // will need a release parameter to fetch the right service addresses for the modifiers
+
+    function _initializePolicyHolder(
+        address registryAddress
+    )
+        internal
+        virtual
+        onlyInitializing()
+    {
+        __RegistryLinked_init(registryAddress);
+        _initializeERC165();
+        _registerInterface(type(IPolicyHolder).interfaceId);
+    }
+
+    /// @dev empty default implementation
+    function policyActivated(NftId policyNftId, Timestamp activatedAt) external virtual {}
+
+    /// @dev empty default implementation
+    function policyExpired(NftId policyNftId, Timestamp expiredAt) external virtual {}
+
+    /// @dev empty default implementation
+    function claimConfirmed(NftId policyNftId, ClaimId claimId, Amount amount) external virtual {}
+
+    /// @dev empty default implementation
+    function payoutExecuted(NftId policyNftId, PayoutId payoutId, Amount amount, address beneficiary) external virtual {}
+
+    //--- IERC165 functions ---------------// 
+    function onERC721Received(
+        address, // operator
+        address, // from
+        uint256, // tokenId
+        bytes calldata // data
+    )
+        external
+        virtual
+        returns (bytes4)
+    {
+        return IERC721Receiver.onERC721Received.selector;
+    }
+}

package/contracts/shared/Registerable.sol

@@ -1,86 +1,106 @@
 // SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
+pragma solidity ^0.8.20;
 
-import {NftId, zeroNftId} from "../types/NftId.sol";
-import {ObjectType} from "../types/ObjectType.sol";
+import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
+import {IAccessManaged} from "@openzeppelin/contracts/access/manager/IAccessManaged.sol";
+
+import {AccessManagerCloneable} from "../authorization/AccessManagerCloneable.sol";
+import {ContractLib} from "../shared/ContractLib.sol";
+import {NftId, NftIdLib} from "../type/NftId.sol";
+import {NftOwnable} from "../shared/NftOwnable.sol";
+import {ObjectType} from "../type/ObjectType.sol";
+import {VersionPart, VersionPartLib} from "../type/Version.sol";
 
 import {IRegistry} from "../registry/IRegistry.sol";
 import {IRegisterable} from "./IRegisterable.sol";
-
-import {ERC165} from "./ERC165.sol";
+import {IRelease} from "../registry/IRelease.sol";
 
 abstract contract Registerable is
-    ERC165,
+    AccessManagedUpgradeable,
+    NftOwnable,
     IRegisterable
 {
-    IRegistry internal immutable _registry;
-    NftId internal immutable _parentNftId;
-    address internal immutable _initialOwner;
-
-    modifier onlyOwner() virtual {
-        require(
-            msg.sender == getOwner(),
-            "ERROR:RGB-001:NOT_OWNER"
-        );
+    // keccak256(abi.encode(uint256(keccak256("gif-next.contracts.shared.Registerable.sol")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant REGISTERABLE_LOCATION_V1 = 0x6548007c3f4340f82f348c576c0ff69f4f529cadd5ad41f96aae61abceeaa300;
+
+    struct RegisterableStorage {
+        NftId _parentNftId;
+        ObjectType _objectType;
+        bool _isInterceptor;
+        bytes _data;
+    }
+
+    modifier onlyActive() {
+        if (!isActive()) {
+            revert ErrorRegisterableNotActive();
+        }
         _;
     }
 
-    constructor(
-        address registryAddress,
-        NftId parentNftId
+    function __Registerable_init(
+        address authority,
+        address registry,
+        NftId parentNftId,
+        ObjectType objectType,
+        bool isInterceptor,
+        address initialOwner,
+        bytes memory data // writeonly data that will saved in the object info record of the registry
     )
-        ERC165()
+        internal
+        virtual
+        onlyInitializing()
     {
-        require(
-            address(registryAddress) != address(0),
-            "ERROR:RGB-010:REGISTRY_ZERO"
-        );
-
-        _registry = IRegistry(registryAddress);
-        require(
-            _registry.supportsInterface(type(IRegistry).interfaceId),
-            "ERROR:RGB-011:NOT_REGISTRY"
-        );
-
-        _parentNftId = parentNftId;
-        require(
-            _registry.isRegistered(_parentNftId),
-            "ERROR:RGB-012:PARENT_NOT_REGISTERED"
-        );
-
-        _initialOwner = msg.sender;
-
-        // register support for IRegisterable
-        _registerInterface(type(IRegisterable).interfaceId);
-    }
+        if (!ContractLib.isAuthority(authority)) {
+            revert ErrorAuthorityInvalid(authority);
+        }
 
-    // from IRegistryLinked
-    function register() public onlyOwner virtual override returns (NftId nftId) {
-        return _registry.register(address(this));
-    }
+        __AccessManaged_init(authority);
+        __NftOwnable_init(registry, initialOwner);
 
-    function getRegistry() public view virtual override returns (IRegistry registry) {
-        return _registry;
+        RegisterableStorage storage $ = _getRegisterableStorage();
+        $._parentNftId = parentNftId;
+        $._objectType = objectType;
+        $._isInterceptor = isInterceptor;
+        $._data = data;
+
+        _registerInterface(type(IAccessManaged).interfaceId);
     }
 
-    function getOwner() public view virtual override returns (address owner) {
-        NftId nftId = _registry.getNftId(address(this));
-        if(nftId == zeroNftId()) {
-            return _initialOwner;
-        }
 
-        return _registry.getOwner(nftId);
+    /// @inheritdoc IRegisterable
+    function isActive() public virtual view returns (bool active) {
+        return !AccessManagerCloneable(authority()).isTargetClosed(address(this));
     }
 
-    function getNftId() public view override returns (NftId nftId) {
-        return _registry.getNftId(address(this));
+
+    /// @inheritdoc IRelease
+    function getRelease() public virtual view returns (VersionPart release) {
+        return AccessManagerCloneable(authority()).getRelease();
     }
 
-    function getParentNftId() public view override returns (NftId nftId) {
-        return _parentNftId;
+
+    /// @inheritdoc IRegisterable
+    function getInitialInfo() 
+        public 
+        view 
+        virtual 
+        returns (IRegistry.ObjectInfo memory info) 
+    {
+        RegisterableStorage storage $ = _getRegisterableStorage();
+        return IRegistry.ObjectInfo(
+            NftIdLib.zero(),
+            $._parentNftId,
+            $._objectType,
+            $._isInterceptor,
+            address(this), 
+            getOwner(),
+            $._data);
     }
 
-    function getData() public view virtual override returns (bytes memory data) {
-        return "";
+
+    function _getRegisterableStorage() private pure returns (RegisterableStorage storage $) {
+        assembly {
+            $.slot := REGISTERABLE_LOCATION_V1
+        }
     }
-}
+}

package/contracts/shared/RegistryLinked.sol

@@ -0,0 +1,38 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol"; 
+
+import {ContractLib} from "../shared/ContractLib.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IRegistryLinked} from "./IRegistryLinked.sol";
+
+contract RegistryLinked is
+    Initializable,
+    IRegistryLinked
+{
+
+    // priorize simplicity and size over using standard upgradeability structs
+    IRegistry private _registry;
+
+    /// @dev initialization for upgradable contracts
+    // used in _initializeRegisterable
+    function __RegistryLinked_init(
+        address registry
+    )
+        internal
+        virtual
+        onlyInitializing()
+    {
+        if (!ContractLib.isRegistry(registry)) {
+            revert ErrorNotRegistry(registry);
+        }
+
+        _registry = IRegistry(registry);
+    }
+
+
+    function getRegistry() public view returns (IRegistry) {
+        return _registry;
+    }
+}

package/contracts/shared/Service.sol

@@ -0,0 +1,65 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IAccessManaged} from "@openzeppelin/contracts/access/manager/IAccessManaged.sol";
+import {ReentrancyGuardUpgradeable} from "@openzeppelin/contracts-upgradeable/utils/ReentrancyGuardUpgradeable.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IService} from "./IService.sol";
+import {IVersionable} from "../upgradeability/IVersionable.sol";
+import {ObjectType, REGISTRY, SERVICE} from "../type/ObjectType.sol";
+import {Registerable} from "./Registerable.sol";
+import {RoleId, RoleIdLib} from "../type/RoleId.sol";
+import {Version, VersionLib, VersionPartLib} from "../type/Version.sol";
+import {Versionable} from "../upgradeability/Versionable.sol";
+
+
+/// @dev service base contract
+abstract contract Service is 
+    Registerable,
+    Versionable,
+    ReentrancyGuardUpgradeable,
+    IService
+{
+
+    function __Service_init(
+        address authority, // real authority for registry service adress(0) for other services
+        address registry, 
+        address initialOwner
+    )
+        internal
+        virtual
+        onlyInitializing()
+    {
+        __ReentrancyGuard_init();
+
+        __Registerable_init(
+            authority,
+            registry, 
+            IRegistry(registry).getNftId(), 
+            SERVICE(), 
+            false, // is interceptor
+            initialOwner, 
+            ""); // data
+
+        _registerInterface(type(IService).interfaceId);
+    }
+
+    function getDomain() external virtual pure returns(ObjectType serviceDomain) {
+        return _getDomain();
+    }
+
+    function getVersion() public pure virtual override (IVersionable, Versionable) returns(Version) {
+        return VersionLib.toVersion(3, 0, 0);
+    }
+
+    function getRoleId() external virtual view returns(RoleId serviceRoleId) {
+        return RoleIdLib.roleForTypeAndVersion(_getDomain(), getRelease());
+    }
+
+    function _getDomain() internal virtual pure returns (ObjectType);
+
+    function _getServiceAddress(ObjectType domain) internal view returns (address) {
+        return getRegistry().getServiceAddress(domain, getRelease());
+    }
+}