@etherisc/gif-next 0.0.2-d911522 → 0.0.2-d9e8211-569

package/contracts/shared/NftOwnable.sol

@@ -0,0 +1,107 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {InitializableERC165} from "./InitializableERC165.sol";
+import {INftOwnable} from "./INftOwnable.sol";
+import {NftId} from "../type/NftId.sol";
+import {RegistryLinked} from "./RegistryLinked.sol";
+
+contract NftOwnable is
+    InitializableERC165,
+    RegistryLinked,
+    INftOwnable
+{
+    // keccak256(abi.encode(uint256(keccak256("etherisc.storage.NftOwnable")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant NFT_OWNABLE_STORAGE_LOCATION_V1 = 0x07ebcf49758b6ed3af50fa146bec0abe157c0218fe65dc0874c286e9d5da4f00;
+
+    struct NftOwnableStorage {
+        NftId _nftId;
+        address _initialOwner; 
+    }
+
+    /// @dev enforces msg.sender is owner of nft (or initial owner of nft ownable)
+    modifier onlyOwner() {
+        if (msg.sender != getOwner()) {
+            revert ErrorNftOwnableNotOwner(msg.sender);
+        }
+        _;
+    }
+
+
+    /// @dev initialization for upgradable contracts
+    // used in _initializeRegisterable
+    function _initializeNftOwnable(
+        address initialOwner,
+        address registryAddress
+    )
+        internal
+        virtual
+        onlyInitializing()
+    {
+        _initializeRegistryLinked(registryAddress);
+        _initializeERC165();
+
+        if(initialOwner == address(0)) {
+            revert ErrorNftOwnableInitialOwnerZero();
+        }
+
+        _getNftOwnableStorage()._initialOwner = initialOwner;
+    }
+
+
+    /// @dev links this contract to nft after registration
+    // needs to be done once per registered contract and 
+    // reduces registry calls to check ownership
+    // does not need any protection as function can only do the "right thing"
+    function linkToRegisteredNftId()
+        public
+        virtual
+        returns (NftId nftId)
+    {
+        return _linkToNftOwnable(address(this));
+    }
+
+    function getNftId() public view virtual override returns (NftId) {
+        return _getNftOwnableStorage()._nftId;
+    }
+
+    function getOwner() public view virtual override returns (address) {
+        NftOwnableStorage storage $ = _getNftOwnableStorage();
+
+        if ($._nftId.gtz()) {
+            return getRegistry().ownerOf($._nftId);
+        }
+
+        return $._initialOwner;
+    }
+
+    /// @dev used in constructor of registry service manager
+    // links ownership of registry service manager ot nft owner of registry service
+    function _linkToNftOwnable(
+        address nftOwnableAddress
+    )
+        internal
+        returns (NftId)
+    {
+        NftOwnableStorage storage $ = _getNftOwnableStorage();
+
+        if ($._nftId.gtz()) {
+            revert ErrorNftOwnableAlreadyLinked($._nftId);
+        }
+
+        if (!getRegistry().isRegistered(nftOwnableAddress)) {
+            revert ErrorNftOwnableContractNotRegistered(nftOwnableAddress);
+        }
+
+        $._nftId = getRegistry().getNftIdForAddress(nftOwnableAddress);
+
+        return $._nftId;
+    }
+
+
+    function _getNftOwnableStorage() private pure returns (NftOwnableStorage storage $) {
+        assembly {
+            $.slot := NFT_OWNABLE_STORAGE_LOCATION_V1
+        }
+    }
+}

package/contracts/shared/PolicyHolder.sol

