@etherisc/gif-next 0.0.2-d3ee0cc-268 → 0.0.2-d442a8c-073

package/contracts/registry/RegistryAdmin.sol

@@ -0,0 +1,237 @@
+// SPDX-License-Identifier: UNLICENSED
+pragma solidity ^0.8.20;
+
+import {IAccessManaged} from "@openzeppelin/contracts/access/manager/IAccessManaged.sol";
+import {AccessManaged} from "@openzeppelin/contracts/access/manager/AccessManaged.sol";
+import {AuthorityUtils} from "@openzeppelin/contracts/access/manager/AuthorityUtils.sol";
+
+import {RoleId, RoleIdLib, GIF_MANAGER_ROLE, GIF_ADMIN_ROLE} from "../type/RoleId.sol";
+
+import {AccessManagerExtendedInitializeable} from "../shared/AccessManagerExtendedInitializeable.sol";
+import {InitializableCustom} from "../shared/InitializableCustom.sol";
+
+import {IRegistry} from "./IRegistry.sol";
+import {ReleaseManager} from "./ReleaseManager.sol";
+import {TokenRegistry} from "./TokenRegistry.sol";
+
+/*
+    1) GIF_MANAGER_ROLE
+        - can have arbitrary number of members
+        - responsible for services registrations
+        - responsible for token registration and activation
+
+    2) GIF_ADMIN_ROLE
+        - admin of GIF_MANAGER_ROLE
+        - MUST have 1 member at any time
+        - granted/revoked ONLY in transferAdminRole() -> consider lock out situations!!!
+        - responsible for creation and activation of releases
+*/
+
+// !!! USE BUILDER PATTERN FOR CONFIG 
+// introduce class - config
+// create instance of this class in admin initializer function
+// call it "add"/"push" function for each entry in config (provide entry parameneters)
+// each call will configure access manager for given parameneters
+// in the end you have fully configured access manager and config object
+
+// grants GIF_ADMIN_ROLE to registry owner as registryOwner is transaction sender
+// grants GIF_MANAGER_ROLE to registry owner via contructor argument
+contract RegistryAdmin is
+    AccessManaged,
+    InitializableCustom
+{
+    error ErrorRegistryAdminReleaseManagerAuthorityMismatch();
+    error ErrorRegistryAdminTokenRegistryAuthorityMismatch();
+    error ErrorRegistryAdminStakingAuthorityMismatch();
+
+    string public constant GIF_ADMIN_ROLE_NAME = "GifAdminRole";
+    string public constant GIF_MANAGER_ROLE_NAME = "GifManagerRole";
+
+    string public constant RELEASE_MANAGER_TARGET_NAME = "ReleaseManager";
+    string public constant TOKEN_REGISTRY_TARGET_NAME = "TokenRegistry";
+    string public constant STAKING_TARGET_NAME = "Staking";
+    
+    address private _releaseManager;
+    address private _tokenRegistry;
+    address private _staking;
+
+    constructor()
+        AccessManaged(msg.sender)
+        InitializableCustom()
+    {
+        AccessManagerExtendedInitializeable accessManager = new AccessManagerExtendedInitializeable();
+        accessManager.initialize(address(this));
+        setAuthority(address(accessManager));
+    }
+
+    function initialize(
+        IRegistry registry,
+        address gifAdmin, 
+        address gifManager
+    )
+        external
+        initializer
+    {
+        // validate input
+        address releaseManagerAddress = registry.getReleaseManagerAddress();
+        if(IAccessManaged(releaseManagerAddress).authority() != authority()) {
+            revert ErrorRegistryAdminReleaseManagerAuthorityMismatch();
+        }
+
+        address tokenRegistryAddress = registry.getTokenRegistryAddress();
+        if(IAccessManaged(tokenRegistryAddress).authority() != authority()) {
+            revert ErrorRegistryAdminTokenRegistryAuthorityMismatch();
+        }
+
+        address stakingAddress = registry.getStakingAddress();
+        if(IAccessManaged(stakingAddress).authority() != authority()) {
+            revert ErrorRegistryAdminStakingAuthorityMismatch();
+        }
+
+        _releaseManager = releaseManagerAddress;
+        _tokenRegistry = tokenRegistryAddress;
+        _staking = stakingAddress;
+
+        // at this moment all registry contracts are deployed and fully intialized
+        _createRole(GIF_ADMIN_ROLE(), GIF_ADMIN_ROLE_NAME);
+        _createRole(GIF_MANAGER_ROLE(), GIF_MANAGER_ROLE_NAME);
+
+        _createTarget(_releaseManager, RELEASE_MANAGER_TARGET_NAME);
+        _createTarget(_tokenRegistry, TOKEN_REGISTRY_TARGET_NAME);
+        _createTarget(_staking, STAKING_TARGET_NAME);
+
+        _setGifAdminRole();
+        _setGifManagerRole();
+
+        _grantRole(GIF_ADMIN_ROLE(), gifAdmin, 0);
+        _grantRole(GIF_MANAGER_ROLE(), gifManager, 0);
+
+        // set gif manager role admin
+        _setRoleAdmin(GIF_MANAGER_ROLE(), GIF_ADMIN_ROLE());
+    }
+
+    // TODO makes sense to do this in intialize() function
+    // it is a single contract
+    // but if many token registries a possible...
+    /*function setTokenRegistry(
+        address tokenRegistry
+    )
+        external
+        restricted() // GIF_ADMIN_ROLE
+    {
+        // for TokenRegistry
+        bytes4[] memory functionSelector = new bytes4[](5);
+        functionSelector[0] = TokenRegistry.registerToken.selector;
+        functionSelector[1] = TokenRegistry.registerRemoteToken.selector;
+        functionSelector[2] = TokenRegistry.setActive.selector;
+        functionSelector[3] = TokenRegistry.setActiveForVersion.selector;
+
+        // only needed for testing TODO find a better way
+        functionSelector[4] = TokenRegistry.setActiveWithVersionCheck.selector;
+        _setTargetFunctionRole(address(tokenRegistry), functionSelector, GIF_MANAGER_ROLE());
+    }*/
+
+
+    function setTargetFunctionRole(
+        address target, 
+        bytes4[] memory selector,
+        RoleId roleId
+    )
+        external
+        restricted // RELEASE_MANAGER_ROLE -> TODO create this role
+    {
+        _setTargetFunctionRole(target, selector, roleId);
+    }
+
+    /*function transferAdmin(address to)
+        external
+        restricted // only with GIF_ADMIN_ROLE or nft owner
+    {
+        _accessManager.revoke(GIF_ADMIN_ROLE, );
+        _accesssManager.grant(GIF_ADMIN_ROLE, to, 0);
+    }*/
+
+    //--- view functions ----------------------------------------------------//
+
+    function hasRole(address account, RoleId roleId) external view returns(bool) {
+        (bool isMember,) =  AccessManagerExtendedInitializeable(authority()).hasRole(roleId.toInt(), account);
+        return isMember;
+    }
+
+
+    function canCall(
+        address account,
+        address target,
+        bytes4 functionSelector
+    )
+        external
+        view
+        returns(bool)
+    {
+        (bool immediate,) = AuthorityUtils.canCallWithDelay(
+            authority(),
+            account,
+            target,
+            functionSelector);
+
+        return immediate;
+    }
+
+    //--- private functions -------------------------------------------------//
+
+    function _setGifAdminRole() private
+    {
+        // for ReleaseManager
+        bytes4[] memory functionSelector2 = new bytes4[](2);
+        //functionSelector2[0] = ReleaseManager.registerStaking.selector;
+        functionSelector2[0] = ReleaseManager.createNextRelease.selector;
+        functionSelector2[1] = ReleaseManager.activateNextRelease.selector;
+
+        _setTargetFunctionRole(_releaseManager, functionSelector2, GIF_ADMIN_ROLE());
+
+        // for Staking
+    }
+    
+    function _setGifManagerRole() private 
+    {
+        // for TokenRegistry
+        bytes4[] memory functionSelectorTr = new bytes4[](5);
+        functionSelectorTr[0] = TokenRegistry.registerToken.selector;
+        functionSelectorTr[1] = TokenRegistry.registerRemoteToken.selector;
+        functionSelectorTr[2] = TokenRegistry.setActive.selector;
+        functionSelectorTr[3] = TokenRegistry.setActiveForVersion.selector;
+
+        // only needed for testing TODO find a better way
+        functionSelectorTr[4] = TokenRegistry.setActiveWithVersionCheck.selector;
+        _setTargetFunctionRole(_tokenRegistry, functionSelectorTr, GIF_MANAGER_ROLE());
+
+        // for ReleaseManager
+        bytes4[] memory functionSelectorRm = new bytes4[](2);
+        functionSelectorRm[0] = ReleaseManager.registerService.selector;
+        functionSelectorRm[1] = ReleaseManager.prepareNextRelease.selector;
+        _setTargetFunctionRole(_releaseManager, functionSelectorRm, GIF_MANAGER_ROLE());
+
+        // for Staking
+    }
+
+
+    function _setTargetFunctionRole(address target, bytes4[] memory selectors, RoleId roleId) private {
+        AccessManagerExtendedInitializeable(authority()).setTargetFunctionRole(target, selectors, roleId.toInt());        
+    }
+
+    function _setRoleAdmin(RoleId roleId, RoleId adminRoleId) private {
+        AccessManagerExtendedInitializeable(authority()).setRoleAdmin(roleId.toInt(), adminRoleId.toInt());
+    }
+
+    function _grantRole(RoleId roleId, address account, uint32 executionDelay) private {
+        AccessManagerExtendedInitializeable(authority()).grantRole(roleId.toInt(), account, executionDelay);
+    }
+
+    function _createRole(RoleId roleId, string memory roleName) private {
+        AccessManagerExtendedInitializeable(authority()).createRole(roleId.toInt(), roleName);
+    }
+
+    function _createTarget(address target, string memory targetName) private {
+        AccessManagerExtendedInitializeable(authority()).createTarget(target, targetName);
+    }
+}

