@etherisc/gif-next 0.0.2-d64ea51-772 → 0.0.2-d67ce7f-686

package/contracts/type/NftIdSet.sol

@@ -0,0 +1,62 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {NftId} from "../type/NftId.sol";
+
+// based on https://github.com/OpenZeppelin/openzeppelin-contracts/blob/master/contracts/utils/structs/EnumerableSet.sol
+library LibNftIdSet {
+
+    struct Set {
+        NftId[] ids;
+        mapping(NftId nftid => uint256 index) at;
+    }
+
+    error ErrorNftIdSetAlreadyAdded(NftId nftId);
+    error ErrorNftIdSetNotInSet(NftId nftId);
+
+
+    function add(Set storage set, NftId nftId) external {
+        if (set.at[nftId] > 0) {
+            revert ErrorNftIdSetAlreadyAdded(nftId);
+        }
+
+        set.ids.push(nftId);
+        set.at[nftId] = set.ids.length;
+    }
+
+    function remove(Set storage set, NftId nftId) external {
+        uint256 nftIdIndex = set.at[nftId];
+
+        if (nftIdIndex == 0) {
+            revert ErrorNftIdSetNotInSet(nftId);
+        }
+
+        uint256 toDeleteIndex = nftIdIndex - 1;
+        uint256 lastIndex = set.ids.length - 1;
+
+        if (lastIndex != toDeleteIndex) {
+            NftId lastId = set.ids[lastIndex];
+            set.ids[toDeleteIndex] = lastId;
+            set.at[lastId] = nftIdIndex; // Replace lastValue's index to valueIndex
+        }
+
+        set.ids.pop();
+        delete set.at[nftId];
+    }
+
+    function isEmpty(Set storage set) external view returns(bool empty) {
+        return set.ids.length == 0;
+    }
+
+    function contains(Set storage set, NftId nftId) external view returns(bool inSet) {
+        return set.at[nftId] > 0;
+    }
+
+    function size(Set storage set) external view returns(uint256 length) {
+        return set.ids.length;
+    }
+
+    function getElementAt(Set storage set, uint256 index) external view returns(NftId nftId) {
+        return set.ids[index];
+    }
+}

package/contracts/type/ObjectType.sol

