@etherisc/gif-next 0.0.2-d3543ee-217 → 0.0.2-d39f345-355

package/contracts/instance/service/DistributionService.sol

@@ -0,0 +1,431 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../registry/IRegistry.sol";
+import {IInstance} from "../../instance/IInstance.sol";
+import {InstanceAccessManager} from "../InstanceAccessManager.sol";
+import {InstanceReader} from "../../instance/InstanceReader.sol";
+import {ISetup} from "../../instance/module/ISetup.sol";
+import {IPolicy} from "../module/IPolicy.sol";
+
+import {NftId, NftIdLib, zeroNftId} from "../../types/NftId.sol";
+import {Fee, FeeLib} from "../../types/Fee.sol";
+import {PRODUCT_SERVICE_ROLE, DISTRIBUTION_OWNER_ROLE} from "../../types/RoleId.sol";
+import {KEEP_STATE} from "../../types/StateId.sol";
+import {ObjectType, DISTRIBUTION, INSTANCE, DISTRIBUTION, DISTRIBUTOR} from "../../types/ObjectType.sol";
+import {Version, VersionLib} from "../../types/Version.sol";
+import {RoleId} from "../../types/RoleId.sol";
+
+import {IVersionable} from "../../shared/IVersionable.sol";
+import {Versionable} from "../../shared/Versionable.sol";
+
+import {IService} from "../../shared/IService.sol";
+import {Service} from "../../shared/Service.sol";
+import {ComponentService} from "../base/ComponentService.sol";
+import {InstanceService} from "../InstanceService.sol";
+import {IComponent} from "../../components/IComponent.sol";
+import {IDistributionComponent} from "../../components/IDistributionComponent.sol";
+import {IDistributionService} from "./IDistributionService.sol";
+
+import {UFixed, UFixedLib} from "../../types/UFixed.sol";
+import {DistributorType, DistributorTypeLib} from "../../types/DistributorType.sol";
+import {ReferralId, ReferralStatus, ReferralLib} from "../../types/Referral.sol";
+import {Timestamp, TimestampLib, zeroTimestamp} from "../../types/Timestamp.sol";
+import {Key32} from "../../types/Key32.sol";
+import {IDistribution} from "../module/IDistribution.sol";
+
+
+contract DistributionService is
+    ComponentService,
+    IDistributionService
+{
+    using NftIdLib for NftId;
+    using TimestampLib for Timestamp;
+    using UFixedLib for UFixed;
+    using FeeLib for Fee;
+    using ReferralLib for ReferralId;
+
+    address internal _registryAddress;
+    
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        initializer
+        virtual override
+    {
+        address initialOwner;
+        address registryAddress;
+        (registryAddress, initialOwner) = abi.decode(data, (address, address));
+        // TODO while DistributionService is not deployed in DistributionServiceManager constructor
+        //      owner is DistributionServiceManager deployer
+        initializeService(registryAddress, address(0), owner);
+        registerInterface(type(IDistributionService).interfaceId);
+    }
+
+    function getDomain() public pure override returns(ObjectType) {
+        return DISTRIBUTION();
+    }
+
+    function register(address distributionAddress) 
+        external
+        returns(NftId distributionNftId)
+    {
+        (
+            IComponent component,
+            address owner,
+            IInstance instance,
+            NftId instanceNftId
+        ) = _checkComponentForRegistration(
+            distributionAddress,
+            DISTRIBUTION(),
+            DISTRIBUTION_OWNER_ROLE());
+
+        IRegistry.ObjectInfo memory distributionInfo = getRegistryService().registerDistribution(component, owner);
+        IDistributionComponent distribution = IDistributionComponent(distributionAddress);
+        distribution.linkToRegisteredNftId();
+        distributionNftId = distributionInfo.nftId;
+
+        instance.createDistributionSetup(distributionNftId, distribution.getSetupInfo());
+        // TODO move to distribution?
+        bytes4[][] memory selectors = new bytes4[][](2);
+        selectors[0] = new bytes4[](1);
+        selectors[1] = new bytes4[](2);
+
+        selectors[0][0] = IDistributionComponent.setFees.selector;
+        selectors[1][0] = IDistributionComponent.processRenewal.selector;
+
+        RoleId[] memory roles = new RoleId[](2);
+        roles[0] = DISTRIBUTION_OWNER_ROLE();
+        roles[1] = PRODUCT_SERVICE_ROLE();
+
+        getInstanceService().createGifTarget(
+            instanceNftId, 
+            distributionAddress, 
+            distribution.getName(), 
+            selectors, 
+            roles);
+    }
+
+    function setFees(
+        Fee memory minDistributionOwnerFee,
+        Fee memory distributionFee
+    )
+        external
+        override
+    {
+        if (minDistributionOwnerFee.fractionalFee > distributionFee.fractionalFee) {
+            revert ErrorIDistributionServiceMinFeeTooHigh(minDistributionOwnerFee.fractionalFee.toInt(), distributionFee.fractionalFee.toInt());
+        }
+
+        (NftId distributionNftId, IRegistry.ObjectInfo memory info , IInstance instance) = _getAndVerifyComponentInfoAndInstance(DISTRIBUTION());
+        InstanceReader instanceReader = instance.getInstanceReader();
+
+        ISetup.DistributionSetupInfo memory distSetupInfo = instanceReader.getDistributionSetupInfo(distributionNftId);
+        distSetupInfo.minDistributionOwnerFee = minDistributionOwnerFee;
+        distSetupInfo.distributionFee = distributionFee;
+        
+        instance.updateDistributionSetup(distributionNftId, distSetupInfo, KEEP_STATE());
+    }
+
+    function createDistributorType(
+        string memory name,
+        UFixed minDiscountPercentage,
+        UFixed maxDiscountPercentage,
+        UFixed commissionPercentage,
+        uint32 maxReferralCount,
+        uint32 maxReferralLifetime,
+        bool allowSelfReferrals,
+        bool allowRenewals,
+        bytes memory data
+    )
+        external
+        returns (DistributorType distributorType)
+    {
+        (NftId distributionNftId, IInstance instance) = _getAndVerifyCallingDistribution();
+
+        {
+            ISetup.DistributionSetupInfo memory setupInfo = instance.getInstanceReader().getDistributionSetupInfo(distributionNftId);
+            UFixed variableFeesPartsTotal = setupInfo.minDistributionOwnerFee.fractionalFee.add(commissionPercentage);
+            UFixed maxDiscountPercentageLimit = setupInfo.distributionFee.fractionalFee.sub(variableFeesPartsTotal);
+            if (maxDiscountPercentage.gt(maxDiscountPercentageLimit)) {
+                revert ErrorIDistributionServiceMaxDiscountTooHigh(maxDiscountPercentage.toInt(), maxDiscountPercentageLimit.toInt());
+            }
+        }
+        
+        distributorType = DistributorTypeLib.toDistributorType(distributionNftId, name);
+        IDistribution.DistributorTypeInfo memory info = IDistribution.DistributorTypeInfo(
+            name,
+            minDiscountPercentage,
+            maxDiscountPercentage,
+            commissionPercentage,
+            maxReferralCount,
+            maxReferralLifetime,
+            allowSelfReferrals,
+            allowRenewals,
+            data);
+
+        instance.createDistributorType(distributorType, info);
+    }
+
+    function createDistributor(
+        address distributor,
+        DistributorType distributorType,
+        bytes memory data
+    ) external returns (NftId distributorNftId)
+    {
+        (NftId distributionNftId, IInstance instance) = _getAndVerifyCallingDistribution();
+
+        distributorNftId = getRegistryService().registerDistributor(
+            IRegistry.ObjectInfo(
+                zeroNftId(), 
+                distributionNftId,
+                DISTRIBUTOR(),
+                true, // intercepting property for bundles is defined on pool
+                address(0),
+                distributor,
+                ""
+            ));
+
+        IDistribution.DistributorInfo memory info = IDistribution.DistributorInfo(
+            distributorType,
+            true, // active
+            data,
+            0,
+            0);
+
+        instance.createDistributor(distributorNftId, info);
+    }
+
+    function updateDistributorType(
+        NftId distributorNftId,
+        DistributorType distributorType,
+        bytes memory data
+    ) external virtual
+    {
+        (, IInstance instance) = _getAndVerifyCallingDistribution();
+        InstanceReader instanceReader = instance.getInstanceReader();
+        IDistribution.DistributorInfo memory distributorInfo = instanceReader.getDistributorInfo(distributorNftId);
+        distributorInfo.distributorType = distributorType;
+        distributorInfo.data = data;
+        instance.updateDistributor(distributorNftId, distributorInfo, KEEP_STATE());
+    }
+
+
+    function createReferral(
+        NftId distributorNftId,
+        string memory code,
+        UFixed discountPercentage,
+        uint32 maxReferrals,
+        Timestamp expiryAt,
+        bytes memory data
+    )
+        external
+        virtual
+        returns (ReferralId referralId)
+    {
+        (NftId distributionNftId, IInstance instance) = _getAndVerifyCallingDistribution();
+
+        if (bytes(code).length == 0) {
+            revert ErrorIDistributionServiceInvalidReferral(code);
+        }
+        if (expiryAt.eqz()) {
+            revert ErrorIDistributionServiceExpirationInvalid(expiryAt);
+        }
+
+        InstanceReader instanceReader = instance.getInstanceReader();
+        IDistribution.DistributorInfo memory distributorInfo = instanceReader.getDistributorInfo(distributorNftId);
+        DistributorType distributorType = distributorInfo.distributorType;
+        IDistribution.DistributorTypeInfo memory distributorTypeData = instanceReader.getDistributorTypeInfo(distributorType);
+
+        if (distributorTypeData.maxReferralCount < maxReferrals) {
+            revert ErrorIDistributionServiceMaxReferralsExceeded(distributorTypeData.maxReferralCount);
+        }
+        if (distributorTypeData.minDiscountPercentage > discountPercentage) {
+            revert ErrorIDistributionServiceDiscountTooLow(distributorTypeData.minDiscountPercentage.toInt(), discountPercentage.toInt());
+        }
+        if (distributorTypeData.maxDiscountPercentage < discountPercentage) {
+            revert ErrorIDistributionServiceDiscountTooHigh(distributorTypeData.maxDiscountPercentage.toInt(), discountPercentage.toInt());
+        }
+        if (expiryAt.toInt() - TimestampLib.blockTimestamp().toInt() > distributorTypeData.maxReferralLifetime) {
+            revert ErrorIDistributionServiceExpiryTooLong(distributorTypeData.maxReferralLifetime, expiryAt.toInt());
+        }
+
+        referralId = ReferralLib.toReferralId(distributionNftId, code);
+        IDistribution.ReferralInfo memory info = IDistribution.ReferralInfo(
+            distributorNftId,
+            code,
+            discountPercentage,
+            maxReferrals,
+            0, // used referrals
+            expiryAt,
+            data
+        );
+
+        instance.createReferral(referralId, info);
+        return referralId;
+    }
+
+    function processSale(
+        NftId distributionNftId,
+        ReferralId referralId,
+        IPolicy.Premium memory premium,
+        uint256 transferredDistributionFeeAmount
+    )
+        external
+        virtual
+    {
+        bool isReferral = ! referralId.eqz();
+        bool referralValid = referralIsValid(distributionNftId, referralId);
+
+        if (isReferral && ! referralValid) {
+            revert ErrorIDistributionServiceReferralInvalid(distributionNftId, referralId);
+        }
+
+        IInstance instance = _getInstanceForDistribution(distributionNftId);
+        InstanceReader reader = instance.getInstanceReader();
+        IDistribution.ReferralInfo memory referralInfo = reader.getReferralInfo(referralId);
+        IDistribution.DistributorInfo memory distributorInfo = reader.getDistributorInfo(referralInfo.distributorNftId);
+        ISetup.DistributionSetupInfo memory setupInfo = reader.getDistributionSetupInfo(distributionNftId);
+        
+        uint256 distributionOwnerFee = premium.distributionOwnerFeeFixAmount + premium.distributionOwnerFeeVarAmount;
+        uint256 commissionAmount = premium.commissionAmount;
+
+        if (transferredDistributionFeeAmount != distributionOwnerFee + commissionAmount) {
+            revert ErrorIDistributionServiceInvalidFeeTransferred(transferredDistributionFeeAmount, distributionOwnerFee + commissionAmount);
+        }
+
+
+        if (distributionOwnerFee > 0) {
+            setupInfo.sumDistributionOwnerFees += distributionOwnerFee;
+            instance.updateDistributionSetup(distributionNftId, setupInfo, KEEP_STATE());
+        }
+
+        if (isReferral) {
+            referralInfo.usedReferrals += 1;
+            instance.updateReferral(referralId, referralInfo, KEEP_STATE());
+
+            if (commissionAmount > 0) {
+                distributorInfo.sumCommisions += commissionAmount;
+                distributorInfo.numPoliciesSold += 1;
+                instance.updateDistributor(referralInfo.distributorNftId, distributorInfo, KEEP_STATE());
+            }
+        }
+    }
+
+    function calculateFeeAmount(
+        NftId distributionNftId,
+        ReferralId referralId,
+        IPolicy.Premium memory premium
+    )
+        external
+        virtual
+        view 
+        returns (IPolicy.Premium memory finalPremium)
+    {
+        IInstance instance = _getInstanceForDistribution(distributionNftId);
+        InstanceReader reader = instance.getInstanceReader();
+        
+        // first calculate all fixed and variable fees for the distribution - this will defined the fullPremium
+        ISetup.DistributionSetupInfo memory setupInfo = reader.getDistributionSetupInfo(distributionNftId);
+        Fee memory distributionFee = setupInfo.distributionFee;
+        Fee memory minDistributionOwnerFee = setupInfo.minDistributionOwnerFee;
+        uint256 distributionFeeVarAmount = (UFixedLib.toUFixed(premium.netPremiumAmount) * distributionFee.fractionalFee).toInt();
+        premium.distributionFeeVarAmount = distributionFeeVarAmount;
+        premium.fullPremiumAmount += distributionFeeVarAmount;
+            
+        // if the referral is not valid, then the distribution owner gets everything
+        if (! referralIsValid(distributionNftId, referralId)) {
+            premium.distributionOwnerFeeFixAmount = premium.distributionFeeFixAmount;
+            premium.distributionOwnerFeeVarAmount = premium.distributionFeeVarAmount;
+            premium.premiumAmount = premium.fullPremiumAmount;
+            return premium;
+        }
+
+        // if the referral is valid, the the commission and discount are calculated based in the full premium
+        // the remaing amount goes to the distribution owner
+        {
+            IDistribution.ReferralInfo memory referralInfo = reader.getReferralInfo(referralId);
+            IDistribution.DistributorInfo memory distributorInfo = reader.getDistributorInfo(referralInfo.distributorNftId);
+            IDistribution.DistributorTypeInfo memory distributorTypeInfo = reader.getDistributorTypeInfo(distributorInfo.distributorType);
+
+            uint256 commissionAmount = UFixedLib.toUFixed(premium.netPremiumAmount).mul(distributorTypeInfo.commissionPercentage).toInt();
+            premium.commissionAmount = commissionAmount;
+            premium.discountAmount = UFixedLib.toUFixed(premium.fullPremiumAmount).mul(referralInfo.discountPercentage).toInt();
+            premium.distributionOwnerFeeFixAmount = minDistributionOwnerFee.fixedFee;
+            premium.distributionOwnerFeeVarAmount = distributionFeeVarAmount - commissionAmount - premium.discountAmount;
+            premium.premiumAmount = premium.fullPremiumAmount - premium.discountAmount;
+        }
+
+        // sanity check to validate the fee calculation
+        if (premium.distributionOwnerFeeFixAmount < minDistributionOwnerFee.fixedFee) {
+            revert ErrorIDistributionServiceFeeCalculationMismatch(
+                premium.distributionFeeFixAmount,
+                premium.distributionFeeVarAmount,
+                premium.distributionOwnerFeeFixAmount,
+                premium.distributionOwnerFeeVarAmount,
+                premium.commissionAmount,
+                premium.discountAmount
+            );
+        }
+        if ((premium.distributionFeeVarAmount) != (premium.discountAmount + premium.distributionOwnerFeeVarAmount + premium.commissionAmount)) {
+            revert ErrorIDistributionServiceFeeCalculationMismatch(
+                premium.distributionFeeFixAmount,
+                premium.distributionFeeVarAmount,
+                premium.distributionOwnerFeeFixAmount,
+                premium.distributionOwnerFeeVarAmount,
+                premium.commissionAmount,
+                premium.discountAmount
+            );
+        }
+        
+        return premium; 
+    }
+
+    // TODO: zero should return false
+    function referralIsValid(NftId distributionNftId, ReferralId referralId) public view returns (bool isValid) {
+        IInstance instance = _getInstanceForDistribution(distributionNftId);
+        IDistribution.ReferralInfo memory info = instance.getInstanceReader().getReferralInfo(referralId);
+
+        if (info.distributorNftId.eqz()) {
+            return false;
+        }
+
+        isValid = info.expiryAt.eqz() || (info.expiryAt.gtz() && TimestampLib.blockTimestamp() <= info.expiryAt);
+        isValid = isValid && info.usedReferrals < info.maxReferrals;
+    }
+
+    function _getAndVerifyCallingDistribution()
+        internal
+        view
+        returns(
+            NftId distributionNftId,
+            IInstance instance
+        )
+    {
+        distributionNftId = getRegistry().getNftId(msg.sender);
+        if (distributionNftId.eqz()) {
+            revert ErrorDistributionServiceCallerNotRegistered(msg.sender);
+        }
+
+        IRegistry.ObjectInfo memory info = getRegistry().getObjectInfo(distributionNftId);
+        if(info.objectType != DISTRIBUTION()) {
+            revert ErrorIDistributionServiceCallerNotDistributor(msg.sender);
+        }
+
+        address instanceAddress = getRegistry().getObjectInfo(info.parentNftId).objectAddress;
+        instance = IInstance(instanceAddress);
+    }
+
+
+    function _getInstanceForDistribution(NftId distributionNftId)
+        internal
+        view
+        returns(IInstance instance)
+    {
+        NftId instanceNftId = getRegistry().getObjectInfo(distributionNftId).parentNftId;
+        address instanceAddress = getRegistry().getObjectInfo(instanceNftId).objectAddress;
+        return IInstance(instanceAddress);
+    }
+}

