@etherisc/gif-next 0.0.2-d3543ee-217 → 0.0.2-d3ee0cc-268

package/contracts/registry/IRegistryLinked.sol

@@ -0,0 +1,8 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../registry/IRegistry.sol";
+
+interface IRegistryLinked {
+    function getRegistry() external view returns (IRegistry registry);
+}

package/contracts/registry/Registry.sol

@@ -1,80 +1,79 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity ^0.8.19;
 
-import {IChainNft} from "./IChainNft.sol";
-import {IRegistry, IRegistryLinked, IRegisterable} from "./IRegistry.sol";
-import {NftId, toNftId, NftIdLib} from "../types/NftId.sol";
-import {ObjectType, INSTANCE, POLICY, BUNDLE} from "../types/ObjectType.sol";
-
-contract RegistryLinked is IRegistryLinked {
-    IRegistry internal _registry;
+import {IRegisterable} from "../shared/IRegisterable.sol";
+import {IService} from "../instance/base/IService.sol";
 
-    constructor(address registry) {
-        _registry = IRegistry(registry);
-    }
-
-    function getRegistry() external view override returns (IRegistry registry) {
-        return _registry;
-    }
-}
-
-abstract contract Registerable is RegistryLinked, IRegisterable {
-    using NftIdLib for NftId;
-
-    address private _initialOwner;
-
-    constructor(address registry) RegistryLinked(registry) {
-        _initialOwner = msg.sender;
-    }
-
-    // getType, getData and register need to be implemented by concrete contract
-
-    function isRegisterable() external pure override returns (bool) {
-        return true;
-    }
-
-    function getInitialOwner() public view override returns (address deployer) {
-        return _initialOwner;
-    }
-
-    function isRegistered() public view override returns (bool) {
-        NftId nftId = _registry.getNftId(address(this));
-        return nftId.gtz();
-    }
-
-    function getNftId() public view override returns (NftId nftId) {
-        return _registry.getNftId(address(this));
-    }
-
-    function getOwner() public view override returns (address owner) {
-        NftId id = _registry.getNftId(address(this));
-        owner = _registry.getOwner(id);
-        return owner != address(0) ? owner : _initialOwner;
-    }
-}
-
-contract Registry is IRegistry {
+import {IChainNft} from "./IChainNft.sol";
+import {ChainNft} from "./ChainNft.sol";
+import {IRegistry} from "./IRegistry.sol";
+import {NftId, toNftId, zeroNftId, NftIdLib} from "../types/NftId.sol";
+import {VersionPart} from "../types/Version.sol";
+import {ObjectType, PROTOCOL, REGISTRY, TOKEN, SERVICE, INSTANCE, STAKE, PRODUCT, DISTRIBUTOR, ORACLE, POOL, POLICY, BUNDLE} from "../types/ObjectType.sol";
+
+// TODO make registry upgradable
+contract Registry is
+    IRegisterable,
+    IRegistry
+{
     using NftIdLib for NftId;
 
     string public constant EMPTY_URI = "";
 
-    mapping(NftId nftId => RegistryInfo info) private _info;
+    mapping(NftId nftId => ObjectInfo info) private _info;
     mapping(NftId nftId => address owner) private _owner;
     mapping(address object => NftId nftId) private _nftIdByAddress;
+    mapping(ObjectType objectType => bool) private _isValidType;
+    mapping(ObjectType objectType => mapping(ObjectType objectParentType => bool)) private _isValidParentType;
 
+    mapping(NftId nftId => string stringValue) private _string;
+    mapping(bytes32 serviceNameHash => mapping(VersionPart majorVersion => address service)) _service;
+
+    NftId private _nftId;
     IChainNft private _chainNft;
+    ChainNft private _chainNftInternal;
+    address private _initialOwner;
 
-    function initialize(address chainNft) external {
+    // @dev will own protocol nft and registry nft(s) minted during initialize
+    address private _protocolOwner;
+
+    // TODO refactor once registry becomes upgradable
+    // @Dev the protocol owner will get ownership of the
+    // protocol nft and the global registry nft minted in this 
+    // initializer function 
+    function initialize(
+        address chainNft, 
+        address protocolOwner
+    )
+        public 
+    {
         require(
             address(_chainNft) == address(0),
             "ERROR:REG-001:ALREADY_INITIALIZED"
         );
+
+        _initialOwner = msg.sender;
+        _protocolOwner = protocolOwner;
+
         _chainNft = IChainNft(chainNft);
+        _chainNftInternal = ChainNft(chainNft);
+
+        // initial registry setup
+        _registerProtocol();
+        _nftId = _registerRegistry();
+
+        // setup rules for further registrations
+        _setupValidTypes();
+        _setupValidParentTypes();
     }
 
+
     function register(
         address objectAddress
-    ) external override returns (NftId nftId) {
+    )
+    // TODO add authz (only services may register components etc)
+    // we have to check how we do authz for registring services (just restrict to protocol owner/registry owner)
+    external override returns (NftId nftId) {
         require(
             _nftIdByAddress[objectAddress].eqz(),
             "ERROR:REG-002:ALREADY_REGISTERED"
@@ -82,44 +81,69 @@ contract Registry is IRegistry {
 
         IRegisterable registerable = IRegisterable(objectAddress);
         require(
-            registerable.isRegisterable(),
+            registerable.supportsInterface(type(IRegisterable).interfaceId),
             "ERROR:REG-003:NOT_REGISTERABLE"
         );
 
-        // check parent exists (for objects not instances)
-        if (registerable.getType() != INSTANCE()) {
-            RegistryInfo memory parentInfo = _info[
-                registerable.getParentNftId()
-            ];
-            require(parentInfo.nftId.gtz(), "ERROR:REG-004:PARENT_NOT_FOUND");
-            // check validity of parent relation, valid relations are
-            // policy -> product, bundle -> pool, product -> instance, pool -> instance
-        }
+        ObjectType objectType = registerable.getType();
+        require(
+            _isValidType[objectType],
+            "ERROR:REG-004:TYPE_INVALID"
+        );
+
+        NftId parentNftId = registerable.getParentNftId();
+        require(
+            isRegistered(parentNftId),
+            "ERROR:REG-005:PARENT_NOT_REGISTERED"
+        );
+
+        require(
+            _isValidParentType[objectType][_info[parentNftId].objectType],
+            "ERROR:REG-006:PARENT_TYPE_INVALID"
+        );
+
+        // also check that nftId and parentNFtId are on the same chain if applicable
 
+        // nft minting
         uint256 mintedTokenId = _chainNft.mint(
-            registerable.getInitialOwner(),
+            registerable.getOwner(),
             EMPTY_URI
         );
-        nftId = toNftId(mintedTokenId);
 
-        RegistryInfo memory info = RegistryInfo(
-            nftId,
-            registerable.getParentNftId(),
-            registerable.getType(),
-            objectAddress,
-            registerable.getInitialOwner()
-        );
+        nftId = toNftId(mintedTokenId);
 
-        _info[nftId] = info;
-        _nftIdByAddress[objectAddress] = nftId;
+        // special case services
+        if(registerable.getType() == SERVICE()) {
+            IService service = IService(objectAddress);
+            require(
+                service.supportsInterface(type(IService).interfaceId),
+                "ERROR:REG-007:NOT_SERVICE"
+            );
+
+            string memory serviceName = service.getName();
+            VersionPart majorVersion = service.getMajorVersion();
+            bytes32 serviceNameHash = keccak256(abi.encode(serviceName));
+
+            // service specific state
+            _string[nftId] = serviceName;
+
+            require(
+                _service[serviceNameHash][majorVersion] == address(0),
+                "ERROR:REG-008:ALREADY_REGISTERED"
+            );
+            _service[serviceNameHash][majorVersion] = objectAddress;
+        }
 
-        // add logging
+        // create object info and link nft id with it
+        _registerObjectInfo(registerable, nftId);
     }
 
+
     function registerObjectForInstance(
         NftId parentNftId,
         ObjectType objectType,
-        address initialOwner
+        address initialOwner,
+        bytes memory data
     )
         external
         override
@@ -131,18 +155,19 @@ contract Registry is IRegistry {
         // TODO add more validation
         require(
             objectType == POLICY() || objectType == BUNDLE(),
-            "ERROR:REG-005:TYPE_INVALID"
+            "ERROR:REG-010:TYPE_INVALID"
         );
 
         uint256 mintedTokenId = _chainNft.mint(initialOwner, EMPTY_URI);
         nftId = toNftId(mintedTokenId);
 
-        RegistryInfo memory info = RegistryInfo(
+        ObjectInfo memory info = ObjectInfo(
             nftId,
             parentNftId,
             objectType,
             address(0),
-            initialOwner
+            initialOwner,
+            data
         );
 
         _info[nftId] = info;
@@ -160,23 +185,197 @@ contract Registry is IRegistry {
         return _nftIdByAddress[object];
     }
 
+    function isRegistered(
+        NftId nftId
+    ) public view override returns (bool) {
+        return _info[nftId].objectType.gtz();
+    }
+
     function isRegistered(
         address object
     ) external view override returns (bool) {
         return _nftIdByAddress[object].gtz();
     }
 
-    function getInfo(
+    function getObjectInfo(
         NftId nftId
-    ) external view override returns (RegistryInfo memory info) {
+    ) external view override returns (ObjectInfo memory info) {
         return _info[nftId];
     }
 
+    function getName(
+        NftId nftId
+    ) external view returns (string memory name) {
+        return _string[nftId];
+    }
+
     function getOwner(NftId nftId) external view override returns (address) {
         return _chainNft.ownerOf(nftId.toInt());
     }
 
-    function getNftAddress() external view override returns (address nft) {
-        return address(_chainNft);
+    function getChainNft() external view override returns (IChainNft) {
+        return _chainNft;
+    }
+
+    // special case to retrive a gif service
+    function getServiceAddress(string memory serviceName, VersionPart majorVersion) external view override returns (address serviceAddress) {
+        bytes32 serviceNameHash = keccak256(abi.encode(serviceName));
+        return _service[serviceNameHash][majorVersion];
+    }
+
+    // from IERC165
+    function supportsInterface(bytes4 interfaceId) external pure override returns (bool) {
+        return interfaceId == type(IRegistry).interfaceId;
+    }
+
+    // from IRegistryLinked
+    function getRegistry() external view override returns (IRegistry registry) {
+        return this;
+    }
+
+    // from IRegisterable
+    function register() external pure override returns (NftId nftId) {
+        return zeroNftId();
+    }
+
+    function getType() external pure override returns (ObjectType objectType) {
+        return REGISTRY();
+    }
+
+
+    function getOwner() public view override returns (address owner) {
+        return _nftId.gtz() ? this.getOwner(_nftId) : _initialOwner;
+    }
+
+    function getNftId() external view override (IRegisterable, IRegistry) returns (NftId nftId) {
+        return _nftId;
+    }
+
+    function getParentNftId() external view returns (NftId nftId) {
+        // we're the global registry
+        if(block.chainid == 1) {
+            return toNftId(_chainNftInternal.PROTOCOL_NFT_ID());
+        }
+        else {
+            return toNftId(_chainNftInternal.GLOBAL_REGISTRY_ID());
+        }
+    }
+
+    function getData() external pure returns (bytes memory data) {
+        return "";
+    }
+
+    // registry specific functions
+    function getProtocolOwner() external view override returns (address) {
+        return _protocolOwner;
+    }
+
+    /// @dev defines which types are allowed to register
+    function _setupValidTypes() internal {
+        _isValidType[REGISTRY()] = true; // only for global registry 
+        _isValidType[TOKEN()] = true;
+        _isValidType[SERVICE()] = true;
+        _isValidType[INSTANCE()] = true;
+        _isValidType[STAKE()] = true;
+        _isValidType[PRODUCT()] = true;
+        _isValidType[ORACLE()] = true;
+        _isValidType[POOL()] = true;
+        _isValidType[POLICY()] = true;
+        _isValidType[BUNDLE()] = true;
     }
+
+    /// @dev defines which types - parent type relations are allowed to register
+    function _setupValidParentTypes() internal {
+        // registry as parent
+        _isValidParentType[TOKEN()][REGISTRY()] = true;
+        _isValidParentType[SERVICE()][REGISTRY()] = true;
+        _isValidParentType[INSTANCE()][REGISTRY()] = true;
+
+        // instance as parent
+        _isValidParentType[PRODUCT()][INSTANCE()] = true;
+        _isValidParentType[DISTRIBUTOR()][INSTANCE()] = true;
+        _isValidParentType[ORACLE()][INSTANCE()] = true;
+        _isValidParentType[POOL()][INSTANCE()] = true;
+
+        // product as parent
+        _isValidParentType[POLICY()][PRODUCT()] = true;
+
+        // pool as parent
+        _isValidParentType[BUNDLE()][POOL()] = true;
+        _isValidParentType[STAKE()][POOL()] = true;
+    }
+
+    /// @dev protocol registration used to anchor the dip ecosystem relations
+    function _registerProtocol() virtual internal {
+        uint256 protocolId = _chainNftInternal.PROTOCOL_NFT_ID();
+        _chainNftInternal.mint(_protocolOwner, protocolId);
+
+        NftId protocolNftid = toNftId(protocolId);
+        ObjectInfo memory protocolInfo = ObjectInfo(
+            protocolNftid,
+            zeroNftId(), // parent nft id
+            PROTOCOL(),
+            address(0), // contract address
+            _protocolOwner,
+            "" // data
+        );
+
+        _info[protocolNftid] = protocolInfo;
+    }
+
+    /// @dev registry registration
+    /// might also register the global registry when not on mainnet
+    function _registerRegistry() virtual internal returns (NftId registryNftId) {
+        uint256 registryId = _chainNftInternal.calculateTokenId(2);
+        registryNftId = toNftId(registryId);
+
+        // we're not the global registry
+        if(registryId != _chainNftInternal.GLOBAL_REGISTRY_ID()) {
+            _registerGlobalRegistry();
+        }
+
+        _chainNftInternal.mint(_protocolOwner, registryId);
+        _registerObjectInfo(this, registryNftId);
+    }
+
+
+    /// @dev global registry registration for non mainnet registries
+    function _registerGlobalRegistry() virtual internal {
+        uint256 globalRegistryId = _chainNftInternal.GLOBAL_REGISTRY_ID();
+        _chainNftInternal.mint(_protocolOwner, globalRegistryId);
+
+        NftId globalRegistryNftId = toNftId(globalRegistryId);
+        ObjectInfo memory globalRegistryInfo = ObjectInfo(
+            globalRegistryNftId,
+            toNftId(_chainNftInternal.PROTOCOL_NFT_ID()),
+            REGISTRY(),
+            address(0), // contract address
+            _protocolOwner,
+            "" // data
+        );
+
+        _info[globalRegistryNftId] = globalRegistryInfo;
+    }
+
+
+    function _registerObjectInfo(
+        IRegisterable registerable,
+        NftId nftId
+    ) internal virtual {
+        address objectAddress = address(registerable);
+        ObjectInfo memory info = ObjectInfo(
+            nftId,
+            registerable.getParentNftId(),
+            registerable.getType(),
+            objectAddress,
+            registerable.getOwner(),
+            registerable.getData()
+        );
+
+        _info[nftId] = info;
+        _nftIdByAddress[objectAddress] = nftId;
+
+        // add logging
+    }
+
 }

package/contracts/shared/ERC165.sol

@@ -0,0 +1,21 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
+
+contract ERC165 is IERC165 {
+    mapping(bytes4 => bool) private _isSupported;
+
+    constructor() {
+        // register support for ERC165
+        _registerInterface(type(IERC165).interfaceId);
+    }
+
+    function supportsInterface(bytes4 interfaceId) external view override returns (bool) {
+        return _isSupported[interfaceId];
+    }
+
+    function _registerInterface(bytes4 interfaceId) internal {
+        _isSupported[interfaceId] = true;
+    }
+}

package/contracts/shared/IOwnable.sol

@@ -0,0 +1,6 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+interface IOwnable {
+    function getOwner() external view returns (address owner);
+}

package/contracts/shared/IRegisterable.sol

@@ -0,0 +1,24 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {NftId} from "../types/NftId.sol";
+import {ObjectType} from "../types/ObjectType.sol";
+
+import {IOwnable} from "./IOwnable.sol";
+
+interface IRegisterable is IERC165, IOwnable {
+    function getRegistry() external view returns (IRegistry registry);
+
+    function register() external returns (NftId nftId);
+
+    function getType() external pure returns (ObjectType objectType);
+
+    function getNftId() external view returns (NftId nftId);
+
+    function getParentNftId() external view returns (NftId nftId);
+
+    function getData() external view returns (bytes memory data);
+}

package/contracts/shared/IVersionable.sol

@@ -0,0 +1,52 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Blocknumber, blockNumber} from "../types/Blocknumber.sol";
+import {Timestamp, blockTimestamp} from "../types/Timestamp.sol";
+import {Version, VersionPart} from "../types/Version.sol";
+
+interface IVersionable {
+
+    struct VersionInfo {
+        Version version;
+        address implementation;
+        address activatedBy;
+        Timestamp activatedAt;
+        Blocknumber activatedIn;
+    }
+
+    event LogVersionableActivated(Version version, address implementation, address activatedBy);
+
+    /**
+     * @dev IMPORTANT this function needs to be implemented by each new version
+     * any such activate implementation needs to call internal function call _activate() 
+     * any new version needs to inherit from previous version
+     */
+    function activate(address implementation, address activatedBy) external;
+
+    /**
+     * @dev returns true if the specified version has been activated for the current contract
+     */
+    function isActivated(Version version) external view returns(bool);
+
+    /**
+     * @dev returns currently active version of this contract
+     */
+    function getVersion() external pure returns(Version);
+
+    /**
+     * @dev returns the number of all deployed versions of this contract
+     */
+    function getVersionCount() external view returns(uint256 numberOfVersions);
+
+    /**
+     * @dev returns the i-th (index) version of this contract
+     */
+    function getVersion(uint256 index) external view returns(Version version);
+
+    /**
+     * @dev returns the i-th (index) version info of this contract
+     */
+    function getVersionInfo(Version version) external view returns(VersionInfo memory versionInfo);
+
+}

package/contracts/shared/Registerable.sol

@@ -0,0 +1,86 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {NftId, zeroNftId} from "../types/NftId.sol";
+import {ObjectType} from "../types/ObjectType.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IRegisterable} from "./IRegisterable.sol";
+
+import {ERC165} from "./ERC165.sol";
+
+abstract contract Registerable is
+    ERC165,
+    IRegisterable
+{
+    IRegistry internal immutable _registry;
+    NftId internal immutable _parentNftId;
+    address internal immutable _initialOwner;
+
+    modifier onlyOwner() virtual {
+        require(
+            msg.sender == getOwner(),
+            "ERROR:RGB-001:NOT_OWNER"
+        );
+        _;
+    }
+
+    constructor(
+        address registryAddress,
+        NftId parentNftId
+    )
+        ERC165()
+    {
+        require(
+            address(registryAddress) != address(0),
+            "ERROR:RGB-010:REGISTRY_ZERO"
+        );
+
+        _registry = IRegistry(registryAddress);
+        require(
+            _registry.supportsInterface(type(IRegistry).interfaceId),
+            "ERROR:RGB-011:NOT_REGISTRY"
+        );
+
+        _parentNftId = parentNftId;
+        require(
+            _registry.isRegistered(_parentNftId),
+            "ERROR:RGB-012:PARENT_NOT_REGISTERED"
+        );
+
+        _initialOwner = msg.sender;
+
+        // register support for IRegisterable
+        _registerInterface(type(IRegisterable).interfaceId);
+    }
+
+    // from IRegistryLinked
+    function register() public onlyOwner virtual override returns (NftId nftId) {
+        return _registry.register(address(this));
+    }
+
+    function getRegistry() public view virtual override returns (IRegistry registry) {
+        return _registry;
+    }
+
+    function getOwner() public view virtual override returns (address owner) {
+        NftId nftId = _registry.getNftId(address(this));
+        if(nftId == zeroNftId()) {
+            return _initialOwner;
+        }
+
+        return _registry.getOwner(nftId);
+    }
+
+    function getNftId() public view override returns (NftId nftId) {
+        return _registry.getNftId(address(this));
+    }
+
+    function getParentNftId() public view override returns (NftId nftId) {
+        return _parentNftId;
+    }
+
+    function getData() public view virtual override returns (bytes memory data) {
+        return "";
+    }
+}