@etherisc/gif-next 0.0.2-ce87da3-250 → 0.0.2-cf22d7b-845

package/contracts/components/Component.sol

@@ -1,241 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.20;
-
-import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
-import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
-import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
-
-import {IComponent} from "./IComponent.sol";
-import {IProductService} from "../instance/service/IProductService.sol";
-import {IInstanceService} from "../instance/IInstanceService.sol";
-import {IInstance} from "../instance/IInstance.sol";
-import {InstanceAccessManager} from "../instance/InstanceAccessManager.sol";
-import {InstanceReader} from "../instance/InstanceReader.sol";
-import {IRegistry} from "../registry/IRegistry.sol";
-import {NftId} from "../types/NftId.sol";
-import {ObjectType, INSTANCE, PRODUCT} from "../types/ObjectType.sol";
-import {VersionPart} from "../types/Version.sol";
-import {Registerable} from "../shared/Registerable.sol";
-import {RoleId, RoleIdLib} from "../types/RoleId.sol";
-import {IAccess} from "../instance/module/IAccess.sol";
-import {VersionPart} from "../types/Version.sol";
-
-// TODO discuss to inherit from oz accessmanaged
-// then add (Distribution|Pool|Product)Upradeable that also intherit from Versionable
-// same pattern as for Service which is also upgradeable
-abstract contract Component is
-    Registerable,
-    IComponent,
-    AccessManagedUpgradeable
-{
-    // keccak256(abi.encode(uint256(keccak256("gif-next.contracts.component.Component.sol")) - 1)) & ~bytes32(uint256(0xff));
-    bytes32 public constant CONTRACT_LOCATION_V1 = 0xffe8d4462baed26a47154f4b8f6db497d2f772496965791d25bd456e342b7f00;
-
-    struct ComponentStorage {
-        IInstance _instance; // instance for this component
-        InstanceReader _instanceReader; // instance reader for this component
-        string _name; // unique (per instance) component name
-        IERC20Metadata _token; // token for this component
-        address _wallet; // wallet for this component (default = component contract itself)
-        bool _isNftInterceptor; // declares if component is involved in nft transfers
-        IInstanceService _instanceService; // instance service for this component
-
-        NftId _productNftId; // only relevant for components that are linked to a aproduct
-        IProductService _productService; // product service for component, might not be relevant for some component types (eg oracles)
-    }
-
-
-    modifier onlyChainNft() {
-        if(msg.sender != getRegistry().getChainNftAddress()) {
-            revert ErrorComponentNotChainNft(msg.sender);
-        }
-        _;
-    }
-
-
-    modifier onlyProductService() {
-        if(msg.sender != address(_getComponentStorage()._productService)) {
-            revert ErrorComponentNotProductService(msg.sender);
-        }
-        _;
-    }
-
-    function _getComponentStorage() private pure returns (ComponentStorage storage $) {
-        assembly {
-            $.slot := CONTRACT_LOCATION_V1
-        }
-    }
-
-    function initializeComponent(
-        address registry,
-        NftId instanceNftId,
-        string memory name,
-        address token,
-        ObjectType componentType,
-        bool isInterceptor,
-        address initialOwner,
-        bytes memory data
-    )
-        public
-        virtual
-        onlyInitializing()
-    {
-        ComponentStorage storage $ = _getComponentStorage();
-        initializeRegisterable(registry, instanceNftId, componentType, isInterceptor, initialOwner, data);
-
-        // set unique name of component
-        $._name = name;
-        $._isNftInterceptor = isInterceptor;
-
-        // set and check linked instance
-        IRegistry.ObjectInfo memory instanceInfo = getRegistry().getObjectInfo(instanceNftId);
-        $._instance = IInstance(instanceInfo.objectAddress);
-        if(!$._instance.supportsInterface(type(IInstance).interfaceId)) {
-            revert ErrorComponentNotInstance(instanceNftId, instanceInfo.objectAddress);
-        }
-
-        // initialize AccessManagedUpgradeable
-        __AccessManaged_init($._instance.authority());
-
-        // set linked services
-        VersionPart gifVersion = $._instance.getMajorVersion();
-        $._instanceService = IInstanceService(getRegistry().getServiceAddress(INSTANCE(), gifVersion));
-        $._instanceReader = $._instance.getInstanceReader();
-        $._productService = IProductService(getRegistry().getServiceAddress(PRODUCT(), gifVersion));
-
-        // set wallet and token
-        $._wallet = address(this);
-        $._token = IERC20Metadata(token);
-
-        registerInterface(type(IComponent).interfaceId);
-    }
-
-    /// @dev callback function for nft transfers. may only be called by chain nft contract.
-    /// default implementation is empty. overriding functions MUST add onlyChainNft modifier
-    function nftTransferFrom(address from, address to, uint256 tokenId)
-        external
-        virtual override
-        onlyChainNft()
-    { }
-
-    function lock() external onlyOwner override {
-        _getComponentStorage()._instanceService.setTargetLocked(getName(), true);
-    }
-    
-    function unlock() external onlyOwner override {
-        _getComponentStorage()._instanceService.setTargetLocked(getName(), false);
-    }
-
-    // only product service may set product nft id during registration of product setup
-    function setProductNftId(NftId productNftId)
-        external
-        override
-        onlyProductService() 
-    {
-        ComponentStorage storage $ = _getComponentStorage();
-
-        if($._productNftId.gtz()) {
-            revert ErrorComponentProductNftAlreadySet();
-        }
-
-        $._productNftId = productNftId;
-    }
-
-    /// @dev Sets the wallet address for the component. 
-    /// if the current wallet has tokens, these will be transferred. 
-    /// if the new wallet address is externally owned, an approval from the 
-    /// owner of the external wallet for the component to move all tokens must exist. 
-    function setWallet(address newWallet)
-        external
-        override
-        onlyOwner
-    {
-        ComponentStorage storage $ = _getComponentStorage();
-
-        address currentWallet = $._wallet;
-        uint256 currentBalance = $._token.balanceOf(currentWallet);
-
-        // checks
-        if (newWallet == address(0)) {
-            revert ErrorComponentWalletAddressZero();
-        }
-        if (newWallet == currentWallet) {
-            revert ErrorComponentWalletAddressIsSameAsCurrent(newWallet);
-        }
-
-        if (currentBalance > 0) {
-            if (currentWallet == address(this)) {
-                // move tokens from component smart contract to external wallet
-            } else {
-                // move tokens from external wallet to component smart contract or another external wallet
-                uint256 allowance = $._token.allowance(currentWallet, address(this));
-                if (allowance < currentBalance) {
-                    revert ErrorComponentWalletAllowanceTooSmall(currentWallet, newWallet, allowance, currentBalance);
-                }
-            }
-        }
-
-        // effects
-        $._wallet = newWallet;
-        emit LogComponentWalletAddressChanged(newWallet);
-
-        // interactions
-        if (currentBalance > 0) {
-            // transfer tokens from current wallet to new wallet
-            if (currentWallet == address(this)) {
-                // transferFrom requires self allowance too
-                $._token.approve(address(this), currentBalance);
-            }
-            
-            SafeERC20.safeTransferFrom($._token, currentWallet, newWallet, currentBalance);
-            emit LogComponentWalletTokensTransferred(currentWallet, newWallet, currentBalance);
-        }
-    }
-
-    function getWallet()
-        public
-        view
-        override
-        returns (address walletAddress)
-    {
-        return _getComponentStorage()._wallet;
-    }
-
-    function getToken() public view override returns (IERC20Metadata token) {
-        return _getComponentStorage()._token;
-    }
-
-    function isNftInterceptor() public view override returns(bool isInterceptor) {
-        return _getComponentStorage()._isNftInterceptor;
-    }
-
-    function getInstance() public view override returns (IInstance instance) {
-        return _getComponentStorage()._instance;
-    }
-
-    function getInstanceReader() public view returns (InstanceReader reader) {
-        return _getComponentStorage()._instanceReader;
-    }
-
-    function getServiceAddress(ObjectType domain) public view returns (address service) {
-        VersionPart majorVersion = getInstance().getMajorVersion();
-        return getRegistry().getServiceAddress(domain, majorVersion);
-    }
-
-    function getName() public view override returns(string memory name) {
-        return _getComponentStorage()._name;
-    }
-
-    function getProductNftId() public view override returns (NftId productNftId) {
-        return _getComponentStorage()._productNftId;
-    }
-
-    function getInstanceService() public view returns (IInstanceService) {
-        return _getComponentStorage()._instanceService;
-    }
-
-    function getProductService() public view returns (IProductService) {
-        return _getComponentStorage()._productService;
-    }
-
-}

