@etherisc/gif-next 0.0.2-ce8407f-016 → 0.0.2-cf68d0c-530

package/contracts/components/IDistributionComponent.sol

@@ -0,0 +1,46 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Fee} from "../types/Fee.sol";
+import {ReferralId} from "../types/Referral.sol";
+import {NftId} from "../types/NftId.sol";
+import {ISetup} from "../instance/module/ISetup.sol";
+
+interface IDistributionComponent {
+
+    function getInitialSetupInfo() external view returns (ISetup.DistributionSetupInfo memory setupInfo);
+
+    function setFees(
+        Fee memory distributionFee
+    ) external;
+
+    function calculateFeeAmount(
+        ReferralId referralId,
+        uint256 netPremiumAmount
+    ) external view returns (uint256 feeAmount);
+
+    function calculateRenewalFeeAmount(
+        ReferralId referralId,
+        uint256 netPremiumAmount
+    ) external view returns (uint256 feeAmount);
+
+    /// @dev callback from product service when selling a policy for a specific referralId
+    /// the used referral id and the collected fee are provided as parameters
+    /// the component implementation can then process this information accordingly
+    function processSale(
+        ReferralId referralId,
+        uint256 feeAmount
+    ) external;
+
+    /// @dev callback from product service when a policy is renews for a specific referralId
+    function processRenewal(
+        ReferralId referralId,
+        uint256 feeAmount
+    ) external;
+
+    /// @dev returns true iff the referral id is valid
+    function referralIsValid(ReferralId referralId) external view returns (bool isValid);
+
+    /// @dev returns true iff the component needs to be called when selling/renewing policis
+    function isVerifying() external view returns (bool verifying);
+}

package/contracts/components/IPoolComponent.sol

@@ -0,0 +1,62 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {NftId} from "../types/NftId.sol";
+import {Fee} from "../types/Fee.sol";
+import {UFixed} from "../types/UFixed.sol";
+
+interface IPoolComponent {
+
+    event LogUnderwrittenByPool(NftId policyNftId, uint256 collateralizationAmount, address pool);
+
+    function setFees(
+        Fee memory poolFee,
+        Fee memory stakingFee,
+        Fee memory performanceFee
+    ) external;
+
+    /**
+     * @dev creates a new bundle for this pool.
+     */
+    function createBundle(
+        Fee memory fee,
+        uint256 initialAmount,
+        uint256 lifetime,
+        bytes memory filter
+    ) external returns(NftId bundleNftId);
+
+    function setBundleFee(
+        NftId policyNftId, 
+        Fee memory fee
+    ) external;
+
+    /** 
+     * @dev this is a callback function that is called by the product service when underwriting a policy.
+     * the pool has the option to check the details and object to underwriting by reverting.
+     * the function is only called for "active" pools that ask to be involved/notified
+     * by product related state changes.
+     */
+    function underwrite(
+        NftId policyNftId, 
+        bytes memory policyData,
+        bytes memory bundleFilter,
+        uint256 collateralizationAmount
+    ) external;
+
+    /**
+     * @dev returns true iff the policy application data in policyData matches
+     * with the bundle filter criteria encoded in bundleFilter. 
+     */
+    function policyMatchesBundle(
+        bytes memory policyData,
+        bytes memory bundleFilter
+    )
+        external
+        view
+        returns (bool isMatching);
+
+    function isVerifying() external view returns (bool verifying);
+
+    function getCollateralizationLevel() external view returns (UFixed collateralizationLevel);
+
+}

package/contracts/components/IProductComponent.sol

@@ -0,0 +1,35 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Fee} from "../types/Fee.sol";
+import {NftId} from "../types/NftId.sol";
+import {ReferralId} from "../types/Referral.sol";
+import {RiskId} from "../types/RiskId.sol";
+
+interface IProductComponent {
+
+    function setFees(
+        Fee memory productFee,
+        Fee memory processingFee
+    ) external;
+
+    function calculatePremium(
+        uint256 sumInsuredAmount,
+        RiskId riskId,
+        uint256 lifetime,
+        bytes memory applicationData,
+        ReferralId referralId,
+        NftId bundleNftId
+    ) external view returns (uint256 premiumAmount);
+
+    function calculateNetPremium(
+        uint256 sumInsuredAmount,
+        RiskId riskId,
+        uint256 lifetime,
+        bytes memory applicationData
+    ) external view returns (uint256 netPremiumAmount);    
+
+    
+    function getPoolNftId() external view returns (NftId poolNftId);
+    function getDistributionNftId() external view returns (NftId distributionNftId);
+}

