@etherisc/gif-next 0.0.2-d408403-475 → 0.0.2-d442a8c-593

package/contracts/instance/InstanceService.sol

@@ -0,0 +1,362 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Clones} from "@openzeppelin/contracts/proxy/Clones.sol";
+import {ShortString, ShortStrings} from "@openzeppelin/contracts/utils/ShortStrings.sol";
+
+import {BundleManager} from "./BundleManager.sol";
+import {ChainNft} from "../registry/ChainNft.sol";
+import {NftId} from "../type/NftId.sol";
+import {RoleId} from "../type/RoleId.sol";
+import {SecondsLib} from "../type/Seconds.sol";
+import {UFixedLib} from "../type/UFixed.sol";
+import {ADMIN_ROLE, INSTANCE_OWNER_ROLE, DISTRIBUTION_OWNER_ROLE, POOL_OWNER_ROLE, PRODUCT_OWNER_ROLE, INSTANCE_SERVICE_ROLE, DISTRIBUTION_SERVICE_ROLE, POOL_SERVICE_ROLE, PRODUCT_SERVICE_ROLE, APPLICATION_SERVICE_ROLE, POLICY_SERVICE_ROLE, CLAIM_SERVICE_ROLE, BUNDLE_SERVICE_ROLE, INSTANCE_ROLE} from "../type/RoleId.sol";
+import {ObjectType, INSTANCE, BUNDLE, APPLICATION, CLAIM, DISTRIBUTION, POLICY, POOL, PRODUCT, REGISTRY, STAKING} from "../type/ObjectType.sol";
+
+import {Service} from "../shared/Service.sol";
+import {IInstanceLinkedComponent} from "../shared/IInstanceLinkedComponent.sol";
+import {IService} from "../shared/IService.sol";
+import {AccessManagerExtendedInitializeable} from "../shared/AccessManagerExtendedInitializeable.sol";
+
+import {IDistributionComponent} from "../distribution/IDistributionComponent.sol";
+import {IPoolComponent} from "../pool/IPoolComponent.sol";
+import {IProductComponent} from "../product/IProductComponent.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IRegistryService} from "../registry/IRegistryService.sol";
+import {IStakingService} from "../staking/IStakingService.sol";
+import {TargetManagerLib} from "../staking/TargetManagerLib.sol";
+
+import {Instance} from "./Instance.sol";
+import {IInstance} from "./IInstance.sol";
+import {InstanceAdmin} from "./InstanceAdmin.sol";
+import {IInstanceService} from "./IInstanceService.sol";
+import {InstanceReader} from "./InstanceReader.sol";
+import {InstanceStore} from "./InstanceStore.sol";
+import {InstanceAuthorizationsLib} from "./InstanceAuthorizationsLib.sol";
+
+contract InstanceService is
+    Service,
+    IInstanceService
+{
+
+    // TODO update to real hash when instance is stable
+    bytes32 public constant INSTANCE_CREATION_CODE_HASH = bytes32(0);
+
+    IRegistryService internal _registryService;
+    IStakingService internal _stakingService;
+
+    address internal _masterAccessManager;
+    address internal _masterInstanceAdmin;
+    address internal _masterInstance;
+    address internal _masterInstanceReader;
+    address internal _masterInstanceBundleManager;
+    address internal _masterInstanceStore;
+
+    modifier onlyInstanceOwner(NftId instanceNftId) {        
+        if(msg.sender != getRegistry().ownerOf(instanceNftId)) {
+            revert ErrorInstanceServiceRequestUnauhorized(msg.sender);
+        }
+        _;
+    }
+
+    // TODO check component - service - instance version match
+    modifier onlyComponent() {
+        if (! getRegistry().isRegisteredComponent(msg.sender)) {
+            revert ErrorInstanceServiceRequestUnauhorized(msg.sender);
+        }
+        _;
+    }
+
+    function createInstanceClone()
+        external 
+        returns (
+            Instance clonedInstance,
+            NftId clonedInstanceNftId
+        )
+    {
+        address instanceOwner = msg.sender;
+        AccessManagerExtendedInitializeable clonedAccessManager = AccessManagerExtendedInitializeable(
+            Clones.clone(_masterAccessManager));
+
+        // initially grants ADMIN_ROLE to this (being the instance service). 
+        // This will allow the instance service to bootstrap the authorizations of the instance.
+        // Instance service will renounce ADMIN_ROLE when bootstraping is finished
+        clonedAccessManager.initialize(address(this));
+
+        clonedInstance = Instance(Clones.clone(_masterInstance));
+        clonedInstance.initialize(
+            address(clonedAccessManager),
+            address(getRegistry()), 
+            instanceOwner);
+        // initialize and set before instance reader
+        InstanceStore clonedInstanceStore = InstanceStore(Clones.clone(address(_masterInstanceStore)));
+        clonedInstanceStore.initialize(address(clonedInstance));
+        clonedInstance.setInstanceStore(clonedInstanceStore);
+        
+        InstanceReader clonedInstanceReader = InstanceReader(Clones.clone(address(_masterInstanceReader)));
+        clonedInstanceReader.initialize(address(clonedInstance));
+        clonedInstance.setInstanceReader(clonedInstanceReader);
+
+        BundleManager clonedBundleManager = BundleManager(Clones.clone(_masterInstanceBundleManager));
+        clonedBundleManager.initialize(address(clonedInstance));
+        clonedInstance.setBundleManager(clonedBundleManager);
+
+        InstanceAdmin clonedInstanceAdmin = InstanceAdmin(Clones.clone(_masterInstanceAdmin));
+        clonedAccessManager.grantRole(ADMIN_ROLE().toInt(), address(clonedInstanceAdmin), 0);
+        clonedInstanceAdmin.initialize(address(clonedInstance));
+        clonedInstance.setInstanceAdmin(clonedInstanceAdmin);
+
+        // TODO amend setters with instance specific , policy manager ...
+
+        // TODO library does external calls -> but it is registry and access manager -> find out is it best practice
+        InstanceAuthorizationsLib.grantInitialAuthorizations(
+            clonedAccessManager, 
+            clonedInstanceAdmin, 
+            clonedInstance, 
+            clonedBundleManager, 
+            clonedInstanceStore, 
+            instanceOwner,
+            getRegistry(),
+            getVersion().toMajorPart());
+
+        clonedAccessManager.renounceRole(ADMIN_ROLE().toInt(), address(this));
+
+        // register new instance with registry
+        IRegistry.ObjectInfo memory info = _registryService.registerInstance(clonedInstance, instanceOwner);
+        clonedInstanceNftId = info.nftId;
+
+        // create corresponding staking target
+        _stakingService.createInstanceTarget(
+            clonedInstanceNftId,
+            TargetManagerLib.getDefaultLockingPeriod(),
+            TargetManagerLib.getDefaultRewardRate());
+
+        emit LogInstanceCloned(
+            address(clonedAccessManager), 
+            address(clonedInstanceAdmin), 
+            address(clonedInstance),
+            address(clonedInstanceStore),
+            address(clonedBundleManager), 
+            address(clonedInstanceReader), 
+            clonedInstanceNftId);
+    }
+
+    function setComponentLocked(bool locked)
+        external
+        virtual
+        onlyComponent()
+    {
+        // checks
+        address componentAddress = msg.sender;
+
+        if (!IInstanceLinkedComponent(componentAddress).supportsInterface(type(IInstanceLinkedComponent).interfaceId)) {
+            revert ErrorInstanceServiceComponentNotInstanceLinked(componentAddress);
+        }
+
+        IRegistry registry = getRegistry();
+        NftId instanceNftId = registry.getObjectInfo(componentAddress).parentNftId;
+
+        IInstance instance = IInstance(
+            registry.getObjectInfo(
+                instanceNftId).objectAddress);
+
+        // no revert in case already locked
+        instance.getInstanceAdmin().setTargetLockedByService(
+            componentAddress, 
+            locked);
+    }
+
+
+    function getMasterInstanceReader() external view returns (address) {
+        return _masterInstanceReader;
+    }
+
+    // From IService
+    function getDomain() public pure override returns(ObjectType) {
+        return INSTANCE();
+    }
+
+    function setAndRegisterMasterInstance(address instanceAddress)
+            external 
+            onlyOwner 
+            returns(NftId masterInstanceNftId)
+    {
+        if(_masterInstance != address(0)) { revert ErrorInstanceServiceMasterInstanceAlreadySet(); }
+        if(_masterAccessManager != address(0)) { revert ErrorInstanceServiceMasterInstanceAccessManagerAlreadySet(); }
+        if(_masterInstanceAdmin != address(0)) { revert ErrorInstanceServiceMasterInstanceAdminAlreadySet(); }
+        if(_masterInstanceBundleManager != address(0)) { revert ErrorInstanceServiceMasterBundleManagerAlreadySet(); }
+
+        if(instanceAddress == address(0)) { revert ErrorInstanceServiceInstanceAddressZero(); }
+
+        IInstance instance = IInstance(instanceAddress);
+        InstanceAdmin instanceAdmin = instance.getInstanceAdmin();
+        address instanceAdminAddress = address(instanceAdmin);
+        InstanceReader instanceReader = instance.getInstanceReader();
+        address instanceReaderAddress = address(instanceReader);
+        BundleManager bundleManager = instance.getBundleManager();
+        address bundleManagerAddress = address(bundleManager);
+        InstanceStore instanceStore = instance.getInstanceStore();
+        address instanceStoreAddress = address(instanceStore);
+
+        if(instanceAdminAddress == address(0)) { revert ErrorInstanceServiceInstanceAdminZero(); }
+        if(instanceReaderAddress == address(0)) { revert ErrorInstanceServiceInstanceReaderZero(); }
+        if(bundleManagerAddress == address(0)) { revert ErrorInstanceServiceBundleManagerZero(); }
+        if(instanceStoreAddress == address(0)) { revert ErrorInstanceServiceInstanceStoreZero(); }
+        
+        if(instance.authority() != instanceAdmin.authority()) { revert ErrorInstanceServiceInstanceAuthorityMismatch(); }
+        if(bundleManager.authority() != instanceAdmin.authority()) { revert ErrorInstanceServiceBundleManagerAuthorityMismatch(); }
+        if(instanceStore.authority() != instanceAdmin.authority()) { revert ErrorInstanceServiceInstanceStoreAuthorityMismatch(); }
+        if(bundleManager.getInstance() != instance) { revert ErrorInstanceServiceBundleMangerInstanceMismatch(); }
+        if(instanceReader.getInstance() != instance) { revert ErrorInstanceServiceInstanceReaderInstanceMismatch2(); }
+
+        _masterAccessManager = instance.authority();
+        _masterInstanceAdmin = instanceAdminAddress;
+        _masterInstance = instanceAddress;
+        _masterInstanceReader = instanceReaderAddress;
+        _masterInstanceBundleManager = bundleManagerAddress;
+        _masterInstanceStore = instanceStoreAddress;
+        
+        IInstance masterInstance = IInstance(_masterInstance);
+        IRegistry.ObjectInfo memory info = _registryService.registerInstance(masterInstance, getOwner());
+        masterInstanceNftId = info.nftId;
+    }
+
+    function upgradeMasterInstanceReader(address instanceReaderAddress) external onlyOwner {
+        if(_masterInstanceReader == address(0)) { revert ErrorInstanceServiceMasterInstanceReaderNotSet(); }
+        if(instanceReaderAddress == address(0)) { revert ErrorInstanceServiceInstanceReaderAddressZero(); }
+        if(instanceReaderAddress == _masterInstanceReader) { revert ErrorInstanceServiceInstanceReaderSameAsMasterInstanceReader(); }
+
+        InstanceReader instanceReader = InstanceReader(instanceReaderAddress);
+        if(instanceReader.getInstance() != IInstance(_masterInstance)) { revert ErrorInstanceServiceInstanceReaderInstanceMismatch(); }
+
+        _masterInstanceReader = instanceReaderAddress;
+    }
+
+    function upgradeInstanceReader(NftId instanceNftId) 
+        external 
+        onlyInstanceOwner(instanceNftId) 
+    {
+        IRegistry registry = getRegistry();
+        IRegistry.ObjectInfo memory instanceInfo = registry.getObjectInfo(instanceNftId);
+        Instance instance = Instance(instanceInfo.objectAddress);
+        
+        InstanceReader upgradedInstanceReaderClone = InstanceReader(Clones.clone(address(_masterInstanceReader)));
+        upgradedInstanceReaderClone.initialize(address(instance));
+        instance.setInstanceReader(upgradedInstanceReaderClone);
+    }
+
+
+    function createGifTarget(
+        NftId instanceNftId,
+        address targetAddress,
+        string memory targetName,
+        bytes4[][] memory selectors,
+        RoleId[] memory roles
+    )
+        external
+        virtual
+        restricted()
+    {
+        _createGifTarget(
+            instanceNftId,
+            targetAddress,
+            targetName,
+            roles,
+            selectors
+        );
+    }
+
+
+    function createComponentTarget(
+        NftId instanceNftId,
+        address targetAddress,
+        string memory targetName,
+        bytes4[][] memory selectors,
+        RoleId[] memory roles
+    )
+        external
+        virtual
+        restricted()
+    {
+        _createGifTarget(
+            instanceNftId,
+            targetAddress,
+            targetName,
+            roles,
+            selectors
+        );
+    }
+
+
+    /// all gif targets MUST be children of instanceNftId
+    function _createGifTarget(
+        NftId instanceNftId,
+        address targetAddress,
+        string memory targetName,
+        RoleId[] memory roles,
+        bytes4[][] memory selectors
+    )
+        internal
+        virtual
+    {
+        // TODO instanceAdmin will check target instance match anyway
+        (
+            IInstance instance, // or instanceInfo
+            // or targetInfo
+        ) = _validateInstanceAndComponent(instanceNftId, targetAddress);
+
+        InstanceAdmin instanceAdmin = instance.getInstanceAdmin();
+        instanceAdmin.createGifTarget(targetAddress, targetName);
+        // set proposed target config
+        // TODO restriction: gif targets are set only once and only here?
+        //      assume config is a mix of gif and custom roles and no further configuration by INSTANCE_OWNER_ROLE is ever needed?
+        for(uint roleIdx = 0; roleIdx < roles.length; roleIdx++) {
+            instanceAdmin.setTargetFunctionRoleByService(targetName, selectors[roleIdx], roles[roleIdx]);
+        }
+    }
+    
+    /// @dev top level initializer
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        initializer
+        virtual override
+    {
+        (
+            address registryAddress,, 
+            //address managerAddress
+            address authority
+        ) = abi.decode(data, (address, address, address));
+
+        initializeService(registryAddress, authority, owner);
+
+        _registryService = IRegistryService(_getServiceAddress(REGISTRY()));
+        _stakingService = IStakingService(_getServiceAddress(STAKING()));
+
+        registerInterface(type(IInstanceService).interfaceId);
+    }
+
+
+    function _validateInstanceAndComponent(NftId instanceNftId, address componentAddress) 
+        internal
+        view
+        returns (IInstance instance, NftId componentNftId)
+    {
+        IRegistry registry = getRegistry();
+        IRegistry.ObjectInfo memory instanceInfo = registry.getObjectInfo(instanceNftId);
+        if(instanceInfo.objectType != INSTANCE()) {
+            revert ErrorInstanceServiceNotInstance(instanceNftId);
+        }
+
+        IRegistry.ObjectInfo memory componentInfo = registry.getObjectInfo(componentAddress);
+        if(componentInfo.parentNftId != instanceNftId) {
+            revert ErrorInstanceServiceInstanceComponentMismatch(instanceNftId, componentInfo.nftId);
+        }
+
+        instance = Instance(instanceInfo.objectAddress);
+        componentNftId = componentInfo.nftId;
+    }
+}