@@ -0,0 +1,56 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC721Receiver} from "@openzeppelin/contracts/token/ERC721/IERC721Receiver.sol";
+
+import {Amount} from "../type/Amount.sol";
+import {ClaimId} from "../type/ClaimId.sol";
+import {InitializableERC165} from "./InitializableERC165.sol";
+import {IPolicyHolder} from "./IPolicyHolder.sol";
+import {NftId} from "../type/NftId.sol";
+import {PayoutId, PayoutIdLib} from "../type/PayoutId.sol";
+import {RegistryLinked} from "./RegistryLinked.sol";
+
+/// @dev template implementation for IPolicyHolder
+contract PolicyHolder is
+    InitializableERC165,
+    RegistryLinked, // TODO need upgradeable version
+    IPolicyHolder
+{
+    function _initializePolicyHolder(
+        address registryAddress
+    )
+        internal
+        virtual
+        onlyInitializing()
+    {
+        _initializeRegistryLinked(registryAddress);
+        _registerInterface(type(IPolicyHolder).interfaceId);
+    }
+
+    /// @dev empty default implementation
+    function policyActivated(NftId policyNftId) external {}
+
+    /// @dev empty default implementation
+    function policyExpired(NftId policyNftId) external {}
+
+    /// @dev empty default implementation
+    function claimConfirmed(NftId policyNftId, ClaimId claimId, Amount amount) external {}
+
+    /// @dev empty default implementation
+    function payoutExecuted(NftId policyNftId, PayoutId payoutId, address beneficiary, Amount amount) external {}
+
+    //--- IERC165 functions ---------------// 
+    function onERC721Received(
+        address, // operator
+        address, // from
+        uint256, // tokenId
+        bytes calldata // data
+    )
+        external
+        virtual
+        returns (bytes4)
+    {
+        return IERC721Receiver.onERC721Received.selector;
+    }
+}

package/contracts/shared/Registerable.sol

@@ -0,0 +1,75 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol"; 
+
+import {NftId, NftIdLib} from "../type/NftId.sol";
+import {NftOwnable} from "../shared/NftOwnable.sol";
+import {ObjectType} from "../type/ObjectType.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IRegisterable} from "./IRegisterable.sol";
+
+contract Registerable is
+    NftOwnable,
+    IRegisterable
+{
+    // keccak256(abi.encode(uint256(keccak256("gif-next.contracts.shared.Registerable.sol")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant REGISTERABLE_LOCATION_V1 = 0x6548007c3f4340f82f348c576c0ff69f4f529cadd5ad41f96aae61abceeaa300;
+
+    struct RegisterableStorage {
+        NftId _parentNftId;
+        ObjectType _objectType;
+        bool _isInterceptor;
+        bytes _data;
+    }
+
+    function _initializeRegisterable(
+        address registryAddress,
+        NftId parentNftId,
+        ObjectType objectType,
+        bool isInterceptor,
+        address initialOwner,
+        bytes memory registryData // writeonly data that will saved in the object info record of the registry
+    )
+        internal
+        virtual
+        onlyInitializing()
+    {
+        _initializeNftOwnable(
+            initialOwner,
+            registryAddress);
+
+        RegisterableStorage storage $;
+        assembly {
+            $.slot := REGISTERABLE_LOCATION_V1
+        }
+
+        $._parentNftId = parentNftId;
+        $._objectType = objectType;
+        $._isInterceptor = isInterceptor;
+        $._data = registryData;
+    }
+
+
+    function getInitialInfo() 
+        public 
+        view 
+        virtual 
+        returns (IRegistry.ObjectInfo memory info) 
+    {
+        RegisterableStorage storage $;
+        assembly {
+            $.slot := REGISTERABLE_LOCATION_V1
+        }
+
+        info = IRegistry.ObjectInfo(
+            NftIdLib.zero(),
+            $._parentNftId,
+            $._objectType,
+            $._isInterceptor,
+            address(this), 
+            getOwner(),
+            $._data);
+    }
+}

package/contracts/shared/RegistryLinked.sol