@@ -0,0 +1,271 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+type ObjectType is uint8;
+
+// type bindings
+using {
+    eqObjectType as ==,
+    neObjectType as !=,
+    ObjectTypeLib.toInt,
+    ObjectTypeLib.eqz,
+    ObjectTypeLib.gtz
+} for ObjectType global;
+
+
+//--- GIF object types/domains (rage: 1 - 99) -------------------------------//
+
+function PROTOCOL() pure returns (ObjectType) {
+    return ObjectType.wrap(1);
+}
+
+function REGISTRY() pure returns (ObjectType) {
+    return ObjectType.wrap(2);
+}
+
+function STAKING() pure returns (ObjectType) {
+    return ObjectType.wrap(3);
+}
+
+function RELEASE() pure returns (ObjectType) {
+    return ObjectType.wrap(6);
+}
+
+function ROLE() pure returns (ObjectType) {
+    return ObjectType.wrap(7);
+}
+
+function SERVICE() pure returns (ObjectType) {
+    return ObjectType.wrap(8);
+}
+
+function INSTANCE() pure returns (ObjectType) {
+    return ObjectType.wrap(10);
+}
+
+function COMPONENT() pure returns (ObjectType) {
+    return ObjectType.wrap(11);
+}
+
+function PRODUCT() pure returns (ObjectType) {
+    return ObjectType.wrap(12);
+}
+
+function ORACLE() pure returns (ObjectType) {
+    return ObjectType.wrap(13);
+}
+
+function DISTRIBUTION() pure returns (ObjectType) {
+    return ObjectType.wrap(14);
+}
+
+function POOL() pure returns (ObjectType) {
+    return ObjectType.wrap(15);
+}
+
+function APPLICATION() pure returns (ObjectType) {
+    return ObjectType.wrap(20);
+}
+
+function POLICY() pure returns (ObjectType) {
+    return ObjectType.wrap(21);
+}
+
+function CLAIM() pure returns (ObjectType) {
+    return ObjectType.wrap(22);
+}
+
+function PAYOUT() pure returns (ObjectType) {
+    return ObjectType.wrap(23); 
+}
+
+function RISK() pure returns (ObjectType) {
+    return ObjectType.wrap(24);
+}
+
+function PRICE() pure returns (ObjectType) {
+    return ObjectType.wrap(25);
+}
+
+function REQUEST() pure returns (ObjectType) {
+    return ObjectType.wrap(26);
+}
+
+function DISTRIBUTOR_TYPE() pure returns (ObjectType) {
+    return ObjectType.wrap(27);
+}
+
+function DISTRIBUTOR() pure returns (ObjectType) {
+    return ObjectType.wrap(28);
+}
+
+function REFERRAL() pure returns (ObjectType) {
+    return ObjectType.wrap(29);
+}
+
+function BUNDLE() pure returns (ObjectType) {
+    return ObjectType.wrap(30);
+}
+
+function TARGET() pure returns (ObjectType) {
+    return ObjectType.wrap(31);
+}
+
+function STAKE() pure returns (ObjectType) {
+    return ObjectType.wrap(32);
+}
+
+/// @dev Object type that includes any other object type.
+/// Note that eq()/'==' does not take this property into account.
+function ALL() pure returns (ObjectType) {
+    return ObjectType.wrap(99);
+}
+
+// other pure free functions for operators
+function eqObjectType(ObjectType a, ObjectType b) pure returns (bool isSame) {
+    return ObjectType.unwrap(a) == ObjectType.unwrap(b);
+}
+
+function neObjectType(ObjectType a, ObjectType b) pure returns (bool isSame) {
+    return ObjectType.unwrap(a) != ObjectType.unwrap(b);
+}
+
+// library functions that operate on user defined type
+library ObjectTypeLib {
+
+    error ErrorVersionTooBig(uint256 version);
+
+    function zero() public pure returns (ObjectType) {
+        return ObjectType.wrap(0);
+    }
+
+    /// @dev Converts the uint256 into ObjectType.
+    function toObjectType(uint256 objectType) public pure returns (ObjectType) {
+        return ObjectType.wrap(uint8(objectType));
+    }
+
+    /// @dev Converts the NftId to a uint256.
+    function toInt(ObjectType objectType) public pure returns (uint96) {
+        return uint96(ObjectType.unwrap(objectType));
+    }
+
+    /// @dev Returns true if the value is non-zero (> 0).
+    function gtz(ObjectType a) public pure returns (bool) {
+        return ObjectType.unwrap(a) > 0;
+    }
+
+    /// @dev Returns true if the value is zero (== 0).
+    function eqz(ObjectType a) public pure returns (bool) {
+        return ObjectType.unwrap(a) == 0;
+    }
+
+    /// @dev Returns true if the values are equal (==).
+    function eq(ObjectType a, ObjectType b) public pure returns (bool isSame) {
+        return ObjectType.unwrap(a) == ObjectType.unwrap(b);
+    }
+
+    /// @dev Returns true if the values are not equal (!=).
+    function ne(ObjectType a, ObjectType b) public pure returns (bool isSame) {
+        return ObjectType.unwrap(a) != ObjectType.unwrap(b);
+    }
+
+    /// @dev Returns the type/domain name for the provided object type
+    function toName(ObjectType objectType) public pure returns (string memory name) {
+        if (objectType == REGISTRY()) {
+            return "Registry";
+        } else if (objectType == STAKING()) {
+            return "Staking";
+        } else if (objectType == INSTANCE()) {
+            return "Instance";
+        } else if (objectType == COMPONENT()) {
+            return "Component";
+        } else if (objectType == PRODUCT()) {
+            return "Product";
+        } else if (objectType == ORACLE()) {
+            return "Oracle";
+        } else if (objectType == DISTRIBUTION()) {
+            return "Distribution";
+        } else if (objectType == POOL()) {
+            return "Pool";
+        } else if (objectType == APPLICATION()) {
+            return "Application";
+        } else if (objectType == POLICY()) {
+            return "Policy";
+        } else if (objectType == CLAIM()) {
+            return "Claim";
+        } else if (objectType == PRICE()) {
+            return "Price";
+        } else if (objectType == BUNDLE()) {
+            return "Bundle";
+        }
+
+        // fallback: ObjectType<obect-type-int>
+        return string(
+            abi.encodePacked(
+                "ObjectType",
+                toString(
+                    toInt(objectType))));
+    }
+
+    function toVersionedName(
+        string memory name, 
+        string memory suffix, 
+        uint256 version
+    )
+        external
+        pure
+        returns (string memory versionedName)
+    {
+        if (version > maxNumReleases()) {
+            revert ErrorVersionTooBig(version);
+        }
+
+        string memory versionName = "_v0";
+
+        if (version >= 10) {
+            versionName = "_v";
+        }
+
+        versionedName = string(
+            abi.encodePacked(
+                name,
+                suffix,
+                versionName,
+                toString(version)));
+    }
+
+    /// @dev returns the max number of releases (major versions) this gif setup can handle.
+    function maxNumReleases() public pure returns (uint8) {
+        return 99;
+    }
+
+    /// @dev returns the provied int as a string
+    function toString(uint256 value) public pure returns (string memory name) {
+
+        if (value == 0) {
+            return "0";
+        }
+
+        uint256 temp = value;
+        uint256 digits = 0;
+        while (temp != 0) {
+            digits++;
+            temp /= 10;
+        }
+
+        bytes memory buffer = new bytes(digits);
+        uint index = digits - 1;
+
+        temp = value;
+        while (temp != 0) {
+            buffer[index] = bytes1(uint8(48 + temp % 10));
+            temp /= 10;
+
+            if (index > 0) {
+                index--;
+            }
+        }
+
+        return string(buffer);
+    }
+}

