@etherisc/gif-next 0.0.2-d5b7b78-706 → 0.0.2-d5fac82-078

package/contracts/product/PricingService.sol

@@ -0,0 +1,276 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Seconds} from "../type/Seconds.sol";
+import {UFixed, UFixedLib} from "../type/UFixed.sol";
+import {ObjectType} from "../type/ObjectType.sol";
+import {NftId} from "../type/NftId.sol";
+import {Fee} from "../type/Fee.sol";
+import {ReferralId} from "../type/Referral.sol";
+import {RiskId} from "../type/RiskId.sol";
+import {PRODUCT, DISTRIBUTION, PRICE} from "../type/ObjectType.sol";
+import {Amount} from "../type/Amount.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+
+import {IProductComponent} from "./IProductComponent.sol";
+
+import {IInstance} from "../instance/IInstance.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {IComponents} from "../instance/module/IComponents.sol";
+import {IPolicy} from "../instance/module/IPolicy.sol";
+import {IBundle} from "../instance/module/IBundle.sol";
+import {ISetup} from "../instance/module/ISetup.sol";
+import {IDistribution} from "../instance/module/IDistribution.sol";
+
+import {ComponentService} from "../shared/ComponentService.sol";
+
+import {IPricingService} from "./IPricingService.sol";
+import {IDistributionService} from "../distribution/IDistributionService.sol";
+
+
+contract PricingService is 
+    ComponentService, 
+    IPricingService
+{
+    using UFixedLib for UFixed;
+
+    IDistributionService internal _distributionService;
+
+
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        virtual override
+        initializer()
+    {
+        (
+            address registryAddress,, 
+            //address managerAddress
+            address authority
+        ) = abi.decode(data, (address, address, address));
+
+        initializeService(registryAddress, authority, owner);
+        registerInterface(type(IPricingService).interfaceId);
+
+        _distributionService = IDistributionService(_getServiceAddress(DISTRIBUTION()));
+    }
+
+
+    function getDomain() public pure override returns(ObjectType) {
+        return PRICE();
+    }
+
+    /// @dev calculates the premium amount for the specified attributes
+    /// also returns the various fee components involved with creating a policy
+    function calculatePremium(
+        NftId productNftId,
+        RiskId riskId,
+        Amount sumInsuredAmount,
+        Seconds lifetime,
+        bytes memory applicationData,
+        NftId bundleNftId,
+        ReferralId referralId
+    )
+        external
+        view
+        virtual override
+        returns (
+            IPolicy.Premium memory premium
+        )
+    {
+        InstanceReader reader;
+        Amount netPremiumAmount;
+
+        {
+            // verify product
+            (
+                IRegistry.ObjectInfo memory productInfo, 
+                IInstance instance
+            ) = _getAndVerifyComponentInfoAndInstance(productNftId, PRODUCT());
+
+            reader = instance.getInstanceReader();
+
+            // calculate net premium
+            netPremiumAmount = IProductComponent(productInfo.objectAddress).calculateNetPremium(
+                sumInsuredAmount,
+                riskId,
+                lifetime,
+                applicationData
+            );
+        }
+
+        {
+            // get configurations for all involed objects
+            ISetup.ProductSetupInfo memory productSetup = reader.getProductSetupInfo(productNftId);
+
+            bytes memory componentData = reader.getComponentInfo(productSetup.poolNftId).data;
+            IComponents.PoolInfo memory poolInfo = abi.decode(componentData, (IComponents.PoolInfo));
+
+            IBundle.BundleInfo memory bundleInfo = reader.getBundleInfo(bundleNftId);
+            if(bundleInfo.poolNftId != productSetup.poolNftId) {
+                revert ErrorIPricingServiceBundlePoolMismatch(bundleNftId, bundleInfo.poolNftId, productSetup.poolNftId);
+            }
+
+            NftId distributionNftId = productSetup.distributionNftId;
+            ISetup.DistributionSetupInfo memory distSetup = reader.getDistributionSetupInfo(distributionNftId);
+
+            // calculate premium, order is important
+            premium = _getFixedFeeAmounts(
+                netPremiumAmount,
+                productSetup,
+                poolInfo,
+                distSetup,
+                bundleInfo
+            );
+
+            premium = _calculateVariableFeeAmounts(
+                premium,
+                productSetup,
+                poolInfo,
+                distSetup,
+                bundleInfo
+            );
+
+            premium = _calculateDistributionOwnerFeeAmount(
+                premium,
+                distSetup,
+                referralId,
+                distributionNftId,
+                reader
+            );
+
+            // sanity check to validate the fee calculation
+            if (premium.distributionOwnerFeeFixAmount < distSetup.minDistributionOwnerFee.fixedFee) {
+                revert ErrorIPricingServiceFeeCalculationMismatch( 
+                    premium.distributionFeeFixAmount,
+                    premium.distributionFeeVarAmount,
+                    premium.distributionOwnerFeeFixAmount,
+                    premium.distributionOwnerFeeVarAmount,
+                    premium.commissionAmount,
+                    premium.discountAmount
+                );
+            }
+
+            if ((premium.distributionFeeVarAmount) != (premium.discountAmount + premium.distributionOwnerFeeVarAmount + premium.commissionAmount)) {
+                revert ErrorIPricingServiceFeeCalculationMismatch(
+                    premium.distributionFeeFixAmount,
+                    premium.distributionFeeVarAmount,
+                    premium.distributionOwnerFeeFixAmount,
+                    premium.distributionOwnerFeeVarAmount,
+                    premium.commissionAmount,
+                    premium.discountAmount
+                );
+            }
+        }
+    }
+
+    // internal functions
+    function _getFixedFeeAmounts(
+        Amount netPremiumAmount,
+        ISetup.ProductSetupInfo memory productInfo,
+        IComponents.PoolInfo memory poolInfo,
+        ISetup.DistributionSetupInfo memory distInfo,
+        IBundle.BundleInfo memory bundleInfo
+    )
+        internal
+        view
+        returns (
+            IPolicy.Premium memory premium
+        )
+    {
+        // initial premium amount is the net premium
+        premium.netPremiumAmount = netPremiumAmount.toInt();
+        premium.fullPremiumAmount = netPremiumAmount.toInt();
+
+        uint256 t = productInfo.productFee.fixedFee;
+        premium.productFeeFixAmount = t;
+        premium.fullPremiumAmount += t;
+
+        t = poolInfo.poolFee.fixedFee;
+        premium.poolFeeFixAmount = t;
+        premium.fullPremiumAmount += t;
+
+        t = bundleInfo.fee.fixedFee;
+        premium.bundleFeeFixAmount = t;
+        premium.fullPremiumAmount += t;
+
+        t = distInfo.distributionFee.fixedFee;
+        premium.distributionFeeFixAmount = t;
+        premium.fullPremiumAmount += t;
+    }
+
+    function _calculateVariableFeeAmounts(
+        IPolicy.Premium memory premium,
+        ISetup.ProductSetupInfo memory productInfo,
+        IComponents.PoolInfo memory poolInfo,
+        ISetup.DistributionSetupInfo memory distInfo,
+        IBundle.BundleInfo memory bundleInfo
+    )
+        internal
+        view
+        returns (
+            IPolicy.Premium memory intermadiatePremium
+        )
+    {
+        UFixed netPremiumAmount = UFixedLib.toUFixed(premium.netPremiumAmount);
+
+        uint256 t = (netPremiumAmount * productInfo.productFee.fractionalFee).toInt();
+        premium.productFeeVarAmount = t;
+        premium.fullPremiumAmount += t;
+
+        t = (netPremiumAmount * poolInfo.poolFee.fractionalFee).toInt();
+        premium.poolFeeVarAmount = t;
+        premium.fullPremiumAmount += t;
+
+        t = (netPremiumAmount * bundleInfo.fee.fractionalFee).toInt();
+        premium.bundleFeeVarAmount = t;
+        premium.fullPremiumAmount += t;
+
+        t = (netPremiumAmount * distInfo.distributionFee.fractionalFee).toInt();
+        premium.distributionFeeVarAmount = t;
+        premium.fullPremiumAmount += t;
+
+        return premium;
+    }
+
+    function _calculateDistributionOwnerFeeAmount(
+        IPolicy.Premium memory premium,
+        ISetup.DistributionSetupInfo memory distInfo,
+        ReferralId referralId,
+        NftId distributionNftId,
+        InstanceReader reader
+    )
+        internal
+        view 
+        returns (IPolicy.Premium memory finalPremium)
+    {
+        // if the referral is not valid, then the distribution owner gets everything
+        if (! _distributionService.referralIsValid(distributionNftId, referralId)) {
+            premium.distributionOwnerFeeFixAmount = premium.distributionFeeFixAmount;
+            premium.distributionOwnerFeeVarAmount = premium.distributionFeeVarAmount;
+            premium.premiumAmount = premium.fullPremiumAmount;
+            return premium;
+        }
+
+        Fee memory minDistributionOwnerFee = distInfo.minDistributionOwnerFee;
+
+        // if the referral is valid, the the commission and discount are calculated based in the full premium
+        // the remaing amount goes to the distribution owner
+        {
+            IDistribution.ReferralInfo memory referralInfo = reader.getReferralInfo(referralId);
+            IDistribution.DistributorInfo memory distributorInfo = reader.getDistributorInfo(referralInfo.distributorNftId);
+            IDistribution.DistributorTypeInfo memory distributorTypeInfo = reader.getDistributorTypeInfo(distributorInfo.distributorType);
+
+            uint256 commissionAmount = UFixedLib.toUFixed(premium.netPremiumAmount).mul(distributorTypeInfo.commissionPercentage).toInt();
+            premium.commissionAmount = commissionAmount;
+            premium.discountAmount = UFixedLib.toUFixed(premium.fullPremiumAmount).mul(referralInfo.discountPercentage).toInt();
+            premium.distributionOwnerFeeFixAmount = distInfo.minDistributionOwnerFee.fixedFee;
+            premium.distributionOwnerFeeVarAmount = premium.distributionFeeVarAmount - commissionAmount - premium.discountAmount;
+            premium.premiumAmount = premium.fullPremiumAmount - premium.discountAmount;
+        }
+
+        return premium; 
+    }
+}