package/contracts/components/Pool.sol

@@ -0,0 +1,258 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ObjectType, POOL} from "../types/ObjectType.sol";
+import {IProductService} from "../instance/service/IProductService.sol";
+import {IPoolService} from "../instance/service/IPoolService.sol";
+import {NftId, zeroNftId, NftIdLib} from "../types/NftId.sol";
+import {Fee} from "../types/Fee.sol";
+import {UFixed} from "../types/UFixed.sol";
+import {IPoolComponent} from "./IPoolComponent.sol";
+import {BaseComponent} from "./BaseComponent.sol";
+import {TokenHandler} from "../shared/TokenHandler.sol";
+import {ISetup} from "../instance/module/ISetup.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+
+// import {IPool} from "../instance/module/pool/IPoolModule.sol";
+import {ITreasury} from "../instance/module/ITreasury.sol";
+import {ISetup} from "../instance/module/ISetup.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+
+import {IRegisterable} from "../shared/IRegisterable.sol";
+import {Registerable} from "../shared/Registerable.sol";
+
+contract Pool is BaseComponent, IPoolComponent {
+    using NftIdLib for NftId;
+
+    bool internal _isVerifying;
+    UFixed internal _collateralizationLevel;
+
+    Fee internal _initialPoolFee;
+    Fee internal _initialStakingFee;
+    Fee internal _initialPerformanceFee;
+
+    // may be used to interact with instance by derived contracts
+    IPoolService internal _poolService;
+
+    // only relevant to protect callback functions for "active" pools
+    IProductService private _productService;
+
+    modifier onlyPoolService() {
+        require(
+            msg.sender == address(_poolService), 
+            "ERROR:POL-001:NOT_POOL_SERVICE");
+        _;
+    }
+
+    modifier onlyProductService() {
+        require(
+            msg.sender == address(_productService), 
+            "ERROR:POL-002:NOT_PRODUCT_SERVICE");
+        _;
+    }
+
+    constructor(
+        address registry,
+        NftId instanceNftId,
+        // TODO refactor into tokenNftId
+        address token,
+        bool isInterceptor,
+        bool verifying,
+        UFixed collateralizationLevel,
+        Fee memory poolFee,
+        Fee memory stakingFee,
+        Fee memory performanceFee,
+        address initialOwner
+    )
+        BaseComponent(registry, instanceNftId, token, POOL(), isInterceptor, initialOwner)
+    {
+        _isVerifying = verifying;
+        // TODO add validation
+        _collateralizationLevel = collateralizationLevel;
+        _initialPoolFee = poolFee;
+        _initialStakingFee = stakingFee;
+        _initialPerformanceFee = performanceFee;
+
+        // TODO: reactivate when services are available again
+        // _poolService = _instance.getPoolService();
+        // _productService = _instance.getProductService();
+
+        _registerInterface(type(IPoolComponent).interfaceId);
+    }
+
+    function createBundle(
+        Fee memory fee,
+        uint256 initialAmount,
+        uint256 lifetime,
+        bytes memory filter
+    )
+        external
+        virtual override
+        returns(NftId bundleNftId)
+    {
+        address owner = msg.sender;
+        bundleNftId = _poolService.createBundle(
+            owner,
+            fee,
+            initialAmount,
+            lifetime,
+            filter
+        );
+
+        // TODO add logging
+    }
+
+    /**
+     * @dev see {IPool.underwrite}. 
+     * Default implementation that only writes a {LogUnderwrittenByPool} entry.
+     */
+    function underwrite(
+        NftId policyNftId, 
+        bytes memory policyData,
+        bytes memory bundleFilter,
+        uint256 collateralizationAmount
+    )
+        external
+        onlyProductService
+        virtual override 
+    {
+        _underwrite(policyNftId, policyData, bundleFilter, collateralizationAmount);
+    }
+
+    /**
+     * @dev see {IPoolComponent.policyMatchesBundle}. 
+     * Default implementation always returns true
+     */
+    function policyMatchesBundle(
+        bytes memory, // policyData
+        bytes memory // bundleFilter
+    )
+        public
+        view
+        virtual override
+        returns (bool isMatching)
+    {
+        return true;
+    }
+
+
+    function isVerifying() external view override returns (bool verifying) {
+        return _isVerifying;
+    }
+
+    function getCollateralizationLevel() external view override returns (UFixed collateralizationLevel) {
+        return _collateralizationLevel;
+    }
+
+    function setFees(
+        Fee memory poolFee,
+        Fee memory stakingFee,
+        Fee memory performanceFee
+    )
+        external
+        onlyOwner
+        override
+    {
+        _poolService.setFees(poolFee, stakingFee, performanceFee);
+    }
+
+    function setBundleFee(
+        NftId bundleNftId, 
+        Fee memory fee
+    )
+        external
+        override
+        // TODO add onlyBundleOwner
+    {
+        _poolService.setBundleFee(bundleNftId, fee);
+    }
+
+    function getSetupInfo() public view returns (ISetup.PoolSetupInfo memory setupInfo) {
+        // TODO fix this
+        if (getNftId().eq(zeroNftId())) {
+            return ISetup.PoolSetupInfo(
+                _productNftId,
+                TokenHandler(address(0)),
+                _collateralizationLevel,
+                _initialPoolFee,
+                _initialStakingFee,
+                _initialPerformanceFee,
+                _isVerifying,
+                _wallet
+            );
+        } 
+
+        InstanceReader reader = _instance.getInstanceReader();
+        return reader.getPoolSetupInfo(getNftId());
+    }
+
+    // from IRegisterable
+
+    // TODO used only once, occupies space
+    // TODO do not use super
+    function getInitialInfo() 
+        public
+        view
+        override (IRegisterable, Registerable)
+        returns (IRegistry.ObjectInfo memory, bytes memory)
+    {
+        (
+            IRegistry.ObjectInfo memory info, 
+            bytes memory data
+        ) = super.getInitialInfo();
+
+        return (
+            info,
+            abi.encode(
+                ISetup.PoolSetupInfo(
+                    getProductNftId(),
+                    TokenHandler(address(0)),
+                    _collateralizationLevel,
+                    _initialPoolFee,
+                    _initialStakingFee,
+                    _initialPerformanceFee,
+                    _isVerifying,
+                    _wallet
+                )
+            )
+        );
+    }
+
+    // Internals
+
+    function _underwrite(
+        NftId policyNftId, 
+        bytes memory policyData,
+        bytes memory bundleFilter,
+        uint256 collateralizationAmount
+    )
+        internal 
+    {
+        require(
+            policyMatchesBundle(policyData, bundleFilter),
+            "ERROR:POL-020:POLICY_BUNDLE_MISMATCH"
+        );
+
+        emit LogUnderwrittenByPool(policyNftId, collateralizationAmount, address(this));
+    }
+
+    function _createBundle(
+        address bundleOwner,
+        Fee memory fee,
+        uint256 amount,
+        uint256 lifetime, 
+        bytes calldata filter
+    )
+        internal
+        returns(NftId bundleNftId)
+    {
+        bundleNftId = _poolService.createBundle(
+            bundleOwner,
+            fee,
+            amount,
+            lifetime,
+            filter
+        );
+    }
+}

