@etherisc/gif-next 0.0.2-cf68d0c-530 → 0.0.2-cffb0b6-814

package/contracts/pool/PoolService.sol

@@ -0,0 +1,434 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IBundleService} from "./IBundleService.sol";
+import {IComponents} from "../instance/module/IComponents.sol";
+import {IComponentService} from "../shared/IComponentService.sol";
+import {IInstance} from "../instance/IInstance.sol";
+import {IInstanceService} from "../instance/IInstanceService.sol";
+import {IPolicy} from "../instance/module/IPolicy.sol";
+import {IPoolService} from "./IPoolService.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IRegistryService} from "../registry/IRegistryService.sol";
+import {IStaking} from "../staking/IStaking.sol";
+
+import {Amount, AmountLib} from "../type/Amount.sol";
+import {Fee, FeeLib} from "../type/Fee.sol";
+import {NftId, NftIdLib} from "../type/NftId.sol";
+import {ObjectType, POOL, BUNDLE, COMPONENT, INSTANCE, REGISTRY} from "../type/ObjectType.sol";
+import {RoleId, PUBLIC_ROLE} from "../type/RoleId.sol";
+import {Fee, FeeLib} from "../type/Fee.sol";
+import {KEEP_STATE} from "../type/StateId.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {TokenHandler} from "../shared/TokenHandler.sol";
+import {UFixed} from "../type/UFixed.sol";
+import {ComponentVerifyingService} from "../shared/ComponentVerifyingService.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {InstanceStore} from "../instance/InstanceStore.sol";
+
+string constant POOL_SERVICE_NAME = "PoolService";
+
+contract PoolService is 
+    ComponentVerifyingService, 
+    IPoolService 
+{
+    IBundleService internal _bundleService;
+    IComponentService internal _componentService;
+    IInstanceService private _instanceService;
+    IRegistryService private _registryService;
+
+    IStaking private _staking;
+
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        initializer
+        virtual override
+    {
+        (
+            address registryAddress,, 
+            //address managerAddress
+            address authority
+        ) = abi.decode(data, (address, address, address));
+
+        initializeService(registryAddress, authority, owner);
+
+        _registryService = IRegistryService(_getServiceAddress(REGISTRY()));
+        _bundleService = IBundleService(_getServiceAddress(BUNDLE()));
+        _instanceService = IInstanceService(_getServiceAddress(INSTANCE()));
+        _componentService = IComponentService(_getServiceAddress(COMPONENT()));
+
+        _staking = IStaking(getRegistry().getStakingAddress());
+
+        registerInterface(type(IPoolService).interfaceId);
+    }
+
+
+    function setMaxCapitalAmount(Amount maxCapitalAmount)
+        external
+        virtual
+    {
+        /*
+        (NftId poolNftId,, IInstance instance) = _getAndVerifyActiveComponent(POOL());
+        InstanceReader instanceReader = instance.getInstanceReader();
+
+        IComponents.ComponentInfo memory componentInfo = instanceReader.getComponentInfo(poolNftId);
+        IComponents.PoolInfo memory poolInfo = abi.decode(componentInfo.data, (IComponents.PoolInfo));
+        Amount previousMaxCapitalAmount = poolInfo.maxCapitalAmount;
+
+        poolInfo.maxCapitalAmount = maxCapitalAmount;
+        instance.getInstanceStore().updatePool(poolNftId, poolInfo, KEEP_STATE());
+
+        emit LogPoolServiceMaxCapitalAmountUpdated(poolNftId, previousMaxCapitalAmount, maxCapitalAmount);
+        */
+    }
+
+    function setBundleOwnerRole(RoleId bundleOwnerRole)
+        external
+        virtual
+    {
+        (NftId poolNftId,, IInstance instance) = _getAndVerifyActiveComponent(POOL());
+        InstanceReader instanceReader = instance.getInstanceReader();
+
+        IComponents.ComponentInfo memory componentInfo = instanceReader.getComponentInfo(poolNftId);
+        IComponents.PoolInfo memory poolInfo = abi.decode(componentInfo.data, (IComponents.PoolInfo));
+
+        // bundle owner role may only be set once per pool
+        if(poolInfo.bundleOwnerRole != PUBLIC_ROLE()) {
+            revert ErrorPoolServiceBundleOwnerRoleAlreadySet(poolNftId);
+        }
+
+        poolInfo.bundleOwnerRole = bundleOwnerRole;
+        instance.getInstanceStore().updatePool(poolNftId, poolInfo, KEEP_STATE());
+
+        emit LogPoolServiceBundleOwnerRoleSet(poolNftId, bundleOwnerRole);
+    }
+
+
+    function setFees(
+        Fee memory poolFee,
+        Fee memory stakingFee,
+        Fee memory performanceFee
+    )
+        external
+        virtual
+    {
+        (NftId poolNftId,, IInstance instance) = _getAndVerifyActiveComponent(POOL());
+
+        IComponents.PoolInfo memory poolInfo = instance.getInstanceReader().getPoolInfo(poolNftId);
+        poolInfo.poolFee = poolFee;
+        poolInfo.stakingFee = stakingFee;
+        poolInfo.performanceFee = performanceFee;
+
+        instance.getInstanceStore().updatePool(poolNftId, poolInfo, KEEP_STATE());
+
+        // TODO add logging
+    }
+
+    function createBundle(
+        address bundleOwner, // initial bundle owner
+        Fee memory fee, // fees deducted from premium that go to bundle owner
+        Amount stakingAmount, // staking amount - staking fees result in initial bundle capital
+        Seconds lifetime, // initial duration for which new policies are covered
+        bytes calldata filter // optional use case specific criteria that define if a policy may be covered by this bundle
+    )
+        external 
+        virtual
+        returns(NftId bundleNftId)
+    {
+        (NftId poolNftId,, IInstance instance) = _getAndVerifyActiveComponent(POOL());
+        InstanceReader instanceReader = instance.getInstanceReader();
+
+        (
+            Amount stakingFeeAmount,
+            Amount stakingNetAmount
+        ) = FeeLib.calculateFee(
+            _getStakingFee(instanceReader, poolNftId), 
+            stakingAmount);
+
+        bundleNftId = _bundleService.create(
+            instance,
+            poolNftId,
+            bundleOwner,
+            fee,
+            stakingNetAmount,
+            lifetime,
+            filter);
+
+        // pool book keeping
+        _componentService.increasePoolBalance(
+            instance.getInstanceStore(), 
+            poolNftId, 
+            stakingAmount, 
+            stakingFeeAmount);
+
+        // pool bookkeeping and collect tokens from bundle owner
+        _collectStakingAmount(
+            instanceReader, 
+            poolNftId, 
+            bundleOwner, 
+            stakingAmount);
+
+        emit LogPoolServiceBundleCreated(instance.getNftId(), poolNftId, bundleNftId);
+    }
+
+    function _getStakingFee(InstanceReader instanceReader, NftId poolNftId)
+        internal
+        virtual
+        view
+        returns (Fee memory stakingFee)
+    {
+        NftId productNftId = instanceReader.getPoolInfo(poolNftId).productNftId;
+        return instanceReader.getPoolInfo(productNftId).stakingFee;
+    }
+
+    function closeBundle(NftId bundleNftId)
+        external
+        virtual
+    {
+        (NftId poolNftId,, IInstance instance) = _getAndVerifyActiveComponent(POOL());
+
+        // TODO book keeping for pool collateral released outside of retention level
+
+        // releasing collateral in bundle
+        _bundleService.close(instance, bundleNftId);
+
+        // TODO get performance fee for pool, transfer of remaining funds + bundle fees to bundle owner
+
+        emit LogPoolServiceBundleClosed(instance.getNftId(), poolNftId, bundleNftId);
+    }
+
+
+    function processSale(
+        NftId bundleNftId, 
+        IPolicy.Premium memory premium 
+    ) 
+        external
+        virtual
+        restricted()
+    {
+        IRegistry registry = getRegistry();
+        IRegistry.ObjectInfo memory bundleObjectInfo = registry.getObjectInfo(bundleNftId);
+        IRegistry.ObjectInfo memory poolObjectInfo = registry.getObjectInfo(bundleObjectInfo.parentNftId);
+        IRegistry.ObjectInfo memory instanceObjectInfo = registry.getObjectInfo(poolObjectInfo.parentNftId);
+        IInstance instance = IInstance(instanceObjectInfo.objectAddress);
+
+        Amount poolFeeAmount = AmountLib.toAmount(premium.poolFeeFixAmount + premium.poolFeeVarAmount);
+        Amount bundleFeeAmount = AmountLib.toAmount(premium.bundleFeeFixAmount + premium.bundleFeeVarAmount);
+        Amount bundleNetAmount = AmountLib.toAmount(premium.netPremiumAmount);
+
+        InstanceStore instanceStore = instance.getInstanceStore();
+        _componentService.increasePoolBalance(
+            instanceStore,
+            poolObjectInfo.nftId,
+            bundleNetAmount + bundleFeeAmount, 
+            poolFeeAmount);
+
+        _componentService.increaseBundleBalance(
+            instanceStore,
+            bundleObjectInfo.nftId,
+            bundleNetAmount, 
+            bundleFeeAmount);
+    }
+
+
+    function lockCollateral(
+        IInstance instance, 
+        address token,
+        NftId productNftId,
+        NftId applicationNftId,
+        NftId bundleNftId,
+        Amount sumInsuredAmount // premium amount after product and distribution fees
+    )
+        external
+        virtual
+        restricted()
+        returns (
+            Amount localCollateralAmount,
+            Amount totalCollateralAmount
+        )
+    {
+        (
+            localCollateralAmount,
+            totalCollateralAmount
+        ) = calculateRequiredCollateral(
+            instance.getInstanceReader(),
+            productNftId, 
+            sumInsuredAmount);
+
+        // lock collateral amount from involved bundle
+        _bundleService.lockCollateral(
+            instance,
+            applicationNftId, 
+            bundleNftId,
+            localCollateralAmount);
+
+        // update value locked with staking service
+        _staking.increaseTotalValueLocked(
+            instance.getNftId(),
+            token,
+            totalCollateralAmount);
+
+        // hierarhical riskpool setup
+        // TODO loop in with pool component to guarantee availability of external capital
+        if(totalCollateralAmount > localCollateralAmount) {
+
+        }
+    }
+
+
+    function reduceCollateral(
+        IInstance instance, 
+        address token,
+        NftId policyNftId, 
+        IPolicy.PolicyInfo memory policyInfo,
+        Amount payoutAmount
+    )
+        external
+        virtual
+        restricted()
+    {
+        _bundleService.releaseCollateral(
+            instance, 
+            policyNftId, 
+            policyInfo.bundleNftId, 
+            payoutAmount);
+
+        // update value locked with staking service
+        _staking.decreaseTotalValueLocked(
+            instance.getNftId(),
+            token,
+            payoutAmount);
+    }
+
+
+    /// @dev releases the remaining collateral linked to the specified policy
+    /// may only be called by the policy service for unlocked pool components
+    function releaseCollateral(
+        IInstance instance, 
+        address token,
+        NftId policyNftId, 
+        IPolicy.PolicyInfo memory policyInfo
+    )
+        external
+        virtual
+        restricted()
+    {
+        Amount remainingCollateralAmount = policyInfo.sumInsuredAmount - policyInfo.claimAmount;
+
+        _bundleService.releaseCollateral(
+            instance, 
+            policyNftId, 
+            policyInfo.bundleNftId, 
+            remainingCollateralAmount);
+
+        _bundleService.unlinkPolicy(
+            instance, 
+            policyNftId);
+
+        // update value locked with staking service
+        _staking.decreaseTotalValueLocked(
+            instance.getNftId(),
+            token,
+            remainingCollateralAmount);
+    }
+
+
+    function calculateRequiredCollateral(
+        InstanceReader instanceReader,
+        NftId productNftId, 
+        Amount sumInsuredAmount
+    )
+        public
+        view 
+        returns(
+            Amount localCollateralAmount,
+            Amount totalCollateralAmount
+        )
+    {
+        NftId poolNftId = instanceReader.getProductInfo(productNftId).poolNftId;
+        IComponents.PoolInfo memory poolInfo = instanceReader.getPoolInfo(poolNftId);
+
+        (
+            localCollateralAmount,
+            totalCollateralAmount
+        ) = calculateRequiredCollateral(
+            poolInfo.collateralizationLevel,
+            poolInfo.retentionLevel,
+            sumInsuredAmount);
+    }
+
+
+    function calculateRequiredCollateral(
+        UFixed collateralizationLevel, 
+        UFixed retentionLevel, 
+        Amount sumInsuredAmount
+    )
+        public
+        pure 
+        returns(
+            Amount localCollateralAmount,
+            Amount totalCollateralAmount
+        )
+    {
+        // TODO define if only applies to local collateral
+        // TODO add minimalistic implementation
+
+        // assumptions 
+        // - collateralizationLevel == 1.0
+        // - retentionLevel == 1.0
+        localCollateralAmount = sumInsuredAmount;
+        totalCollateralAmount = localCollateralAmount;
+    }
+
+
+    function _processStakingFees(
+        Fee memory stakingFee, 
+        Amount stakingAmount
+    )
+        internal
+        returns (Amount stakingNetAmount)
+    {
+        stakingNetAmount = stakingAmount;
+
+        // check if any staking fees apply
+        if (FeeLib.gtz(stakingFee)) {
+            (Amount feeAmount, Amount netAmount) = FeeLib.calculateFee(stakingFee, stakingAmount);
+            stakingNetAmount = netAmount;
+
+            // TODO update fee balance for pool
+        }
+    }
+
+
+    // TODO create (I)TreasuryService that deals with all gif related token transfers
+    /// @dev transfers the specified amount from the bundle owner to the pool's wallet
+    function _collectStakingAmount(
+        InstanceReader instanceReader,
+        NftId poolNftId,
+        address bundleOwner,
+        Amount amount
+    )
+        internal
+    {
+
+        // collecting investor token
+        IComponents.ComponentInfo memory componentInfo = instanceReader.getComponentInfo(poolNftId);
+        TokenHandler tokenHandler = componentInfo.tokenHandler;
+        address poolWallet = componentInfo.wallet;
+
+        if(amount.gtz()) {
+            // TODO: centralize token handling (issue #471)
+            tokenHandler.transfer(
+                bundleOwner,
+                poolWallet,
+                amount);
+        }
+    }
+
+    function _getDomain() internal pure override returns(ObjectType) {
+        return POOL();
+    }
+}