package/contracts/instance/InstanceServiceManager.sol

@@ -0,0 +1,44 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Instance} from "./Instance.sol";
+import {IVersionable} from "../shared/IVersionable.sol";
+import {ProxyManager} from "../shared/ProxyManager.sol";
+import {InstanceService} from "./InstanceService.sol";
+import {Registry} from "../registry/Registry.sol";
+import {RegistryService} from "../registry/RegistryService.sol";
+import {REGISTRY} from "../type/ObjectType.sol";
+
+contract InstanceServiceManager is ProxyManager {
+
+    InstanceService private _instanceService;
+
+    /// @dev initializes proxy manager with instance service implementation
+    constructor(
+        address authority, 
+        address registryAddress,
+        bytes32 salt
+    ) 
+        ProxyManager(registryAddress)
+    {
+        InstanceService instSrv = new InstanceService{salt: salt}();
+        // bytes memory initCode = type(InstanceService).creationCode;
+        bytes memory data = abi.encode(registryAddress, address(this), authority);
+        IVersionable versionable = deployDetermenistic(
+            address(instSrv), 
+            data,
+            salt);
+
+        _instanceService = InstanceService(address(versionable));
+    }
+
+    //--- view functions ----------------------------------------------------//
+    function getInstanceService()
+        external
+        view
+        returns (InstanceService instanceService)
+    {
+        return _instanceService;
+    }
+
+}