package/contracts/product/PricingServiceManager.sol

@@ -0,0 +1,42 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IVersionable} from "../shared/IVersionable.sol";
+import {ProxyManager} from "../shared/ProxyManager.sol";
+import {PricingService} from "./PricingService.sol";
+import {Registry} from "../registry/Registry.sol";
+import {RegistryService} from "../registry/RegistryService.sol";
+import {REGISTRY} from "../type/ObjectType.sol";
+
+contract PricingServiceManager is ProxyManager {
+
+    PricingService private _pricingService;
+
+    /// @dev initializes proxy manager with pricing service implementation and deploys instance
+    constructor(
+        address authority, 
+        address registryAddress,
+        bytes32 salt
+    )
+        ProxyManager(registryAddress)
+    {
+        PricingService pricingSrv = new PricingService{salt: salt}();
+        bytes memory data = abi.encode(registryAddress, address(this), authority);
+        IVersionable versionable = deployDetermenistic(
+            address(pricingSrv), 
+            data,
+            salt);
+
+        _pricingService = PricingService(address(versionable));
+    }
+
+    //--- view functions ----------------------------------------------------//
+    function getPricingService()
+        external
+        view
+        returns (PricingService)
+    {
+        return _pricingService;
+    }
+
+}

package/contracts/{components → product}/Product.sol