package/contracts/registry/RegistryService.sol

@@ -0,0 +1,266 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ERC165Checker} from "@openzeppelin/contracts/utils/introspection/ERC165Checker.sol";
+// import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
+
+import {IRegistry} from "./IRegistry.sol";
+import {IInstance} from "../instance/IInstance.sol";
+
+import {IComponent} from "../../contracts/shared/IComponent.sol";
+import {IPoolComponent} from "../../contracts/pool/IPoolComponent.sol";
+import {IProductComponent} from "../../contracts/product/IProductComponent.sol";
+import {IDistributionComponent} from "../../contracts/distribution/IDistributionComponent.sol";
+
+import {IVersionable} from "../../contracts/shared/IVersionable.sol";
+import {Versionable} from "../../contracts/shared/Versionable.sol";
+import {IRegisterable} from "../../contracts/shared/IRegisterable.sol";
+
+import {RoleId, PRODUCT_OWNER_ROLE, POOL_OWNER_ROLE, ORACLE_OWNER_ROLE} from "../../contracts/type/RoleId.sol";
+import {ObjectType, REGISTRY, SERVICE, PRODUCT, ORACLE, POOL, INSTANCE, COMPONENT, DISTRIBUTION, DISTRIBUTOR, APPLICATION, POLICY, CLAIM, BUNDLE, STAKE, STAKING, PRICE} from "../../contracts/type/ObjectType.sol";
+import {StateId, ACTIVE, PAUSED} from "../../contracts/type/StateId.sol";
+import {NftId, NftIdLib} from "../../contracts/type/NftId.sol";
+import {Fee, FeeLib} from "../../contracts/type/Fee.sol";
+import {Version, VersionPart, VersionLib} from "../../contracts/type/Version.sol";
+
+import {Service} from "../shared/Service.sol";
+import {IService} from "../shared/IService.sol";
+import {IRegistryService} from "./IRegistryService.sol";
+import {Registry} from "./Registry.sol";
+
+contract RegistryService is
+    Service,
+    IRegistryService
+{
+    using NftIdLib for NftId;
+
+    // TODO update to real hash when registry is stable
+    bytes32 public constant REGISTRY_CREATION_CODE_HASH = bytes32(0);
+
+    // From IService
+    function getDomain() public pure override returns(ObjectType serviceDomain) {
+        return REGISTRY(); 
+    }
+
+    // from Versionable
+
+    /// @dev top level initializer
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        virtual override
+        initializer()
+    {
+        (
+            address registryAddress,
+            address initialAuthority
+        ) = abi.decode(data, (address, address));
+
+        initializeService(registryAddress, initialAuthority, owner);
+        registerInterface(type(IRegistryService).interfaceId);
+    }
+
+
+    function registerStaking(IRegisterable staking, address owner)
+        external
+        virtual
+        restricted()
+        returns(
+            IRegistry.ObjectInfo memory info
+        )
+    {
+        info = _getAndVerifyContractInfo(staking, STAKING(), owner);
+        info.nftId = getRegistry().register(info);
+    }
+
+
+    function registerInstance(IRegisterable instance, address owner)
+        external
+        virtual
+        restricted
+        returns(
+            IRegistry.ObjectInfo memory info
+        ) 
+    {
+        if(!instance.supportsInterface(type(IInstance).interfaceId)) {
+            revert ErrorRegistryServiceNotInstance(address(instance));
+        }
+
+        info = _getAndVerifyContractInfo(instance, INSTANCE(), owner);
+        info.nftId = getRegistry().register(info);
+
+        instance.linkToRegisteredNftId(); // asume safe
+    }
+
+    function registerProduct(IComponent product, address owner)
+        external
+        restricted
+        returns(
+            IRegistry.ObjectInfo memory info
+        ) 
+    {
+        // CAN revert if no ERC165 support -> will revert with empty message 
+        if(!product.supportsInterface(type(IProductComponent).interfaceId)) {
+            revert ErrorRegistryServiceNotProduct(address(product));
+        }
+
+        info = _getAndVerifyContractInfo(product, PRODUCT(), owner);
+        info.nftId = getRegistry().register(info);
+    }
+
+    function registerComponent(
+        IComponent component, 
+        ObjectType objectType,
+        address initialOwner
+    )
+        external
+        restricted
+        returns(
+            IRegistry.ObjectInfo memory info
+        ) 
+    {
+        // CAN revert if no ERC165 support -> will revert with empty message 
+        if(!component.supportsInterface(type(IComponent).interfaceId)) {
+            revert ErrorRegistryServiceNotComponent(address(component));
+        }
+
+        info = _getAndVerifyContractInfo(component, objectType, initialOwner);
+        info.nftId = getRegistry().register(info);
+    }
+
+    function registerPool(IComponent pool, address owner)
+        external
+        restricted
+        returns(
+            IRegistry.ObjectInfo memory info
+        ) 
+    {
+        if(!pool.supportsInterface(type(IPoolComponent).interfaceId)) {
+            revert ErrorRegistryServiceNotPool(address(pool));
+        }
+
+        info = _getAndVerifyContractInfo(pool, POOL(), owner);
+        info.nftId = getRegistry().register(info);
+    }
+
+    function registerDistribution(IComponent distribution, address owner)
+        external
+        restricted
+        returns(
+            IRegistry.ObjectInfo memory info
+        ) 
+    {
+        if(!distribution.supportsInterface(type(IDistributionComponent).interfaceId)) {
+            revert ErrorRegistryServiceNotDistribution(address(distribution));
+        }
+
+        info = _getAndVerifyContractInfo(distribution, DISTRIBUTION(), owner);
+        info.nftId = getRegistry().register(info);
+    }
+
+    function registerDistributor(IRegistry.ObjectInfo memory info)
+        external
+        restricted 
+        returns(NftId nftId) 
+    {
+        _verifyObjectInfo(info, DISTRIBUTOR());
+        nftId = getRegistry().register(info);
+    }
+
+    function registerPolicy(IRegistry.ObjectInfo memory info)
+        external
+        restricted 
+        returns(NftId nftId) 
+    {
+        _verifyObjectInfo(info, POLICY());
+        nftId = getRegistry().register(info);
+    }
+
+    function registerBundle(IRegistry.ObjectInfo memory info)
+        external
+        restricted 
+        returns(NftId nftId) 
+    {
+        _verifyObjectInfo(info, BUNDLE());
+        nftId = getRegistry().register(info);
+    }
+
+    function registerStake(IRegistry.ObjectInfo memory info)
+        external
+        restricted 
+        returns(NftId nftId) 
+    {
+        _verifyObjectInfo(info, STAKE());
+        nftId = getRegistry().register(info);
+    }
+
+    // Internal
+
+    function _getAndVerifyContractInfo(
+        IRegisterable registerable,
+        ObjectType expectedType, // assume can be valid only
+        address expectedOwner // assume can be 0 when given by other service
+    )
+        internal
+        view
+        returns(
+            IRegistry.ObjectInfo memory info 
+        )
+    {
+        info = registerable.getInitialInfo();
+
+        if(info.objectAddress != address(registerable)) {
+            revert ErrorRegistryServiceRegisterableAddressInvalid(registerable, info.objectAddress);
+        }
+
+        if(info.objectType != expectedType) {// type is checked in registry anyway...but service logic may depend on expected value
+            revert ErrorRegistryServiceRegisterableTypeInvalid(registerable, expectedType, info.objectType);
+        }
+
+        address owner = info.initialOwner;
+
+        if(owner != expectedOwner) { // registerable owner protection
+            revert ErrorRegistryServiceRegisterableOwnerInvalid(registerable, expectedOwner, owner);
+        }
+
+        if(owner == address(registerable)) {
+            revert ErrorRegistryServiceRegisterableSelfRegistration(registerable);
+        }
+
+        if(owner == address(0)) {
+            revert ErrorRegistryServiceRegisterableOwnerZero(registerable);
+        }
+        
+        if(getRegistry().isRegistered(owner)) { 
+            revert ErrorRegistryServiceRegisterableOwnerRegistered(registerable, owner);
+        }
+    }
+
+    function _verifyObjectInfo(
+        IRegistry.ObjectInfo memory info,
+        ObjectType expectedType
+    )
+        internal
+        view
+    {
+        if(info.objectAddress > address(0)) {
+            revert ErrorRegistryServiceObjectAddressNotZero(info.objectType);
+        }
+
+        if(info.objectType != expectedType) {// type is checked in registry anyway...but service logic may depend on expected value
+            revert ErrorRegistryServiceObjectTypeInvalid(expectedType, info.objectType);
+        }
+
+        address owner = info.initialOwner;
+
+        if(owner == address(0)) {
+            revert ErrorRegistryServiceObjectOwnerZero(info.objectType);
+        }
+
+        if(getRegistry().isRegistered(owner)) { 
+            revert ErrorRegistryServiceObjectOwnerRegistered(info.objectType, owner);
+        }
+    }
+}