package/contracts/components/IComponent.sol

@@ -1,54 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.20;
-
-import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
-
-import {IInstance} from "../instance/IInstance.sol";
-import {IInstanceService} from "../instance/IInstanceService.sol";
-import {IProductService} from "../instance/service/IProductService.sol";
-import {IRegisterable} from "../shared/IRegisterable.sol";
-import {ITransferInterceptor} from "../registry/ITransferInterceptor.sol";
-import {NftId} from "../types/NftId.sol";
-import {ObjectType} from "../types/ObjectType.sol";
-
-interface IComponent is 
-    IRegisterable,
-    ITransferInterceptor
-{
-
-    error ErrorComponentNotChainNft(address caller);
-    error ErrorComponentNotProductService(address caller);
-    error ErrorComponentNotInstance(NftId instanceNftId, address instance);
-    error ErrorComponentProductNftAlreadySet();
-    error ErrorComponentWalletAddressZero();
-    error ErrorComponentWalletAddressIsSameAsCurrent(address newWallet);
-    error ErrorComponentWalletAllowanceTooSmall(address oldWallet, address newWallet, uint256 allowance, uint256 balance);
-    error ErrorComponentUnauthorized(address caller, uint64 requiredRoleIdNum);
-
-    event LogComponentWalletAddressChanged(address newWallet);
-    event LogComponentWalletTokensTransferred(address from, address to, uint256 amount);
-
-    function getName() external view returns (string memory name);
-
-    function lock() external;
-    function unlock() external;
-
-    function getToken() external view returns (IERC20Metadata token);
-
-    function setWallet(address walletAddress) external;
-    function getWallet() external view returns (address walletAddress);
-
-    function isNftInterceptor() external view returns(bool isInterceptor);
-
-    function getInstance() external view returns (IInstance instance);
-
-    /// @dev returns the service address for the specified domain
-    /// gets address via lookup from registry using the major version form the linked instance
-    function getServiceAddress(ObjectType domain) external view returns (address service);
-
-    function setProductNftId(NftId productNftId) external;
-    function getProductNftId() external view returns (NftId productNftId);
-
-    function getInstanceService() external view returns (IInstanceService);
-    function getProductService() external view returns (IProductService);
-}