package/contracts/type/PayoutId.sol

@@ -0,0 +1,82 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+// uint24 allows for 65'535 claims with 255 payouts each per policy
+type PayoutId is uint24;
+
+import {ClaimId} from "./ClaimId.sol";
+import {PAYOUT} from "./ObjectType.sol";
+import {Key32, KeyId, Key32Lib} from "./Key32.sol";
+import {NftId} from "./NftId.sol";
+
+// type bindings
+using {
+    eqPayoutId as ==, 
+    nePayoutId as !=, 
+    PayoutIdLib.eqz,
+    PayoutIdLib.gtz,
+    PayoutIdLib.toInt,
+    PayoutIdLib.toClaimId,
+    PayoutIdLib.toPayoutNo,
+    PayoutIdLib.toKey32
+} for PayoutId global;
+
+
+// pure free functions for operators
+function eqPayoutId(PayoutId a, PayoutId b) pure returns (bool isSame) {
+    return PayoutId.unwrap(a) == PayoutId.unwrap(b);
+}
+
+function nePayoutId(PayoutId a, PayoutId b) pure returns (bool isDifferent) {
+    return PayoutId.unwrap(a) != PayoutId.unwrap(b);
+}
+
+// library functions that operate on user defined type
+library PayoutIdLib {
+    /// @dev Converts the PayoutId to a uint.
+    function zero() public pure returns (PayoutId) {
+        return PayoutId.wrap(0);
+    }
+
+    /// @dev Converts an uint into a PayoutId.
+    function toPayoutId(ClaimId claimId, uint8 payoutNo) public pure returns (PayoutId) {
+        return PayoutId.wrap((ClaimId.unwrap(claimId) << 8) + payoutNo);
+    }
+
+    function toClaimId(PayoutId payoutId) public pure returns (ClaimId) {
+        return ClaimId.wrap(uint16(PayoutId.unwrap(payoutId) >> 8));
+    }
+
+    function toPayoutNo(PayoutId payoutId) public pure returns (uint8) {
+        return uint8(PayoutId.unwrap(payoutId) & 255);
+    }
+
+    /// @dev Converts the PayoutId to a uint.
+    function toInt(PayoutId a) public pure returns (uint24) {
+        return uint24(PayoutId.unwrap(a));
+    }
+
+    /// @dev Returns true if the value is non-zero (> 0).
+    function gtz(PayoutId a) public pure returns (bool) {
+        return PayoutId.unwrap(a) > 0;
+    }
+
+    /// @dev Returns true if the value is zero (== 0).
+    function eqz(PayoutId a) public pure returns (bool) {
+        return PayoutId.unwrap(a) == 0;
+    }
+
+    /// @dev Converts the PayoutId and NftId to a Key32.
+    function toKey32(PayoutId payoutId, NftId policyNftId) public pure returns (Key32) {
+        return Key32Lib.toKey32(PAYOUT(), toKeyId(payoutId, policyNftId));
+    }
+
+    /// @dev Converts the PayoutId and NftId to a Key32.
+    function toKeyId(PayoutId payoutId, NftId policyNftId) public pure returns (KeyId) {
+        return KeyId.wrap(
+            bytes31(
+                bytes15(
+                    uint120(
+                        (NftId.unwrap(policyNftId) << 24) + PayoutId.unwrap(payoutId)))));
+    }
+}