package/contracts/instance/service/DistributionServiceManager.sol

@@ -0,0 +1,51 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IVersionable} from "../../shared/IVersionable.sol";
+import {ProxyManager} from "../../shared/ProxyManager.sol";
+import {DistributionService} from "./DistributionService.sol";
+import {Registry} from "../../registry/Registry.sol";
+import {RegistryService} from "../../registry/RegistryService.sol";
+import {REGISTRY} from "../../types/ObjectType.sol";
+
+contract DistributionServiceManager is ProxyManager {
+
+    DistributionService private _distributionService;
+
+    /// @dev initializes proxy manager with distribution service implementation and deploys instance
+    constructor(
+        address registryAddress
+    )
+        ProxyManager(registryAddress)
+    {
+        DistributionService distSrv = new DistributionService();
+        bytes memory data = abi.encode(registryAddress, address(this));
+        IVersionable versionable = deploy(
+            address(distSrv), 
+            data);
+
+        _distributionService = DistributionService(address(versionable));
+        
+        // TODO `thi` must have a role or own nft to register service
+        //Registry registry = Registry(registryAddress);
+        //address registryServiceAddress = registry.getServiceAddress(REGISTRY(), _distributionService.getMajorVersion());
+        //RegistryService registryService = RegistryService(registryServiceAddress);
+        //registryService.registerService(_distributionService);
+        
+        // TODO no nft to link yet
+        // link ownership of instance service manager ot nft owner of instance service
+        //_linkToNftOwnable(
+        //    address(registryAddress),
+        //    address(_distributionService));
+    }
+
+    //--- view functions ----------------------------------------------------//
+    function getDistributionService()
+        external
+        view
+        returns (DistributionService distributionService)
+    {
+        return _distributionService;
+    }
+
+}