@@ -0,0 +1,44 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol"; 
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IRegistryLinked} from "./IRegistryLinked.sol";
+
+contract RegistryLinked is
+    Initializable,
+    IRegistryLinked
+{
+
+    // priorize simplicity and size over using standard upgradeability structs
+    IRegistry private _registry;
+
+    /// @dev initialization for upgradable contracts
+    // used in _initializeRegisterable
+    function _initializeRegistryLinked(
+        address registryAddress
+    )
+        internal
+        virtual
+        onlyInitializing()
+    {
+        if (registryAddress.code.length == 0) {
+            revert ErrorNotRegistry(registryAddress);
+        }
+
+        _registry = IRegistry(registryAddress);
+
+        try _registry.supportsInterface(type(IRegistry).interfaceId) returns (bool isRegistry) {
+            if (!isRegistry) {
+                revert ErrorNotRegistry(registryAddress);
+            }
+        } catch {
+            revert ErrorNotRegistry(registryAddress);
+        }
+    }
+
+
+    function getRegistry() public view returns (IRegistry) {
+        return _registry;
+    }
+}

package/contracts/shared/Service.sol

@@ -0,0 +1,82 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
+import {IAccessManaged} from "@openzeppelin/contracts/access/manager/IAccessManaged.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IService} from "./IService.sol";
+import {IVersionable} from "../upgradeability/IVersionable.sol";
+import {ObjectType, REGISTRY, SERVICE} from "../type/ObjectType.sol";
+import {Registerable} from "./Registerable.sol";
+import {RoleId, RoleIdLib} from "../type/RoleId.sol";
+import {Version, VersionLib, VersionPartLib} from "../type/Version.sol";
+import {Versionable} from "../upgradeability/Versionable.sol";
+
+
+/// @dev service base contract
+abstract contract Service is 
+    Registerable,
+    Versionable,
+    AccessManagedUpgradeable,
+    IService
+{
+
+    uint8 private constant GIF_MAJOR_VERSION = 3;
+
+
+    function _initializeService(
+        address registry, 
+        address authority, // real authority for registry service adress(0) for other services
+        address initialOwner
+    )
+        internal
+        virtual
+        onlyInitializing()
+    {
+        _initializeRegisterable(
+            registry, 
+            IRegistry(registry).getNftId(), 
+            SERVICE(), 
+            false, // is interceptor
+            initialOwner, 
+            ""); // data
+
+        // externally provided authority
+        if(authority != address(0)) {
+            __AccessManaged_init(authority);
+        } else {
+            address registryServiceAddress = _getServiceAddress(REGISTRY());
+
+            // copy authority from already registered registry services
+            __AccessManaged_init(IAccessManaged(registryServiceAddress).authority());
+        }
+
+        _registerInterface(type(IAccessManaged).interfaceId);
+        _registerInterface(type(IService).interfaceId);
+    }
+
+    function getDomain() external virtual pure returns(ObjectType serviceDomain) {
+        return _getDomain();
+    }
+
+    function getRoleId() external virtual pure returns(RoleId serviceRoleId) {
+        return RoleIdLib.roleForTypeAndVersion(_getDomain(), VersionPartLib.toVersionPart(GIF_MAJOR_VERSION));
+    }
+
+    // from Versionable
+    function getVersion()
+        public 
+        pure 
+        virtual override (IVersionable, Versionable)
+        returns(Version)
+    {
+        return VersionLib.toVersion(GIF_MAJOR_VERSION,0,0);
+    }
+
+    function _getDomain() internal virtual pure returns (ObjectType);
+
+    function _getServiceAddress(ObjectType domain) internal view returns (address) {
+        return getRegistry().getServiceAddress(domain, VersionPartLib.toVersionPart(GIF_MAJOR_VERSION));
+    }
+}

package/contracts/shared/TokenHandler.sol