package/contracts/pool/PoolServiceManager.sol

@@ -0,0 +1,39 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IVersionable} from "../upgradeability/IVersionable.sol";
+import {ProxyManager} from "../upgradeability/ProxyManager.sol";
+import {PoolService} from "./PoolService.sol";
+
+contract PoolServiceManager is ProxyManager {
+
+    PoolService private _poolService;
+
+    /// @dev initializes proxy manager with pool service implementation 
+    constructor(
+        address authority, 
+        address registryAddress,
+        bytes32 salt
+    ) 
+        ProxyManager(registryAddress)
+    {
+        PoolService poolSrv = new PoolService{salt: salt}();
+        bytes memory data = abi.encode(registryAddress, address(this), authority);
+        IVersionable versionable = deployDetermenistic(
+            address(poolSrv), 
+            data,
+            salt);
+
+        _poolService = PoolService(address(versionable));
+    }
+
+    //--- view functions ----------------------------------------------------//
+    function getPoolService()
+        external
+        view
+        returns (PoolService poolService)
+    {
+        return _poolService;
+    }
+
+}

package/contracts/product/ApplicationService.sol

@@ -0,0 +1,230 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IApplicationService} from "./IApplicationService.sol";
+import {IComponents} from "../instance/module/IComponents.sol";
+import {IInstance} from "../instance/IInstance.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IPolicy} from "../instance/module/IPolicy.sol";
+import {IDistributionService} from "../distribution/IDistributionService.sol";
+import {IPricingService} from "./IPricingService.sol";
+import {IRegistryService} from "../registry/IRegistryService.sol";
+
+import {AmountLib} from "../type/Amount.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {zeroTimestamp} from "../type/Timestamp.sol";
+import {ObjectType, DISTRIBUTION, PRODUCT, REGISTRY, APPLICATION, POLICY, PRICE} from "../type/ObjectType.sol";
+import {REVOKED} from "../type/StateId.sol";
+import {NftId, NftIdLib} from "../type/NftId.sol";
+import {ReferralId} from "../type/Referral.sol";
+import {RiskId} from "../type/RiskId.sol";
+import {Amount, AmountLib} from "../type/Amount.sol";
+import {ComponentVerifyingService} from "../shared/ComponentVerifyingService.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+
+
+
+contract ApplicationService is 
+    ComponentVerifyingService, 
+    IApplicationService
+{
+    IDistributionService private _distributionService;
+    IPricingService private _pricingService;
+    IRegistryService private _registryService;
+
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        virtual override
+        initializer()
+    {
+        (
+            address registryAddress,, 
+            //address managerAddress
+            address authority
+        ) = abi.decode(data, (address, address, address));
+
+        initializeService(registryAddress, address(0), owner);
+
+        _distributionService = IDistributionService(_getServiceAddress(DISTRIBUTION()));
+        _pricingService = IPricingService(_getServiceAddress(PRICE()));
+        _registryService = IRegistryService(_getServiceAddress(REGISTRY()));
+
+        registerInterface(type(IApplicationService).interfaceId);
+    }
+
+
+    function _checkLinkedpplicationParameters(
+        InstanceReader instanceReader,
+        NftId productNftId,
+        RiskId rirskId,
+        ReferralId referralId,
+        NftId bundleNftId
+    )
+        internal
+        virtual
+        view
+    {
+        IComponents.ProductInfo memory productInfo = instanceReader.getProductInfo(productNftId);
+
+        // TODO check riskId with product
+
+        // TODO check referral with distribution
+
+        // check bundle with pool
+        NftId productPoolNftId = productInfo.poolNftId;
+        NftId bundlePoolNftId = instanceReader.getBundleInfo(bundleNftId).poolNftId;
+        if(bundlePoolNftId != productPoolNftId) {
+            revert ErrorApplicationServiceBundlePoolMismatch(bundleNftId, productPoolNftId, bundlePoolNftId);
+        }
+    }
+
+
+    function _registerApplication(
+        NftId productNftId,
+        address applicationOwner
+    )
+        internal
+        virtual
+        returns (NftId applicationNftId)
+    {
+        IRegistry.ObjectInfo memory objectInfo = IRegistry.ObjectInfo(
+            NftIdLib.zero(),
+            productNftId,
+            POLICY(),
+            false, // intercepting property for policies is defined on product
+            address(0),
+            applicationOwner,
+            "");
+
+        applicationNftId = _registryService.registerPolicy(objectInfo);
+    }
+
+
+    function _calculatePremiumAmount(
+        IPolicy.PolicyInfo memory info
+    )
+        internal
+        virtual
+        view
+        returns (Amount premiumAmount)
+    {
+        return AmountLib.toAmount(
+            _pricingService.calculatePremium(
+                info.productNftId,
+                info.riskId,
+                info.sumInsuredAmount,
+                info.lifetime,
+                info.applicationData,
+                info.bundleNftId,
+                info.referralId
+            ).premiumAmount);
+    }
+
+
+    function create(
+        address applicationOwner,
+        RiskId riskId,
+        Amount sumInsuredAmount,
+        Seconds lifetime,
+        NftId bundleNftId,
+        ReferralId referralId,
+        bytes memory applicationData
+    )
+        external
+        virtual
+        returns (NftId applicationNftId)
+    {
+        (NftId productNftId,, IInstance instance) = _getAndVerifyActiveComponent(PRODUCT());
+
+        // check if provided references are valid and linked to calling product contract
+        InstanceReader instanceReader = instance.getInstanceReader();
+        _checkLinkedpplicationParameters(
+            instanceReader,
+            productNftId,
+            riskId,
+            referralId,
+            bundleNftId);
+
+        // register application with registry
+        applicationNftId = _registerApplication(productNftId, applicationOwner);
+
+        // create policy info for application
+        IPolicy.PolicyInfo memory applicationInfo = IPolicy.PolicyInfo({
+            productNftId:       productNftId,
+            bundleNftId:        bundleNftId,
+            referralId:         referralId,
+            riskId:             riskId,
+            sumInsuredAmount:   sumInsuredAmount,
+            premiumAmount:      AmountLib.zero(),
+            premiumPaidAmount:  AmountLib.zero(),
+            lifetime:           lifetime,
+            applicationData:    applicationData,
+            processData:        "",
+            claimsCount:        0,
+            openClaimsCount:    0,
+            claimAmount:        AmountLib.zero(),
+            payoutAmount:       AmountLib.zero(),
+            activatedAt:        zeroTimestamp(),
+            expiredAt:          zeroTimestamp(),
+            closedAt:           zeroTimestamp()
+        });
+
+        // TODO consider to provide this amount externally
+        // actual calculation is done 2nd time anyway for premium collection
+        // calculate premium amount
+        applicationInfo.premiumAmount = _calculatePremiumAmount(applicationInfo);
+
+        // register application with instance
+        instance.getInstanceStore().createApplication(
+            applicationNftId, 
+            applicationInfo);
+
+        // TODO: add logging
+    }
+
+
+    function renew(
+        NftId policyNftId, // policy to be renewd (renewal inherits policy attributes)
+        NftId bundleNftId // will likely need a newer bundle for underwriting
+    )
+        external
+        virtual override
+        returns (NftId applicationNftId)
+    {
+
+    }
+
+
+    function adjust(
+        NftId applicationNftId,
+        RiskId riskId,
+        NftId bundleNftId,
+        ReferralId referralId,
+        Amount sumInsuredAmount,
+        Seconds lifetime,
+        bytes memory applicationData
+    )
+        external
+        virtual override
+    {
+
+    }
+
+    function revoke(NftId applicationNftId)
+        external
+        virtual override
+    {
+        (,, IInstance instance) = _getAndVerifyActiveComponent(PRODUCT());
+        instance.getInstanceStore().updateApplicationState(applicationNftId, REVOKED());
+    }
+
+    // internal functions
+
+
+    function _getDomain() internal pure override returns(ObjectType) {
+        return APPLICATION();
+    }
+}