package/contracts/instance/InstanceStore.sol

@@ -0,0 +1,260 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
+
+import {Amount} from "../type/Amount.sol";
+import {Key32, KeyId, Key32Lib} from "../type/Key32.sol";
+import {NftId} from "../type/NftId.sol";
+import {ClaimId} from "../type/ClaimId.sol";
+import {ObjectType, BUNDLE, DISTRIBUTION, FEE, INSTANCE, POLICY, POOL, ROLE, PRODUCT, TARGET, COMPONENT, DISTRIBUTOR, DISTRIBUTOR_TYPE} from "../type/ObjectType.sol";
+import {RiskId, RiskIdLib} from "../type/RiskId.sol";
+import {RoleId, RoleIdLib, INSTANCE_ROLE, INSTANCE_OWNER_ROLE} from "../type/RoleId.sol";
+import {StateId, ACTIVE} from "../type/StateId.sol";
+import {TimestampLib} from "../type/Timestamp.sol";
+import {VersionPart, VersionPartLib} from "../type/Version.sol";
+import {ReferralId} from "../type/Referral.sol";
+import {DistributorType} from "../type/DistributorType.sol";
+import {PayoutId} from "../type/PayoutId.sol";
+
+import {BalanceStore} from "./base/BalanceStore.sol";
+import {IInstance} from "./IInstance.sol";
+import {KeyValueStore} from "../shared/KeyValueStore.sol";
+import {IKeyValueStore} from "../shared/KeyValueStore.sol";
+
+import {IBundle} from "./module/IBundle.sol";
+import {IComponents} from "./module/IComponents.sol";
+import {IDistribution} from "./module/IDistribution.sol";
+import {IPolicy} from "./module/IPolicy.sol";
+import {IRisk} from "./module/IRisk.sol";
+
+
+contract InstanceStore is
+    AccessManagedUpgradeable, 
+    KeyValueStore,
+    BalanceStore
+{
+    function initialize(address instance)
+        public 
+        initializer()
+    {
+        address authority = IInstance(instance).authority();
+        __AccessManaged_init(authority);
+        initializeLifecycle();
+    }
+
+    //--- Component ---------------------------------------------------------//
+    function createComponent(
+        NftId componentNftId, 
+        IComponents.ComponentInfo memory componentInfo
+    )
+        external 
+        restricted()
+    {
+        _registerBalanceTarget(componentNftId);
+        _create(_toNftKey32(componentNftId, COMPONENT()), abi.encode(componentInfo));
+    }
+
+    function updateComponent(
+        NftId componentNftId, 
+        IComponents.ComponentInfo memory componentInfo,
+        StateId newState
+    )
+        external 
+        restricted()
+    {
+        _update(_toNftKey32(componentNftId, COMPONENT()), abi.encode(componentInfo), newState);
+    }
+
+    //--- ProductSetup ------------------------------------------------------//
+
+    function createProduct(NftId productNftId, IComponents.ProductInfo memory info) external restricted() {
+        _create(_toNftKey32(productNftId, PRODUCT()), abi.encode(info));
+    }
+
+    function updateProduct(NftId productNftId, IComponents.ProductInfo memory info, StateId newState) external restricted() {
+        _update(_toNftKey32(productNftId, PRODUCT()), abi.encode(info), newState);
+    }
+
+    function updateProductSetupState(NftId productNftId, StateId newState) external restricted() {
+        _updateState(_toNftKey32(productNftId, PRODUCT()), newState);
+    }
+
+    //--- PoolSetup ------------------------------------------------------//
+
+    function createPool(
+        NftId poolNftId, 
+        IComponents.PoolInfo memory info
+    )
+        external 
+        restricted()
+    {
+        _create(_toNftKey32(poolNftId, POOL()), abi.encode(info));
+    }
+
+    function updatePool(NftId poolNftId, IComponents.PoolInfo memory info, StateId newState) external restricted() {
+        _update(_toNftKey32(poolNftId, POOL()), abi.encode(info), newState);
+    }
+
+    function updatePoolState(NftId poolNftId, StateId newState) external restricted() {
+        _updateState(_toNftKey32(poolNftId, POOL()), newState);
+    }
+
+    //--- DistributorType -------------------------------------------------------//
+    function createDistributorType(DistributorType distributorType, IDistribution.DistributorTypeInfo memory info) external restricted() {
+        _create(distributorType.toKey32(), abi.encode(info));
+    }
+
+    function updateDistributorType(DistributorType distributorType, IDistribution.DistributorTypeInfo memory info, StateId newState) external restricted() {
+        _update(distributorType.toKey32(), abi.encode(info), newState);
+    }
+
+    function updateDistributorTypeState(DistributorType distributorType, StateId newState) external restricted() {
+        _updateState(distributorType.toKey32(), newState);
+    }
+
+    //--- Distributor -------------------------------------------------------//
+    function createDistributor(NftId distributorNftId, IDistribution.DistributorInfo memory info) external restricted() {
+        _create(_toNftKey32(distributorNftId, DISTRIBUTOR()), abi.encode(info));
+    }
+
+    function updateDistributor(NftId distributorNftId, IDistribution.DistributorInfo memory info, StateId newState) external restricted() {
+        _update(_toNftKey32(distributorNftId, DISTRIBUTOR()), abi.encode(info), newState);
+    }
+
+    function updateDistributorState(NftId distributorNftId, StateId newState) external restricted() {
+        _updateState(_toNftKey32(distributorNftId, DISTRIBUTOR()), newState);
+    }
+
+    //--- Referral ----------------------------------------------------------//
+    function createReferral(ReferralId referralId, IDistribution.ReferralInfo memory referralInfo) external restricted() {
+        _create(referralId.toKey32(), abi.encode(referralInfo));
+    }
+
+    function updateReferral(ReferralId referralId, IDistribution.ReferralInfo memory referralInfo, StateId newState) external restricted() {
+        _update(referralId.toKey32(), abi.encode(referralInfo), newState);
+    }
+
+    function updateReferralState(ReferralId referralId, StateId newState) external restricted() {
+        _updateState(referralId.toKey32(), newState);
+    }
+
+    //--- Bundle ------------------------------------------------------------//
+    function createBundle(NftId bundleNftId, IBundle.BundleInfo memory bundle) external restricted() {
+        _registerBalanceTarget(bundleNftId);
+        _create(_toNftKey32(bundleNftId, BUNDLE()), abi.encode(bundle));
+    }
+
+    function updateBundle(NftId bundleNftId, IBundle.BundleInfo memory bundle, StateId newState) external restricted() {
+        _update(_toNftKey32(bundleNftId, BUNDLE()), abi.encode(bundle), newState);
+    }
+
+    function updateBundleState(NftId bundleNftId, StateId newState) external restricted() {
+        _updateState(_toNftKey32(bundleNftId, BUNDLE()), newState);
+    }
+
+    //--- Risk --------------------------------------------------------------//
+    function createRisk(RiskId riskId, IRisk.RiskInfo memory risk) external restricted() {
+        _create(riskId.toKey32(), abi.encode(risk));
+    }
+
+    function updateRisk(RiskId riskId, IRisk.RiskInfo memory risk, StateId newState) external restricted() {
+        _update(riskId.toKey32(), abi.encode(risk), newState);
+    }
+
+    function updateRiskState(RiskId riskId, StateId newState) external restricted() {
+        _updateState(riskId.toKey32(), newState);
+    }
+
+    //--- Application (Policy) ----------------------------------------------//
+    function createApplication(NftId applicationNftId, IPolicy.PolicyInfo memory policy) external restricted() {
+        _registerBalanceTarget(applicationNftId);
+        _create(_toNftKey32(applicationNftId, POLICY()), abi.encode(policy));
+    }
+
+    function updateApplication(NftId applicationNftId, IPolicy.PolicyInfo memory policy, StateId newState) external restricted() {
+        _update(_toNftKey32(applicationNftId, POLICY()), abi.encode(policy), newState);
+    }
+
+    function updateApplicationState(NftId applicationNftId, StateId newState) external restricted() {
+        _updateState(_toNftKey32(applicationNftId, POLICY()), newState);
+    }
+
+    //--- Policy ------------------------------------------------------------//
+    function updatePolicy(NftId policyNftId, IPolicy.PolicyInfo memory policy, StateId newState) external restricted() {
+        _update(_toNftKey32(policyNftId, POLICY()), abi.encode(policy), newState);
+    }
+
+    function updatePolicyClaims(NftId policyNftId, IPolicy.PolicyInfo memory policy, StateId newState) external restricted() {
+        _update(_toNftKey32(policyNftId, POLICY()), abi.encode(policy), newState);
+    }
+
+    function updatePolicyState(NftId policyNftId, StateId newState) external restricted() {
+        _updateState(_toNftKey32(policyNftId, POLICY()), newState);
+    }
+
+    //--- Claim -------------------------------------------------------------//
+    function createClaim(NftId policyNftId, ClaimId claimId, IPolicy.ClaimInfo memory claim) external restricted() {
+        _create(_toClaimKey32(policyNftId, claimId), abi.encode(claim));
+    }
+
+    function updateClaim(NftId policyNftId, ClaimId claimId, IPolicy.ClaimInfo memory claim, StateId newState) external restricted() {
+        _update(_toClaimKey32(policyNftId, claimId), abi.encode(claim), newState);
+    }
+
+    function updateClaimState(NftId policyNftId, ClaimId claimId, StateId newState) external restricted() {
+        _updateState(_toClaimKey32(policyNftId, claimId), newState);
+    }
+
+    //--- Payout ------------------------------------------------------------//
+    function createPayout(NftId policyNftId, PayoutId payoutId, IPolicy.PayoutInfo memory payout) external restricted() {
+        _create(_toPayoutKey32(policyNftId, payoutId), abi.encode(payout));
+    }
+
+    function updatePayout(NftId policyNftId, PayoutId payoutId, IPolicy.PayoutInfo memory payout, StateId newState) external restricted() {
+        _update(_toPayoutKey32(policyNftId, payoutId), abi.encode(payout), newState);
+    }
+
+    function updatePayoutState(NftId policyNftId, PayoutId payoutId, StateId newState) external restricted() {
+        _updateState(_toPayoutKey32(policyNftId, payoutId), newState);
+    }
+
+    //--- balance and fee management functions ------------------------------//
+
+    function increaseBalance(NftId targetNftId, Amount amount) external restricted() returns (Amount newBalance) {
+        return _increaseBalance(targetNftId, amount);
+    }
+
+    function decreaseBalance(NftId targetNftId, Amount amount) external restricted() returns (Amount newBalance) {
+        return _decreaseBalance(targetNftId, amount);
+    }
+
+    function increaseFees(NftId targetNftId, Amount amount) external restricted() returns (Amount newFeeBalance) {
+        return _increaseFees(targetNftId, amount);
+    }
+
+    function decreaseFees(NftId targetNftId, Amount amount) external restricted() returns (Amount newFeeBalance) {
+        return _decreaseFees(targetNftId, amount);
+    }
+
+    function increaseLocked(NftId targetNftId, Amount amount) external restricted() returns (Amount newBalance) {
+        return _increaseLocked(targetNftId, amount);
+    }
+
+    function decreaseLocked(NftId targetNftId, Amount amount) external restricted() returns (Amount newBalance) {
+        return _decreaseLocked(targetNftId, amount);
+    }
+
+    //--- internal view/pure functions --------------------------------------//
+    function _toNftKey32(NftId nftId, ObjectType objectType) private pure returns (Key32) {
+        return nftId.toKey32(objectType);
+    }
+
+    function _toClaimKey32(NftId policyNftId, ClaimId claimId) private pure returns (Key32) {
+        return claimId.toKey32(policyNftId);
+    }
+
+    function _toPayoutKey32(NftId policyNftId, PayoutId payoutId) private pure returns (Key32) {
+        return payoutId.toKey32(policyNftId);
+    }
+}