package/contracts/{types → type}/Referral.sol

@@ -1,5 +1,5 @@
 // SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
+pragma solidity ^0.8.20;
 
 import {Key32, KeyId, Key32Lib} from "./Key32.sol";
 import {NftId} from "./NftId.sol";
@@ -12,6 +12,7 @@ type ReferralStatus is uint8;
 using {
     eqReferralId as ==, 
     neReferralId as !=,
+    ReferralLib.eqz,
     ReferralLib.toKey32
 } for ReferralId global;
 
@@ -82,4 +83,8 @@ library ReferralLib {
     function toKeyId(ReferralId id) public pure returns (KeyId keyId) {
         return KeyId.wrap(bytes31(ReferralId.unwrap(id)));
     }
+
+    function eqz(ReferralId id) public pure returns (bool) {
+        return eqReferralId(id, zero());
+    }
 }

package/contracts/type/RequestId.sol

@@ -0,0 +1,75 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Key32, KeyId, Key32Lib} from "./Key32.sol";
+import {REQUEST} from "./ObjectType.sol";
+
+type RequestId is uint64;
+
+// type bindings
+using {
+    eqRequestId as ==, 
+    neRequestId as !=,
+    RequestIdLib.eqz,
+    RequestIdLib.gtz,
+    RequestIdLib.toInt,
+    RequestIdLib.toKey32
+} for RequestId global;
+
+// general pure free functions
+
+function eqRequestId(RequestId a, RequestId b) pure returns (bool isSame) {
+    return RequestIdLib.eq(a, b);
+}
+
+function neRequestId(RequestId a, RequestId b) pure returns (bool isSame) {
+    return RequestIdLib.ne(a, b);
+}
+
+library RequestIdLib {
+
+    // @dev zero element to refer to a non existing/initialized request
+    function zero() public pure returns (RequestId) {
+        return RequestId.wrap(0);
+    }
+
+    // @dev Converts an int id into a request id.
+    function toRequestId(uint256 id) public pure returns (RequestId) {
+        return RequestId.wrap(uint64(id));
+    }
+
+    // @dev Converts a request id back to an int value.
+    function toInt(RequestId requestId) public pure returns (uint256) {
+        return RequestId.unwrap(requestId);
+    }
+
+    // @dev Returns true iff request id a == 0
+    function eqz(RequestId a) public pure returns (bool) {
+        return RequestId.unwrap(a) == 0;
+    }
+
+    // @dev Returns true iff request id a > 0
+    function gtz(RequestId a) public pure returns (bool) {
+        return RequestId.unwrap(a) > 0;
+    }
+
+    // @dev Returns true iff risk ids a and b are identical
+    function eq(RequestId a, RequestId b) public pure returns (bool isSame) {
+        return RequestId.unwrap(a) == RequestId.unwrap(b);
+    }
+
+    // @dev Returns true iff risk ids a and b are different
+    function ne(RequestId a, RequestId b) public pure returns (bool isSame) {
+        return RequestId.unwrap(a) != RequestId.unwrap(b);
+    }
+
+    /// @dev Returns the key32 value for the specified nft id and object type.
+    function toKey32(RequestId id) public pure returns (Key32 key) {
+        return Key32Lib.toKey32(REQUEST(), toKeyId(id));
+    }
+
+    /// @dev Returns the key id value for the specified nft id
+    function toKeyId(RequestId id) public pure returns (KeyId keyId) {
+        return KeyId.wrap(bytes31(uint248(RequestId.unwrap(id))));
+    }
+}