package/contracts/components/Product.sol

@@ -0,0 +1,297 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {IRisk} from "../instance/module/IRisk.sol";
+import {ITreasury} from "../instance/module/ITreasury.sol";
+import {IProductService} from "../instance/service/IProductService.sol";
+import {IProductComponent} from "./IProductComponent.sol";
+import {NftId, zeroNftId, NftIdLib} from "../types/NftId.sol";
+import {ObjectType, PRODUCT} from "../types/ObjectType.sol";
+import {ReferralId} from "../types/Referral.sol";
+import {RiskId, RiskIdLib} from "../types/RiskId.sol";
+import {StateId} from "../types/StateId.sol";
+import {Timestamp} from "../types/Timestamp.sol";
+import {Fee, FeeLib} from "../types/Fee.sol";
+import {BaseComponent} from "./BaseComponent.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IRegisterable} from "../shared/IRegisterable.sol";
+import {Registerable} from "../shared/Registerable.sol";
+import {TokenHandler} from "../shared/TokenHandler.sol";
+
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {ISetup} from "../instance/module/ISetup.sol";
+import {Pool} from "../components/Pool.sol";
+
+import {zeroNftId} from "../types/NftId.sol";
+
+contract Product is BaseComponent, IProductComponent {
+    using NftIdLib for NftId;
+
+    IProductService internal _productService;
+    Pool internal _pool;
+    address internal _distribution;
+    Fee internal _initialProductFee;
+    Fee internal _initialProcessingFee;
+
+    NftId internal _poolNftId;
+    NftId internal _distributionNftId;
+
+    constructor(
+        address registry,
+        NftId instanceNftid,
+        address token,
+        bool isInterceptor,
+        address pool,
+        address distribution,
+        Fee memory productFee,
+        Fee memory processingFee,
+        address initialOwner
+    ) BaseComponent(registry, instanceNftid, token, PRODUCT(), isInterceptor, initialOwner) {
+        // TODO add validation
+        // TODO: reactivate when services are available again
+        // _productService = _instance.getProductService();
+        _pool = Pool(pool);
+        _distribution = distribution;
+        _initialProductFee = productFee;
+        _initialProcessingFee = processingFee;  
+
+        _poolNftId = getRegistry().getNftId(address(_pool));
+        _distributionNftId = getRegistry().getNftId(_distribution);
+
+        _registerInterface(type(IProductComponent).interfaceId);  
+    }
+
+
+    function calculatePremium(
+        uint256 sumInsuredAmount,
+        RiskId riskId,
+        uint256 lifetime,
+        bytes memory applicationData,
+        ReferralId referralId,
+        NftId bundleNftId
+    )
+        external 
+        view 
+        override 
+        returns (uint256 premiumAmount)
+    {
+        (premiumAmount,,,,) = _productService.calculatePremium(
+            riskId,
+            sumInsuredAmount,
+            lifetime,
+            applicationData,
+            bundleNftId,
+            referralId
+        );
+    }
+
+
+    function calculateNetPremium(
+        uint256 sumInsuredAmount,
+        RiskId riskId,
+        uint256 lifetime,
+        bytes memory applicationData
+    )
+        external
+        view
+        virtual override
+        returns (uint256 netPremiumAmount)
+    {
+        // default 10% of sum insured
+        return sumInsuredAmount / 10;
+    }
+
+    function _toRiskId(string memory riskName) internal pure returns (RiskId riskId) {
+        return RiskIdLib.toRiskId(riskName);
+    }
+
+    function _createRisk(
+        RiskId id,
+        bytes memory data
+    ) internal {
+        _productService.createRisk(
+            id,
+            data
+        );
+    }
+
+    function _setRiskInfo(
+        RiskId id,
+        IRisk.RiskInfo memory info
+    ) internal {
+        _productService.setRiskInfo(
+            id,
+            info
+        );
+    }
+
+    function _updateRiskState(
+        RiskId id,
+        StateId state
+    ) internal {
+        _productService.updateRiskState(
+            id,
+            state
+        );
+    }
+
+    function _getRiskInfo(RiskId id) internal view returns (IRisk.RiskInfo memory info) {
+        return _instance.getInstanceReader().getRiskInfo(id);
+    }
+
+    function _createApplication(
+        address applicationOwner,
+        RiskId riskId,
+        uint256 sumInsuredAmount,
+        uint256 lifetime,
+        bytes memory applicationData,
+        NftId bundleNftId,
+        ReferralId referralId
+    ) internal returns (NftId nftId) {
+        nftId = _productService.createApplication(
+            applicationOwner,
+            riskId,
+            sumInsuredAmount,
+            lifetime,
+            applicationData,
+            bundleNftId,
+            referralId
+        );
+    }
+
+    function _underwrite(
+        NftId policyNftId,
+        bool requirePremiumPayment,
+        Timestamp activateAt
+    )
+        internal
+    {
+        _productService.underwrite(
+            policyNftId, 
+            requirePremiumPayment, 
+            activateAt);
+    }
+
+    function _collectPremium(
+        NftId policyNftId,
+        Timestamp activateAt
+    )
+        internal
+    {
+        _productService.collectPremium(
+            policyNftId, 
+            activateAt);
+    }
+
+    function _activate(
+        NftId policyNftId,
+        Timestamp activateAt
+    )
+        internal
+    {
+        _productService.activate(
+            policyNftId, 
+            activateAt);
+    }
+
+    function getPoolNftId() external view override returns (NftId poolNftId) {
+        return getRegistry().getNftId(address(_pool));
+    }
+
+    function getDistributionNftId() external view override returns (NftId distributionNftId) {
+        return getRegistry().getNftId(_distribution);
+    }
+
+    // from product component
+    function setFees(
+        Fee memory productFee,
+        Fee memory processingFee
+    )
+        external
+        onlyOwner
+        override
+    {
+        _productService.setFees(productFee, processingFee);
+    }
+
+    function getSetupInfo() public view returns (ISetup.ProductSetupInfo memory setupInfo) {
+        if (getNftId().eq(zeroNftId())) {
+            return ISetup.ProductSetupInfo(
+                _token,
+                TokenHandler(address(0)),
+                _distributionNftId,
+                _poolNftId,
+                FeeLib.zeroFee(), //_instance.getDistributionFee(_distributionNftId)
+                _initialProductFee,
+                _initialProcessingFee,
+                FeeLib.zeroFee(), //_instance.getPoolFee(_poolNftId)
+                FeeLib.zeroFee(), //_instance.getStakingFee(_poolNftId)
+                FeeLib.zeroFee() //_instance.getPerformanceFee(_poolNftId)
+            );
+        } 
+
+        InstanceReader reader = _instance.getInstanceReader();
+        return reader.getProductSetupInfo(getNftId());
+    }
+
+    // from IRegisterable
+
+    // TODO used only once, occupies space
+    function getInitialInfo() 
+        public
+        view 
+        override (IRegisterable, Registerable)
+        returns (IRegistry.ObjectInfo memory, bytes memory)
+    {
+        // from Registerable
+        (
+            IRegistry.ObjectInfo memory productInfo, 
+            bytes memory data
+        ) = super.getInitialInfo();
+ 
+        // TODO read pool & distribution fees
+        // 1) from pool -> the only option -> pool must be registered first?
+        // 2) from instance -> all fees are set into instance at product registration which is ongoing here
+        // checks are done in registryProduct() where THIS function is called
+        //require(getRegistry().getObjectInfo(_poolNftId).objectType == POOL(), "POOL_NOT_REGISTERED");
+        //require(getRegistry().getObjectInfo(_distributionNftId).objectType == DISTRIBUTION(), "DISTRIBUTION_NOT_REGISTERED");
+        
+        // from PoolComponent
+        (
+            IRegistry.ObjectInfo memory poolInfo, 
+            bytes memory poolData
+        ) = _pool.getInitialInfo();
+
+        (
+            /*IPool.PoolInfo memory info*/,
+            /*address wallet*/,
+            /*IERC20Metadata token*/,
+            Fee memory initialPoolFee,
+            Fee memory initialStakingFee,
+            Fee memory initialPerformanceFee
+        )  = abi.decode(poolData, (ISetup.PoolSetupInfo, address, IERC20Metadata, Fee, Fee, Fee));
+
+        // TODO from DistributionComponent
+
+        return (
+            productInfo,
+            abi.encode(
+                ISetup.ProductSetupInfo(
+                    _token,
+                    TokenHandler(address(0)),
+                    _distributionNftId,
+                    _poolNftId,
+                    FeeLib.zeroFee(), //_instance.getDistributionFee(_distributionNftId)
+                    _initialProductFee,
+                    _initialProcessingFee,
+                    initialPoolFee,
+                    initialStakingFee,
+                    initialPerformanceFee
+                )
+            )
+        );
+    }
+}