@@ -0,0 +1,139 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {AccessManaged} from "@openzeppelin/contracts/access/manager/AccessManaged.sol";
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
+
+import {Amount} from "../type/Amount.sol";
+
+/// @dev token specific transfer helper
+/// a default token contract is provided via contract constructor
+/// relies internally on oz SafeERC20.safeTransferFrom
+contract TokenHandler is AccessManaged {
+    error ErrorTokenHandlerAmountIsZero();
+    error ErrorTokenHandlerBalanceTooLow(address token, address from, uint256 balance, uint256 expectedBalance);
+    error ErrorTokenHandlerAllowanceTooSmall(address token, address from, address spender, uint256 allowance, uint256 expectedAllowance);
+    error ErrorTokenHandlerRecipientWalletsMustBeDistinct(address to, address to2, address to3);
+    
+    event LogTokenHandlerTokenTransfer(address token, address from, address to, uint256 amountTransferred);
+
+    IERC20Metadata private _token;
+
+    constructor(address token, address initialAuthority) AccessManaged(initialAuthority) {
+        _token = IERC20Metadata(token);
+    }
+
+    /// @dev returns the default token defined for this TokenHandler
+    function getToken()
+        external
+        view 
+        returns (IERC20Metadata)
+    {
+        return _token;
+    }
+    
+    /// @dev collect tokens from outside of the gif and transfer them to one wallet within the scope of gif.
+    /// This method also checks balance and allowance and makes sure the amount is greater than zero.
+    function collectTokens(
+        address from,
+        address to,
+        Amount amount
+    )
+        external
+        restricted()
+    {
+        _transfer(from, to, amount, true);
+    }
+
+    /// @dev collect tokens from outside of the gif and transfer them to three distinct wallets within the scope of gif
+    /// This method also checks balance and allowance and makes sure the amount is greater than zero.
+    function collectTokensToThreeRecipients( 
+        address from,
+        address to,
+        Amount amount,
+        address to2,
+        Amount amount2,
+        address to3,
+        Amount amount3
+    )
+        external
+        restricted()
+    {
+        if (to == to2 || to == to3 || to2 == to3) {
+            revert ErrorTokenHandlerRecipientWalletsMustBeDistinct(to, to2, to3);
+        }
+
+        _checkPreconditions(from, amount + amount2 + amount3);
+
+        if (amount.gtz()) {
+            _transfer(from, to, amount, false);
+        }
+        if (amount2.gtz()) {
+            _transfer(from, to2, amount2, false);
+        }
+        if (amount3.gtz()) {
+            _transfer(from, to3, amount3, false);
+        }
+    }
+
+    /// @dev distribute tokens from a wallet within the scope of gif to an external address.
+    /// This method also checks balance and allowance and makes sure the amount is greater than zero.
+    function distributeTokens(
+        address from,
+        address to,
+        Amount amount
+    )
+        external
+        restricted()
+    {
+        _transfer(from, to, amount, true);
+    }
+
+    function _transfer(
+        address from,
+        address to,
+        Amount amount,
+        bool checkPreconditions
+    )
+        internal
+    {
+        if (checkPreconditions) {
+            // check amount > 0, balance >= amount and allowance >= amount
+            _checkPreconditions(from, amount);
+        }
+
+        // transfer the tokens
+        emit LogTokenHandlerTokenTransfer(address(_token), from, to, amount.toInt());
+        SafeERC20.safeTransferFrom(
+            _token, 
+            from, 
+            to, 
+            amount.toInt());
+    }
+
+    function _checkPreconditions(
+        address from,
+        Amount amount
+    ) 
+        internal
+        view
+    {
+        // amount must be greater than zero
+        if (amount.eqz()) {
+            revert ErrorTokenHandlerAmountIsZero();
+        }
+
+        // balance must be >= amount
+        uint256 balance = _token.balanceOf(from);
+        if (balance < amount.toInt()) {
+            revert ErrorTokenHandlerBalanceTooLow(address(_token), from, balance, amount.toInt());
+        }
+
+        // allowance must be >= amount
+        uint256 allowance = _token.allowance(from, address(this));
+        if (allowance < amount.toInt()) {
+            revert ErrorTokenHandlerAllowanceTooSmall(address(_token), from, address(this), allowance, amount.toInt());
+        }
+    }
+}

package/contracts/shared/TokenHandlerDeployerLib.sol

