@etherisc/gif-next 0.0.2-d250c72 → 0.0.2-d2fd9d7-008

package/contracts/shared/IService.sol

@@ -0,0 +1,15 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {VersionPart} from "../types/Version.sol";
+
+import {IRegisterable} from "./IRegisterable.sol";
+import {IVersionable} from "./IVersionable.sol";
+
+interface IService is 
+    IRegisterable,
+    IVersionable
+{
+    function getName() external pure returns(string memory name);
+    function getMajorVersion() external view returns(VersionPart majorVersion);
+}

package/contracts/shared/IVersionable.sol

@@ -0,0 +1,96 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Blocknumber} from "../types/Blocknumber.sol";
+import {Timestamp} from "../types/Timestamp.sol";
+import {Version} from "../types/Version.sol";
+
+
+/// IMPORTANT
+// Upgradeable contract MUST:
+// 1) inherit from Versionable
+// 2) implement version() function
+// 3) implement internal _initialize() function with onlyInitializing modifier 
+// 4) implement internal _upgrade() function with onlyInitializing modifier (1st version MUST revert)
+// 5) have onlyInitialising modifier for each function callable inside _initialize()/_upgrade() (MUST use different functions for initialization/upgrade and normal operations)
+// 6) use default empty constructor -> _disableInitializer() is called from Versionable contructor
+// 7) use namespace storage
+// 8) since now inheritance is used for upgradability, contract MUST BE inherited ONLY by the next version 
+// Upgradeable contract SHOULD:
+// 9) define all non private methods as virtual (in order to be able to upgrade them latter)
+//    otherwise, it is still possible to upgrade contract, but everyone who is using it will have to switch to a new fucntions
+//    in some cases this ok but not in the others...
+//
+// IMPORTANT
+// Each version MUST:
+// 1) define namespace storage struct if accessing storage
+//      - DO NOT use structs inside, except
+//      - CAN use structs ONLY inside mappings
+// 2) ALWAYS define private getter if accessing storage
+//      - MUST use default implementation, CAN change ONLY return type
+//      - MUST use the same "LOCATION_V1"
+
+interface IVersionable {
+
+    struct VersionInfo {
+        Version version;
+        address implementation;
+        address activatedBy;
+        Timestamp activatedAt;
+        Blocknumber activatedIn;
+    }
+
+    event LogVersionableInitialized(Version version, address implementation, address activatedBy);
+
+    // TODO uncomment when all implementations are ready
+    /**
+     * @dev IMPORTANT
+     * implementation MUST be guarded by initializer modifier
+     * implementation MUST call internal function Versionable._updateVersionHistory 
+     * new version MUST inherit from previous version
+     */
+    function initialize(address implementation, address activatedBy, bytes memory activationData) external;
+
+    /**
+     * @dev
+     * implementation MUST be guarded by reinitializer(version().toUint64()) modifier
+     * implementation MUST call internal function Versionable._updateVersionHistory
+     * new version MUST inherit from previous version
+     * the first verion MUST revert 
+     */
+    function upgrade(address implementation, address activatedBy, bytes memory upgradeData) external;
+
+    /**
+     * @dev returns true if the specified version has been activated for the current contract
+     */
+    function isInitialized(Version version) external view returns(bool);
+
+    /**
+     * @dev returns version of this contract
+     * each new implementation MUST implement this function
+     * version number MUST increase 
+     */
+    function getVersion() external pure returns(Version);
+
+    /**
+     * @dev returns the number of all deployed versions of this contract
+     */
+    function getVersionCount() external view returns(uint256 numberOfVersions);
+
+    /**
+     * @dev returns the i-th (index) version of this contract
+     */
+    function getVersion(uint256 index) external view returns(Version version);
+
+    /**
+     * @dev returns the i-th (index) version info of this contract
+     */
+    function getVersionInfo(Version version) external view returns(VersionInfo memory versionInfo);
+
+    // TODO make sure it is needed here
+    /**
+     * @dev returns currently active version
+     */
+    function getInitializedVersion() external view returns(uint64);
+
+}

package/contracts/shared/NftOwnable.sol