@@ -3,21 +3,25 @@ pragma solidity ^0.8.19;
 
 import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
 
+import {Amount, AmountLib} from "../type/Amount.sol";
+import {ClaimId} from "../type/ClaimId.sol";
+import {Component} from "../shared/Component.sol";
+import {Fee} from "../type/Fee.sol";
 import {IRisk} from "../instance/module/IRisk.sol";
-import {IApplicationService} from "../instance/service/IApplicationService.sol";
-import {IPolicyService} from "../instance/service/IPolicyService.sol";
-import {IProductService} from "../instance/service/IProductService.sol";
-import {IClaimService} from "../instance/service/IClaimService.sol";
+import {IApplicationService} from "./IApplicationService.sol";
+import {IPolicyService} from "./IPolicyService.sol";
+import {IProductService} from "./IProductService.sol";
+import {IClaimService} from "./IClaimService.sol";
+import {IPricingService} from "./IPricingService.sol";
 import {IProductComponent} from "./IProductComponent.sol";
-import {NftId, NftIdLib} from "../types/NftId.sol";
-import {PRODUCT, APPLICATION, POLICY, CLAIM } from "../types/ObjectType.sol";
-import {ReferralId} from "../types/Referral.sol";
-import {RiskId, RiskIdLib} from "../types/RiskId.sol";
-import {Seconds} from "../types/Seconds.sol";
-import {StateId} from "../types/StateId.sol";
-import {Timestamp} from "../types/Timestamp.sol";
-import {Fee} from "../types/Fee.sol";
-import {Component} from "./Component.sol";
+import {NftId, NftIdLib} from "../type/NftId.sol";
+import {PayoutId} from "../type/PayoutId.sol";
+import {PRODUCT, APPLICATION, POLICY, CLAIM, PRICE } from "../type/ObjectType.sol";
+import {ReferralId} from "../type/Referral.sol";
+import {RiskId, RiskIdLib} from "../type/RiskId.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {StateId} from "../type/StateId.sol";
+import {Timestamp} from "../type/Timestamp.sol";
 
 import {TokenHandler} from "../shared/TokenHandler.sol";
 