@@ -0,0 +1,12 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {TokenHandler} from "./TokenHandler.sol";
+
+library TokenHandlerDeployerLib {
+
+    function deployTokenHandler(address token, address authority) public returns (TokenHandler) {
+        return new TokenHandler(address(token), authority);
+    }
+
+}

package/contracts/staking/IStaking.sol

@@ -0,0 +1,168 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Amount} from "../type/Amount.sol";
+import {IComponent} from "../shared/IComponent.sol";
+import {IVersionable} from "../upgradeability/IVersionable.sol";
+import {NftId} from "../type/NftId.sol";
+import {ObjectType} from "../type/ObjectType.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {StakingReader} from "./StakingReader.sol";
+import {StakingStore} from "./StakingStore.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+import {UFixed} from "../type/UFixed.sol";
+
+interface IStaking is 
+    IComponent,
+    IVersionable
+{
+    // staking rate
+    event LogStakingStakingRateSet(uint256 chainId, address token, UFixed oldStakingRate, UFixed newStakingRate);
+
+    // target parameters
+    event LogStakingLockingPeriodSet(NftId targetNftId, Seconds oldLockingPeriod, Seconds lockingPeriod);
+    event LogStakingRewardRateSet(NftId targetNftId, UFixed oldRewardRate, UFixed rewardRate);
+
+    // modifiers
+    error ErrorStakingNotStake(NftId stakeNftId);
+    error ErrorStakingNotTarget(NftId targetNftId);
+
+    error ErrorStakingNotStakingOwner();
+    error ErrorStakingNotNftOwner(NftId nftId);
+
+    // staking rate
+    error ErrorStakingTokenNotRegistered(uint256 chainId, address token);
+
+    // check dip balance and allowance
+    error ErrorStakingDipBalanceInsufficient(address owner, uint256 amount, uint256 dipBalance);
+    error ErrorStakingDipAllowanceInsufficient(address owner, address tokenHandler, uint256 amount, uint256 dipAllowance);
+
+    error ErrorStakingStakingReaderStakingMismatch(address stakingByStakingReader);
+    error ErrorStakingTargetAlreadyRegistered(NftId targetNftId);
+    error ErrorStakingTargetNftIdZero();
+    error ErrorStakingTargetTypeNotSupported(NftId targetNftId, ObjectType objectType);
+    error ErrorStakingTargetUnexpectedObjectType(NftId targetNftId, ObjectType expectedObjectType, ObjectType actualObjectType);
+    error ErrorStakingLockingPeriodTooShort(NftId targetNftId, Seconds minLockingPeriod, Seconds lockingPeriod);
+    error ErrorStakingLockingPeriodTooLong(NftId targetNftId, Seconds maxLockingPeriod, Seconds lockingPeriod);
+    error ErrorStakingStakeLocked(NftId stakeNftId, Timestamp lockedUntil);
+    error ErrorStakingRewardRateTooHigh(NftId targetNftId, UFixed maxRewardRate, UFixed rewardRate);
+    error ErrorStakingTargetNotFound(NftId targetNftId);
+    error ErrorStakingTargetTokenNotFound(NftId targetNftId, uint256 chainId, address token);
+
+    error ErrorStakingTargetNotActive(NftId targetNftId);
+    error ErrorStakingStakeAmountZero(NftId targetNftId);
+
+    // info for individual stake
+    struct StakeInfo {
+        Timestamp lockedUntil;
+    }
+
+    struct TargetInfo {
+        ObjectType objectType;
+        uint256 chainId;
+        Seconds lockingPeriod;
+        UFixed rewardRate;
+    }
+
+    // staking rate management 
+
+    /// @dev sets the rate that converts 1 token of total value locked into the
+    /// the required staked dip amount to back up the locked token value
+    function setStakingRate(uint256 chainId, address token, UFixed stakingRate) external;
+
+
+    // target management
+
+    function registerTarget(
+        NftId targetNftId,
+        ObjectType expectedObjectType,
+        uint256 chainId,
+        Seconds initialLockingPeriod,
+        UFixed initialRewardRate
+    ) external;
+
+
+    /// @dev set the stake locking period to the specified duration.
+    /// permissioned: only the staking service may call this function
+    function setLockingPeriod(NftId targetNftId, Seconds lockingPeriod) external;
+
+    /// @dev update the target specific reward rate.
+    /// permissioned: only the staking service may call this function
+    function setRewardRate(NftId targetNftId, UFixed rewardRate) external;
+
+    /// @dev (re)fills the staking reward reserves for the specified target
+    /// unpermissioned: anybody may fill up staking reward reserves
+    function refillRewardReserves(NftId targetNftId, Amount dipAmount) external returns (Amount newBalance);
+
+    /// @dev defunds the staking reward reserves for the specified target
+    /// permissioned: only the staking service may call this function
+    function withdrawRewardReserves(NftId targetNftId, Amount dipAmount) external returns (Amount newBalance);
+
+
+    /// @dev increases the total value locked amount for the specified target by the provided token amount.
+    /// function is called when a new policy is collateralized.
+    /// function restricted to the pool service.
+    function increaseTotalValueLocked(NftId targetNftId, address token, Amount amount) external returns (Amount newBalance);
+
+
+    /// @dev decreases the total value locked amount for the specified target by the provided token amount.
+    /// function is called when a new policy is closed or payouts are executed.
+    /// function restricted to the pool service.
+    function decreaseTotalValueLocked(NftId targetNftId, address token, Amount amount) external returns (Amount newBalance);
+
+
+    function updateRemoteTvl(NftId targetNftId, address token, Amount amount) external;
+
+    // staking functions
+
+    /// @dev creat a new stake info object
+    /// permissioned: only staking service may call this function.
+    function createStake(NftId stakeNftId, NftId targetNftId, Amount dipAmount) external;
+
+    /// @dev increase the staked dip by dipAmount for the specified stake.
+    /// staking rewards are updated and added to the staked dips as well.
+    /// the function returns the new total amount of staked dips.
+    function stake(NftId stakeNftId, Amount dipAmount) external returns (Amount stakeBalance);
+
+    /// @dev restakes the dips to a new target.
+    /// the sum of the staked dips and the accumulated rewards will be restaked.
+    /// permissioned: only staking service may call this function.
+    function restake(NftId stakeNftId, NftId newTargetNftId) external returns (NftId newStakeNftId);
+
+    /// @dev retuns the specified amount of dips to the holder of the specified stake nft.
+    /// if dipAmount is set to Amount.max() all staked dips and all rewards are transferred to 
+    /// permissioned: only staking service may call this function.
+    function unstake(NftId stakeNftId)
+        external
+        returns (
+            Amount unstakedAmount,
+            Amount rewardsClaimedAmount
+        );
+
+    /// @dev update stake rewards for current time.
+    /// may be called before an announement of a decrease of a reward rate reduction.
+    /// calling this functions ensures that reward balance is updated using the current (higher) reward rate.
+    /// unpermissioned.
+    function updateRewards(NftId stakeNftId) external;
+
+    /// @dev transfers all rewards accumulated so far to the holder of the specified stake nft.
+    /// permissioned: only staking service may call this function.
+    function claimRewards(NftId stakeNftId)
+        external
+        returns (
+            Amount rewardsClaimedAmount
+        );
+
+    //--- helper functions --------------------------------------------------//
+
+    /// @dev transfers the specified amount of dips from the from address to the staking wallet.
+    function collectDipAmount(address from, Amount dipAmount) external;
+
+    /// @dev transfers the specified amount of dips from the staking wallet to the to addess.
+    function transferDipAmount(address to, Amount dipAmount) external;
+
+    //--- view and pure functions -------------------------------------------//
+
+    function getStakingStore() external view returns (StakingStore stakingStore);
+    function getStakingReader() external view returns (StakingReader reader);
+}