@@ -0,0 +1,134 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {INftOwnable} from "./INftOwnable.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {NftId, zeroNftId} from "../types/NftId.sol";
+
+contract NftOwnable is INftOwnable {
+
+    IRegistry internal _registry;
+    NftId private _nftId;
+    address private _initialOwner; 
+
+    /// @dev enforces msg.sender is owner of nft (or initial owner of nft ownable)
+    modifier onlyOwner() {
+        if (msg.sender != getOwner()) {
+            revert ErrorNotOwner(msg.sender);
+        }
+        _;
+    }
+
+    constructor() {
+        _initialOwner = msg.sender;
+    }
+
+    /// @dev links this contract to nft after registration
+    // needs to be done once per registered contract and 
+    // reduces registry calls to check ownership
+    // does not need any protection as function can only do the "right thing"
+    function linkToRegisteredNftId() public {
+        if (_nftId.gtz()) {
+            revert ErrorAlreadyLinked(address(_registry), _nftId);
+        }
+
+        if (address(_registry) == address(0)) {
+            revert ErrorRegistryNotInitialized();
+        }
+
+        address contractAddress = address(this);
+
+        if (!_registry.isRegistered(contractAddress)) {
+            revert ErrorContractNotRegistered(contractAddress);
+        }
+
+        _nftId = _registry.getNftId(contractAddress);
+    }
+
+
+    function getRegistry() public view virtual override returns (IRegistry) {
+        return _registry;
+    }
+
+
+    function getNftId() public view virtual override returns (NftId) {
+        return _nftId;
+    }
+
+
+    function getOwner() public view virtual override returns (address) {
+        if (_nftId.gtz()) {
+            return _registry.ownerOf(_nftId);
+        }
+
+        return _initialOwner;
+    }
+
+
+    /// @dev initialization for upgradable contracts
+    // used in _initializeRegisterable
+    function _initializeNftOwnable(
+        address initialOwner,
+        address registryAddress
+    )
+        internal
+        virtual
+    {
+        require(initialOwner > address(0), "NftOwnable: initial owner is 0");
+        _initialOwner = initialOwner;
+        _setRegistry(registryAddress);
+    }
+
+
+    /// @dev used in constructor of registry service manager
+    // links ownership of registry service manager ot nft owner of registry service
+    function _linkToNftOwnable(
+        address registryAddress,
+        address nftOwnableAddress
+    )
+        internal
+        onlyOwner()
+        returns (NftId)
+    {
+        if (_nftId.gtz()) {
+            revert ErrorAlreadyLinked(address(_registry), _nftId);
+        }
+
+        _setRegistry(registryAddress);
+
+        if (!_registry.isRegistered(nftOwnableAddress)) {
+            revert ErrorContractNotRegistered(nftOwnableAddress);
+        }
+
+        _nftId = _registry.getNftId(nftOwnableAddress);
+
+        return _nftId;
+    }
+
+
+    function _setRegistry(address registryAddress)
+        private
+    {
+        if (address(_registry) != address(0)) {
+            revert ErrorRegistryAlreadyInitialized(address(_registry));
+        }
+
+        if (registryAddress == address(0)) {
+            revert ErrorRegistryAddressZero();
+        }
+
+        if (registryAddress.code.length == 0) {
+            revert ErrorNotRegistry(registryAddress);
+        }
+
+        _registry = IRegistry(registryAddress);
+
+        try _registry.supportsInterface(type(IRegistry).interfaceId) returns (bool isRegistry) {
+            if (!isRegistry) {
+                revert ErrorNotRegistry(registryAddress);
+            }
+        } catch {
+            revert ErrorNotRegistry(registryAddress);
+        }
+    }
+}

package/contracts/shared/ProxyManager.sol