package/contracts/components/IPoolComponent.sol

@@ -1,87 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.20;
-
-import {Fee} from "../types/Fee.sol";
-import {IComponent} from "./IComponent.sol";
-import {ISetup} from "../instance/module/ISetup.sol";
-import {NftId} from "../types/NftId.sol";
-import {UFixed} from "../types/UFixed.sol";
-
-/// @dev pool components hold and manage the collateral to cover active policies
-/// pools come in different flavors
-interface IPoolComponent is IComponent {
-
-    event LogUnderwrittenByPool(NftId policyNftId, uint256 collateralizationAmount, address pool);
-
-    error ErrorPoolNotPoolService(address service);
-
-    function getSetupInfo() external view returns (ISetup.PoolSetupInfo memory setupInfo);
-
-    function setFees(
-        Fee memory poolFee,
-        Fee memory stakingFee,
-        Fee memory performanceFee
-    ) external;
-
-    /// @dev sets an additional bundle fee, this fee is added on top of the poolFee and deducted from the premium amounts.
-    /// via these fees individual bundler owner may earn income per policy in the context of peer to peer pools
-    function setBundleFee(
-        NftId bundleNftId, 
-        Fee memory fee
-    ) external;
-
-    /// @dev this is a callback function that is called by the product service when underwriting a policy.
-    /// the pool has the option to check the details and object to underwriting by reverting.
-    /// the function is only called for "active" pools that ask to be involved/notified
-    /// by product related state changes.
-    function verifyApplication(
-        NftId applicationNftId, 
-        bytes memory policyData,
-        bytes memory bundleFilter,
-        uint256 collateralizationAmount
-    ) external;
-
-    function lockBundle(NftId bundleNftId) external;
-
-    function unlockBundle(NftId bundleNftId) external;
-
-    /// @dev defines the multiplier to calculate the required collateral to cover a given sum insured amount
-    /// default implementation returns 100%
-    function getCollateralizationLevel() external view returns (UFixed collateralizationLevel);
-
-    /// @dev defines the amount of collateral held in the pool.
-    /// if the value is < 100% the pool is required to hold a policy that covers the locally missing collateral
-    /// default implementation returns 100%
-    function getRetentionLevel() external view returns (UFixed retentionLevel);
-
-    /// @dev declares if pool intercept transfers of bundle nft ids
-    /// - yes: pool may block transfer of bundle ownership or simply updates some bookkeeping related to bundle ownership. callback function is nftTransferFrom
-    /// - no: pool is not involved in transfer of bundle ownership
-    /// default implementation returns false (no)
-    function isInterceptingBundleTransfers() external view returns (bool);
-
-    /// @dev declares if pool relies on external management of collateral (yes/no): 
-    /// - yes: underwriting of new policies does not require an actual token balance, instead it is assumed that the pool owner will manage funds externally and inject enough tokens to allow process confirmed payouts
-    /// - no: the pool smart contract ensures that the necessary capacity of the pool prior to underwriting.
-    /// default implementation returns false (no)
-    function isExternallyManaged() external view returns (bool);
-
-    /// @dev declares if pool component is actively involved in underwriting (yes/no): 
-    /// - yes: verifying pools components actively confirm underwriting applications, ie the pool component logic explicitly needs to confirm the locking of collateral to cover the sum insured of the policy
-    /// - no: underwriting a policy does not require any interaction with the pool component if the covering bundle can provide the necessary captial
-    /// default implementation returnsfalse (no)
-    function isVerifyingApplications() external view returns (bool);
-
-    /// @dev returns true iff the policy application data in policyData matches
-    /// with the bundle filter criteria encoded in bundleFilter
-    /// this is a callback function that is only called if a pool declares itself as a verifying pool
-    /// default implementation returns true
-    function policyMatchesBundle(
-        bytes memory policyData,
-        bytes memory bundleFilter
-    )
-        external
-        view
-        returns (bool isMatching);
-
-}