@@ -25,8 +29,8 @@ import {InstanceReader} from "../instance/InstanceReader.sol";
 import {IPolicy} from "../instance/module/IPolicy.sol";
 import {ISetup} from "../instance/module/ISetup.sol";
 import {IComponents} from "../instance/module/IComponents.sol";
-import {Pool} from "../components/Pool.sol";
-import {Distribution} from "../components/Distribution.sol";
+import {Pool} from "../pool/Pool.sol";
+import {Distribution} from "../distribution/Distribution.sol";
 
 abstract contract Product is
     Component, 
@@ -40,6 +44,7 @@ abstract contract Product is
         IApplicationService _applicationService;
         IPolicyService _policyService;
         IClaimService _claimService;
+        IPricingService _pricingService;
         Pool _pool;
         Distribution _distribution;
         Fee _initialProductFee;
@@ -70,11 +75,12 @@ abstract contract Product is
 
         ProductStorage storage $ = _getProductStorage();
         // TODO add validation
-        // TODO refactor to go via registry
+        // TODO refactor to go via registry ?
         $._productService = IProductService(_getServiceAddress(PRODUCT())); 
         $._applicationService = IApplicationService(_getServiceAddress(APPLICATION())); 
         $._policyService = IPolicyService(_getServiceAddress(POLICY())); 
         $._claimService = IClaimService(_getServiceAddress(CLAIM())); 
+        $._pricingService = IPricingService(_getServiceAddress(PRICE()));
         $._pool = Pool(pool);
         $._distribution = Distribution(distribution);
         $._initialProductFee = productFee;
@@ -86,50 +92,17 @@ abstract contract Product is
         registerInterface(type(IProductComponent).interfaceId);  
     }
 