@@ -0,0 +1,94 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
+import {ProxyAdmin} from "@openzeppelin/contracts/proxy/transparent/ProxyAdmin.sol";
+import {ITransparentUpgradeableProxy} from "@openzeppelin/contracts/proxy/transparent/TransparentUpgradeableProxy.sol";
+
+import {IVersionable} from "./IVersionable.sol";
+import {NftOwnable} from "./NftOwnable.sol";
+import {UpgradableProxyWithAdmin} from "./UpgradableProxyWithAdmin.sol";
+
+/// @dev manages proxy deployments for upgradable contracs of type IVersionable
+contract ProxyManager is
+    NftOwnable
+{
+
+    event LogProxyDeployed(address indexed proxy, address initialImplementation);
+    event LogProxyDeployedWithSalt(address indexed proxy, address initialImplementation);
+    event LogProxyUpgraded(address indexed proxy, address upgradedImplementation);
+
+    error ErrorAlreadyDeployed();
+    error ErrorAlreadyDeployedWithSalt();
+    error ErrorNotYetDeployed();
+
+    UpgradableProxyWithAdmin internal _proxy;
+    bool internal _isDeployed;
+
+    /// @dev only used to capture proxy owner
+    constructor()
+        NftOwnable()
+    { }
+
+    /// @dev deploy initial contract
+    function deploy(address initialImplementation, bytes memory initializationData)
+        public
+        virtual
+        onlyOwner()
+        returns (IVersionable versionable)
+    {
+        if (_isDeployed) { revert ErrorAlreadyDeployed(); }
+
+        address currentProxyOwner = getOwner(); // used by implementation
+        address initialProxyAdminOwner = address(this); // used by proxy
+        bytes memory data = getDeployData(initialImplementation, currentProxyOwner, initializationData);
+        
+        _proxy = new UpgradableProxyWithAdmin(
+            initialImplementation,
+            initialProxyAdminOwner,
+            data
+        );
+
+        _isDeployed = true;
+        versionable = IVersionable(address(_proxy));
+
+        emit LogProxyDeployed(address(_proxy), initialImplementation);
+    }
+
+    /// @dev upgrade existing contract
+    function upgrade(address newImplementation, bytes memory upgradeData)
+        public
+        virtual
+        onlyOwner()
+        returns (IVersionable versionable)
+    {
+        if (!_isDeployed) { revert ErrorNotYetDeployed(); }
+
+        address currentProxyOwner = getOwner();
+        ProxyAdmin proxyAdmin = getProxy().getProxyAdmin();
+        ITransparentUpgradeableProxy proxy = ITransparentUpgradeableProxy(address(_proxy));
+        bytes memory data = getUpgradeData(newImplementation, currentProxyOwner, upgradeData);
+
+        proxyAdmin.upgradeAndCall(
+            proxy,
+            newImplementation, 
+            data);
+
+        versionable = IVersionable(address(_proxy));
+
+        emit LogProxyUpgraded(address(_proxy), newImplementation);
+
+    }
+
+    function getDeployData(address implementation, address proxyOwner, bytes memory deployData) public pure returns (bytes memory data) {
+        return abi.encodeWithSelector(IVersionable.initialize.selector, implementation, proxyOwner, deployData);
+    }
+
+    function getUpgradeData(address implementation, address proxyOwner, bytes memory upgradeData) public pure returns (bytes memory data) {
+        return abi.encodeWithSelector(IVersionable.upgrade.selector, implementation, proxyOwner, upgradeData);
+    }
+
+    function getProxy() public returns (UpgradableProxyWithAdmin) {
+        return _proxy;
+    }
+}

package/contracts/shared/Registerable.sol

@@ -0,0 +1,90 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol"; 
+
+import {NftId, zeroNftId} from "../types/NftId.sol";
+import {NftOwnable} from "../shared/NftOwnable.sol";
+import {ObjectType} from "../types/ObjectType.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IRegisterable} from "./IRegisterable.sol";
+import {Versionable} from "./Versionable.sol";
+
+import {ERC165} from "./ERC165.sol";
+
+contract Registerable is
+    ERC165,
+    Initializable,
+    NftOwnable,
+    IRegisterable
+{
+    // keccak256(abi.encode(uint256(keccak256("gif-next.contracts.shared.Registerable.sol")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant REGISTERABLE_LOCATION_V1 = 0x6548007c3f4340f82f348c576c0ff69f4f529cadd5ad41f96aae61abceeaa300;
+
+    error ErrorRegisterableNotRegistry(address registryAddress);
+
+    struct RegisterableStorage {
+        NftId _parentNftId;
+        ObjectType _objectType;
+        bool _isInterceptor;
+        bytes _data;
+    }
+
+    function _getRegisterableStorage() private pure returns (RegisterableStorage storage $) {
+        assembly {
+            $.slot := REGISTERABLE_LOCATION_V1
+        }
+    }
+
+    function _initializeRegisterable(
+        address registryAddress,
+        NftId parentNftId,
+        ObjectType objectType,
+        bool isInterceptor,
+        address initialOwner,
+        bytes memory data
+    )
+        internal
+        //onlyInitializing//TODO uncomment when "fully" upgradeable
+        virtual
+    {
+        _initializeERC165();
+        _initializeNftOwnable(
+            initialOwner,
+            registryAddress);
+
+        // TODO check parentNftId -> registry.isRegistered(parentNftId)
+        // TODO check object-parent type pair -> registry.isValidTypeCombo() or something...verify with registry that setup will be able to register...
+
+        RegisterableStorage storage $ = _getRegisterableStorage();
+        $._parentNftId = parentNftId;
+        $._objectType = objectType;
+        $._isInterceptor = isInterceptor;
+        $._data = data;
+
+        _registerInterface(type(IRegisterable).interfaceId);
+    }
+
+
+    function getInitialInfo() 
+        public 
+        view 
+        virtual 
+        returns (IRegistry.ObjectInfo memory, bytes memory data) 
+    {
+        RegisterableStorage storage $ = _getRegisterableStorage();
+        return (
+            IRegistry.ObjectInfo(
+                getNftId(),
+                $._parentNftId,
+                $._objectType,
+                $._isInterceptor,
+                address(this), 
+                getOwner(),
+                $._data
+            ),
+            bytes("")
+        );
+    }
+}