package/contracts/{types → type}/RiskId.sol

@@ -1,5 +1,5 @@
 // SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
+pragma solidity ^0.8.20;
 
 import {Key32, KeyId, Key32Lib} from "./Key32.sol";
 import {RISK} from "./ObjectType.sol";

package/contracts/type/RoleId.sol

@@ -0,0 +1,174 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Key32, KeyId, Key32Lib} from "./Key32.sol";
+import {ObjectType, ROLE} from "./ObjectType.sol";
+import {VersionPart} from "./Version.sol";
+
+type RoleId is uint64;
+
+// type bindings
+using {
+    eqRoleId as ==, 
+    neRoleId as !=,
+    RoleIdLib.eqz,
+    RoleIdLib.gtz,
+    RoleIdLib.toInt
+    // RoleIdLib.toKey32
+} for RoleId global;
+
+// general pure free functions
+
+// @dev Returns true iff role ids a and b are identical
+function eqRoleId(RoleId a, RoleId b) pure returns (bool isSame) {
+    return RoleId.unwrap(a) == RoleId.unwrap(b);
+}
+
+// @dev Returns true iff role ids a and b are different
+function neRoleId(RoleId a, RoleId b) pure returns (bool isDifferent) {
+    return RoleId.unwrap(a) != RoleId.unwrap(b);
+}
+
+//--- OpenZeppelin provided roles -------------------------------------------//
+
+/// @dev Role ID needs to match with oz AccessManager.ADMIN_ROLE
+function ADMIN_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(type(uint64).min); }
+
+/// @dev Role ID needs to match with oz AccessManager.PUBLIC_ROLE
+function PUBLIC_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(type(uint64).max); }
+
+//--- GIF roles (range: 1-99) ----------------------------------------------//
+
+/// @dev cental role for gif release management.
+/// this role is necessary to call ReleaseManager.createNextRelease/activateNextRelease
+/// the actual deployment of a release requires the GIF_MANAGER_ROLE.
+/// GIF_ADMIN_ROLE is the admin of the GIF_MANAGER_ROLE.
+/// only a single holder may hold this role at any time
+function GIF_ADMIN_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(1); } 
+
+/// @dev role for token whith/blacklisting, deploying and registering the services for a new major release
+/// registering services for a new major release is only possible after a new initial release has been created by the GIF_ADMIN_ROLE
+/// token white/blacklisting is possible for any active release
+function GIF_MANAGER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(2); } 
+
+/// @dev role for registering remote staking targets and reporting remote total value locked amounts.
+function GIF_REMOTE_MANAGER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(3); } 
+
+/// @dev instance specific  role to register/own a product component
+function PRODUCT_OWNER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(11); }
+
+/// @dev instance specific  role to register/own an oracle component
+function ORACLE_OWNER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(12); }
+
+/// @dev instance specific role to register/own a distribution component
+function DISTRIBUTION_OWNER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(13); }
+
+/// @dev instance specific  role to register/own a pool component
+function POOL_OWNER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(14); }
+
+//--- GIF core contract roles (range: 200 - 9'900) --------------------------//
+// created and assigned during initial deployment for registry and staking
+// granting for instances and components in instance service
+// object type * 100 + 0, examples:
+// - registry contract role: 200 
+// - staking contract role: 300 
+// - instance contract role: 1000
+
+//--- GIF service roles (range 201 - 9'9xx) ---------------------------------//
+// created and assigned by release manager contract
+// object type * 100 + 1/major version, examples:
+// - registry service role (any version): 299
+// - registry service role (version 3): 203
+// - registry service role (any version): 399
+// - staking service role: (version 3): 303
+// - application service role (version 3): 2003
+
+//--- GIF component contract roles (range 12'001 - 19'099) ------------------//
+// assigned at component registration time
+// object type * 1000 + instane specific component counter
+// on any instance a maximum number of 999 components may be deployed
+// examples:
+// - 1st pool on instance: 15001
+// - 1st distribution on instance: 14002
+// - 1st product on instance: 12003
+// - 2nd pool on instance: 15004
+// - 2nd distribution on instance: 14005
+// - 2nd product on instance: 12006
+
+
+//--- Custom roles (range >= 1'000'000) -------------------------------------//
+
+function CUSTOM_ROLE_MIN() pure returns (RoleId) { return RoleIdLib.toRoleId(1000000); }
+
+library RoleIdLib {
+
+    uint64 public constant ALL_VERSIONS = 99;
+    uint64 public constant SERVICE_DOMAIN_ROLE_FACTOR = 100;
+    uint64 public constant COMPONENT_ROLE_FACTOR = 100;
+    uint64 public constant CUSTOM_ROLE_MIN = 1000000;
+
+    /// @dev Converts the RoleId to a uint.
+    function zero() public pure returns (RoleId) {
+        return RoleId.wrap(0);
+    }
+
+    /// @dev Converts an uint into a role id.
+    function toRoleId(uint64 a) public pure returns (RoleId) {
+        return RoleId.wrap(a);
+    }
+
+    /// @dev Converts an uint into a component role id.
+    function toComponentRoleId(ObjectType objectType, uint64 index) public pure returns (RoleId) {
+        return toRoleId(COMPONENT_ROLE_FACTOR * uint64(objectType.toInt()) + index);
+    }
+
+    /// @dev Converts an uint into a custom role id.
+    function toCustomRoleId(uint64 index) public pure returns (RoleId) {
+        return toRoleId(CUSTOM_ROLE_MIN + index);
+    }
+
+    /// @dev Converts the role id to a uint.
+    function toInt(RoleId a) public pure returns (uint64) {
+        return uint64(RoleId.unwrap(a));
+    }
+
+    /// @dev Converts an uint into a role id.
+    /// Used for GIF core contracts.
+    function roleForType(ObjectType objectType) public pure returns (RoleId) {
+        return RoleId.wrap(SERVICE_DOMAIN_ROLE_FACTOR * uint64(objectType.toInt()));
+    }
+
+    /// @dev Converts an uint into a RoleId.
+    /// Used for GIF core contracts.
+    function roleForTypeAndVersion(ObjectType objectType, VersionPart majorVersion) public pure returns (RoleId) {
+        return RoleId.wrap(
+            uint64(SERVICE_DOMAIN_ROLE_FACTOR * objectType.toInt() + majorVersion.toInt()));
+    }
+
+    /// @dev Converts an uint into a RoleId.
+    /// Used for GIF core contracts.
+    function roleForTypeAndAllVersions(ObjectType objectType) public pure returns (RoleId) {
+        return RoleId.wrap(
+            uint64(SERVICE_DOMAIN_ROLE_FACTOR * objectType.toInt() + ALL_VERSIONS));
+    }
+
+    /// @dev Returns true if the value is non-zero (> 0).
+    function gtz(RoleId a) public pure returns (bool) {
+        return RoleId.unwrap(a) > 0;
+    }
+
+    /// @dev Returns true if the value is zero (== 0).
+    function eqz(RoleId a) public pure returns (bool) {
+        return RoleId.unwrap(a) == 0;
+    }
+
+    /// @dev Returns the key32 value for the specified id and object type.
+    function toKey32(RoleId a) public pure returns (Key32 key) {
+        return Key32Lib.toKey32(ROLE(), toKeyId(a));
+    }
+
+    /// @dev Returns the key id value for the specified id
+    function toKeyId(RoleId a) public pure returns (KeyId keyId) {
+        return KeyId.wrap(bytes31(uint248(RoleId.unwrap(a))));
+    }
+}