package/contracts/components/IProductComponent.sol

@@ -1,39 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.20;
-
-import {Fee} from "../types/Fee.sol";
-import {IComponent} from "./IComponent.sol";
-import {ISetup} from "../instance/module/ISetup.sol";
-import {NftId} from "../types/NftId.sol";
-import {ReferralId} from "../types/Referral.sol";
-import {RiskId} from "../types/RiskId.sol";
-
-interface IProductComponent is IComponent {
-
-    function getSetupInfo() external view returns (ISetup.ProductSetupInfo memory setupInfo);
-
-    function setFees(
-        Fee memory productFee,
-        Fee memory processingFee
-    ) external;
-
-    function calculatePremium(
-        uint256 sumInsuredAmount,
-        RiskId riskId,
-        uint256 lifetime,
-        bytes memory applicationData,
-        NftId bundleNftId,
-        ReferralId referralId
-    ) external view returns (uint256 premiumAmount);
-
-    function calculateNetPremium(
-        uint256 sumInsuredAmount,
-        RiskId riskId,
-        uint256 lifetime,
-        bytes memory applicationData
-    ) external view returns (uint256 netPremiumAmount);    
-
-    
-    function getPoolNftId() external view returns (NftId poolNftId);
-    function getDistributionNftId() external view returns (NftId distributionNftId);
-}