package/contracts/shared/RegisterableUpgradable.sol

@@ -0,0 +1,16 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Registerable} from "./Registerable.sol";
+import {Versionable} from "./Versionable.sol";
+
+/// @dev base contract for upgradable objects like services and upgradable components
+/// deriving contracs need to call _initializeRegisterable
+/// TODO internalizes versionable here, a non-registerable versionalbe might itself have some value but is outside the scope of the gif
+/// after this merge versionable will no longer exist on its own in gif
+/// only registerable and upgradable (which is a registerable too) will remain
+abstract contract RegisterableUpgradable is 
+    Registerable,
+    Versionable
+{
+}

package/contracts/shared/Service.sol

@@ -0,0 +1,55 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IService} from "./IService.sol";
+import {IVersionable} from "./IVersionable.sol";
+import {NftId, zeroNftId} from "../types/NftId.sol";
+import {RegisterableUpgradable} from "./RegisterableUpgradable.sol";
+import {SERVICE} from "../types/ObjectType.sol";
+import {Version, VersionPart, VersionLib} from "../types/Version.sol";
+import {Versionable} from "./Versionable.sol";
+
+/// @dev service base contract
+abstract contract Service is 
+    RegisterableUpgradable,
+    IService
+{
+    function getName() public pure virtual override returns(string memory name);
+
+    function getMajorVersion() public view virtual override returns(VersionPart majorVersion) {
+        return getVersion().toMajorPart(); 
+    }
+
+    // from Versionable
+    function getVersion()
+        public 
+        pure 
+        virtual override (IVersionable, Versionable)
+        returns(Version)
+    {
+        return VersionLib.toVersion(3,0,0);
+    }
+
+    function _initializeService(
+        address registry, 
+        address initialOwner
+    )
+        internal
+        virtual
+        //onlyInitializing //TODO uncomment when "fully" upgradeable
+    {
+        // service must provide its name and version upon registration
+        bytes memory data = abi.encode(getName(), getMajorVersion());
+        NftId registryNftId = _getRegistryNftId(registry); 
+        bool isInterceptor = false;
+
+        _initializeRegisterable(registry, registryNftId, SERVICE(), isInterceptor, initialOwner, data);
+        _registerInterface(type(IService).interfaceId);
+    }
+
+    // this is just a conveniene function, actual validation will be done upon registration
+    function _getRegistryNftId(address registryAddress) internal view returns (NftId) {
+        return IRegistry(registryAddress).getNftId(registryAddress);
+    }
+}

package/contracts/shared/TokenHandler.sol

@@ -0,0 +1,27 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
+
+contract TokenHandler {
+    IERC20Metadata private _token;
+
+    constructor(address token) {
+        _token = IERC20Metadata(token);
+    }
+
+    // TODO add logging
+    function transfer(
+        address from,
+        address to,
+        uint256 amount // TODO add authz (only treasury/instance/product/pool/ service)
+    ) external {
+        SafeERC20.safeTransferFrom(_token, from, to, amount);
+        // _token.transferFrom(from, to, amount);
+    }
+
+    function getToken() external view returns (IERC20Metadata) {
+        return _token;
+    }
+}

package/contracts/shared/UpgradableProxyWithAdmin.sol

@@ -0,0 +1,16 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ProxyAdmin} from "@openzeppelin/contracts/proxy/transparent/ProxyAdmin.sol";
+import {TransparentUpgradeableProxy, ITransparentUpgradeableProxy} from "@openzeppelin/contracts/proxy/transparent/TransparentUpgradeableProxy.sol";
+
+import {IVersionable} from "./IVersionable.sol";
+
+contract UpgradableProxyWithAdmin is TransparentUpgradeableProxy {
+
+    constructor(address implementation, address initialProxyAdminOwner, bytes memory data)
+        TransparentUpgradeableProxy(implementation, initialProxyAdminOwner, data)
+    {}
+
+    function getProxyAdmin() external returns (ProxyAdmin) { return ProxyAdmin(_proxyAdmin()); }
+}

