@etherisc/gif-next 0.0.2-d5522f6-712 → 0.0.2-d5fac82-078

package/contracts/shared/Component.sol

@@ -0,0 +1,271 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
+import {IAccessManaged} from "@openzeppelin/contracts/access/manager/IAccessManaged.sol";
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
+
+import {IComponent} from "./IComponent.sol";
+import {IComponents} from "../instance/module/IComponents.sol";
+import {IInstanceService} from "../instance/IInstanceService.sol";
+import {IInstance} from "../instance/IInstance.sol";
+import {InstanceAdmin} from "../instance/InstanceAdmin.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {NftId} from "../type/NftId.sol";
+import {ObjectType, INSTANCE, PRODUCT} from "../type/ObjectType.sol";
+import {VersionPart} from "../type/Version.sol";
+import {Registerable} from "../shared/Registerable.sol";
+import {RoleId, RoleIdLib} from "../type/RoleId.sol";
+import {IAccess} from "../instance/module/IAccess.sol";
+import {TokenHandler} from "../shared/TokenHandler.sol";
+import {VersionPart} from "../type/Version.sol";
+
+// TODO discuss to inherit from oz accessmanaged
+// then add (Distribution|Pool|Product)Upradeable that also intherit from Versionable
+// same pattern as for Service which is also upgradeable
+abstract contract Component is
+    Registerable,
+    IComponent,
+    AccessManagedUpgradeable
+{
+    // keccak256(abi.encode(uint256(keccak256("gif-next.contracts.component.Component.sol")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant COMPONENT_LOCATION_V1 = 0xffe8d4462baed26a47154f4b8f6db497d2f772496965791d25bd456e342b7f00;
+
+    struct ComponentStorage {
+        string _name; // unique (per instance) component name
+        IERC20Metadata _token; // token for this component
+        IInstance _instance; // instance for this component
+        address _wallet; // wallet for this component (default = component contract itself)
+        InstanceReader _instanceReader; // instance reader for this component
+        bool _isNftInterceptor; // declares if component is involved in nft transfers
+        NftId _productNftId; // only relevant for components that are linked to a aproduct
+    }
+
+    function _getComponentStorage() private pure returns (ComponentStorage storage $) {
+        assembly {
+            $.slot := COMPONENT_LOCATION_V1
+        }
+    }
+
+    modifier onlyChainNft() {
+        if(msg.sender != getRegistry().getChainNftAddress()) {
+            revert ErrorComponentNotChainNft(msg.sender);
+        }
+        _;
+    }
+
+    function initializeComponent(
+        address registry,
+        NftId instanceNftId,
+        string memory name,
+        address token,
+        ObjectType componentType,
+        bool isInterceptor,
+        address initialOwner,
+        bytes memory registryData // writeonly data that will saved in the object info record of the registry
+    )
+        public
+        virtual
+        onlyInitializing()
+    {
+        initializeRegisterable(registry, instanceNftId, componentType, isInterceptor, initialOwner, registryData);
+
+        // set and check linked instance
+        ComponentStorage storage $ = _getComponentStorage();
+        $._instance = IInstance(
+            getRegistry().getObjectInfo(instanceNftId).objectAddress);
+
+        if(!$._instance.supportsInterface(type(IInstance).interfaceId)) {
+            revert ErrorComponentNotInstance(instanceNftId);
+        }
+
+        // initialize AccessManagedUpgradeable
+        __AccessManaged_init($._instance.authority());
+
+        // set component state
+        $._name = name;
+        $._isNftInterceptor = isInterceptor;
+        $._instanceReader = $._instance.getInstanceReader();
+        $._wallet = address(this);
+        $._token = IERC20Metadata(token);
+
+        registerInterface(type(IAccessManaged).interfaceId);
+        registerInterface(type(IComponent).interfaceId);
+    }
+
+    function lock() external onlyOwner {
+        IInstanceService(_getServiceAddress(INSTANCE())).setComponentLocked(true);
+    }
+    
+    function unlock() external onlyOwner {
+        IInstanceService(_getServiceAddress(INSTANCE())).setComponentLocked(false);
+    }
+
+    function approveTokenHandler(uint256 spendingLimitAmount) external onlyOwner {
+        IComponents.ComponentInfo memory info = getComponentInfo();
+
+        if(info.wallet != address(this)) {
+            revert ErrorComponentWalletNotComponent();
+        }
+
+        info.token.approve(
+            address(info.tokenHandler),
+            spendingLimitAmount);
+
+        emit LogComponentTokenHandlerApproved(spendingLimitAmount);
+    }
+
+    function setWallet(address newWallet)
+        external
+        override
+        onlyOwner
+    {
+        ComponentStorage storage $ = _getComponentStorage();
+
+        address currentWallet = $._wallet;
+        uint256 currentBalance = $._token.balanceOf(currentWallet);
+
+        // checks
+        if (newWallet == address(0)) {
+            revert ErrorComponentWalletAddressZero();
+        }
+
+        if (newWallet == currentWallet) {
+            revert ErrorComponentWalletAddressIsSameAsCurrent();
+        }
+
+        if (currentBalance > 0) {
+            if (currentWallet == address(this)) {
+                // move tokens from component smart contract to external wallet
+            } else {
+                // move tokens from external wallet to component smart contract or another external wallet
+                uint256 allowance = $._token.allowance(currentWallet, address(this));
+                if (allowance < currentBalance) {
+                    revert ErrorComponentWalletAllowanceTooSmall(currentWallet, newWallet, allowance, currentBalance);
+                }
+            }
+        }
+
+        // effects
+        $._wallet = newWallet;
+        emit LogComponentWalletAddressChanged(currentWallet, newWallet);
+
+        // interactions
+        if (currentBalance > 0) {
+            // transfer tokens from current wallet to new wallet
+            if (currentWallet == address(this)) {
+                // transferFrom requires self allowance too
+                $._token.approve(address(this), currentBalance);
+            }
+            
+            SafeERC20.safeTransferFrom($._token, currentWallet, newWallet, currentBalance);
+            emit LogComponentWalletTokensTransferred(currentWallet, newWallet, currentBalance);
+        }
+    }
+
+    function setProductNftId(NftId productNftId)
+        external
+        override
+    {
+        ComponentStorage storage $ = _getComponentStorage();
+
+        // verify caller is product service
+        if(msg.sender != _getServiceAddress(PRODUCT())) {
+            revert ErrorComponentNotProductService(msg.sender);
+        }
+
+        // verify component is not yet linked to a product
+        if($._productNftId.gtz()) {
+            revert ErrorComponentProductNftAlreadySet();
+        }
+
+        $._productNftId = productNftId;
+    }
+
+    function nftMint(address to, uint256 tokenId) 
+        external 
+        virtual
+        onlyChainNft
+    {}
+
+    /// @dev callback function for nft transfers
+    /// may only be called by chain nft contract.
+    /// do not override this function to implement business logic for handling transfers
+    /// override internal function _nftTransferFrom instead
+    function nftTransferFrom(address from, address to, uint256 tokenId)
+        external
+        virtual
+        onlyChainNft
+    {
+        _nftTransferFrom(from, to, tokenId);
+    }
+
+    function getWallet() public view override returns (address walletAddress)
+    {
+        return _getComponentStorage()._wallet;
+    }
+
+    function getToken() public view override returns (IERC20Metadata token) {
+        return _getComponentStorage()._token;
+    }
+
+    function getTokenHandler() public view returns (TokenHandler tokenHandler) {
+        return getComponentInfo().tokenHandler;
+    }
+
+    function isNftInterceptor() public view override returns(bool isInterceptor) {
+        return _getComponentStorage()._isNftInterceptor;
+    }
+
+    function getInstance() public view override returns (IInstance instance) {
+        return _getComponentStorage()._instance;
+    }
+
+    function getName() public view override returns(string memory name) {
+        return _getComponentStorage()._name;
+    }
+
+    function getProductNftId() public view override returns (NftId productNftId) {
+        return _getComponentStorage()._productNftId;
+    }
+
+    function getComponentInfo() public view returns (IComponents.ComponentInfo memory info) {
+        info = _getInstanceReader().getComponentInfo(getNftId());
+
+        // fallback to initial info (wallet is always != address(0))
+        if(info.wallet == address(0)) {
+            info = _getInitialInfo();
+        }
+    }
+
+    /// @dev defines initial component specification
+    /// overwrite this function according to your use case
+    function _getInitialInfo()
+        internal
+        view 
+        virtual
+        returns (IComponents.ComponentInfo memory info)
+    { }
+
+
+    /// @dev internal function for nft transfers.
+    /// handling logic that deals with nft transfers need to overwrite this function
+    function _nftTransferFrom(address from, address to, uint256 tokenId)
+        internal
+        virtual
+    { }
+
+    /// @dev returns reader for linked instance
+    function _getInstanceReader() internal view returns (InstanceReader reader) {
+        return _getComponentStorage()._instanceReader;
+    }
+
+    /// @dev returns the service address for the specified domain
+    /// gets address via lookup from registry using the major version form the linked instance
+    function _getServiceAddress(ObjectType domain) internal view returns (address service) {
+        VersionPart majorVersion = _getComponentStorage()._instance.getMajorVersion();
+        return getRegistry().getServiceAddress(domain, majorVersion);
+    }
+}