package/contracts/components/Pool.sol

@@ -1,254 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.20;
-
-import {POOL} from "../types/ObjectType.sol";
-import {IPoolService} from "../instance/service/IPoolService.sol";
-import {IBundleService} from "../instance/service/IBundleService.sol";
-import {NftId, NftIdLib} from "../types/NftId.sol";
-import {Fee, FeeLib} from "../types/Fee.sol";
-import {UFixed} from "../types/UFixed.sol";
-import {IPoolComponent} from "./IPoolComponent.sol";
-import {Component} from "./Component.sol";
-import {TokenHandler} from "../shared/TokenHandler.sol";
-import {ISetup} from "../instance/module/ISetup.sol";
-
-import {ISetup} from "../instance/module/ISetup.sol";
-import {InstanceReader} from "../instance/InstanceReader.sol";
-
-
-abstract contract Pool is
-    Component, 
-    IPoolComponent 
-{
-    // keccak256(abi.encode(uint256(keccak256("etherisc.storage.Pool")) - 1)) & ~bytes32(uint256(0xff));
-    bytes32 public constant POOL_STORAGE_LOCATION_V1 = 0x25e3e51823fbfffb988e0a2744bb93722d9f3e906c07cc0a9e77884c46c58300;
-
-    struct PoolStorage {
-        UFixed _collateralizationLevel;
-        UFixed _retentionLevel;
-
-        bool _isExternallyManaged;
-        bool _isInterceptingBundleTransfers;
-        bool _isVerifyingApplications;
-
-        Fee _initialPoolFee;
-        Fee _initialStakingFee;
-        Fee _initialPerformanceFee;
-
-        TokenHandler _tokenHandler;
-
-        // may be used to interact with instance by derived contracts
-        IPoolService _poolService;
-        IBundleService _bundleService;
-    }
-
-    modifier onlyPoolService() {
-        if(msg.sender != address(_getPoolStorage()._poolService)) {
-            revert ErrorPoolNotPoolService(msg.sender);
-        }
-        _;
-    }
-
-
-    function initializePool(
-        address registry,
-        NftId instanceNftId,
-        string memory name,
-        // TODO refactor into tokenNftId
-        address token,
-        bool isInterceptingNftTransfers,
-        bool isExternallyManaging,
-        bool isVerifying,
-        UFixed collateralizationLevel,
-        UFixed retentionLevel,
-        address initialOwner,
-        bytes memory data
-    )
-        public
-        virtual
-        onlyInitializing()
-    {
-        initializeComponent(registry, instanceNftId, name, token, POOL(), isInterceptingNftTransfers, initialOwner, data);
-
-        PoolStorage storage $ = _getPoolStorage();
-        // TODO add validation
-        $._tokenHandler = new TokenHandler(token);
-        $._isExternallyManaged = isExternallyManaging;
-        $._isVerifyingApplications = isVerifying;
-        $._collateralizationLevel = collateralizationLevel;
-        $._retentionLevel = retentionLevel;
-        $._initialPoolFee = FeeLib.zeroFee();
-        $._initialStakingFee = FeeLib.zeroFee();
-        $._initialPerformanceFee = FeeLib.zeroFee();
-        $._poolService = getInstance().getPoolService();
-        $._bundleService = getInstance().getBundleService();
-
-        registerInterface(type(IPoolComponent).interfaceId);
-    }
-
-    /**
-     * @dev see {IPool.verifyApplication}. 
-     * Default implementation that only writes a {LogUnderwrittenByPool} entry.
-     */
-    function verifyApplication(
-        NftId applicationNftId, 
-        bytes memory applicationData,
-        bytes memory bundleFilter,
-        uint256 collateralizationAmount
-    )
-        external
-        restricted()
-        virtual override 
-    {
-        require(
-            policyMatchesBundle(applicationData, bundleFilter),
-            "ERROR:POL-020:POLICY_BUNDLE_MISMATCH"
-        );
-
-        emit LogUnderwrittenByPool(applicationNftId, collateralizationAmount, address(this));
-    }
-
-
-    function isInterceptingBundleTransfers() external view override returns (bool) {
-        return isNftInterceptor();
-    }
-
-
-    function isExternallyManaged() external view override returns (bool) {
-        return _getPoolStorage()._isExternallyManaged;
-    }
-
-
-    function getRetentionLevel() external view override returns (UFixed retentionLevel) {
-        return _getPoolStorage()._retentionLevel;
-    }
-
-
-    function getCollateralizationLevel() external view override returns (UFixed collateralizationLevel) {
-        return _getPoolStorage()._collateralizationLevel;
-    }
-
-
-    function isVerifyingApplications() external view override returns (bool isConfirmingApplication) {
-        return _getPoolStorage()._isVerifyingApplications;
-    }
-
-
-    /// @dev see {IPoolComponent.policyMatchesBundle}. 
-    /// Default implementation always returns true
-    function policyMatchesBundle(
-        bytes memory, // policyData
-        bytes memory // bundleFilter
-    )
-        public
-        pure
-        virtual override
-        returns (bool isMatching)
-    {
-        return true;
-    }
-
-
-    function setFees(
-        Fee memory poolFee,
-        Fee memory stakingFee,
-        Fee memory performanceFee
-    )
-        external
-        onlyOwner
-        restricted()
-        override
-    {
-        _getPoolStorage()._poolService.setFees(poolFee, stakingFee, performanceFee);
-    }
-
-    function setBundleFee(
-        NftId bundleNftId, 
-        Fee memory fee
-    )
-        external
-        override
-        // TODO add onlyBundleOwner
-    {
-        _getPoolStorage()._bundleService.setBundleFee(bundleNftId, fee);
-    }
-
-    function lockBundle(
-        NftId bundleNftId
-    )
-        external
-        override
-        // TODO add onlyBundleOwner
-    {
-        _getPoolStorage()._bundleService.lockBundle(bundleNftId);
-    }
-
-    function unlockBundle(
-        NftId bundleNftId
-    )
-        external
-        override
-        // TODO add onlyBundleOwner
-    {
-        _getPoolStorage()._bundleService.unlockBundle(bundleNftId);
-    }
-
-    function getSetupInfo() public view returns (ISetup.PoolSetupInfo memory setupInfo) {
-        InstanceReader reader = getInstance().getInstanceReader();
-        setupInfo = reader.getPoolSetupInfo(getNftId());
-
-        // fallback to initial setup info (wallet is always != address(0))
-        if(setupInfo.wallet == address(0)) {
-            setupInfo = _getInitialSetupInfo();
-        }
-    }
-
-    function _getInitialSetupInfo() internal view returns (ISetup.PoolSetupInfo memory) {
-        PoolStorage storage $ = _getPoolStorage();
-        return ISetup.PoolSetupInfo(
-            getProductNftId(),
-            $._tokenHandler,
-            isNftInterceptor(),
-            $._isExternallyManaged,
-            $._isVerifyingApplications,
-            $._collateralizationLevel,
-            $._retentionLevel,
-            $._initialPoolFee,
-            $._initialStakingFee,
-            $._initialPerformanceFee,
-            getWallet()
-        );
-    }
-
-    // Internals
-
-    function _createBundle(
-        address bundleOwner,
-        Fee memory fee,
-        uint256 amount,
-        uint256 lifetime, 
-        bytes memory filter
-    )
-        internal
-        returns(NftId bundleNftId)
-    {
-        bundleNftId = _getPoolStorage()._bundleService.createBundle(
-            bundleOwner,
-            fee,
-            amount,
-            lifetime,
-            filter);
-
-        // TODO add logging
-    }
-
-    function getContractLocation(bytes memory name) external pure returns (bytes32 hash) {
-        return keccak256(abi.encode(uint256(keccak256(name)) - 1)) & ~bytes32(uint256(0xff));
-    }
-
-    function _getPoolStorage() private pure returns (PoolStorage storage $) {
-        assembly {
-            $.slot := POOL_STORAGE_LOCATION_V1
-        }
-    }
-}