package/contracts/instance/service/IApplicationService.sol

@@ -0,0 +1,78 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IPolicy} from "../module/IPolicy.sol";
+import {IService} from "../../shared/IService.sol";
+
+import {NftId} from "../../types/NftId.sol";
+import {ObjectType} from "../../types/ObjectType.sol";
+import {ReferralId} from "../../types/Referral.sol";
+import {RiskId} from "../../types/RiskId.sol";
+import {Seconds} from "../../types/Seconds.sol";
+
+/// @dev gif service responsible for creating applications
+/// only product components may call transaction functions
+interface IApplicationService is IService {
+    
+    error ErrorApplicationServiceNotProduct(NftId callerNftId, ObjectType callerType);
+    error ErrorApplicationServiceBundlePoolMismatch(NftId bundleNftId, NftId bundlePoolNftId, NftId poolNftId);
+
+    /// @dev creates a new application based on the specified attributes
+    /// may only be called by a product component
+    function create(
+        address applicationOwner,
+        RiskId riskId,
+        uint256 sumInsuredAmount,
+        Seconds lifetime,
+        NftId bundleNftId,
+        ReferralId referralId,
+        bytes memory applicationData
+    ) external returns (NftId applicationNftId);
+
+    /// @dev updates application attributes
+    /// may only be called while the application is in applied state
+    /// may only be called by the referenced product related to applicationNftId
+    function adjust(
+        NftId applicationNftId,
+        RiskId riskId,
+        NftId bundleNftId,
+        ReferralId referralId,
+        uint256 sumInsuredAmount,
+        uint256 lifetime,
+        bytes memory applicationData
+    ) external;
+
+    /// @dev creates a new application that extends the provided policy
+    /// lifetime will seamlessly extend referenced policy, for closed policies
+    /// lifetime will start at underwriting time
+    /// product will need to limit the time window for renewal as underwriting
+    /// will lock the collateral at underwriting time which might be earlier than activation time
+    /// policyNftId needs to refer to an underwritten (or active or closed) policy
+    /// may only be called by the referenced product related to policyNftId
+    function renew(
+        NftId policyNftId, // policy to be renewd (renewal inherits policy attributes)
+        NftId bundleNftId // will likely need a newer bundle for underwriting
+    ) external returns (NftId applicationNftId);
+
+    /// @dev revokes the application represented by {policyNftId}
+    /// an application can only be revoked in applied state
+    /// only the application holder may revoke an application
+    function revoke(NftId policyNftId) external;
+
+    /// @dev calculates the premium amount for the specified attributes
+    /// also returns the various fee components involved with creating a policy
+    function calculatePremium(
+        NftId productNftId,
+        RiskId riskId,
+        uint256 sumInsuredAmount,
+        Seconds lifetime,
+        bytes memory applicationData,
+        NftId bundleNftId,
+        ReferralId referralId
+    )
+        external
+        view
+        returns (
+            IPolicy.Premium memory premium
+        );
+}