package/contracts/shared/ComponentService.sol

@@ -0,0 +1,141 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IComponent} from "./IComponent.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IRegistryService} from "../registry/IRegistryService.sol";
+import {IInstance} from "../instance/IInstance.sol";
+import {IAccess} from "../instance/module/IAccess.sol";
+import {ObjectType, INSTANCE, REGISTRY} from "../type/ObjectType.sol";
+import {NftId} from "../type/NftId.sol";
+import {RoleId} from "../type/RoleId.sol";
+
+import {Service} from "../shared/Service.sol";
+import {InstanceService} from "../instance/InstanceService.sol";
+import {InstanceAdmin} from "../instance/InstanceAdmin.sol";
+
+abstract contract ComponentService is
+    Service
+{
+
+    error ErrorComponentServiceNotComponent(address component);
+    error ErrorComponentServiceInvalidType(address component, ObjectType requiredType, ObjectType componentType);
+    error ErrorComponentServiceSenderNotOwner(address component, address initialOwner, address sender);
+    error ErrorComponentServiceExpectedRoleMissing(NftId instanceNftId, RoleId requiredRole, address sender);
+    error ErrorComponentServiceComponentLocked(address component);
+    error ErrorComponentServiceSenderNotService(address sender);
+    error ErrorComponentServiceComponentTypeInvalid(address component, ObjectType expectedType, ObjectType foundType);
+
+    // view functions
+
+    function getRegistryService() public view virtual returns (IRegistryService) {
+        return IRegistryService(_getServiceAddress(REGISTRY()));
+    }
+
+    function getInstanceService() public view returns (InstanceService) {
+        return InstanceService(_getServiceAddress(INSTANCE()));
+    }
+
+    // internal functions
+    function _checkComponentForRegistration(
+        address componentAddress,
+        ObjectType requiredType,
+        RoleId requiredRole
+    )
+        internal
+        view
+        returns (
+            IComponent component,
+            address owner,
+            IInstance instance,
+            NftId instanceNftId
+        )
+    {
+        // component may only be registerd by initial owner of component
+        owner = msg.sender;
+
+        // check this is a component
+        component = IComponent(componentAddress);
+        if(!component.supportsInterface(type(IComponent).interfaceId)) {
+            revert ErrorComponentServiceNotComponent(componentAddress);
+        }
+
+        // check component is of required type
+        IRegistry.ObjectInfo memory componentInfo = component.getInitialInfo();
+        if(componentInfo.objectType != requiredType) {
+            revert ErrorComponentServiceInvalidType(componentAddress, requiredType, componentInfo.objectType);
+        }
+
+        // check msg.sender is component owner
+        address initialOwner = componentInfo.initialOwner;
+        if(owner != initialOwner) {
+            revert ErrorComponentServiceSenderNotOwner(componentAddress, componentInfo.initialOwner, owner);
+        }
+
+        // check instance has assigned required role to owner
+        instanceNftId = componentInfo.parentNftId;
+        instance = _getInstance(instanceNftId);
+        if(!instance.getInstanceAdmin().hasRole(requiredRole, owner)) {
+            revert ErrorComponentServiceExpectedRoleMissing(instanceNftId, requiredRole, owner);
+        }
+    }
+
+    // internal view functions
+    function _getAndVerifyCallingComponentAndInstance(
+        ObjectType expectedType // assume always of `component` type
+    )
+        internal
+        view
+        returns(
+            NftId componentNftId,
+            IRegistry.ObjectInfo memory componentInfo, 
+            IInstance instance
+        )
+    {
+        componentNftId = getRegistry().getNftId(msg.sender);
+        (componentInfo, instance) = _getAndVerifyComponentInfoAndInstance(componentNftId, expectedType);
+
+        // locked component can not call services
+        if (instance.getInstanceAdmin().isTargetLocked(componentInfo.objectAddress)) {
+            revert IAccess.ErrorIAccessTargetLocked(componentInfo.objectAddress);
+        }
+    }
+
+    function _getAndVerifyComponentInfoAndInstance(
+        NftId componentNftId,
+        ObjectType expectedType // assume always of `component` type
+    )
+        internal
+        view
+        returns(
+            IRegistry.ObjectInfo memory componentInfo, 
+            IInstance instance
+        )
+    {
+        componentInfo = getRegistry().getObjectInfo(componentNftId);
+        if(componentInfo.objectType != expectedType) {
+            revert ErrorComponentServiceComponentTypeInvalid(
+                componentInfo.objectAddress, 
+                expectedType, 
+                componentInfo.objectType);
+        }
+
+        instance = _getInstance(componentInfo.parentNftId);
+    }
+    // assume componentNftId is always of `instance` type
+    function _getInstance(NftId instanceNftId) internal view returns (IInstance) {
+        return IInstance(
+            getRegistry().getObjectInfo(
+                instanceNftId).objectAddress);
+    }
+    // assume componentNftId is always of `component` type
+    /*function _getInstanceForComponent(NftId componentNftId) internal view returns (IInstance) {
+        NftId instanceNftId = getRegistry().getObjectInfo(componentNftId).parentNftId;
+        address instanceAddress = getRegistry().getObjectInfo(instanceNftId).objectAddress;
+        return IInstance(instanceAddress);
+    }*/
+
+    function _getServiceAddress(ObjectType domain) internal view returns (address) {
+        return getRegistry().getServiceAddress(domain, getVersion().toMajorPart());
+    }
+}