-
-    function calculatePremium(
-        uint256 sumInsuredAmount,
-        RiskId riskId,
-        Seconds lifetime,
-        bytes memory applicationData,
-        NftId bundleNftId,
-        ReferralId referralId
-    )
-        external 
-        view 
-        override 
-        returns (uint256 premiumAmount)
-    {
-        IPolicy.Premium memory premium = _getProductStorage()._applicationService.calculatePremium(
-            getNftId(),
-            riskId,
-            sumInsuredAmount,
-            lifetime,
-            applicationData,
-            bundleNftId,
-            referralId
-        );
-        premiumAmount = premium.premiumAmount;
-    }
-
-
-    function calculateNetPremium(
-        uint256 sumInsuredAmount,
-        RiskId riskId,
-        Seconds lifetime,
-        bytes memory applicationData
+    // from product component
+    function setFees(
+        Fee memory productFee,
+        Fee memory processingFee
     )
         external
-        view
-        virtual override
-        returns (uint256 netPremiumAmount)
+        onlyOwner
+        restricted()
+        override
     {
-        // default 10% of sum insured
-        return sumInsuredAmount / 10;
-    }
-
-    function _toRiskId(string memory riskName) internal pure returns (RiskId riskId) {
-        return RiskIdLib.toRiskId(riskName);
+        _getProductService().setFees(productFee, processingFee);
     }
 
     function _createRisk(
@@ -169,7 +142,7 @@ abstract contract Product is
     function _createApplication(
         address applicationOwner,
         RiskId riskId,
-        uint256 sumInsuredAmount,
+        Amount sumInsuredAmount,
         Seconds lifetime,
         NftId bundleNftId,
         ReferralId referralId,
@@ -189,14 +162,14 @@ abstract contract Product is
         );
     }
 
-    function _underwrite(
+    function _collateralize(
         NftId policyNftId,
         bool requirePremiumPayment,
         Timestamp activateAt
     )
         internal
     {
-        _getProductStorage()._policyService.underwrite(
+        _getProductStorage()._policyService.collateralize(
             policyNftId, 
             requirePremiumPayment, 
             activateAt);
@@ -229,28 +202,141 @@ abstract contract Product is
     )
         internal
     {
-        _getProductStorage()._policyService.close(policyNftId);
+        _getProductStorage()._policyService.close(
+            policyNftId);
     }
 
-    function getPoolNftId() external view override returns (NftId poolNftId) {
-        return getRegistry().getNftId(address(_getProductStorage()._pool));
+    function _submitClaim(
+        NftId policyNftId,
+        Amount claimAmount,
+        bytes memory claimData
+    )
+        internal
+        returns(ClaimId)
+    {
+        return _getProductStorage()._claimService.submit(
+            policyNftId,
+            claimAmount,
+            claimData);
     }
 
-    function getDistributionNftId() external view override returns (NftId distributionNftId) {
-        return getRegistry().getNftId(address(_getProductStorage()._distribution));
+    function _confirmClaim(
+        NftId policyNftId,
+        ClaimId claimId,
+        Amount confirmedAmount,
+        bytes memory data
+    )
+        internal
+    {
+        _getProductStorage()._claimService.confirm(
+            policyNftId,
+            claimId,
+            confirmedAmount,
+            data);
     }
 
-    // from product component
-    function setFees(
-        Fee memory productFee,
-        Fee memory processingFee
+    function _declineClaim(
+        NftId policyNftId,
+        ClaimId claimId,
+        bytes memory data
+    )
+        internal
+    {
+        _getProductStorage()._claimService.decline(
+            policyNftId,
+            claimId,
+            data);
+    }
+
+    function _closeClaim(
+        NftId policyNftId,
+        ClaimId claimId
+    )
+        internal
+    {
+        _getProductStorage()._claimService.close(
+            policyNftId,
+            claimId);
+    }
+
+    function _createPayout(
+        NftId policyNftId,
+        ClaimId claimId,
+        Amount amount,
+        bytes memory data
+    )
+        internal
+        returns (PayoutId)
+    {
+        return _getProductStorage()._claimService.createPayout(
+            policyNftId, 
+            claimId, 
+            amount, 
+            data);
+    }
+
+    function _processPayout(
+        NftId policyNftId,
+        PayoutId payoutId
+    )
+        internal
+    {
+        _getProductStorage()._claimService.processPayout(
+            policyNftId,
+            payoutId);
+    }
+
+    function calculatePremium(
+        Amount sumInsuredAmount,
+        RiskId riskId,
+        Seconds lifetime,
+        bytes memory applicationData,
+        NftId bundleNftId,
+        ReferralId referralId
+    )
+        external 
+        view 
+        override 
+        returns (Amount premiumAmount)
+    {
+        IPolicy.Premium memory premium = _getProductStorage()._pricingService.calculatePremium(
+            getNftId(),
+            riskId,
+            sumInsuredAmount,
+            lifetime,
+            applicationData,
+            bundleNftId,
+            referralId
+        );
+
+        return AmountLib.toAmount(premium.premiumAmount);
+    }
+
+    function calculateNetPremium(
+        Amount sumInsuredAmount,
+        RiskId riskId,
+        Seconds lifetime,
+        bytes memory applicationData
     )
         external
-        onlyOwner
-        restricted()
-        override
+        view
+        virtual override
+        returns (Amount netPremiumAmount)
     {
-        _getProductService().setFees(productFee, processingFee);
+        // default 10% of sum insured
+        return AmountLib.toAmount(sumInsuredAmount.toInt() / 10);
+    }
+
+    function _toRiskId(string memory riskName) internal pure returns (RiskId riskId) {
+        return RiskIdLib.toRiskId(riskName);
+    }
+
+    function getPoolNftId() external view override returns (NftId poolNftId) {
+        return getRegistry().getNftId(address(_getProductStorage()._pool));
+    }
+
+    function getDistributionNftId() external view override returns (NftId distributionNftId) {
+        return getRegistry().getNftId(address(_getProductStorage()._distribution));
     }
 
     function getSetupInfo() public view returns (ISetup.ProductSetupInfo memory setupInfo) {
@@ -290,4 +376,4 @@ abstract contract Product is
     function _getProductService() internal view returns (IProductService) {
         return _getProductStorage()._productService;
     }
-}
+}