package/contracts/shared/Versionable.sol

@@ -0,0 +1,147 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol";
+
+import {Blocknumber, blockNumber} from "../types/Blocknumber.sol";
+import {Timestamp, TimestampLib} from "../types/Timestamp.sol";
+import {Version, VersionPart, VersionLib} from "../types/Version.sol";
+
+import {IVersionable} from "./IVersionable.sol";
+
+
+
+abstract contract Versionable is 
+    Initializable,
+    IVersionable 
+{
+    // keccak256(abi.encode(uint256(keccak256("gif-next.contracts.shared.Versionable.sol")) - 1)) & ~bytes32(uint256(0xff))
+    bytes32 private constant VERSIONABLE_LOCATION_V1 = 0x4f61291a8ac3d020d0a7d919a76b8592aa88385744dee3f8b4f3873b969ed900;
+
+
+    /// @custom:storage-location erc7201:gif-next.contracts.shared.Versionable.sol
+    struct VersionableStorage {
+        mapping(Version version => VersionInfo info) _versionHistory;
+        Version [] _versions;
+        Version _v1;
+    }
+
+
+    constructor() {
+        _disableInitializers();
+    }
+    // TODO write test where new version of private _updateVersionHistory is added and used... 
+    function initialize(
+        address implementation,
+        address activatedBy,
+        bytes memory data
+    )
+        public
+        initializer
+    {
+        _updateVersionHistory(implementation, activatedBy);
+        _initialize(activatedBy, data);
+    }
+
+    // TODO activatedBy MUST ALWAYS be an owner?
+    function upgrade(
+        address implementation,
+        address activatedBy,
+        bytes memory data
+    )
+        external
+        reinitializer(VersionLib.toUint64(getVersion()))
+    {
+        _updateVersionHistory(implementation, activatedBy);
+        _upgrade(data);
+    }
+
+    function isInitialized(Version _version) public override view returns(bool) {
+        return _getVersionableStorage()._versionHistory[_version].activatedIn.toInt() > 0;
+    }
+
+    function getVersion() public pure virtual returns(Version);
+
+    function getVersionCount() public view override returns(uint256) {
+        return _getVersionableStorage()._versions.length;
+    }
+
+    function getVersion(uint256 idx) public view override returns(Version) {
+        return _getVersionableStorage()._versions[idx];
+    }
+
+    function getVersionInfo(Version _version) public override view returns(VersionInfo memory) {
+        return _getVersionableStorage()._versionHistory[_version];
+    }
+
+    function getInitializedVersion() public view returns(uint64) {
+        return _getInitializedVersion();
+    }
+
+
+
+    // IMPORTANT each version must implement this function 
+    // each implementation MUST use onlyInitialising modifier
+    // each implementation MUST call intializers of all base contracts...
+    function _initialize(address owner, bytes memory data) 
+        internal
+        onlyInitializing
+        virtual 
+    {
+        revert();
+    }
+
+
+    // IMPORTANT each version except version "1" must implement this function 
+    // each implementation MUST use onlyInitialising modifier
+    function _upgrade(bytes memory data)
+        internal
+        onlyInitializing
+        virtual
+    {
+        revert();
+    }
+
+    function _getVersionableStorage() private pure returns (VersionableStorage storage $) {
+        assembly {
+            $.slot := VERSIONABLE_LOCATION_V1
+        }
+    }
+
+    // can only be called once per contract
+    // needs to be called inside the proxy upgrade tx
+    // TODO run reinitializer(version().toUint64()) modifier after "version()" is checked, 
+    function _updateVersionHistory(
+        address implementation,
+        address activatedBy
+    )
+        private
+        onlyInitializing
+    {
+        VersionableStorage storage $ = _getVersionableStorage();
+
+        uint64 version = _getInitializedVersion();
+
+        Version thisVersion = getVersion();
+
+        if(version == 1) {
+            // thisVersion is alias to version "1"
+            $._v1 = thisVersion;
+        }
+        else {
+            require(thisVersion > $._v1, "INVALID VERSION");
+        }
+
+        // update version history
+        $._versions.push(thisVersion);
+        $._versionHistory[thisVersion] = VersionInfo(
+            thisVersion,
+            implementation,
+            activatedBy,
+            TimestampLib.blockTimestamp(),
+            blockNumber()
+        );
+
+        emit LogVersionableInitialized(thisVersion, implementation, activatedBy);
+    }
+}