package/contracts/instance/service/IBundleService.sol

@@ -0,0 +1,102 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Amount} from "../../types/Amount.sol";
+import {NftId} from "../../types/NftId.sol";
+import {Fee} from "../../types/Fee.sol";
+import {IService} from "../../shared/IService.sol";
+import {IBundle} from "../module/IBundle.sol";
+import {IInstance} from "../../instance/IInstance.sol";
+import {Seconds} from "../../types/Seconds.sol";
+import {StateId} from "../../types/StateId.sol";
+import {Timestamp} from "../../types/Timestamp.sol";
+
+interface IBundleService is IService {
+
+    event LogBundleServiceBundleActivated(NftId bundleNftId);
+    event LogBundleServiceBundleLocked(NftId bundleNftId);
+
+    error ErrorBundleServiceInsufficientAllowance(address bundleOwner, address tokenHandlerAddress, uint256 amount);
+    error ErrorBundleServiceBundleNotOpen(NftId bundleNftId, StateId state, Timestamp expiredAt);
+    error ErrorBundleServiceCapacityInsufficient(NftId bundleNftId, uint capacityAmount, uint collateralAmount);
+    error ErrorBundleServiceBundleWithOpenPolicies(NftId bundleNftId, uint256 openPoliciesCount);
+
+    error ErrorBundleServiceBundleUnknown(NftId bundleNftId);
+    error ErrorBundleServiceBundlePoolMismatch(NftId expectedPoolNftId, NftId bundlePoolNftId);
+
+    /// @dev create a new bundle for the specified attributes
+    /// may only be called by pool service
+    function create(
+        IInstance instance, // instance relevant for bundle
+        NftId poolNftId, // the pool the bundle will be linked to
+        address owner, // initial bundle owner
+        Fee memory fee, // fees deducted from premium that go to bundle owner
+        Amount stakingAmount, // staking amount - staking fees result in initial bundle capital
+        Seconds lifetime, // initial duration for which new policies are covered
+        bytes calldata filter // optional use case specific criteria that define if a policy may be covered by this bundle
+    )
+        external 
+        returns(NftId bundleNftId); // the nft id of the newly created bundle
+
+    /// @dev locks the specified bundle, locked bundles are not available to collateralize new policies
+    /// only active bundles may be locked
+    /// may only be called by registered and unlocked pool components
+    function lock(NftId bundleNftId) external;
+
+    /// @dev activates the specified bundle
+    /// only locked bundles may be unlocked
+    /// may only be called by registered and unlocked pool components
+    function unlock(NftId bundleNftId) external;
+
+    /// @dev closes the specified bundle
+    /// only open bundles (active or locked) may be closed
+    /// to close a bundle it may not have any non-closed polices attached to it
+    /// may only be called by registered and unlocked pool components
+    function close(
+        IInstance instance, 
+        NftId bundleNftId
+    ) external;
+
+    /// @dev set bundle fee to provided value
+    /// may only be called by registered and unlocked pool components
+    function setFee(
+        NftId bundleNftId,
+        Fee memory fee
+    ) external;
+
+
+    /// @dev locks the specified collateral in the bundle
+    /// the locked collateral is added to the bundle locked capital
+    /// the bundles' fees are updated with the fees for this premium
+    /// the premium (minus bundle fee) is added to the bundle capital
+    /// may only be called by pool service
+    function lockCollateral(
+        IInstance instanceNftId, 
+        NftId policyNftId, 
+        NftId bundleNftId, 
+        uint256 collateralAmount, 
+        uint256 premium // premium amount after pool fee
+    ) external;
+
+    /// @dev updates the bundle's fees of with the provided fee amount
+    function updateBundleFees(
+        IInstance instance,
+        NftId bundleNftId,
+        Amount feeAmount
+    ) external;
+
+    /// @dev releases the specified collateral in the bundle
+    /// may only be called by pool service
+    function releaseCollateral(
+        IInstance instance, 
+        NftId policyNftId, 
+        NftId bundleNftId, 
+        uint256 collateralAmount
+    ) external;
+
+    function increaseBalance(IInstance instance, NftId bundleNftId,  uint256 amount) external;
+
+    // function stake(NftId bundleNftId, uint256 amount) external returns(uint256 netAmount);
+
+    // function unstake(NftId bundleNftId, uint256 amount) external returns(uint256 netAmount);
+}