package/contracts/registry/RegistryServiceManager.sol

@@ -0,0 +1,58 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {AccessManager} from "@openzeppelin/contracts/access/manager/AccessManager.sol";
+
+import {Registry} from "./Registry.sol";
+import {IVersionable} from "../shared/IVersionable.sol";
+import {ProxyManager} from "../shared/ProxyManager.sol";
+import {RegistryService} from "./RegistryService.sol";
+import {TokenRegistry} from "./TokenRegistry.sol";
+
+
+contract RegistryServiceManager is
+    ProxyManager
+{
+    error ErrorRegistryAccessManagerAuthorityZero();
+    error ErrorRegistryAccessManagerRegistryZero();
+
+    bytes32 constant public ACCESS_MANAGER_CREATION_CODE_HASH = 0x0;
+
+    RegistryService private immutable _registryService;
+
+    /// @dev initializes proxy manager with registry service implementation and deploys registry
+    constructor(
+        address authority, // used by implementation 
+        address registry, // used by implementation 
+        bytes32 salt
+    ) 
+        ProxyManager(registry)
+    {
+        if(authority == address(0)) {
+            revert ErrorRegistryAccessManagerAuthorityZero();
+        }
+
+        if(registry == address(0)) {
+            revert ErrorRegistryAccessManagerRegistryZero();
+        }
+        
+        RegistryService srv = new RegistryService{ salt: salt }();
+        bytes memory data = abi.encode(registry, authority);
+        IVersionable versionable = deployDetermenistic(
+            address(srv), 
+            data,
+            salt);
+
+        _registryService = RegistryService(address(versionable));
+    }
+
+    //--- view functions ----------------------------------------------------//
+
+    function getRegistryService()
+        external
+        view
+        returns (RegistryService registryService)
+    {
+        return _registryService;
+    }
+}