package/contracts/shared/ERC165.sol

@@ -2,24 +2,26 @@
 pragma solidity ^0.8.19;
 
 import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
+import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol"; 
 
-contract ERC165 is IERC165 {
+contract ERC165 is
+    Initializable,
+    IERC165
+{
     mapping(bytes4 => bool) private _isSupported;
 
-    constructor() {
-        _initializeERC165();
-    }
-
-    function supportsInterface(bytes4 interfaceId) external view override returns (bool) {
-        return _isSupported[interfaceId];
-    }
-
-    // @dev register support for ERC165 itself
-    function _initializeERC165() internal {
+    // @dev initializes with support for ERC165
+    function initializeERC165() public onlyInitializing() {
         _isSupported[type(IERC165).interfaceId] = true;
     }
 
-    function _registerInterface(bytes4 interfaceId) internal {
+    // @dev register support for provided interfaceId
+    // includes initialization for ERC165_ID if not yet done
+    function registerInterface(bytes4 interfaceId) public onlyInitializing() {
         _isSupported[interfaceId] = true;
     }
+
+    function supportsInterface(bytes4 interfaceId) external view override returns (bool) {
+        return _isSupported[interfaceId];
+    }
 }

package/contracts/shared/IAccessManagerExtended.sol

@@ -0,0 +1,74 @@
+// SPDX-License-Identifier: MIT
+// OpenZeppelin Contracts (last updated v5.0.0) (access/manager/IAccessManager.sol)
+
+pragma solidity ^0.8.20;
+
+import {IAccessManager} from "@openzeppelin/contracts/access/manager/IAccessManager.sol";
+
+import {Timestamp} from "../type/Timestamp.sol";
+
+interface IAccessManagerExtended is IAccessManager {
+    // Structure that stores the details for a target contract.
+    struct TargetInfo {
+        address taddress;
+        //IAccess.Type ttype;
+        string name;
+        Timestamp createdAt;
+        //Timestamp updatedAt;
+    }
+
+    // Structure that stores the details of a role.
+    struct RoleInfo {
+        uint64 id;
+        //IAccess.Type rtype;
+        string name;
+        Timestamp createdAt;
+    }
+
+    event LogRoleCreation(uint64 roleId, string name);// IAccess.Type rtype);
+    event LogTargetCreation(address target, string name);// IAccess.Type ttype);
+
+    error AccessManagerRoleIdNotExists(uint64 roleId);
+    error AccessManagerRoleIdAlreadyExists(uint64 roleId);
+    error AccessManagerRoleNameAlreadyExists(uint64 newRoleId, uint64 existingRoleId, string duplicateName);
+    error AccessManagerRoleIdZero();
+    error AccessManagerRoleNameEmpty(uint64 roleId);
+    error AccessManagerRoleIdTooBig(uint64 roleId);
+
+    error AccessManagerTargetAlreadyExists(address target);
+    error AccessManagerTargetNotExists(address target);
+    error AccessManagerTargetNameAlreadyExists(address newTarget, address existingTarget, string duplicateName);
+    error AccessManagerTargetAddressZero();
+    error AccessManagerTargetNameEmpty(address target);
+    error AccessManagerTargetAuthorityInvalid(address target, address targetAuthority);
+
+    function getRoleMembers(uint64 roleId) external view returns (uint256 numberOfMembers);
+
+    function getRoleMember(uint64 roleId, uint256 idx) external view returns (address member);
+
+    function getRoleId(uint256 idx) external view returns (uint64 roleId);
+
+    // TODO returns ADMIN_ROLE id for non existent name
+    function getRoleId(string memory name) external view returns (uint64 roleId);
+
+    function getRoles() external view returns (uint256 numberOfRoles);
+
+    function isRoleExists(uint64 roleId) external view returns (bool exists);
+
+    function getRoleInfo(uint64 roleId) external view returns (RoleInfo memory);
+
+    function isRoleNameExists(string memory name) external view returns (bool);
+
+    function isTargetExists(address target) external view returns (bool);
+
+    function isTargetNameExists(string memory name) external view returns (bool);
+    
+    function getTargetAddress(string memory name) external view returns(address targetAddress);
+
+    function getTargetInfo(address target) external view returns (TargetInfo memory);
+
+
+    function createRole(uint64 roleId, string memory roleName/*, IAccess.Type rtype*/) external;
+
+    function createTarget(address target, string memory name/*, IAccess.Type.Custom*/) external;
+}

package/contracts/shared/IAccessManagerExtendedWithDisable.sol

@@ -0,0 +1,17 @@
+// SPDX-License-Identifier: MIT
+
+pragma solidity ^0.8.20;
+
+import {IAccessManagerExtended} from "./IAccessManagerExtended.sol";
+
+import {Timestamp} from "../type/Timestamp.sol";
+import {VersionPart} from "../type/Version.sol";
+
+interface IAccessManagerExtendedWithDisable is IAccessManagerExtended {
+
+    error AccessManagerDisabled();
+
+    function disable() external;
+    function enable() external;
+    function getVersion() external view returns (VersionPart version);
+}

package/contracts/shared/IComponent.sol

@@ -0,0 +1,90 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IAccessManaged} from "@openzeppelin/contracts/access/manager/IAccessManaged.sol";
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {IComponents} from "../instance/module/IComponents.sol";
+import {IInstance} from "../instance/IInstance.sol";
+import {IInstanceService} from "../instance/IInstanceService.sol";
+import {IProductService} from "../product/IProductService.sol";
+import {IRegisterable} from "../shared/IRegisterable.sol";
+import {ITransferInterceptor} from "../registry/ITransferInterceptor.sol";
+import {NftId} from "../type/NftId.sol";
+import {ObjectType} from "../type/ObjectType.sol";
+import {TokenHandler} from "../shared/TokenHandler.sol";
+
+/// @dev component base class
+/// component examples are product, distribution, pool and oracle
+interface IComponent is 
+    IRegisterable,
+    ITransferInterceptor,
+    IAccessManaged
+{
+    error ErrorComponentNotChainNft(address caller);
+    error ErrorComponentNotProductService(address caller);
+    error ErrorComponentNotInstance(NftId instanceNftId);
+    error ErrorComponentProductNftAlreadySet();
+
+    error ErrorComponentWalletAddressZero();
+    error ErrorComponentWalletAddressIsSameAsCurrent();
+    error ErrorComponentWalletAllowanceTooSmall(address oldWallet, address newWallet, uint256 allowance, uint256 balance);
+
+    error ErrorComponentWalletNotComponent();
+
+    event LogComponentWalletAddressChanged(address oldWallet, address newWallet);
+    event LogComponentWalletTokensTransferred(address from, address to, uint256 amount);
+
+    event LogComponentTokenHandlerApproved(uint256 limit);
+
+    /// @dev locks component to disable functions that may change state related to this component, the only exception is function "unlock"
+    /// only component owner (nft holder) is authorizes to call this function
+    function lock() external;
+
+    /// @dev unlocks component to (re-)enable functions that may change state related to this component
+    /// only component owner (nft holder) is authorizes to call this function
+    function unlock() external;
+
+    /// @dev approves token hanlder to spend up to the specified amount of tokens
+    /// reverts if component wallet is not component itself
+    /// only component owner (nft holder) is authorizes to call this function
+    function approveTokenHandler(uint256 spendingLimitAmount) external;
+
+    /// @dev sets the wallet address for the component
+    /// if the current wallet has tokens, these will be transferred
+    /// if the new wallet address is externally owned, an approval from the 
+    /// owner of the external wallet for the component to move all tokens must exist
+    function setWallet(address walletAddress) external;
+
+    /// @dev only product service may set product nft id during registration of product setup
+    function setProductNftId(NftId productNftId) external;
+
+    /// @dev defines the instance to which this component is linked to
+    function getInstance() external view returns (IInstance instance);
+
+    /// @dev returns the name of this component
+    /// to successfully register the component with an instance the name MUST be unique in the linked instance
+    function getName() external view returns (string memory name);
+
+    /// @dev defines which ERC20 token is used by this component
+    function getToken() external view returns (IERC20Metadata token);
+
+    /// @dev returns token handler for this component
+    /// only registered components return a non zero token handler
+    function getTokenHandler() external view returns (TokenHandler tokenHandler);
+
+    /// @dev defines the wallet address used to hold the ERC20 tokens related to this component
+    /// the default address is the component token address
+    function getWallet() external view returns (address walletAddress);
+
+    /// @dev defines the product to which this component is linked to
+    /// this is only relevant for pool and distribution components
+    function getProductNftId() external view returns (NftId productNftId);
+
+    function isNftInterceptor() external view returns(bool isInterceptor);
+
+    /// @dev returns component infos for this pool
+    /// when registered with an instance the info is obtained from the data stored in the instance
+    /// when not registered the function returns the info from the component contract
+    function getComponentInfo() external view returns (IComponents.ComponentInfo memory info);
+}

package/contracts/shared/INftOwnable.sol

@@ -1,22 +1,23 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity ^0.8.20;
 
-import {IRegistry} from "../registry/IRegistry.sol";
-import {NftId} from "../types/NftId.sol";
+import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
 
-interface INftOwnable {
-    error ErrorNotOwner(address account);
+import {IRegistryLinked} from "./IRegistryLinked.sol";
+import {NftId} from "../type/NftId.sol";
 
-    error ErrorAlreadyLinked(address registry, NftId nftId);
-    error ErrorRegistryAlreadyInitialized(address registry);
-    error ErrorRegistryNotInitialized();
-    error ErrorRegistryAddressZero();
-    error ErrorNotRegistry(address registryAddress);
-    error ErrorContractNotRegistered(address contractAddress);
+interface INftOwnable is
+    IERC165,
+    IRegistryLinked
+{
+    error ErrorNftOwnableInitialOwnerZero();
+    error ErrorNftOwnableNotOwner(address account);
+
+    error ErrorNftOwnableAlreadyLinked(NftId nftId);
+    error ErrorNftOwnableContractNotRegistered(address contractAddress);
 
     function linkToRegisteredNftId() external;
 
-    function getRegistry() external view returns (IRegistry);
     function getNftId() external view returns (NftId);
     function getOwner() external view returns (address);
 }